runtime/syntax/2html.vim

   1 " Vim syntax support file
   2 " Maintainer: Bram Moolenaar <Bram@vim.org>
   3 " Last Change: 2009 Jan 13
   4 "              (modified by David Ne\v{c}as (Yeti) <yeti@physics.muni.cz>)
   5 "              (XHTML support by Panagiotis Issaris <takis@lumumba.luc.ac.be>)
   6 "              (made w3 compliant by Edd Barrett <vext01@gmail.com>)
   7 "              (added html_font. Edd Barrett <vext01@gmail.com>)
   8
   9 " Transform a file into HTML, using the current syntax highlighting.
  10
  11 " Number lines when explicitely requested or when `number' is set
  12 if exists("html_number_lines")
  13   let s:numblines = html_number_lines
  14 else
  15   let s:numblines = &number
  16 endif
  17
  18 " Font
  19 if exists("html_font")
  20   let s:htmlfont = html_font . ", monospace"
  21 else
  22   let s:htmlfont = "monospace"
  23 endif
  24
  25 " When not in gui we can only guess the colors.
  26 if has("gui_running")
  27   let s:whatterm = "gui"
  28 else
  29   let s:whatterm = "cterm"
  30   if &t_Co == 8
  31     let s:cterm_color = {0: "#808080", 1: "#ff6060", 2: "#00ff00", 3: "#ffff00", 4: "#8080ff", 5: "#ff40ff", 6: "#00ffff", 7: "#ffffff"}
  32   else
  33     let s:cterm_color = {0: "#000000", 1: "#c00000", 2: "#008000", 3: "#804000", 4: "#0000c0", 5: "#c000c0", 6: "#008080", 7: "#c0c0c0", 8: "#808080", 9: "#ff6060", 10: "#00ff00", 11: "#ffff00", 12: "#8080ff", 13: "#ff40ff", 14: "#00ffff", 15: "#ffffff"}
  34
  35     " Colors for 88 and 256 come from xterm.
  36     if &t_Co == 88
  37       call extend(s:cterm_color, {16: "#000000", 17: "#00008b", 18: "#0000cd", 19: "#0000ff", 20: "#008b00", 21: "#008b8b", 22: "#008bcd", 23: "#008bff", 24: "#00cd00", 25: "#00cd8b", 26: "#00cdcd", 27: "#00cdff", 28: "#00ff00", 29: "#00ff8b", 30: "#00ffcd", 31: "#00ffff", 32: "#8b0000", 33: "#8b008b", 34: "#8b00cd", 35: "#8b00ff", 36: "#8b8b00", 37: "#8b8b8b", 38: "#8b8bcd", 39: "#8b8bff", 40: "#8bcd00", 41: "#8bcd8b", 42: "#8bcdcd", 43: "#8bcdff", 44: "#8bff00", 45: "#8bff8b", 46: "#8bffcd", 47: "#8bffff", 48: "#cd0000", 49: "#cd008b", 50: "#cd00cd", 51: "#cd00ff", 52: "#cd8b00", 53: "#cd8b8b", 54: "#cd8bcd", 55: "#cd8bff", 56: "#cdcd00", 57: "#cdcd8b", 58: "#cdcdcd", 59: "#cdcdff", 60: "#cdff00", 61: "#cdff8b", 62: "#cdffcd", 63: "#cdffff", 64: "#ff0000"})
  38       call extend(s:cterm_color, {65: "#ff008b", 66: "#ff00cd", 67: "#ff00ff", 68: "#ff8b00", 69: "#ff8b8b", 70: "#ff8bcd", 71: "#ff8bff", 72: "#ffcd00", 73: "#ffcd8b", 74: "#ffcdcd", 75: "#ffcdff", 76: "#ffff00", 77: "#ffff8b", 78: "#ffffcd", 79: "#ffffff", 80: "#2e2e2e", 81: "#5c5c5c", 82: "#737373", 83: "#8b8b8b", 84: "#a2a2a2", 85: "#b9b9b9", 86: "#d0d0d0", 87: "#e7e7e7"})
  39     elseif &t_Co == 256
  40       call extend(s:cterm_color, {16: "#000000", 17: "#00005f", 18: "#000087", 19: "#0000af", 20: "#0000d7", 21: "#0000ff", 22: "#005f00", 23: "#005f5f", 24: "#005f87", 25: "#005faf", 26: "#005fd7", 27: "#005fff", 28: "#008700", 29: "#00875f", 30: "#008787", 31: "#0087af", 32: "#0087d7", 33: "#0087ff", 34: "#00af00", 35: "#00af5f", 36: "#00af87", 37: "#00afaf", 38: "#00afd7", 39: "#00afff", 40: "#00d700", 41: "#00d75f", 42: "#00d787", 43: "#00d7af", 44: "#00d7d7", 45: "#00d7ff", 46: "#00ff00", 47: "#00ff5f", 48: "#00ff87", 49: "#00ffaf", 50: "#00ffd7", 51: "#00ffff", 52: "#5f0000", 53: "#5f005f", 54: "#5f0087", 55: "#5f00af", 56: "#5f00d7", 57: "#5f00ff", 58: "#5f5f00", 59: "#5f5f5f", 60: "#5f5f87", 61: "#5f5faf", 62: "#5f5fd7", 63: "#5f5fff", 64: "#5f8700"})
  41       call extend(s:cterm_color, {65: "#5f875f", 66: "#5f8787", 67: "#5f87af", 68: "#5f87d7", 69: "#5f87ff", 70: "#5faf00", 71: "#5faf5f", 72: "#5faf87", 73: "#5fafaf", 74: "#5fafd7", 75: "#5fafff", 76: "#5fd700", 77: "#5fd75f", 78: "#5fd787", 79: "#5fd7af", 80: "#5fd7d7", 81: "#5fd7ff", 82: "#5fff00", 83: "#5fff5f", 84: "#5fff87", 85: "#5fffaf", 86: "#5fffd7", 87: "#5fffff", 88: "#870000", 89: "#87005f", 90: "#870087", 91: "#8700af", 92: "#8700d7", 93: "#8700ff", 94: "#875f00", 95: "#875f5f", 96: "#875f87", 97: "#875faf", 98: "#875fd7", 99: "#875fff", 100: "#878700", 101: "#87875f", 102: "#878787", 103: "#8787af", 104: "#8787d7", 105: "#8787ff", 106: "#87af00", 107: "#87af5f", 108: "#87af87", 109: "#87afaf", 110: "#87afd7", 111: "#87afff", 112: "#87d700"})
  42       call extend(s:cterm_color, {113: "#87d75f", 114: "#87d787", 115: "#87d7af", 116: "#87d7d7", 117: "#87d7ff", 118: "#87ff00", 119: "#87ff5f", 120: "#87ff87", 121: "#87ffaf", 122: "#87ffd7", 123: "#87ffff", 124: "#af0000", 125: "#af005f", 126: "#af0087", 127: "#af00af", 128: "#af00d7", 129: "#af00ff", 130: "#af5f00", 131: "#af5f5f", 132: "#af5f87", 133: "#af5faf", 134: "#af5fd7", 135: "#af5fff", 136: "#af8700", 137: "#af875f", 138: "#af8787", 139: "#af87af", 140: "#af87d7", 141: "#af87ff", 142: "#afaf00", 143: "#afaf5f", 144: "#afaf87", 145: "#afafaf", 146: "#afafd7", 147: "#afafff", 148: "#afd700", 149: "#afd75f", 150: "#afd787", 151: "#afd7af", 152: "#afd7d7", 153: "#afd7ff", 154: "#afff00", 155: "#afff5f", 156: "#afff87", 157: "#afffaf", 158: "#afffd7"})
  43       call extend(s:cterm_color, {159: "#afffff", 160: "#d70000", 161: "#d7005f", 162: "#d70087", 163: "#d700af", 164: "#d700d7", 165: "#d700ff", 166: "#d75f00", 167: "#d75f5f", 168: "#d75f87", 169: "#d75faf", 170: "#d75fd7", 171: "#d75fff", 172: "#d78700", 173: "#d7875f", 174: "#d78787", 175: "#d787af", 176: "#d787d7", 177: "#d787ff", 178: "#d7af00", 179: "#d7af5f", 180: "#d7af87", 181: "#d7afaf", 182: "#d7afd7", 183: "#d7afff", 184: "#d7d700", 185: "#d7d75f", 186: "#d7d787", 187: "#d7d7af", 188: "#d7d7d7", 189: "#d7d7ff", 190: "#d7ff00", 191: "#d7ff5f", 192: "#d7ff87", 193: "#d7ffaf", 194: "#d7ffd7", 195: "#d7ffff", 196: "#ff0000", 197: "#ff005f", 198: "#ff0087", 199: "#ff00af", 200: "#ff00d7", 201: "#ff00ff", 202: "#ff5f00", 203: "#ff5f5f", 204: "#ff5f87"})
  44       call extend(s:cterm_color, {205: "#ff5faf", 206: "#ff5fd7", 207: "#ff5fff", 208: "#ff8700", 209: "#ff875f", 210: "#ff8787", 211: "#ff87af", 212: "#ff87d7", 213: "#ff87ff", 214: "#ffaf00", 215: "#ffaf5f", 216: "#ffaf87", 217: "#ffafaf", 218: "#ffafd7", 219: "#ffafff", 220: "#ffd700", 221: "#ffd75f", 222: "#ffd787", 223: "#ffd7af", 224: "#ffd7d7", 225: "#ffd7ff", 226: "#ffff00", 227: "#ffff5f", 228: "#ffff87", 229: "#ffffaf", 230: "#ffffd7", 231: "#ffffff", 232: "#080808", 233: "#121212", 234: "#1c1c1c", 235: "#262626", 236: "#303030", 237: "#3a3a3a", 238: "#444444", 239: "#4e4e4e", 240: "#585858", 241: "#626262", 242: "#6c6c6c", 243: "#767676", 244: "#808080", 245: "#8a8a8a", 246: "#949494", 247: "#9e9e9e", 248: "#a8a8a8", 249: "#b2b2b2", 250: "#bcbcbc", 251: "#c6c6c6", 252: "#d0d0d0", 253: "#dadada", 254: "#e4e4e4", 255: "#eeeeee"})
  45     endif
  46   endif
  47 endif
  48
  49 " Return good color specification: in GUI no transformation is done, in
  50 " terminal return RGB values of known colors and empty string for unknown
  51 if s:whatterm == "gui"
  52   function! s:HtmlColor(color)
  53     return a:color
  54   endfun
  55 else
  56   function! s:HtmlColor(color)
  57     if has_key(s:cterm_color, a:color)
  58       return s:cterm_color[a:color]
  59     else
  60       return ""
  61     endif
  62   endfun
  63 endif
  64
  65 if !exists("html_use_css")
  66   " Return opening HTML tag for given highlight id
  67   function! s:HtmlOpening(id)
  68     let a = ""
  69     if synIDattr(a:id, "inverse")
  70       " For inverse, we always must set both colors (and exchange them)
  71       let x = s:HtmlColor(synIDattr(a:id, "fg#", s:whatterm))
  72       let a = a . '<span style="background-color: ' . ( x != "" ? x : s:fgc ) . '">'
  73       let x = s:HtmlColor(synIDattr(a:id, "bg#", s:whatterm))
  74       let a = a . '<font color="' . ( x != "" ? x : s:bgc ) . '">'
  75     else
  76       let x = s:HtmlColor(synIDattr(a:id, "bg#", s:whatterm))
  77       if x != "" | let a = a . '<span style="background-color: ' . x . '">' | endif
  78       let x = s:HtmlColor(synIDattr(a:id, "fg#", s:whatterm))
  79       if x != "" | let a = a . '<font color="' . x . '">' | endif
  80     endif
  81     if synIDattr(a:id, "bold") | let a = a . "<b>" | endif
  82     if synIDattr(a:id, "italic") | let a = a . "<i>" | endif
  83     if synIDattr(a:id, "underline") | let a = a . "<u>" | endif
  84     return a
  85   endfun
  86
  87   " Return closing HTML tag for given highlight id
  88   function s:HtmlClosing(id)
  89     let a = ""
  90     if synIDattr(a:id, "underline") | let a = a . "</u>" | endif
  91     if synIDattr(a:id, "italic") | let a = a . "</i>" | endif
  92     if synIDattr(a:id, "bold") | let a = a . "</b>" | endif
  93     if synIDattr(a:id, "inverse")
  94       let a = a . '</font></span>'
  95     else
  96       let x = s:HtmlColor(synIDattr(a:id, "fg#", s:whatterm))
  97       if x != "" | let a = a . '</font>' | endif
  98       let x = s:HtmlColor(synIDattr(a:id, "bg#", s:whatterm))
  99       if x != "" | let a = a . '</span>' | endif
 100     endif
 101     return a
 102   endfun
 103 endif
 104
 105 " Return HTML valid characters enclosed in a span of class style_name with
 106 " unprintable characters expanded and double spaces replaced as necessary.
 107 function! s:HtmlFormat(text, style_name)
 108   " Replace unprintable characters
 109   let formatted = strtrans(a:text)
 110
 111   " Replace the reserved html characters
 112   let formatted = substitute(substitute(substitute(substitute(substitute(formatted, '&', '\&amp;', 'g'), '<', '\&lt;', 'g'), '>', '\&gt;', 'g'), '"', '\&quot;', 'g'), "\x0c", '<hr class="PAGE-BREAK">', 'g')
 113
 114   " Replace double spaces and leading spaces
 115   if ' ' != s:HtmlSpace
 116     let formatted = substitute(formatted, '  ', s:HtmlSpace . s:HtmlSpace, 'g')
 117     let formatted = substitute(formatted, '^ ', s:HtmlSpace, 'g')
 118   endif
 119
 120   " Enclose in a span of class style_name
 121   let formatted = '<span class="' . a:style_name . '">' . formatted . '</span>'
 122
 123   " Add the class to class list if it's not there yet
 124   let s:id = hlID(a:style_name)
 125   if stridx(s:idlist, "," . s:id . ",") == -1
 126     let s:idlist = s:idlist . s:id . ","
 127   endif
 128
 129   return formatted
 130 endfun
 131
 132 " Return CSS style describing given highlight id (can be empty)
 133 function! s:CSS1(id)
 134   let a = ""
 135   if synIDattr(a:id, "inverse")
 136     " For inverse, we always must set both colors (and exchange them)
 137     let x = s:HtmlColor(synIDattr(a:id, "bg#", s:whatterm))
 138     let a = a . "color: " . ( x != "" ? x : s:bgc ) . "; "
 139     let x = s:HtmlColor(synIDattr(a:id, "fg#", s:whatterm))
 140     let a = a . "background-color: " . ( x != "" ? x : s:fgc ) . "; "
 141   else
 142     let x = s:HtmlColor(synIDattr(a:id, "fg#", s:whatterm))
 143     if x != "" | let a = a . "color: " . x . "; " | endif
 144     let x = s:HtmlColor(synIDattr(a:id, "bg#", s:whatterm))
 145     if x != "" | let a = a . "background-color: " . x . "; " | endif
 146   endif
 147   if synIDattr(a:id, "bold") | let a = a . "font-weight: bold; " | endif
 148   if synIDattr(a:id, "italic") | let a = a . "font-style: italic; " | endif
 149   if synIDattr(a:id, "underline") | let a = a . "text-decoration: underline; " | endif
 150   return a
 151 endfun
 152
 153 " Figure out proper MIME charset from the 'encoding' option.
 154 if exists("html_use_encoding")
 155   let s:html_encoding = html_use_encoding
 156 else
 157   let s:vim_encoding = &encoding
 158   if s:vim_encoding =~ '^8bit\|^2byte'
 159     let s:vim_encoding = substitute(s:vim_encoding, '^8bit-\|^2byte-', '', '')
 160   endif
 161   if s:vim_encoding == 'latin1'
 162     let s:html_encoding = 'iso-8859-1'
 163   elseif s:vim_encoding =~ "^cp12"
 164     let s:html_encoding = substitute(s:vim_encoding, 'cp', 'windows-', '')
 165   elseif s:vim_encoding == 'sjis' || s:vim_encoding == 'cp932'
 166     let s:html_encoding = 'Shift_JIS'
 167   elseif s:vim_encoding == 'big5' || s:vim_encoding == 'cp950'
 168     let s:html_encoding = "Big5"
 169   elseif s:vim_encoding == 'euc-cn'
 170     let s:html_encoding = 'GB_2312-80'
 171   elseif s:vim_encoding == 'euc-tw'
 172     let s:html_encoding = ""
 173   elseif s:vim_encoding =~ '^euc\|^iso\|^koi'
 174     let s:html_encoding = substitute(s:vim_encoding, '.*', '\U\0', '')
 175   elseif s:vim_encoding == 'cp949'
 176     let s:html_encoding = 'KS_C_5601-1987'
 177   elseif s:vim_encoding == 'cp936'
 178     let s:html_encoding = 'GBK'
 179   elseif s:vim_encoding =~ '^ucs\|^utf'
 180     let s:html_encoding = 'UTF-8'
 181   else
 182     let s:html_encoding = ""
 183   endif
 184 endif
 185
 186
 187 " Set some options to make it work faster.
 188 " Don't report changes for :substitute, there will be many of them.
 189 let s:old_title = &title
 190 let s:old_icon = &icon
 191 let s:old_et = &l:et
 192 let s:old_report = &report
 193 let s:old_search = @/
 194 set notitle noicon
 195 setlocal et
 196 set report=1000000
 197
 198 " Split window to create a buffer with the HTML file.
 199 let s:orgbufnr = winbufnr(0)
 200 if expand("%") == ""
 201   new Untitled.html
 202 else
 203   new %.html
 204 endif
 205 let s:newwin = winnr()
 206 let s:orgwin = bufwinnr(s:orgbufnr)
 207
 208 set modifiable
 209 %d
 210 let s:old_paste = &paste
 211 set paste
 212 let s:old_magic = &magic
 213 set magic
 214
 215 if exists("use_xhtml")
 216   if s:html_encoding != ""
 217     exe "normal!  a<?xml version=\"1.0\" encoding=\"" . s:html_encoding . "\"?>\n\e"
 218   else
 219     exe "normal! a<?xml version=\"1.0\"?>\n\e"
 220   endif
 221   let s:tag_close = ' />'
 222 else
 223   let s:tag_close = '>'
 224 endif
 225
 226 " Cache html_no_pre in case we have to turn it on for non-css mode
 227 if exists("html_no_pre")
 228   let s:old_html_no_pre = html_no_pre
 229 endif
 230
 231 if !exists("html_use_css")
 232   " Can't put font tags in <pre>
 233   let html_no_pre=1
 234 endif
 235
 236 let s:HtmlSpace = ' '
 237 let s:LeadingSpace = ' '
 238 let s:HtmlEndline = ''
 239 if exists("html_no_pre")
 240   let s:HtmlEndline = '<br' . s:tag_close
 241   let s:LeadingSpace = '&nbsp;'
 242   let s:HtmlSpace = '\' . s:LeadingSpace
 243 endif
 244
 245 " HTML header, with the title and generator ;-). Left free space for the CSS,
 246 " to be filled at the end.
 247 exe "normal! a<html>\n\e"
 248 exe "normal! a<head>\n<title>" . expand("%:p:~") . "</title>\n\e"
 249 exe "normal! a<meta name=\"Generator\" content=\"Vim/" . v:version/100 . "." . v:version %100 . '"' . s:tag_close . "\n\e"
 250 if s:html_encoding != ""
 251   exe "normal! a<meta http-equiv=\"content-type\" content=\"text/html; charset=" . s:html_encoding . '"' . s:tag_close . "\n\e"
 252 endif
 253
 254 if exists("html_use_css")
 255   exe "normal! a<style type=\"text/css\">\n<!--\n-->\n</style>\n\e"
 256 endif
 257 if exists("html_no_pre")
 258   exe "normal! a</head>\n<body>\n\e"
 259 else
 260   exe "normal! a</head>\n<body>\n<pre>\n\e"
 261 endif
 262
 263 exe s:orgwin . "wincmd w"
 264
 265 " List of all id's
 266 let s:idlist = ","
 267
 268 " Loop over all lines in the original text.
 269 " Use html_start_line and html_end_line if they are set.
 270 if exists("html_start_line")
 271   let s:lnum = html_start_line
 272   if s:lnum < 1 || s:lnum > line("$")
 273     let s:lnum = 1
 274   endif
 275 else
 276   let s:lnum = 1
 277 endif
 278 if exists("html_end_line")
 279   let s:end = html_end_line
 280   if s:end < s:lnum || s:end > line("$")
 281     let s:end = line("$")
 282   endif
 283 else
 284   let s:end = line("$")
 285 endif
 286 if s:numblines
 287   let s:margin = strlen(s:end) + 1
 288 else
 289   let s:margin = 0
 290 endif
 291
 292 if has('folding') && !exists('html_ignore_folding')
 293   let s:foldfillchar = &fillchars[matchend(&fillchars, 'fold:')]
 294   if s:foldfillchar == ''
 295     let s:foldfillchar = '-'
 296   endif
 297 endif
 298 let s:difffillchar = &fillchars[matchend(&fillchars, 'diff:')]
 299 if s:difffillchar == ''
 300   let s:difffillchar = '-'
 301 endif
 302
 303
 304 while s:lnum <= s:end
 305
 306   " If there are filler lines for diff mode, show these above the line.
 307   let s:filler = diff_filler(s:lnum)
 308   if s:filler > 0
 309     let s:n = s:filler
 310     while s:n > 0
 311       let s:new = repeat(s:difffillchar, 3)
 312
 313       if s:n > 2 && s:n < s:filler && !exists("html_whole_filler")
 314         let s:new = s:new . " " . s:filler . " inserted lines "
 315         let s:n = 2
 316       endif
 317
 318       if !exists("html_no_pre")
 319         " HTML line wrapping is off--go ahead and fill to the margin
 320         let s:new = s:new . repeat(s:difffillchar, &columns - strlen(s:new) - s:margin)
 321       else
 322         let s:new = s:new . repeat(s:difffillchar, 3)
 323       endif
 324
 325       let s:new = s:HtmlFormat(s:new, "DiffDelete")
 326       if s:numblines
 327         " Indent if line numbering is on; must be after escaping.
 328         let s:new = repeat(s:LeadingSpace, s:margin) . s:new
 329       endif
 330       exe s:newwin . "wincmd w"
 331       exe "normal! a" . s:new . s:HtmlEndline . "\n\e"
 332       exe s:orgwin . "wincmd w"
 333
 334       let s:n = s:n - 1
 335     endwhile
 336     unlet s:n
 337   endif
 338   unlet s:filler
 339
 340   " Start the line with the line number.
 341   if s:numblines
 342     let s:new = repeat(' ', s:margin - 1 - strlen(s:lnum)) . s:lnum . ' '
 343   else
 344     let s:new = ""
 345   endif
 346
 347   if has('folding') && !exists('html_ignore_folding') && foldclosed(s:lnum) > -1
 348     "
 349     " This is the beginning of a folded block
 350     "
 351     let s:new = s:new . foldtextresult(s:lnum)
 352     if !exists("html_no_pre")
 353       " HTML line wrapping is off--go ahead and fill to the margin
 354       let s:new = s:new . repeat(s:foldfillchar, &columns - strlen(s:new))
 355     endif
 356
 357     let s:new = s:HtmlFormat(s:new, "Folded")
 358
 359     " Skip to the end of the fold
 360     let s:lnum = foldclosedend(s:lnum)
 361
 362   else
 363     "
 364     " A line that is not folded.
 365     "
 366     let s:line = getline(s:lnum)
 367     let s:len = strlen(s:line)
 368
 369     if s:numblines
 370       let s:new = s:HtmlFormat(s:new, "lnr")
 371     endif
 372
 373     " Get the diff attribute, if any.
 374     let s:diffattr = diff_hlID(s:lnum, 1)
 375
 376     " Loop over each character in the line
 377     let s:col = 1
 378     while s:col <= s:len || (s:col == 1 && s:diffattr)
 379       let s:startcol = s:col " The start column for processing text
 380       if s:diffattr
 381         let s:id = diff_hlID(s:lnum, s:col)
 382         let s:col = s:col + 1
 383         " Speed loop (it's small - that's the trick)
 384         " Go along till we find a change in hlID
 385         while s:col <= s:len && s:id == diff_hlID(s:lnum, s:col) | let s:col = s:col + 1 | endwhile
 386         if s:len < &columns && !exists("html_no_pre")
 387           " Add spaces at the end to mark the changed line.
 388           let s:line = s:line . repeat(' ', &columns - virtcol([s:lnum, s:len]) - s:margin)
 389           let s:len = &columns
 390         endif
 391       else
 392         let s:id = synID(s:lnum, s:col, 1)
 393         let s:col = s:col + 1
 394         " Speed loop (it's small - that's the trick)
 395         " Go along till we find a change in synID
 396         while s:col <= s:len && s:id == synID(s:lnum, s:col, 1) | let s:col = s:col + 1 | endwhile
 397       endif
 398
 399       " Expand tabs
 400       let s:expandedtab = strpart(s:line, s:startcol - 1, s:col - s:startcol)
 401       let idx = stridx(s:expandedtab, "\t")
 402       while idx >= 0
 403         let i = &ts - ((idx + s:startcol - 1) % &ts)
 404         let s:expandedtab = substitute(s:expandedtab, '\t', repeat(' ', i), '')
 405         let idx = stridx(s:expandedtab, "\t")
 406       endwhile
 407
 408       " Output the text with the same synID, with class set to {s:id_name}
 409       let s:id = synIDtrans(s:id)
 410       let s:id_name = synIDattr(s:id, "name", s:whatterm)
 411       let s:new = s:new . s:HtmlFormat(s:expandedtab,  s:id_name)
 412     endwhile
 413   endif
 414
 415   exe s:newwin . "wincmd w"
 416   exe "normal! a" . s:new . s:HtmlEndline . "\n\e"
 417   exe s:orgwin . "wincmd w"
 418   let s:lnum = s:lnum + 1
 419 endwhile
 420 " Finish with the last line
 421 exe s:newwin . "wincmd w"
 422
 423 " Close off the font tag that encapsulates the whole <body>
 424 if !exists("html_use_css")
 425   exe "normal! a</font>\e"
 426 endif
 427
 428 if exists("html_no_pre")
 429   exe "normal! a</body>\n</html>\e"
 430 else
 431   exe "normal! a</pre>\n</body>\n</html>\e"
 432 endif
 433
 434
 435 " Now, when we finally know which, we define the colors and styles
 436 if exists("html_use_css")
 437   1;/<style type="text/+1
 438 endif
 439
 440 " Find out the background and foreground color.
 441 let s:fgc = s:HtmlColor(synIDattr(hlID("Normal"), "fg#", s:whatterm))
 442 let s:bgc = s:HtmlColor(synIDattr(hlID("Normal"), "bg#", s:whatterm))
 443 if s:fgc == ""
 444   let s:fgc = ( &background == "dark" ? "#ffffff" : "#000000" )
 445 endif
 446 if s:bgc == ""
 447   let s:bgc = ( &background == "dark" ? "#000000" : "#ffffff" )
 448 endif
 449
 450 " Normal/global attributes
 451 " For Netscape 4, set <body> attributes too, though, strictly speaking, it's
 452 " incorrect.
 453 if exists("html_use_css")
 454   if exists("html_no_pre")
 455     execute "normal! A\nbody { color: " . s:fgc . "; background-color: " . s:bgc . "; font-family: ". s:htmlfont ."; }\e"
 456   else
 457     execute "normal! A\npre { font-family: ". s:htmlfont ."; color: " . s:fgc . "; background-color: " . s:bgc . "; }\e"
 458     yank
 459     put
 460     execute "normal! ^cwbody\e"
 461   endif
 462 else
 463     execute '%s:<body>:<body bgcolor="' . s:bgc . '" text="' . s:fgc . '"><font face="'. s:htmlfont .'">'
 464 endif
 465
 466 " Line numbering attributes
 467 if s:numblines
 468   if exists("html_use_css")
 469     execute "normal! A\n.lnr { " . s:CSS1(hlID("LineNr")) . "}\e"
 470   else
 471     execute '%s+^<span class="lnr">\([^<]*\)</span>+' . s:HtmlOpening(hlID("LineNr")) . '\1' . s:HtmlClosing(hlID("LineNr")) . '+g'
 472   endif
 473 endif
 474
 475 " Gather attributes for all other classes
 476 let s:idlist = strpart(s:idlist, 1)
 477 while s:idlist != ""
 478   let s:attr = ""
 479   let s:col = stridx(s:idlist, ",")
 480   let s:id = strpart(s:idlist, 0, s:col)
 481   let s:idlist = strpart(s:idlist, s:col + 1)
 482   let s:attr = s:CSS1(s:id)
 483   let s:id_name = synIDattr(s:id, "name", s:whatterm)
 484   " If the class has some attributes, export the style, otherwise DELETE all
 485   " its occurences to make the HTML shorter
 486   if s:attr != ""
 487     if exists("html_use_css")
 488       execute "normal! A\n." . s:id_name . " { " . s:attr . "}"
 489     else
 490       execute '%s+<span class="' . s:id_name . '">\([^<]*\)</span>+' . s:HtmlOpening(s:id) . '\1' . s:HtmlClosing(s:id) . '+g'
 491     endif
 492   else
 493     execute '%s+<span class="' . s:id_name . '">\([^<]*\)</span>+\1+ge'
 494     if exists("html_use_css")
 495       1;/<style type="text/+1
 496     endif
 497   endif
 498 endwhile
 499
 500 " Add hyperlinks
 501 %s+\(https\=://\S\{-}\)\(\([.,;:}]\=\(\s\|$\)\)\|[\\"'<>]\|&gt;\|&lt;\|&quot;\)+<a href="\1">\1</a>\2+ge
 502
 503 " The DTD
 504 if exists("use_xhtml")
 505   exe "normal! gg$a\n<!DOCTYPE html PUBLIC \"-//W3C//DTD XHTML 1.0 Transitional//EN\" \"http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd\">\e"
 506 else
 507   exe "normal! gg0i<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 4.01 Transitional//EN\" \"http://www.w3.org/TR/html4/loose.dtd\">\n\e"
 508 endif
 509
 510 if exists("use_xhtml")
 511   exe "normal! gg/<html/e\na xmlns=\"http://www.w3.org/1999/xhtml\"\e"
 512 endif
 513
 514 " Cleanup
 515 %s:\s\+$::e
 516
 517 " Restore old settings
 518 let &report = s:old_report
 519 let &title = s:old_title
 520 let &icon = s:old_icon
 521 let &paste = s:old_paste
 522 let &magic = s:old_magic
 523 let @/ = s:old_search
 524 exe s:orgwin . "wincmd w"
 525 let &l:et = s:old_et
 526 exe s:newwin . "wincmd w"
 527
 528 " Reset old <pre> settings
 529 if exists("s:old_html_no_pre")
 530   let html_no_pre = s:old_html_no_pre
 531   unlet s:old_html_no_pre
 532 elseif exists("html_no_pre")
 533   unlet html_no_pre
 534 endif
 535
 536 " Save a little bit of memory (worth doing?)
 537 unlet s:htmlfont
 538 unlet s:old_et s:old_paste s:old_icon s:old_report s:old_title s:old_search
 539 unlet s:whatterm s:idlist s:lnum s:end s:margin s:fgc s:bgc s:old_magic
 540 unlet! s:col s:id s:attr s:len s:line s:new s:expandedtab s:numblines
 541 unlet s:orgwin s:newwin s:orgbufnr
 542 if !v:profiling
 543   delfunc s:HtmlColor
 544   delfunc s:HtmlFormat
 545   delfunc s:CSS1
 546   if !exists("html_use_css")
 547     delfunc s:HtmlOpening
 548     delfunc s:HtmlClosing
 549   endif
 550 endif
 551 silent! unlet s:diffattr s:difffillchar s:foldfillchar s:HtmlSpace s:LeadingSpace s:HtmlEndline