V.pm

   1 #!/pro/bin/perl
   2
   3 package Config::Perl::V;
   4
   5 use strict;
   6 use warnings;
   7
   8 our $VERSION = "0.02";
   9
  10 use Config;
  11
  12 #  Characteristics of this binary (from libperl):
  13 #    Compile-time options: DEBUGGING PERL_DONT_CREATE_GVSV PERL_MALLOC_WRAP
  14 #                          USE_64_BIT_INT USE_LARGE_FILES USE_PERLIO
  15
  16 # The list are as the perl binary has stored it in PL_bincompat_options
  17 #  search for it in
  18 #   perl.c line 1768 (first  block)
  19 #   perl.h line 4454 (second block),
  20 my %BTD = map { $_ => 0 } qw(
  21
  22     DEBUGGING
  23     NO_MATHOMS
  24     PERL_DONT_CREATE_GVSV
  25     PERL_MALLOC_WRAP
  26     PERL_MEM_LOG
  27     PERL_MEM_LOG_ENV
  28     PERL_MEM_LOG_ENV_FD
  29     PERL_MEM_LOG_STDERR
  30     PERL_MEM_LOG_TIMESTAMP
  31     PERL_USE_DEVEL
  32     PERL_USE_SAFE_PUTENV
  33     USE_FAST_STDIO
  34     USE_SITECUSTOMIZE
  35
  36     DEBUG_LEAKING_SCALARS
  37     DEBUG_LEAKING_SCALARS_FORK_DUMP
  38     DECCRTL_SOCKETS
  39     FAKE_THREADS
  40     MULTIPLICITY
  41     MYMALLOC
  42     PERL_DEBUG_READONLY_OPS
  43     PERL_GLOBAL_STRUCT
  44     PERL_IMPLICIT_CONTEXT
  45     PERL_IMPLICIT_SYS
  46     PERL_MAD
  47     PERL_NEED_APPCTX
  48     PERL_NEED_TIMESBASE
  49     PERL_OLD_COPY_ON_WRITE
  50     PERL_POISON
  51     PERL_TRACK_MEMPOOL
  52     PERL_USES_PL_PIDSTATUS
  53     PL_OP_SLAB_ALLOC
  54     THREADS_HAVE_PIDS
  55     USE_64_BIT_ALL
  56     USE_64_BIT_INT
  57     USE_IEEE
  58     USE_ITHREADS
  59     USE_LARGE_FILES
  60     USE_LONG_DOUBLE
  61     USE_PERLIO
  62     USE_REENTRANT_API
  63     USE_SFIO
  64     USE_SOCKS
  65     VMS_DO_SOCKETS
  66     VMS_SYMBOL_CASE_AS_IS
  67     );
  68
  69 # These are all the keys that are
  70 # 1. Always present in %Config (first block)
  71 # 2. Reported by 'perl -V' (the rest)
  72 my @config_vars = qw(
  73
  74     api_subversion
  75     api_version
  76     api_versionstring
  77     archlibexp
  78     dont_use_nlink
  79     d_readlink
  80     d_symlink
  81     exe_ext
  82     inc_version_list
  83     ldlibpthname
  84     patchlevel
  85     path_sep
  86     perl_patchlevel
  87     privlibexp
  88     scriptdir
  89     sitearchexp
  90     sitelibexp
  91     subversion
  92     usevendorprefix
  93     version
  94
  95     git_commit_id
  96     git_describe
  97     git_branch
  98     git_uncommitted_changes
  99     git_commit_id_title
 100     git_snapshot_date
 101
 102     package revision version_patchlevel_string
 103
 104     osname osvers archname
 105     myuname
 106     config_args
 107     hint useposix d_sigaction
 108     useithreads usemultiplicity
 109     useperlio d_sfio uselargefiles usesocks
 110     use64bitint use64bitall uselongdouble
 111     usemymalloc bincompat5005
 112
 113     cc ccflags
 114     optimize
 115     cppflags
 116     ccversion gccversion gccosandvers
 117     intsize longsize ptrsize doublesize byteorder
 118     d_longlong longlongsize d_longdbl longdblsize
 119     ivtype ivsize nvtype nvsize lseektype lseeksize
 120     alignbytes prototype
 121
 122     ld ldflags
 123     libpth
 124     libs
 125     perllibs
 126     libc so useshrplib libperl
 127     gnulibc_version
 128
 129     dlsrc dlext d_dlsymun ccdlflags
 130     cccdlflags lddlflags
 131     );
 132
 133 my %empty_build = (
 134     osname  => "",
 135     stamp   => 0,
 136     options => { %BTD },
 137     patches => [],
 138     );
 139
 140 sub _make_derived
 141 {
 142     my $conf = shift;
 143
 144     for ( [ lseektype           => "Off_t"      ],
 145           [ myuname             => "uname"      ],
 146           [ perl_patchlevel     => "patch"      ],
 147           ) {
 148         my ($official, $derived) = @$_;
 149         $conf->{config}{$derived}  ||= $conf->{config}{$official};
 150         $conf->{config}{$official} ||= $conf->{config}{$derived};
 151         $conf->{derived}{$derived} = delete $conf->{config}{$derived};
 152         }
 153
 154     if (exists $conf->{config}{version_patchlevel_string} &&
 155        !exists $conf->{config}{api_version}) {
 156         my $vps = $conf->{config}{version_patchlevel_string};
 157         $vps =~ s{\b revision   \s+ (\S+) }{}x and
 158             $conf->{config}{revision}        ||= $1;
 159
 160         $vps =~ s{\b version    \s+ (\S+) }{}x and
 161             $conf->{config}{api_version}     ||= $1;
 162         $vps =~ s{\b subversion \s+ (\S+) }{}x and
 163             $conf->{config}{subversion}      ||= $1;
 164         $vps =~ s{\b patch      \s+ (\S+) }{}x and
 165             $conf->{config}{perl_patchlevel} ||= $1;
 166         }
 167
 168     ($conf->{config}{version_patchlevel_string} ||= join " ",
 169         map  { ($_, $conf->{config}{$_} ) }
 170         grep {      $conf->{config}{$_}   }
 171         qw( api_version subversion perl_patchlevel )) =~ s/\bperl_//;
 172
 173     $conf->{config}{perl_patchlevel}  ||= "";   # 0 is not a valid patchlevel
 174
 175     if ($conf->{config}{perl_patchlevel} =~ m{^git\w*-([^-]+)}i) {
 176         $conf->{config}{git_branch}   ||= $1;
 177         $conf->{config}{git_describe} ||= $conf->{config}{perl_patchlevel};
 178         }
 179
 180     $conf;
 181     } # _make_derived
 182
 183 sub plv2hash
 184 {
 185     my %config;
 186     for (split m/\n+/ => join "\n", @_) {
 187
 188         if (s/^Summary of my\s+(\S+)\s+\(\s*(.*?)\s*\)//) {
 189             $config{"package"} = $1;
 190             my $rev = $2;
 191             $rev =~ s/^ revision \s+ (\S+) \s*//x and $config{revision} = $1;
 192             $rev and $config{version_patchlevel_string} = $rev;
 193             next;
 194             }
 195
 196         if (s/^\s+(Snapshot of:)\s+(\S+)//) {
 197             $config{git_commit_id_title} = $1;
 198             $config{git_commit_id}       = $2;
 199             next;
 200             }
 201
 202         my %kv = m/\G,?\s*([^=]+)=('[^']+?'|\S+)/gc;
 203
 204         while (my ($k, $v) = each %kv) {
 205             $k =~ s/\s+$//;
 206             $v =~ s/,$//;
 207             $v =~ m/^'(.*)'$/ and $v = $1;
 208             $v =~ s/^\s+//;
 209             $v =~ s/\s+$//;
 210             $config{$k} = $v;
 211             }
 212         }
 213     my $build = { %empty_build };
 214     $build->{osname} = $config{osname};
 215     return _make_derived ({
 216         build           => $build,
 217         environment     => {},
 218         config          => \%config,
 219         derived         => {},
 220         inc             => [],
 221         });
 222     } # plv2hash
 223
 224 sub summary
 225 {
 226     my $conf = shift;
 227     ref $conf eq "HASH" &&
 228         exists $conf->{config} && exists $conf->{build} or return;
 229
 230     my %info = map {
 231         exists $conf->{config}{$_} ? ( $_ => $conf->{config}{$_} ) : () }
 232         qw( archname osname osvers revision patchlevel subversion version
 233             cc ccversion gccversion config_args inc_version_list
 234             d_longdbl d_longlong use64bitall use64bitint useithreads
 235             uselongdouble usemultiplicity usemymalloc useperlio useshrplib
 236             doublesize intsize ivsize nvsize longdblsize longlongsize lseeksize
 237             );
 238     $info{$_}++ for grep { $conf->{build}{options}{$_} } keys %{$conf->{build}{options}};
 239
 240     return \%info;
 241     } # summary
 242
 243 sub myconfig
 244 {
 245     my $args = shift;
 246     my %args = ref $args eq "HASH"  ? %$args :
 247                ref $args eq "ARRAY" ? @$args : ();
 248
 249     #y $pv = qx[$^X -e"sub Config::myconfig{};" -V];
 250     my $pv = qx[$^X -V];
 251        $pv =~ s{.*?\n\n}{}s;
 252        $pv =~ s{\n(?:  \s+|\t\s*)}{ }g;
 253
 254     #print $pv;
 255
 256     my $build = { %empty_build };
 257     $pv =~ m{^\s+Built under (.*)}m                and $build->{osname} = $1;
 258     $pv =~ m{^\s+Compiled at (.*)}m                and $build->{stamp}  = $1;
 259     $pv =~ m{^\s+Locally applied patches:\s+(.*)}m and $build->{patches} = [ split m/\s+/, $1 ];
 260     $pv =~ m{^\s+Compile-time options:\s+(.*)}m    and map { $build->{options}{$_} = 1 } split m/\s+/, $1;
 261
 262     my @KEYS = keys %ENV;
 263     my %env  =
 264         map {      $_ => $ENV{$_} } grep m/^PERL/      => @KEYS;
 265     $args{env} and
 266         map { $env{$_} = $ENV{$_} } grep m{$args{env}} => @KEYS;
 267
 268     my %config = map { $_ => $Config{$_} } @config_vars;
 269
 270     return _make_derived ({
 271         build           => $build,
 272         environment     => \%env,
 273         config          => \%config,
 274         derived         => {},
 275         inc             => \@INC,
 276         });
 277     } # myconfig
 278
 279 1;
 280
 281 __END__
 282
 283 =head1 NAME
 284
 285 Config::Perl::V - Structured data retreival of perl -V output
 286
 287 =head1 SYNOPSIS
 288
 289  use Config::Perl::V;
 290
 291  my $local_config = Config::Perl::V::myconfig ();
 292  print $local_config->{config}{osname};
 293
 294 =head1 DESCRIPTION
 295
 296 =head2 $conf = myconfig ()
 297
 298 This function will collect the data decribed in L<the hash structure> below,
 299 and return that as a hash reference. It optionally accepts an option to
 300 include more entries from %ENV. See L<environment> below.
 301
 302 =head2 $conf = plv2hash ($text [, ...])
 303
 304 Convert a sole 'perl -V' text block, or list of lines, to a complete
 305 myconfig hash.  All unknown entries are defaulted.
 306
 307 =head2 $info = summary ($conf)
 308
 309 Return an arbitrary selection of the information.
 310
 311 =head2 The hash structure
 312
 313 The returned hash consists of 4 parts:
 314
 315 =over 4
 316
 317 =item build
 318
 319 This information is extracted from the second block that is emitted by
 320 C<perl -V>, and usually looks something like
 321
 322  Characteristics of this binary (from libperl):
 323    Compile-time options: DEBUGGING USE_64_BIT_INT USE_LARGE_FILES
 324    Locally applied patches:
 325          defined-or
 326          MAINT24637
 327    Built under linux
 328    Compiled at Jun 13 2005 10:44:20
 329    @INC:
 330      /usr/lib/perl5/5.8.7/i686-linux-64int
 331      /usr/lib/perl5/5.8.7
 332      /usr/lib/perl5/site_perl/5.8.7/i686-linux-64int
 333      /usr/lib/perl5/site_perl/5.8.7
 334      /usr/lib/perl5/site_perl
 335      .
 336
 337 or
 338
 339  Characteristics of this binary (from libperl):
 340    Compile-time options: DEBUGGING MULTIPLICITY
 341                          PERL_DONT_CREATE_GVSV PERL_IMPLICIT_CONTEXT
 342                          PERL_MALLOC_WRAP PERL_TRACK_MEMPOOL
 343                          PERL_USE_SAFE_PUTENV USE_ITHREADS
 344                          USE_LARGE_FILES USE_PERLIO
 345                          USE_REENTRANT_API
 346    Built under linux
 347    Compiled at Jan 28 2009 15:26:59
 348
 349 This information is not available anywhere else, including C<%Config>,
 350 but it is the information that is only known to the perl binary.
 351
 352 The extracted information is stored in 5 entries in the C<build> hash:
 353
 354 =over 4
 355
 356 =item osname
 357
 358 This is most likely the same as C$Config{osname}>, and was the name
 359 known when perl was built. It might be different if perl was cross-compiled.
 360
 361 The default for this field, if it cannot be extracted, is to copy C<$Config{osname}>.
 362 `
 363 =item stamp
 364
 365 This is the time string for which the perl binary was compiled. The default
 366 value is 0.
 367
 368 =item options
 369
 370 This is a hash with all the known defines as keys. The value is either 0,
 371 which means unknown or unset, or 1, which means defined.
 372
 373 =item derived
 374
 375 As some verables are reported by a different name in the output of C<perl -V>
 376 than their actual name in C<%Config>, I decided to leave the C<config> entry
 377 as close to reality as possible, and put in the entries that might have been
 378 guessed by the printed output in a seperate block.
 379
 380 =item patches
 381
 382 This is a list of optionally locally applied patches. Default is an empty list.
 383
 384 =back
 385
 386 This include the flags that define the binary compatibility, like if
 387 this perl was compiled for 64bitall (C<USE_64_BIT_ALL>), and basically is
 388
 389 =item environment
 390
 391 By default this hash is only filled with the environment variables
 392 out of %ENV that start with C<PERL>, but you can pass the C<env> option
 393 to myconfig to get more
 394
 395  my $conf = Config::Perl::V::myconfig ({ env => qr/^ORACLE/ });
 396  my $conf = Config::Perl::V::myconfig ([ env => qr/^ORACLE/ ]);
 397
 398 =item config
 399
 400 This hash is filled with the variables that C<perl -V> fils it's report
 401 with, and it has the same variables that C<Config::myconfig> returns
 402 from C<%Config>.
 403
 404 =item inc
 405
 406 This is the list of default @INC.
 407
 408 =back
 409
 410 =head1 REASONING
 411
 412 This module was written to be able to return the configuration for the
 413 currently used perl as deeply as needed for the CPANTESTERS framework.
 414 Up until now they used the output of myconfig as a single text blob,
 415 and so it was missing the vital binary characteristics of the running
 416 perl and the optional applied patches.
 417
 418 =head1 BUGS
 419
 420 Please feedback what is wrong
 421
 422 =head1 TODO
 423
 424 * Implement retrieval functions/methods
 425 * Documentation
 426 * Include the perl -V parse block from Andreas
 427
 428 =head1 AUTHOR
 429
 430 H.Merijn Brand <h.m.brand@xs4all.nl>
 431
 432 =head1 COPYRIGHT AND LICENSE
 433
 434 Copyright (C) 2009 H.Merijn Brand
 435
 436 This library is free software; you can redistribute it and/or modify
 437 it under the same terms as Perl itself.
 438
 439 =cut