media-libs/SoQt/SoQt-1.4.1-r1.ebuild

   1 # Copyright 1999-2009 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: /var/cvsroot/gentoo-x86/media-libs/SoQt/SoQt-1.4.1.ebuild,v 1.2 2008/12/15 19:05:07 angelos Exp $
   4
   5 EAPI="2"
   6
   7 inherit flag-o-matic
   8
   9 DESCRIPTION="The glue between Coin3D and Qt"
  10 SRC_URI="ftp://ftp.coin3d.org/pub/coin/src/all/${P}.tar.gz"
  11 HOMEPAGE="http://www.coin3d.org/"
  12
  13 SLOT="0"
  14 LICENSE="|| ( GPL-2 PEL )"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="doc qt4"
  17
  18 RDEPEND=">=media-libs/coin-2.4.4
  19         qt4? (
  20                 x11-libs/qt-gui:4[qt3support]
  21                 x11-libs/qt-opengl:4[qt3support]
  22                 x11-libs/qt-qt3support:4
  23         )
  24         !qt4? ( x11-libs/qt:3[opengl] )"
  25 DEPEND="${RDEPEND}
  26         dev-util/pkgconfig
  27         doc? ( app-doc/doxygen )"
  28
  29 src_configure() {
  30         if use qt4; then
  31                 export PATH="/usr/bin/:${PATH}"
  32                 export QTDIR="/usr"
  33                 export CONFIG_QTLIBS="$(pkg-config --libs QtGui)"
  34         fi
  35
  36         append-ldflags -Wl,--no-as-needed
  37
  38         econf --with-coin --disable-html-help $(use_enable doc html) htmldir=/usr/share/doc/${PF}/html
  39 }
  40
  41 src_compile() {
  42         emake -j1 || die "emake failed"
  43 }
  44
  45 src_install() {
  46         emake DESTDIR="${D}" install || die "emake install failed"
  47         dodoc AUTHORS ChangeLog NEWS README*
  48 }