regression.lsp

   1 ;;; -*- mode: lisp -*-
   2 ;;;
   3 ;;; Copyright (c) 2005--2007, by A.J. Rossini <blindglobe@gmail.com>
   4 ;;; See COPYRIGHT file for any additional restrictions (BSD license).
   5 ;;; Since 1991, ANSI was finally finished.  Modified to match ANSI
   6 ;;; Common Lisp.
   7
   8 ;;;;
   9 ;;;; regression.lsp XLISP-STAT regression model proto and methods
  10 ;;;; XLISP-STAT 2.1 Copyright (c) 1990, by Luke Tierney
  11 ;;;; Additions to Xlisp 2.1, Copyright (c) 1989 by David Michael Betz
  12 ;;;; You may give out copies of this software; for conditions see the file
  13 ;;;; COPYING included with this distribution.
  14 ;;;;
  15 ;;;;
  16 ;;;; Incorporates modifications suggested by Sandy Weisberg.
  17 ;;;;
  18
  19 (in-package :cl-user)
  20
  21 (defpackage :lisp-stat-regression-linear
  22   (:use :common-lisp
  23         :lisp-stat-object-system
  24         :lisp-stat-basics
  25         :lisp-stat-compound-data
  26         :lisp-stat-math
  27         :lisp-stat-matrix
  28         :lisp-stat-linalg
  29         :lisp-stat-descriptive-statistics)
  30   (:shadowing-import-from :lisp-stat-object-system
  31                           slot-value call-method call-next-method)
  32   (:shadowing-import-from :lisp-stat-math
  33       expt + - * / ** mod rem abs 1+ 1- log exp sqrt sin cos tan
  34       asin acos atan sinh cosh tanh asinh acosh atanh float random
  35       truncate floor ceiling round minusp zerop plusp evenp oddp
  36       < <= = /= >= > ;; complex
  37       conjugate realpart imagpart phase
  38       min max logand logior logxor lognot ffloor fceiling
  39       ftruncate fround signum cis)
  40   (:export regression-model regression-model-proto x y intercept sweep-matrix
  41            basis weights included total-sum-of-squares residual-sum-of-squares
  42            predictor-names response-name case-labels))
  43
  44 (in-package :lisp-stat-regression-linear)
  45
  46 ;;; Regresion Model Prototype
  47
  48 (defvar regression-model-proto nil
  49   "Prototype for all regression model instances.")
  50 (defproto regression-model-proto
  51     '(x y intercept sweep-matrix basis weights
  52       included
  53       total-sum-of-squares
  54       residual-sum-of-squares
  55       predictor-names
  56       response-name
  57       case-labels
  58       doc)
  59   ()
  60   *object*
  61   "Normal Linear Regression Model")
  62
  63 (defun regression-model (x y &key
  64                          (intercept T)
  65                          (print T)
  66                          (weights nil)
  67                          (included (repeat t (length y)))
  68                          predictor-names
  69                          response-name
  70                          case-labels
  71                          (doc "Undocumented Regression Model Instance")
  72                          (debug T))
  73   "Args: (x y &key (intercept T) (print T) (weights nil)
  74           included predictor-names response-name case-labels)
  75 X           - list of independent variables or X matrix
  76 Y           - dependent variable.
  77 INTERCEPT   - T to include (default), NIL for no intercept
  78 PRINT       - if not NIL print summary information
  79 WEIGHTS     - if supplied should be the same length as Y; error
  80               variances are
  81               assumed to be inversely proportional to WEIGHTS
  82 PREDICTOR-NAMES, RESPONSE-NAME, CASE-LABELS
  83             - sequences of strings or symbols.
  84 INCLUDED    - if supplied should be the same length as Y, with
  85               elements nil to skip a in computing estimates (but not
  86               in residual analysis).
  87 Returns a regression model object. To examine the model further assign the
  88 result to a variable and send it messages.
  89 Example (data are in file absorbtion.lsp in the sample data directory):
  90   (def m (regression-model (list iron aluminum) absorbtion))
  91   (send m :help) (send m :plot-residuals)"
  92   (let ((x (cond
  93             ((matrixp x) x)
  94             ((typep x 'vector) (list x))
  95             ((and (consp x)
  96                   (numberp (car x))) (list x))
  97             (t x)))
  98         (m (send regression-model-proto :new)))
  99     (format t "~%")
 100     (send m :doc doc)
 101     (send m :x (if (matrixp x) x (apply #'bind-columns x)))
 102     (send m :y y)
 103     (send m :intercept intercept)
 104     (send m :weights weights)
 105     (send m :included included)
 106     (send m :predictor-names predictor-names)
 107     (send m :response-name response-name)
 108     (send m :case-labels case-labels)
 109     (if debug
 110         (progn
 111           (format t "~%")
 112           (format t "~S~%" (send m :doc))
 113           (format t "X: ~S~%" (send m :x))
 114           (format t "Y: ~S~%" (send m :y))))
 115     (if print (send m :display))
 116     m))
 117
 118 (defmeth regression-model-proto :isnew ()
 119   (send self :needs-computing t))
 120
 121 (defmeth regression-model-proto :save ()
 122 "Message args: ()
 123 Returns an expression that will reconstruct the regression model."
 124   `(regression-model ',(send self :x)
 125                      ',(send self :y)
 126                      :intercept ',(send self :intercept)
 127                      :weights ',(send self :weights)
 128                      :included ',(send self :included)
 129                      :predictor-names ',(send self :predictor-names)
 130                      :response-name ',(send self :response-name)
 131                      :case-labels ',(send self :case-labels)))
 132
 133 ;;; Computing and Display Methods
 134
 135 (defmeth regression-model-proto :compute ()
 136 "Message args: ()
 137 Recomputes the estimates. For internal use by other messages"
 138   (let* ((included (if-else (send self :included) 1 0))
 139          (x (send self :x))
 140          (y (send self :y))
 141          (intercept (send self :intercept))
 142          (weights (send self :weights))
 143          (w (if weights (* included weights) included))
 144          (m (make-sweep-matrix x y w)) ;;; ERROR HERE
 145          (n (array-dimension x 1))
 146          (p (- (array-dimension m 0) 1))
 147          (tss (aref m p p))
 148          (tol (* 0.001 (reduce #'* (mapcar #'standard-deviation (column-list x)))))
 149          ;; (tol (* 0.001 (apply #'* (mapcar #'standard-deviation (column-list x)))))
 150          (sweep-result
 151           (if intercept
 152               (sweep-operator m (iseq 1 n) tol)
 153               (sweep-operator m (iseq 0 n) (cons 0.0 tol)))))
 154     (setf (slot-value 'sweep-matrix) (first sweep-result))
 155     (setf (slot-value 'total-sum-of-squares) tss)
 156     (setf (slot-value 'residual-sum-of-squares)
 157           (aref (first sweep-result) p p))
 158     (setf (slot-value 'basis)
 159           (let ((b (remove 0 (second sweep-result))))
 160             (if b (- (reduce #'- (reverse b)) 1)
 161                 (error "no columns could be swept"))))))
 162
 163 (defmeth regression-model-proto :needs-computing (&optional set)
 164    ;;(declare (ignore self))
 165    (if set (setf (slot-value 'sweep-matrix) nil))
 166    (null (slot-value 'sweep-matrix)))
 167
 168 (defmeth regression-model-proto :display ()
 169 "Message args: ()
 170 Prints the least squares regression summary. Variables not used in the fit
 171 are marked as aliased."
 172   (let ((coefs (coerce (send self :coef-estimates) 'list))
 173         (se-s (send self :coef-standard-errors))
 174         (x (send self :x))
 175         (p-names (send self :predictor-names)))
 176     (if (send self :weights)
 177         (format t "~%Weighted Least Squares Estimates:~2%")
 178         (format t "~%Least Squares Estimates:~2%"))
 179     (when (send self :intercept)
 180           (format t "Constant               ~10f   ~A~%"
 181                   (car coefs) (list (car se-s)))
 182           (setf coefs (cdr coefs))
 183           (setf se-s (cdr se-s)))
 184     (dotimes (i (array-dimension x 1))
 185              (cond
 186                ((member i (send self :basis))
 187                 (format t "~22a ~10f   ~A~%"
 188                         (select p-names i) (car coefs) (list (car se-s)))
 189                 (setf coefs (cdr coefs) se-s (cdr se-s)))
 190                (t (format t "~22a    aliased~%" (select p-names i)))))
 191     (format t "~%")
 192     (format t "R Squared:             ~10f~%" (send self :r-squared))
 193     (format t "Sigma hat:             ~10f~%" (send self :sigma-hat))
 194     (format t "Number of cases:       ~10d~%" (send self :num-cases))
 195     (if (/= (send self :num-cases) (send self :num-included))
 196         (format t "Number of cases used:  ~10d~%" (send self :num-included)))
 197     (format t "Degrees of freedom:    ~10d~%" (send self :df))
 198     (format t "~%")))
 199
 200 ;;; Slot accessors and mutators
 201
 202 (defmeth regression-model-proto :doc (&optional new-doc)
 203 "Message args: (&optional new-doc)
 204 With no argument returns the DOC-STRING as supplied to m. With an argument
 205 NEW-DOC sets the DOC-STRING to NEW-DOC."
 206   (when (and new-doc (stringp new-doc))
 207         (setf (slot-value 'doc) new-doc))
 208   (slot-value 'doc))
 209
 210
 211 (defmeth regression-model-proto :x (&optional new-x)
 212 "Message args: (&optional new-x)
 213 With no argument returns the x matrix as supplied to m. With an argument
 214 NEW-X sets the x matrix to NEW-X and recomputes the estimates."
 215   (when (and new-x (matrixp new-x))
 216         (setf (slot-value 'x) new-x)
 217         (send self :needs-computing t))
 218   (slot-value 'x))
 219
 220 (defmeth regression-model-proto :y (&optional new-y)
 221 "Message args: (&optional new-y)
 222 With no argument returns the y sequence as supplied to m. With an argument
 223 NEW-Y sets the y sequence to NEW-Y and recomputes the estimates."
 224   (when (and new-y
 225              (or (matrixp new-y) (typep  new-y 'sequence)))
 226     (setf (slot-value 'y) new-y)
 227     (send self :needs-computing t))
 228   (slot-value 'y))
 229
 230 (defmeth regression-model-proto :intercept (&optional (val nil set))
 231 "Message args: (&optional new-intercept)
 232 With no argument returns T if the model includes an intercept term, nil if
 233 not. With an argument NEW-INTERCEPT the model is changed to include or
 234 exclude an intercept, according to the value of NEW-INTERCEPT."
 235   (when set
 236         (setf (slot-value 'intercept) val)
 237         (send self :needs-computing t))
 238   (slot-value 'intercept))
 239
 240 (defmeth regression-model-proto :weights (&optional (new-w nil set))
 241 "Message args: (&optional new-w)
 242 With no argument returns the weight sequence as supplied to m; NIL means
 243 an unweighted model. NEW-W sets the weights sequence to NEW-W and
 244 recomputes the estimates."
 245   (when set
 246         (setf (slot-value 'weights) new-w)
 247         (send self :needs-computing t))
 248   (slot-value 'weights))
 249
 250 (defmeth regression-model-proto :total-sum-of-squares ()
 251 "Message args: ()
 252 Returns the total sum of squares around the mean."
 253   (if (send self :needs-computing) (send self :compute))
 254   (slot-value 'total-sum-of-squares))
 255
 256 (defmeth regression-model-proto :residual-sum-of-squares ()
 257 "Message args: ()
 258 Returns the residual sum of squares for the model."
 259   (if (send self :needs-computing) (send self :compute))
 260   (slot-value 'residual-sum-of-squares))
 261
 262 (defmeth regression-model-proto :basis ()
 263 "Message args: ()
 264 Returns the indices of the variables used in fitting the model."
 265   (if (send self :needs-computing) (send self :compute))
 266   (slot-value 'basis))
 267
 268 (defmeth regression-model-proto :sweep-matrix ()
 269 "Message args: ()
 270 Returns the swept sweep matrix. For internal use"
 271   (if (send self :needs-computing) (send self :compute))
 272   (slot-value 'sweep-matrix))
 273
 274 (defmeth regression-model-proto :included (&optional new-included)
 275 "Message args: (&optional new-included)
 276 With no argument,  NIL means a case is not used in calculating estimates, and non-nil means it is used.  NEW-INCLUDED is a sequence of length of y of nil and t to select cases.  Estimates are recomputed."
 277   (when (and new-included
 278              (= (length new-included) (send self :num-cases)))
 279         (setf (slot-value 'included) (copy-seq new-included))
 280         (send self :needs-computing t))
 281   (if (slot-value 'included)
 282       (slot-value 'included)
 283       (repeat t (send self :num-cases))))
 284
 285 (defmeth regression-model-proto :predictor-names (&optional (names nil set))
 286 "Message args: (&optional (names nil set))
 287 With no argument returns the predictor names. NAMES sets the names."
 288   (if set (setf (slot-value 'predictor-names) (mapcar #'string names)))
 289   (let ((p (array-dimension (send self :x) 1))
 290         (p-names (slot-value 'predictor-names)))
 291     (if (not (and p-names (= (length p-names) p)))
 292         (setf (slot-value 'predictor-names)
 293               (mapcar #'(lambda (a) (format nil "Variable ~a" a))
 294                       (iseq 0 (- p 1))))))
 295   (slot-value 'predictor-names))
 296
 297 (defmeth regression-model-proto :response-name (&optional (name "Y" set))
 298    "Message args: (&optional name)
 299 With no argument returns the response name. NAME sets the name."
 300    ;;(declare (ignore self))
 301    (if set (setf (slot-value 'response-name) (if name (string name) "Y")))
 302    (slot-value 'response-name))
 303
 304 (defmeth regression-model-proto :case-labels (&optional (labels nil set))
 305 "Message args: (&optional labels)
 306 With no argument returns the case-labels. LABELS sets the labels."
 307   (if set (setf (slot-value 'case-labels)
 308                 (if labels
 309                     (mapcar #'string labels)
 310                     (mapcar #'(lambda (x) (format nil "~d" x))
 311                             (iseq 0 (- (send self :num-cases) 1))))))
 312   (slot-value 'case-labels))
 313
 314 ;;;
 315 ;;; Other Methods
 316 ;;; None of these methods access any slots directly.
 317 ;;;
 318
 319 (defmeth regression-model-proto :num-cases ()
 320 "Message args: ()
 321 Returns the number of cases in the model."
 322   (length (send self :y)))
 323
 324 (defmeth regression-model-proto :num-included ()
 325 "Message args: ()
 326 Returns the number of cases used in the computations."
 327   (sum (if-else (send self :included) 1 0)))
 328
 329 (defmeth regression-model-proto :num-coefs ()
 330 "Message args: ()
 331 Returns the number of coefficients in the fit model (including the
 332 intercept if the model includes one)."
 333   (if (send self :intercept)
 334       (+ 1 (length (send self :basis)))
 335       (length (send self :basis))))
 336
 337 (defmeth regression-model-proto :df ()
 338 "Message args: ()
 339 Returns the number of degrees of freedom in the model."
 340   (- (send self :num-included) (send self :num-coefs)))
 341
 342 (defmeth regression-model-proto :x-matrix ()
 343 "Message args: ()
 344 Returns the X matrix for the model, including a column of 1's, if
 345 appropriate. Columns of X matrix correspond to entries in basis."
 346   (let ((m (select (send self :x)
 347                    (iseq 0 (- (send self :num-cases) 1))
 348                    (send self :basis))))
 349     (if (send self :intercept)
 350         (bind-columns (repeat 1 (send self :num-cases)) m)
 351         m)))
 352
 353 (defmeth regression-model-proto :leverages ()
 354 "Message args: ()
 355 Returns the diagonal elements of the hat matrix."
 356   (let* ((weights (send self :weights))
 357          (x (send self :x-matrix))
 358          (raw-levs
 359           (matmult (* (matmult x (send self :xtxinv)) x)
 360                    (repeat 1 (send self :num-coefs)))))
 361     (if weights (* weights raw-levs) raw-levs)))
 362
 363 (defmeth regression-model-proto :fit-values ()
 364 "Message args: ()
 365 Returns the fitted values for the model."
 366   (matmult (send self :x-matrix) (send self :coef-estimates)))
 367
 368 (defmeth regression-model-proto :raw-residuals ()
 369 "Message args: ()
 370 Returns the raw residuals for a model."
 371   (- (send self :y) (send self :fit-values)))
 372
 373 (defmeth regression-model-proto :residuals ()
 374 "Message args: ()
 375 Returns the raw residuals for a model without weights. If the model
 376 includes weights the raw residuals times the square roots of the weights
 377 are returned."
 378   (let ((raw-residuals (send self :raw-residuals))
 379         (weights (send self :weights)))
 380     (if weights (* (sqrt weights) raw-residuals) raw-residuals)))
 381
 382 (defmeth regression-model-proto :sum-of-squares ()
 383 "Message args: ()
 384 Returns the error sum of squares for the model."
 385   (send self :residual-sum-of-squares))
 386
 387 (defmeth regression-model-proto :sigma-hat ()
 388 "Message args: ()
 389 Returns the estimated standard deviation of the deviations about the
 390 regression line."
 391   (let ((ss (send self :sum-of-squares))
 392         (df (send self :df)))
 393     (if (/= df 0) (sqrt (/ ss df)))))
 394
 395 ;; for models without an intercept the 'usual' formula for R^2 can give
 396 ;; negative results; hence the max.
 397 (defmeth regression-model-proto :r-squared ()
 398 "Message args: ()
 399 Returns the sample squared multiple correlation coefficient, R squared, for
 400 the regression."
 401   (max (- 1 (/ (send self :sum-of-squares) (send self :total-sum-of-squares)))
 402        0))
 403
 404 (defmeth regression-model-proto :coef-estimates ()
 405 "Message args: ()
 406 Returns the OLS (ordinary least squares) estimates of the regression
 407 coefficients. Entries beyond the intercept correspond to entries in basis."
 408   (let ((n (array-dimension (send self :x) 1))
 409         (indices (if (send self :intercept)
 410                      (cons 0 (+ 1 (send self :basis)))
 411                      (+ 1 (send self :basis))))
 412         (m (send self :sweep-matrix)))
 413     (coerce (compound-data-seq (select m (+ 1 n) indices)) 'list)))
 414
 415 (defmeth regression-model-proto :xtxinv ()
 416 "Message args: ()
 417 Returns ((X^T) X)^(-1) or ((X^T) W X)^(-1)."
 418   (let ((indices (if (send self :intercept)
 419                      (cons 0 (1+ (send self :basis)))
 420                      (1+ (send self :basis)))))
 421     (select (send self :sweep-matrix) indices indices)))
 422
 423 (defmeth regression-model-proto :coef-standard-errors ()
 424 "Message args: ()
 425 Returns estimated standard errors of coefficients. Entries beyond the
 426 intercept correspond to entries in basis."
 427   (let ((s (send self :sigma-hat)))
 428     (if s (* (send self :sigma-hat) (sqrt (diagonal (send self :xtxinv)))))))
 429
 430 (defmeth regression-model-proto :studentized-residuals ()
 431 "Message args:  ()
 432 Computes the internally studentized residuals for included cases and externally studentized residuals for excluded cases."
 433   (let ((res (send self :residuals))
 434         (lev (send self :leverages))
 435         (sig (send self :sigma-hat))
 436         (inc (send self :included)))
 437     (if-else inc
 438              (/ res (* sig (sqrt (pmax .00001 (- 1 lev)))))
 439              (/ res (* sig (sqrt (+ 1 lev)))))))
 440
 441 (defmeth regression-model-proto :externally-studentized-residuals ()
 442 "Message args:  ()
 443 Computes the externally studentized residuals."
 444   (let* ((res (send self :studentized-residuals))
 445          (df (send self :df)))
 446     (if-else (send self :included)
 447              (* res (sqrt (/ (- df 1) (- df (^ res 2)))))
 448              res)))
 449
 450 (defmeth regression-model-proto :cooks-distances ()
 451 "Message args: ()
 452 Computes Cook's distances."
 453   (let ((lev (send self :leverages))
 454         (res (/ (^ (send self :studentized-residuals) 2)
 455                 (send self :num-coefs))))
 456     (if-else (send self :included) (* res (/ lev (- 1 lev) )) (* res lev))))
 457
 458
 459 (defun plot-points (x y &rest args)
 460   "FIXME!!"
 461   (declare (ignore x y args))
 462   (error "Graphics not implemented yet."))
 463
 464 ;; Can not plot points yet!!
 465 (defmeth regression-model-proto :plot-residuals (&optional x-values)
 466 "Message args: (&optional x-values)
 467 Opens a window with a plot of the residuals. If X-VALUES are not supplied
 468 the fitted values are used. The plot can be linked to other plots with the
 469 link-views function. Returns a plot object."
 470   (plot-points (if x-values x-values (send self :fit-values))
 471                (send self :residuals)
 472                :title "Residual Plot"
 473                :point-labels (send self :case-labels)))
 474
 475 (defmeth regression-model-proto :plot-bayes-residuals
 476   (&optional x-values)
 477   "Message args: (&optional x-values)
 478
 479 Opens a window with a plot of the standardized residuals and two
 480 standard error bars for the posterior distribution of the actual
 481 deviations from the line. See Chaloner and Brant. If X-VALUES are not
 482 supplied the fitted values are used. The plot can be linked to other
 483 plots with the link-views function.  Returns a plot object."
 484
 485   (let* ((r (/ (send self :residuals)
 486                (send self :sigma-hat)))
 487          (d (* 2 (sqrt (send self :leverages))))
 488          (low (- r d))
 489          (high (+ r d))
 490          (x-values (if x-values x-values (send self :fit-values)))
 491          (p (plot-points x-values r
 492                          :title "Bayes Residual Plot"
 493                          :point-labels (send self :case-labels))))
 494     (map 'list #'(lambda (a b c d) (send p :plotline a b c d nil))
 495          x-values low x-values high)
 496     (send p :adjust-to-data)
 497     p))