configure.in

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Copyright 2006 David Hilvert <dhilvert@auricle.dyndns.org>,
   5 #                              <dhilvert@ugcs.caltech.edu>
   6
   7 #  This file is part of the Anti-Lamenessing Engine.
   8 #
   9 #  The Anti-Lamenessing Engine is free software; you can redistribute it and/or modify
  10 #  it under the terms of the GNU General Public License as published by
  11 #  the Free Software Foundation; either version 2 of the License, or
  12 #  (at your option) any later version.
  13 #
  14 #  The Anti-Lamenessing Engine is distributed in the hope that it will be useful,
  15 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 #  GNU General Public License for more details.
  18 #
  19 #  You should have received a copy of the GNU General Public License
  20 #  along with Anti-Lamenessing Engine; if not, write to the Free Software
  21 #  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  22
  23 #  Parts of this file were automatically generated by the GNU project's
  24 #  configuration generator 'autoscan', part of the 'autoconf' package from the
  25 #  'autotools' family of build and installation tools.
  26
  27
  28 #
  29 # Preliminaries
  30 #
  31
  32 AC_PREREQ(2.60)
  33 AC_INIT(ALE, 0.8.7, ale@ventricle.dyndns.org)
  34 AC_CONFIG_SRCDIR([ale_accum.h])
  35 AC_CONFIG_HEADER([config.h])
  36
  37 AM_INIT_AUTOMAKE
  38
  39 # Checks for programs.
  40 AC_PROG_CXX
  41 AC_PROG_CC
  42
  43 # The strtod check breaks cross-compilation, so disable it.
  44 AC_DEFUN([AC_FUNC_STRTOD],[])
  45
  46 #GNULib startup
  47 gl_EARLY
  48
  49 # Libtool
  50 AC_PROG_LIBTOOL
  51
  52 # For gnulib.
  53 #gl_SOURCE_BASE(gl)
  54 #gl_M4_BASE(m4)
  55 #gl_LIB(lib)
  56 gl_MODULES(strndup)
  57 gl_INIT
  58
  59 # Checks for libraries.
  60 # FIXME: Replace `main' with a function in `-lm':
  61 AC_CHECK_LIB([m], [main])
  62
  63 # Checks for header files.
  64 AC_HEADER_STDC
  65 AC_HEADER_SYS_WAIT
  66 AC_CHECK_HEADERS([limits.h stdint.h stdlib.h string.h sys/ioctl.h unistd.h time.h sys/time.h])
  67
  68 # Checks for typedefs, structures, and compiler characteristics.
  69 AC_C_CONST
  70 AC_C_INLINE
  71 AC_TYPE_INT16_T
  72 AC_TYPE_SIZE_T
  73 AC_TYPE_UINT16_T
  74
  75 # Checks for library functions.  (Commented calls cause problems for cross-compilation.)
  76 AC_FUNC_ERROR_AT_LINE
  77 AC_FUNC_FORK
  78 AC_PROG_GCC_TRADITIONAL
  79 # AC_FUNC_MALLOC
  80 # AC_FUNC_REALLOC
  81 AC_FUNC_SELECT_ARGTYPES
  82 AC_FUNC_STRTOD
  83 AC_FUNC_VPRINTF
  84 AC_CHECK_FUNCS([floor memset pow select sqrt strchr strcspn strdup strndup strspn strtol nrand48 rand_r gettimeofday])
  85
  86 # Check for POSIX threads.
  87 ACX_PTHREAD()
  88
  89 # Determine whether multithreading should be used.
  90 AC_ARG_ENABLE(threads,    [  --enable-threads        enable multithreading: auto, no, yes (default=auto)])
  91 if test x$enable_threads != xno \
  92 && test x$acx_pthread_ok = xyes; then
  93         PTHREAD_CFLAGS="$PTHREAD_CFLAGS -DUSE_PTHREAD=1"
  94
  95         #
  96         # XXX: This is probably wrong.
  97         #
  98
  99         if test x$PTHREAD_CXX = x; then
 100                 PTHREAD_CXX="$CXX"
 101         fi
 102
 103         #
 104         # CC replacement logic from ImageMagick's configuration process
 105         #
 106
 107         if test "$CC" != "$PTHREAD_CC"; then
 108                 AC_MSG_WARN([Replacing compiler $CC with compiler $PTHREAD_CC to support pthreads.])
 109                 CC="$PTHREAD_CC"
 110         fi
 111         if test  "$CXX" != "$PTHREAD_CXX"; then
 112                 AC_MSG_WARN([Replacing compiler $CXX with compiler $PTHREAD_CXX to support pthreads.])
 113                 CXX="$PTHREAD_CXX"
 114         fi
 115 fi
 116
 117 if test x$enable_threads = xyes \
 118 && test x$acx_pthread_ok = xno; then
 119         AC_MSG_ERROR([Multithreaded build requested (--enable-threads=yes), but usable library was found.])
 120 fi
 121
 122
 123 # Determine whether assertions should be enabled.
 124 AC_ARG_ENABLE(assertions, [  --enable-assertions     check runtime assertions (default=yes)])
 125 if test x$enable_assertions = xno; then
 126         ASSERT_FLAGS="-DNDEBUG"
 127 else
 128         ASSERT_FLAGS="-DDEBUG"
 129 fi
 130
 131 # Determine whether ImageMagick should be linked
 132 AC_ARG_WITH(imagemagick, [  --with-imagemagick      ImageMagick file handling: auto,no,yes (default=auto)])
 133 if test x$with_imagemagick != xno; then
 134
 135         # AC_CHECK_TOOL is somewhat broken for cross-compilation in
 136         # some versions of autoconf, so use a conditional instead.
 137
 138         if test x$host = x$build \
 139         || test x$host = x; then
 140                 AC_CHECK_TOOL(MAGICK_CONFIG, Magick-config, no)
 141         else
 142                 AC_CHECK_PROG(MAGICK_CONFIG, ${ac_tool_prefix}Magick-config, ${ac_tool_prefix}Magick-config, no)
 143         fi
 144
 145         if test x$MAGICK_CONFIG != xno; then
 146
 147                 # Bugs have been encountered in certain versions of ImageMagick
 148                 # older than 6.0.6.  Until a test is written to check for these
 149                 # bugs, check the version number instead.
 150
 151                 IMAGEMAGICK_VERSION=`Magick-config --version`
 152                 IMAGEMAGICK_VERSION_A=`echo $IMAGEMAGICK_VERSION | cut -f 1 -d '.'`
 153                 IMAGEMAGICK_VERSION_B=`echo $IMAGEMAGICK_VERSION | cut -f 2 -d '.'`
 154                 IMAGEMAGICK_VERSION_C=`echo $IMAGEMAGICK_VERSION | cut -f 3 -d '.'`
 155
 156                 if test $IMAGEMAGICK_VERSION_A -gt 6 \
 157                 || ( test $IMAGEMAGICK_VERSION_A -eq 6 \
 158                   && test $IMAGEMAGICK_VERSION_B -gt 0 ) \
 159                 || ( test $IMAGEMAGICK_VERSION_A -eq 6 \
 160                   && test $IMAGEMAGICK_VERSION_B -eq 0 \
 161                   && test $IMAGEMAGICK_VERSION_C -ge 6 ); then
 162                         IMAGEMAGICK_CFLAGS=`$MAGICK_CONFIG --cflags`
 163                         IMAGEMAGICK_CPPFLAGS="`$MAGICK_CONFIG --cppflags` -DUSE_MAGICK"
 164                         IMAGEMAGICK_LDFLAGS=`$MAGICK_CONFIG --ldflags`
 165                         IMAGEMAGICK_LIBS=`$MAGICK_CONFIG --libs`
 166                 else
 167                         AC_MSG_WARN([not using ImageMagick older than 6.0.6 (found $IMAGEMAGICK_VERSION)])
 168                 fi
 169         fi
 170 else
 171         IMAGEMAGICK_CFLAGS=""
 172         IMAGEMAGICK_CPPFLAGS=""
 173         IMAGEMAGICK_LDFLAGS=""
 174         IMAGEMAGICK_LIBS=""
 175 fi
 176
 177 # Fatal error if user flag for ImageMagick could not be satisified
 178 if test x$with_imagemagick = xyes \
 179 && test x$IMAGEMAGICK_CPPFLAGS = x; then
 180         AC_MSG_ERROR([ImageMagick build requested (--enable-imagemagick=yes), but no suitable version was found.])
 181 fi
 182
 183 # Determine whether FFTW should be linked
 184 AC_ARG_WITH(fftw3, [  --with-fftw3            FFTW3 fourier transforms: auto,no,yes (default=auto)])
 185 if test x$with_fftw3 != xno; then
 186         AC_CHECK_LIB([fftw3], [main], LIBS="-lfftw3 $LIBS" FFTW_CPPFLAGS="-DUSE_FFTW")
 187 fi
 188
 189 # Fatal error if user flag for FFTW could not be satisified
 190 if test x$with_fftw3 = xyes \
 191 && test x$FFTW_CPPFLAGS = x; then
 192         AC_MSG_ERROR([FFTW3 build requested (--enable-fftw3=yes), but no suitable version was found.])
 193 fi
 194
 195 # Determine the precision of colors that should be used
 196 AC_ARG_WITH(colors, [  --with-colors=[TYPE]      use TYPE colors: single,double (default=single)])
 197 if test x$with_colors = xsingle \
 198 || test x$with_colors = x; then
 199         COLOR_CPPFLAGS="-DALE_COLORS=SINGLE"
 200 elif test x$with_colors = xdouble; then
 201         COLOR_CPPFLAGS="-DALE_COLORS=DOUBLE"
 202 else
 203         AC_MSG_ERROR(option --with-colors=$with_colors is not currently supported)
 204 fi
 205
 206 # Determine the precision of coordinates that should be used
 207 AC_ARG_WITH(coords, [  --with-coords=[TYPE]      use TYPE coords: single,double (default=single)])
 208 if test x$with_coords = xsingle \
 209 || test x$with_coords = x; then
 210         COORD_CPPFLAGS="-DALE_COORDINATES=SINGLE"
 211 elif test x$with_coords = xdouble; then
 212         COORD_CPPFLAGS="-DALE_COORDINATES=DOUBLE"
 213 else
 214         AC_MSG_ERROR(option --with-coords=$with_coords is not currently supported)
 215 fi
 216
 217 # Determine whether optimizations should be used
 218 AC_ARG_ENABLE(optimization, [  --enable-optimizations  use optimization code (default=yes)])
 219 if test x$enable_optimizations = xyes \
 220 || test x$enable_optimizations = x; then
 221         OPTIMIZATION_CPPFLAGS="-DOPTIMIZATIONS=1"
 222 elif test x$enable_optimizations = xno; then
 223         OPTIMIZATION_CPPFLAGS="-DOPTIMIZATIONS=0"
 224 else
 225         AC_MSG_ERROR(option --enable-optimizations=$enable_optimizations is not currently supported)
 226 fi
 227
 228 # Determine whether hash maps should be used.
 229 AC_ARG_WITH(hashmap, [  --with-hashmap=[TYPE]     Use TYPE hash map: no,gnu,std (default=no)])
 230 if test x$with_hashmap = xno \
 231 || test x$with_hashmap = x; then
 232         STL_CPPFLAGS=""
 233 elif test x$with_hashmap = xgnu; then
 234         AC_CACHE_CHECK(whether GNU hash maps are available, ac_cv_gnu_hash,[
 235                 AC_LANG_SAVE
 236                 AC_LANG_CPLUSPLUS
 237                 AC_TRY_COMPILE([
 238                         #include <ext/hash_map>
 239                         struct node_hash
 240                         {
 241                                 size_t operator()(int n) const
 242                                 {
 243                                         return __gnu_cxx::hash<int>()(n);
 244                                 }
 245                         };
 246                         typedef __gnu_cxx::hash_map<int, int, node_hash> int_map_t;
 247                 ],[
 248                         int_map_t foo;
 249                 ], ac_cv_gnu_hash=yes, ac_cv_gnu_hash=no)
 250                 AC_LANG_RESTORE])
 251         if test $ac_cv_gnu_hash = yes; then
 252                 STL_CPPFLAGS="-DHASH_MAP_GNU"
 253         else
 254                 AC_MSG_ERROR([option --with-hashmap=gnu specified, but this configuration fails.])
 255         fi
 256 elif test x$with_hashmap = xstd; then
 257         AC_CACHE_CHECK(whether std hash maps are available, ac_cv_std_hash,[
 258                 AC_LANG_SAVE
 259                 AC_LANG_CPLUSPLUS
 260                 AC_TRY_COMPILE([
 261                         #include <ext/hash_map>
 262                         typedef std::hash_map<int, int> int_map_t;
 263                 ],[
 264                         int_map_t foo;
 265                 ], ac_cv_std_hash=yes, ac_cv_std_hash=no)
 266                 AC_LANG_RESTORE])
 267         if test $ac_cv_std_hash = yes; then
 268                 STL_CPPFLAGS="-DHASH_MAP_STD"
 269         else
 270                 AC_MSG_ERROR([option --with-hashmap=std specified, but this configuration fails.])
 271         fi
 272 else
 273         AC_MSG_ERROR(option --with-hashmap=$with_hashmap is not currently supported)
 274 fi
 275
 276
 277 # Determine whether ioctl() should be used for determining window dimensions
 278 AC_ARG_ENABLE(getsize, [  --enable-getsize        get terminal size: auto,no,yes (default=auto)
 279                             (not doing this disables certain UI updates)])
 280 if test x$enable_getsize != xno; then
 281
 282         # Check for Unix facilities.
 283         AC_CHECK_HEADER(sys/ioctl.h, AC_DEFINE([HAVE_SYS_IOCTL_H]))
 284         AC_CHECK_FUNC(ioctl, AC_DEFINE([HAVE_IOCTL], [], [ioctl() function is available.]))
 285         AC_CHECK_DECL(TIOCGWINSZ, have_winsz=yes, have_winsz=no, [#include <sys/ioctl.h>])
 286
 287         if test x$ac_cv_header_sys_ioctl_h = xyes \
 288         && test x$ac_cv_func_ioctl = xyes \
 289         && test x$have_winsz = xyes; then
 290                 IOCTL_CPPFLAGS="-DUSE_IOCTL"
 291         fi
 292 fi
 293
 294 # Fatal error if IOCTL configuration could not be satisfied
 295 if test x$enable_getsize = xyes \
 296 && test x$IOCTL_CPPFLAGS = x; then
 297         if test x$ac_cv_header_sys_ioctl_h != xyes; then
 298                 AC_MSG_ERROR([ioctl() for window size requested (--enable-getsize=yes), but sys/ioctl.h was not found.])
 299         fi
 300         if test x$ac_cv_func_ioctl != xyes; then
 301                 AC_MSG_ERROR([ioctl() for window size requested (--enable-getsize=yes), but ioctl() was not found.])
 302         fi
 303         if test x$have_winsz != xyes; then
 304                 AC_MSG_ERROR([ioctl() for window size requested (--enable-getsize=yes), but TIOCGWINSZ was not found.])
 305         fi
 306         AC_MSG_ERROR([ioctl() for window size requested (--enable-getsize=yes), but this configuration fails.])
 307 fi
 308
 309 # Determine whether the --wmx flag should be supported
 310 AC_ARG_ENABLE(wmx, [  --enable-wmx            Enable --wmx option: auto,no,yes (default=auto)
 311                             (this option requires execlp() and fork())])
 312 if test x$enable_wmx != xno; then
 313
 314         # Check for Unix facilities.
 315         AC_CHECK_HEADER(unistd.h, AC_DEFINE([HAVE_UNISTD_H]))
 316         AC_CHECK_FUNC(execlp, AC_DEFINE([HAVE_EXECLP], [], [execlp() function is available.]))
 317
 318         if test x$ac_cv_func_fork_works = xyes \
 319         && test x$ac_cv_header_unistd_h = xyes \
 320         && test x$ac_cv_func_execlp = xyes; then
 321                 UNIX_CPPFLAGS="-DUSE_UNIX"
 322         fi
 323 fi
 324
 325 # Fatal error if --wmx configuration could not be satisified
 326 if test x$enable_wmx = xyes \
 327 && test x$UNIX_CPPFLAGS = x; then
 328         if test x$ac_cv_func_execlp != xyes; then
 329                 AC_MSG_ERROR([--wmx support requested (--enable-wmx=yes), but execlp() was not found.])
 330         fi
 331         if test x$ac_cv_header_unistd_h != xyes; then
 332                 AC_MSG_ERROR([--wmx support requested (--enable-wmx=yes), but unistd.h header was not found.])
 333         fi
 334         if test x$ac_cv_func_fork_works != xyes; then
 335                 AC_MSG_ERROR([--wmx support requested (--enable-wmx=yes), but a working fork() was not found.])
 336         fi
 337         AC_MSG_ERROR([--wmx support requested (--enable-wmx=yes), but this configuration fails.])
 338 fi
 339
 340 OPTION_CPPFLAGS="$ASSERT_FLAGS $IMAGEMAGICK_CPPFLAGS $FFTW_CPPFLAGS $UNIX_CPPFLAGS $IOCTL_CPPFLAGS $COORD_CPPFLAGS $COLOR_CPPFLAGS $OPTIMIZATION_CPPFLAGS $STL_CPPFLAGS"
 341 OPTION_CFLAGS="$IMAGEMAGICK_CFLAGS $PTHREAD_CFLAGS"
 342 OPTION_LDFLAGS="$IMAGEMAGICK_LDFLAGS"
 343 OPTION_LIBS="$PTHREAD_LIBS $IMAGEMAGICK_LIBS"
 344
 345 AC_SUBST(OPTION_CPPFLAGS)
 346 AC_SUBST(OPTION_CFLAGS)
 347 AC_SUBST(OPTION_LDFLAGS)
 348 AC_SUBST(OPTION_LIBS)
 349
 350 AC_CONFIG_FILES([Makefile lib/Makefile])
 351
 352 AC_OUTPUT
 353
 354 # Since the generated Makefile seems to sometimes miss build steps that are
 355 # required due to reconfiguration, 'make clean' here.
 356
 357 AC_MSG_NOTICE(making clean)
 358 make clean &> /dev/null
 359