configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20 #
  21 # Process this file with autoconf to produce a configure script
  22
  23 # Initialize Autoconf
  24 AC_PREREQ([2.60])
  25 AC_INIT([xf86-video-sis],
  26         [0.12.1],
  27         [https://gitlab.freedesktop.org/xorg/driver/xf86-video-sis/issues],
  28         [xf86-video-sis])
  29 AC_CONFIG_SRCDIR([Makefile.am])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR(.)
  32
  33 # Initialize Automake
  34 AM_INIT_AUTOMAKE([foreign dist-xz])
  35
  36 # Require X.Org macros 1.8 or later for MAN_SUBSTS set by XORG_MANPAGE_SECTIONS
  37 m4_ifndef([XORG_MACROS_VERSION],
  38           [m4_fatal([must install xorg-macros 1.8 or later before running autoconf/autogen])])
  39 XORG_MACROS_VERSION(1.8)
  40 XORG_DEFAULT_OPTIONS
  41
  42 # Initialize libtool
  43 LT_INIT([disable-static])
  44
  45 AH_TOP([#include "xorg-server.h"])
  46
  47 # Define a configure option for an alternate module directory
  48 AC_ARG_WITH(xorg-module-dir,
  49             AS_HELP_STRING([--with-xorg-module-dir=DIR],
  50                            [Default xorg module directory [[default=$libdir/xorg/modules]]]),
  51             [moduledir="$withval"],
  52             [moduledir="$libdir/xorg/modules"])
  53
  54 AC_ARG_ENABLE(dri, AS_HELP_STRING([--disable-dri],
  55                                   [Disable DRI support [[default=auto]]]),
  56               [DRI="$enableval"],
  57               [DRI=auto])
  58
  59 # Store the list of server defined optional extensions in REQUIRED_MODULES
  60 XORG_DRIVER_CHECK_EXT(XINERAMA, xineramaproto)
  61 XORG_DRIVER_CHECK_EXT(RANDR, randrproto)
  62 XORG_DRIVER_CHECK_EXT(RENDER, renderproto)
  63 XORG_DRIVER_CHECK_EXT(XV, videoproto)
  64 XORG_DRIVER_CHECK_EXT(DPMSExtension, xextproto)
  65
  66 # Obtain compiler/linker options for the driver dependencies
  67 PKG_CHECK_MODULES(XORG, [xorg-server >= 1.18 xproto fontsproto xf86dgaproto >= 2.1 $REQUIRED_MODULES])
  68 PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
  69                   HAVE_XEXTPROTO_71="yes"; AC_DEFINE(HAVE_XEXTPROTO_71, 1, [xextproto 7.1 available]),
  70                   HAVE_XEXTPROTO_71="no")
  71 AM_CONDITIONAL(HAVE_XEXTPROTO_71, [ test "$HAVE_XEXTPROTO_71" = "yes" ])
  72 sdkdir=`$PKG_CONFIG --variable=sdkdir xorg-server`
  73
  74 # Checks for libraries.
  75
  76 if test "$DRI" != no; then
  77         if test "$cross_compiling" = "no" ; then
  78                AC_CHECK_FILE([${sdkdir}/dri.h],
  79                              [have_dri_h="yes"], [have_dri_h="no"])
  80                AC_CHECK_FILE([${sdkdir}/sarea.h],
  81                              [have_sarea_h="yes"], [have_sarea_h="no"])
  82                AC_CHECK_FILE([${sdkdir}/dristruct.h],
  83                              [have_dristruct_h="yes"], [have_dristruct_h="no"])
  84         else
  85                 have_dri_h="yes"
  86                 have_sarea_h="yes"
  87                 have_dristruct_h="yes"
  88         fi
  89 fi
  90
  91 AC_MSG_CHECKING([whether to include DRI support])
  92 if test x$DRI = xauto; then
  93         if test "$have_dri_h" = yes -a \
  94                 "$have_sarea_h" = yes -a \
  95                 "$have_dristruct_h" = yes; then
  96                 DRI="yes"
  97         else
  98                 DRI="no"
  99         fi
 100 fi
 101 AC_MSG_RESULT([$DRI])
 102
 103 AM_CONDITIONAL(DRI, test x$DRI = xyes)
 104 if test "$DRI" = yes; then
 105         PKG_CHECK_MODULES(DRI, [libdrm >= 2.0 xf86driproto])
 106         AC_DEFINE(SISDRI,1,[Enable DRI driver support])
 107         AC_DEFINE(SISDRI_DEVEL,1,[Enable developmental DRI driver support])
 108 fi
 109
 110 AC_ARG_ENABLE(xaa,
 111               AS_HELP_STRING([--enable-xaa],
 112                              [Enable legacy X Acceleration Architecture (XAA) [default=auto]]),
 113               [XAA="$enableval"],
 114               [XAA=auto])
 115 if test "x$XAA" != xno; then
 116         save_CFLAGS=$CFLAGS
 117         save_CPPFLAGS=$CPPFLAGS
 118         CFLAGS=$XORG_CFLAGS
 119         CPPFLAGS="$XORG_CFLAGS"
 120         AC_CHECK_HEADERS([xaa.h], XAA=yes, XAA=no)
 121         CFLAGS=$save_CFLAGS
 122         CPPFLAGS=$save_CPPFLAGS
 123 fi
 124 AC_MSG_CHECKING([whether to include XAA support])
 125 AM_CONDITIONAL(XAA, test "x$XAA" = xyes)
 126 AC_MSG_RESULT([$XAA])
 127
 128 # technically this should be a configure flag.  meh.
 129 AC_DEFINE(USE_EXA, 1, [Build support for EXA])
 130
 131 SAVE_CPPFLAGS="$CPPFLAGS"
 132 CPPFLAGS="$CPPFLAGS $XORG_CFLAGS"
 133 AC_CHECK_DECL(XSERVER_LIBPCIACCESS,
 134               [XSERVER_LIBPCIACCESS=yes],[XSERVER_LIBPCIACCESS=no],
 135               [#include "xorg-server.h"])
 136 CPPFLAGS="$SAVE_CPPFLAGS"
 137
 138 if test "x$XSERVER_LIBPCIACCESS" = xyes; then
 139     PKG_CHECK_MODULES([PCIACCESS], [pciaccess >= 0.12.901])
 140     XORG_CFLAGS="$XORG_CFLAGS $PCIACCESS_CFLAGS"
 141 fi
 142 AM_CONDITIONAL(XSERVER_LIBPCIACCESS, test "x$XSERVER_LIBPCIACCESS" = xyes)
 143
 144 # Checks for library functions
 145 # We don't use strlcat, strlcpy, or timingsafe_memcmp, but check to quiet
 146 # -Wredundant-decls warning from xorg/os.h which will otherwise redefine them.
 147 AC_CHECK_FUNCS([strlcat strlcpy timingsafe_memcmp])
 148
 149 AC_SUBST([moduledir])
 150
 151 DRIVER_NAME=sis
 152 AC_SUBST([DRIVER_NAME])
 153
 154 AC_CONFIG_FILES([
 155                 Makefile
 156                 src/Makefile
 157                 man/Makefile
 158 ])
 159 AC_OUTPUT