configure.ac

   1 # libmodbus package version number, (as distinct from shared library version)
   2 # An odd micro number indicates in-progress development from Git
   3 # An even micro number indicates a released version
   4 #
   5 # Making a point release:
   6 # - increase libmodbus_version_micro to the next even number
   7 #
   8 # After the release:
   9 # - increase libmodbus_version_minor to the next odd number
  10 #
  11 # Take care to update the libtool versioning when required (LIBMODBUS_LD_*).
  12 # http://www.gnu.org/software/libtool/manual/html_node/Libtool-versioning.html
  13 #
  14 m4_define([libmodbus_version_major], [3])
  15 m4_define([libmodbus_version_minor], [1])
  16 m4_define([libmodbus_version_micro], [10])
  17
  18 m4_define([libmodbus_release_status],
  19     [m4_if(m4_eval(libmodbus_version_minor % 2), [1], [snapshot], [release])])
  20
  21 m4_define([libmodbus_version],
  22     [libmodbus_version_major.libmodbus_version_minor.libmodbus_version_micro])
  23
  24 AC_PREREQ([2.63])
  25 AC_INIT([libmodbus],
  26         [libmodbus_version],
  27         [https://github.com/stephane/libmodbus/issues],
  28         [libmodbus],
  29         [http://libmodbus.org/])
  30 AC_CONFIG_SRCDIR([src/modbus.c])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32 AM_INIT_AUTOMAKE([check-news foreign 1.11 -Wall -Wno-portability silent-rules tar-pax subdir-objects])
  33 AC_PROG_CC
  34 AC_USE_SYSTEM_EXTENSIONS
  35 AC_SYS_LARGEFILE
  36 AC_CONFIG_MACRO_DIR([m4])
  37 AM_SILENT_RULES([yes])
  38
  39 LIBMODBUS_VERSION_MAJOR=libmodbus_version_major
  40 LIBMODBUS_VERSION_MINOR=libmodbus_version_minor
  41 LIBMODBUS_VERSION_MICRO=libmodbus_version_micro
  42 LIBMODBUS_VERSION=libmodbus_version
  43 AC_SUBST(LIBMODBUS_VERSION_MAJOR)
  44 AC_SUBST(LIBMODBUS_VERSION_MINOR)
  45 AC_SUBST(LIBMODBUS_VERSION_MICRO)
  46 AC_SUBST(LIBMODBUS_VERSION)
  47
  48 # ABI version
  49 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  50 LIBMODBUS_LD_CURRENT=6
  51 LIBMODBUS_LD_REVISION=0
  52 LIBMODBUS_LD_AGE=1
  53 LIBMODBUS_LT_VERSION_INFO=$LIBMODBUS_LD_CURRENT:$LIBMODBUS_LD_REVISION:$LIBMODBUS_LD_AGE
  54 AC_SUBST(LIBMODBUS_LT_VERSION_INFO)
  55
  56 AC_CANONICAL_HOST
  57
  58 # OS check
  59 os_win32="false"
  60 os_cygwin="false"
  61 os_qnx="false"
  62 case "${host_os}" in
  63       *mingw32*)
  64     os_win32="true"
  65   ;;
  66       *nto-qnx*)
  67     os_qnx="true"
  68   ;;
  69       *cygwin*)
  70     os_cygwin="true"
  71   ;;
  72 esac
  73 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "true")
  74 AM_CONDITIONAL(OS_QNX, test "$os_qnx" = "true")
  75
  76 m4_pattern_forbid([^LT_INIT])dnl
  77 LT_INIT([disable-static win32-dll pic-only])
  78
  79 AC_CHECK_HEADERS([ \
  80     arpa/inet.h \
  81     byteswap.h \
  82     errno.h \
  83     fcntl.h \
  84     limits.h \
  85     linux/serial.h \
  86     netdb.h \
  87     netinet/in.h \
  88     netinet/tcp.h \
  89     sys/ioctl.h \
  90     sys/params.h \
  91     sys/socket.h \
  92     sys/time.h \
  93     sys/types.h \
  94     termios.h \
  95     time.h \
  96     unistd.h \
  97 ])
  98
  99 # Cygwin defines IPTOS_LOWDELAY but can't handle that flag so it's necessary to
 100 # workaround that problem and Cygwin doesn't define MSG_DONTWAIT.
 101 AC_CHECK_DECLS([__CYGWIN__])
 102
 103 # Check for network function in libnetwork for Haiku
 104 AC_SEARCH_LIBS(accept, network socket)
 105
 106 # Checks for library functions.
 107 AC_CHECK_FUNCS([accept4 getaddrinfo gettimeofday inet_pton inet_ntop select socket strerror strlcpy])
 108
 109 # Required for MinGW with GCC v4.8.1 on Win7
 110 AC_DEFINE(WINVER, 0x0501, _)
 111
 112 # Required for bswap
 113 AC_C_INLINE
 114
 115 # libtool
 116 AC_PROG_CXX
 117
 118 # Various types
 119 AC_TYPE_INT64_T
 120 AC_TYPE_SIZE_T
 121 AC_TYPE_SSIZE_T
 122 AC_TYPE_UINT16_T
 123 AC_TYPE_UINT32_T
 124 AC_TYPE_UINT8_T
 125
 126 if test "$os_cygwin" = "false"; then
 127     # Required for getaddrinfo (TCP IP - IPv6)
 128     AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 129     if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 130         LIBS="$LIBS -lws2_32"
 131     AC_SUBST(LIBS)
 132     fi
 133 fi
 134
 135 # Check for RS485 support (Linux kernel version 2.6.28+)
 136 AC_CHECK_DECLS([TIOCSRS485], [], [], [[#include <sys/ioctl.h>]])
 137 # Check for RTS flags
 138 AC_CHECK_DECLS([TIOCM_RTS], [], [], [[#include <sys/ioctl.h>]])
 139
 140 # Wtype-limits is not supported by gcc 4.2 (default on recent Mac OS X)
 141 my_CFLAGS="-Wall \
 142 -Wmissing-declarations -Wmissing-prototypes \
 143 -Wnested-externs -Wpointer-arith \
 144 -Wpointer-arith -Wsign-compare -Wchar-subscripts \
 145 -Wstrict-prototypes -Wshadow \
 146 -Wformat-security"
 147 AC_SUBST([my_CFLAGS])
 148
 149 # Build options
 150 AC_ARG_ENABLE(tests,
 151         AS_HELP_STRING([--disable-tests],
 152         [Build tests (default: yes)]),,
 153         [enable_tests=yes])
 154 AM_CONDITIONAL(BUILD_TESTS, [test $enable_tests != no])
 155
 156 AC_CONFIG_HEADERS([config.h tests/unit-test.h])
 157 AC_CONFIG_FILES([
 158         Makefile
 159         src/Makefile
 160         src/modbus-version.h
 161         src/win32/modbus.dll.manifest
 162         tests/Makefile
 163         libmodbus.pc
 164 ])
 165
 166 AC_OUTPUT
 167 AC_MSG_RESULT([
 168         $PACKAGE $VERSION
 169         ===============
 170
 171         prefix:                 ${prefix}
 172         sysconfdir:             ${sysconfdir}
 173         libdir:                 ${libdir}
 174         includedir:             ${includedir}
 175
 176         compiler:               ${CC}
 177         cflags:                 ${CFLAGS}
 178         ldflags:                ${LDFLAGS}
 179
 180         tests:                  ${enable_tests}
 181 ])