configure.ac

   1 # FileManager-Actions
   2 # A file-manager extension which offers configurable context menu actions.
   3 #
   4 # Copyright (C) 2005 The GNOME Foundation
   5 # Copyright (C) 2006-2008 Frederic Ruaudel and others (see AUTHORS)
   6 # Copyright (C) 2009-2014 Pierre Wieser and others (see AUTHORS)
   7 #
   8 # FileManager-Actions is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU General Public License as
  10 # published by the Free Software Foundation; either version 2 of
  11 # the License, or (at your option) any later version.
  12 #
  13 # FileManager-Actions is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with FileManager-Actions; see the file COPYING. If not, see
  20 # <http://www.gnu.org/licenses/>.
  21 #
  22 # Authors:
  23 #   Frederic Ruaudel <grumz@grumz.net>
  24 #   Rodrigo Moya <rodrigo@gnome-db.org>
  25 #   Pierre Wieser <pwieser@trychlos.org>
  26 #   ... and many others (see AUTHORS)
  27
  28 AC_PREREQ([2.53])
  29
  30 AC_INIT([FileManager-Actions],[3.4],[maintainer@nautilus-actions.org],,[http://www.nautilus-actions.org])
  31 AX_IS_RELEASE([git-directory])
  32
  33 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  34 AC_CANONICAL_TARGET
  35 AM_INIT_AUTOMAKE
  36
  37 # Code coverage
  38 AX_CODE_COVERAGE()
  39
  40 AC_CONFIG_SRCDIR([src/ui/main.c])
  41 AC_CONFIG_HEADERS([src/config.h])
  42 AC_CONFIG_MACRO_DIR([m4])
  43
  44 # check for compiler characteristics and options
  45 AC_PROG_CC
  46 AC_PROG_GCC_TRADITIONAL
  47 AC_STDC_HEADERS
  48 AM_DISABLE_STATIC
  49
  50 # define specific compilation options
  51 FMA_COMPILER_WARNINGS([],[-ansi -Wno-overlength-strings -Wformat=2])
  52 FMA_COMPILER_LINK_AS_NEEDED
  53 AC_SUBST([AM_CFLAGS],["${AM_CFLAGS} ${WARN_CFLAGS}"])
  54
  55 # other traditional tools
  56 AC_PROG_INSTALL
  57 AC_PROG_MAKE_SET
  58
  59 # Maintainer mode
  60 FMA_MAINTAINER_CHECK_MODE
  61
  62 # libtool
  63 AM_PROG_LIBTOOL
  64
  65 # we are using pkgconfig for all development libraries we need
  66 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  67 if test "${PKG_CONFIG}" = "no"; then
  68         AC_MSG_ERROR([You need to install pkg-config])
  69 fi
  70
  71 # required versions of tools and libraries
  72 source ${0%/*}/fma_required_versions
  73
  74 # localization
  75 GETTEXT_PACKAGE=${PACKAGE}
  76 AC_SUBST([GETTEXT_PACKAGE])
  77 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["${GETTEXT_PACKAGE}"],[gettext package])
  78 AM_GLIB_GNU_GETTEXT
  79 IT_PROG_INTLTOOL([${intltool_required}])
  80
  81 # a counter of fatal warnings emitted
  82 let fma_fatal_count=0
  83 fma_fatal_list=""
  84
  85 # GLib marshaling
  86 AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
  87 if test "${GLIB_GENMARSHAL}" = "no"; then
  88         AC_MSG_WARN([glib2-devel installed, but glib-genmarshal not found])
  89         let fma_fatal_count+=1
  90 fi
  91
  92 # add --enable-docs (for all documentation stuff)
  93 # have to be set early in the configure.ac in order to set all needed
  94 # variables
  95 FMA_ENABLE_DOCS
  96
  97 # Have and want GConf support ?
  98 # As of 3.4 release, we are deprecating GConf, disabling it by default.
  99 # We only search for the libraries when explicitely required from
 100 # configure. This is a first step deprecation; in a second step, we
 101 # will emit a warning.
 102 FMA_CHECK_FOR_GCONF
 103
 104 # cf. fma_required_versions
 105 # aclocal complains if the comma is not just after the square bracket
 106 FMA_CHECK_MODULE([GTK3],    [gtk+-3.0],   [${gtk_required}])
 107 FMA_CHECK_MODULE([GLIB],    [glib-2.0],   [${glib_required}])
 108 FMA_CHECK_MODULE([GMODULE], [gmodule-2.0],[${glib_required}])
 109 FMA_CHECK_MODULE([GIO_UNIX],[gio-unix-2.0])
 110 FMA_CHECK_MODULE([GTOP],    [libgtop-2.0],[${gtop_required}])
 111 FMA_CHECK_MODULE([LIBXML],  [libxml-2.0], [${xml_required}])
 112 FMA_CHECK_MODULE([UUID],    [uuid],       [${uuid_required}])
 113
 114 AC_SUBST([NAUTILUS_ACTIONS_CFLAGS])
 115 AC_SUBST([NAUTILUS_ACTIONS_LIBS])
 116
 117 # print the debug output be printed to the console
 118 AC_DEFINE([NAUTILUS_ACTIONS_DEBUG],["NAUTILUS_ACTIONS_DEBUG"],[Debug environment variable])
 119
 120 # target a file manager (nautilus, nemo, caja, ...)
 121 FMA_TARGET_FILE_MANAGER
 122
 123 # add --with-default-io-provider option
 124 FMA_SET_DEFAULT_IO_PROVIDER([io-desktop])
 125
 126 # Enable deprecated functions ?
 127 FMA_MAINTAINER_CHECK_FOR_DEPRECATED
 128
 129 # check for gtk-doc
 130 # - starting with gtk-doc 1.16, is able to handle srcdir != builddir
 131 # - API documentation should not be built (would be incomplete) when deprecated
 132 #   symbols are not enabled
 133 GTK_DOC_CHECK([1.16],[--flavour no-tmpl])
 134 if test "${enable_gtk_doc}" = "yes" -a "${enable_deprecated}" = "no"; then
 135         AC_MSG_WARN([API documentation will be incomplete as deprecated symbols are disabled])
 136 fi
 137
 138 # check for gnome-doc-utils
 139 # - starting with N-A 3.1.5, gnome-doc-utils is no more required when one want
 140 #   compile the tarball distribution (i.e. without regenerating users's manuals)
 141 GNOME_DOC_INIT(,,[gdu_cv_have_gdu=no])
 142
 143 # add --enable-html-manuals and --enable-pdf-manuals configure options
 144 FMA_ENABLE_MANUALS
 145
 146 ###
 147
 148 AC_CONFIG_FILES([
 149         Makefile
 150         data/Makefile
 151         data/actions/Makefile
 152         data/exports/Makefile
 153         data/gconf-schemas/Makefile
 154         docs/Makefile
 155         docs/manual/Makefile
 156         docs/reference/Makefile
 157         docs/reference/version.xml
 158         icons/Makefile
 159         icons/16x16/Makefile
 160         icons/22x22/Makefile
 161         icons/32x32/Makefile
 162         icons/48x48/Makefile
 163         icons/scalable/Makefile
 164         m4/Makefile
 165         maintainer/Makefile
 166         po/Makefile.in
 167         src/Makefile
 168         src/api/Makefile
 169         src/core/Makefile
 170         src/io-desktop/Makefile
 171         src/io-gconf/Makefile
 172         src/io-xml/Makefile
 173         src/plugin-menu/Makefile
 174         src/plugin-tracker/Makefile
 175         src/test/Makefile
 176         src/ui/Makefile
 177         src/utils/Makefile
 178 ])
 179
 180 # display and keep configuration informations
 181 config_options="`$as_echo "$ac_configure_args" | sed 's/^ //; s/[\\""\`\$]/\\\\&/g'`"
 182 AC_DEFINE_UNQUOTED([FMA_CONFIG_OPTIONS],["$0 ${config_options}"],["Configure options"])
 183
 184 AC_OUTPUT
 185
 186 msg_gtk_doc=`if test "x${enable_gtk_doc}" = "xno"; then echo "disabled"; else echo "enabled"; fi`
 187 $as_echo "
 188         ${PACKAGE_STRING} configuration summary:
 189
 190         Installation prefix             ${prefix}
 191         Build system type               ${ac_cv_build}
 192         Gtk+ version                    ${GTK3_msg_version}
 193         GLib version                    ${GLIB_msg_version}
 194         Default I/O provider            ${with_default_io_provider}"
 195 if test "${with_nautilus_ok}" = "yes"; then
 196         $as_echo "      Targeting Nautilus
 197           installing extensions in      ${with_nautilus_extdir}"
 198 fi
 199 if test "${with_nemo_ok}" = "yes"; then
 200         $as_echo "      Targeting Nemo
 201           installing extensions in      ${with_nemo_extdir}"
 202 fi
 203 if test "${with_caja_ok}" = "yes"; then
 204         $as_echo "      Targeting Caja
 205           installing extensions in      ${with_caja_extdir}"
 206 fi
 207 $as_echo "      GConf enabled                   ${enable_gconf}"
 208 if test "${enable_gconf}" = "yes"; then
 209         $as_echo "      GConf schemas installation      ${msg_schemas_install}"
 210 fi
 211 $as_echo "      Maintainer mode                 ${msg_maintainer_mode}
 212         Enable deprecated functions     ${enable_deprecated}
 213         API Reference generation        ${msg_gtk_doc}
 214         HTML User's Manuals generation  ${msg_html_manuals}
 215         PDF User's Manuals generation   ${msg_pdf_manuals}
 216 "
 217 if test ${fma_fatal_count} -gt 0; then
 218         $as_echo "${fma_fatal_list}
 219 "
 220         exit 1
 221 fi
 222
 223 #       Preprocessor flags              ${AM_CPPFLAGS}
 224 #       Compiler flags                  ${AM_CFLAGS} ${NAUTILUS_ACTIONS_CFLAGS}
 225 #       Linker flags                    ${NAUTILUS_ACTIONS_LIBS}