configure.in

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT
   7 AM_INIT_AUTOMAKE(tor, 0.2.2.19-alpha)
   8 AM_CONFIG_HEADER(orconfig.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 if test -f /etc/redhat-release ; then
  13   if test -f /usr/kerberos/include ; then
  14     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  15   fi
  16 fi
  17
  18 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  19 # the += operator on it in src/or/Makefile.am
  20 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  21
  22 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  23 AC_ARG_ENABLE(buf-freelists,
  24    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  25 AC_ARG_ENABLE(openbsd-malloc,
  26    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  27 AC_ARG_ENABLE(instrument-downloads,
  28    AS_HELP_STRING(--enable-instrument-downloads, Instrument downloads of directory resources etc.))
  29 AC_ARG_ENABLE(static-openssl,
  30    AS_HELP_STRING(--enable-static-openssl, Link against a static openssl library. Requires --with-openssl-dir))
  31 AC_ARG_ENABLE(static-libevent,
  32    AS_HELP_STRING(--enable-static-libevent, Link against a static libevent library. Requires --with-libevent-dir))
  33 AC_ARG_ENABLE(static-zlib,
  34    AS_HELP_STRING(--enable-static-zlib, Link against a static zlib library. Requires --with-zlib-dir))
  35
  36 if test x$enable_buf_freelists != xno; then
  37   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  38             [Defined if we try to use freelists for buffer RAM chunks])
  39 fi
  40 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  41 if test x$enable_instrument_downloads = xyes; then
  42   AC_DEFINE(INSTRUMENT_DOWNLOADS, 1,
  43             [Defined if we want to keep track of how much of each kind of resource we download.])
  44 fi
  45
  46 AC_ARG_ENABLE(transparent,
  47      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  48      [case "${enableval}" in
  49         yes) transparent=true ;;
  50         no)  transparent=false ;;
  51         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  52       esac], [transparent=true])
  53
  54 AC_ARG_ENABLE(asciidoc,
  55      AS_HELP_STRING(--disable-asciidoc, don't use asciidoc (disables building of manpages)),
  56      [case "${enableval}" in
  57         yes) asciidoc=true ;;
  58         no)  asciidoc=false ;;
  59         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  60       esac], [asciidoc=true])
  61
  62
  63 AC_ARG_ENABLE(threads,
  64      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  65
  66 if test x$enable_threads = x; then
  67    case $host in
  68     *-*-solaris* )
  69      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  70      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  71 cpu workers lock up here, so I will disable threads.])
  72      enable_threads="no";;
  73     *)
  74      enable_threads="yes";;
  75    esac
  76 fi
  77
  78 if test "$enable_threads" = "yes"; then
  79   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  80 fi
  81
  82 case $host in
  83    *-*-solaris* )
  84      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  85      ;;
  86 esac
  87
  88 AC_ARG_ENABLE(gcc-warnings,
  89      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  90 AC_ARG_ENABLE(gcc-warnings-advisory,
  91      AS_HELP_STRING(--enable-gcc-warnings-advisory, [enable verbose warnings, excluding -Werror]))
  92
  93 dnl Adam shostack suggests the following for Windows:
  94 dnl -D_FORTIFY_SOURCE=2 -fstack-protector-all
  95 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
  96 dnl This requires that we use gcc and that we add -O2 to the CFLAGS.
  97 AC_ARG_ENABLE(gcc-hardening,
  98      AS_HELP_STRING(--enable-gcc-hardening, enable compiler security checks),
  99 [if test x$enableval = xyes; then
 100     CFLAGS="$CFLAGS -D_FORTIFY_SOURCE=2 -fstack-protector-all"
 101     CFLAGS="$CFLAGS -fwrapv -fPIE -Wstack-protector"
 102     CFLAGS="$CFLAGS --param ssp-buffer-size=1"
 103     LDFLAGS="$LDFLAGS -pie"
 104 fi])
 105
 106 dnl Linker hardening options
 107 dnl Currently these options are ELF specific - you can't use this with MacOSX
 108 AC_ARG_ENABLE(linker-hardening,
 109         AS_HELP_STRING(--enable-linker-hardening, enable linker security fixups),
 110 [if test x$enableval = xyes; then
 111     LDFLAGS="$LDFLAGS -z relro -z now"
 112 fi])
 113
 114 AC_ARG_ENABLE(local-appdata,
 115    AS_HELP_STRING(--enable-local-appdata, default to host local application data paths on Windows))
 116 if test "$enable_local_appdata" = "yes"; then
 117   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 118             [Defined if we default to host local appdata paths on Windows])
 119 fi
 120
 121 AC_PROG_CC
 122 AC_PROG_CPP
 123 AC_PROG_MAKE_SET
 124 AC_PROG_RANLIB
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 128
 129 dnl check for asciidoc and a2x
 130 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 131 AC_PATH_PROG([A2X], [a2x], none)
 132
 133 AM_CONDITIONAL(USE_ASCIIDOC, test x$asciidoc = xtrue)
 134
 135 AC_PATH_PROG([SHA1SUM], [sha1sum], none)
 136 AC_PATH_PROG([OPENSSL], [openssl], none)
 137
 138 TORUSER=_tor
 139 AC_ARG_WITH(tor-user,
 140         [  --with-tor-user=NAME    Specify username for tor daemon ],
 141         [
 142            TORUSER=$withval
 143         ]
 144 )
 145 AC_SUBST(TORUSER)
 146
 147 TORGROUP=_tor
 148 AC_ARG_WITH(tor-group,
 149         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 150         [
 151            TORGROUP=$withval
 152         ]
 153 )
 154 AC_SUBST(TORGROUP)
 155
 156
 157 dnl If WIN32 is defined and non-zero, we are building for win32
 158 AC_MSG_CHECKING([for win32])
 159 AC_RUN_IFELSE([AC_LANG_SOURCE([
 160 int main(int c, char **v) {
 161 #ifdef WIN32
 162 #if WIN32
 163   return 0;
 164 #else
 165   return 1;
 166 #endif
 167 #else
 168   return 2;
 169 #endif
 170 }])],
 171 bwin32=true; AC_MSG_RESULT([yes]),
 172 bwin32=false; AC_MSG_RESULT([no]),
 173 bwin32=cross; AC_MSG_RESULT([cross])
 174 )
 175
 176 if test "$bwin32" = cross; then
 177 AC_MSG_CHECKING([for win32 (cross)])
 178 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 179 #ifdef WIN32
 180 int main(int c, char **v) {return 0;}
 181 #else
 182 #error
 183 int main(int c, char **v) {return x(y);}
 184 #endif
 185 ])],
 186 bwin32=true; AC_MSG_RESULT([yes]),
 187 bwin32=false; AC_MSG_RESULT([no]))
 188 fi
 189
 190 if test "$bwin32" = true; then
 191 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 192 fi
 193 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 194
 195 dnl Enable C99 when compiling with MIPSpro
 196 AC_MSG_CHECKING([for MIPSpro compiler])
 197 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 198 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 199 #error
 200   return x(y);
 201 #endif
 202 ])],
 203 bmipspro=false; AC_MSG_RESULT(no),
 204 bmipspro=true; AC_MSG_RESULT(yes))
 205
 206 if test "$bmipspro" = true; then
 207   CFLAGS="$CFLAGS -c99"
 208 fi
 209
 210 AC_C_BIGENDIAN
 211
 212 AC_SEARCH_LIBS(socket, [socket])
 213 AC_SEARCH_LIBS(gethostbyname, [nsl])
 214 AC_SEARCH_LIBS(dlopen, [dl])
 215 AC_SEARCH_LIBS(inet_aton, [resolv])
 216
 217 if test "$enable_threads" = "yes"; then
 218   AC_SEARCH_LIBS(pthread_create, [pthread])
 219   AC_SEARCH_LIBS(pthread_detach, [pthread])
 220 fi
 221
 222 dnl -------------------------------------------------------------------
 223 dnl Check for functions before libevent, since libevent-1.2 apparently
 224 dnl exports strlcpy without defining it in a header.
 225
 226 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull getaddrinfo localtime_r gmtime_r memmem strtok_r writev readv flock prctl vasprintf)
 227
 228 using_custom_malloc=no
 229 if test x$enable_openbsd_malloc = xyes ; then
 230    AC_DEFINE(HAVE_MALLOC_GOOD_SIZE, 1, [Defined if we have the malloc_good_size function])
 231    using_custom_malloc=yes
 232 fi
 233 if test x$tcmalloc = xyes ; then
 234    using_custom_malloc=yes
 235 fi
 236 if test $using_custom_malloc = no ; then
 237    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 238 fi
 239
 240 if test "$enable_threads" = "yes"; then
 241   AC_CHECK_HEADERS(pthread.h)
 242   AC_CHECK_FUNCS(pthread_create)
 243 fi
 244
 245 dnl ------------------------------------------------------
 246 dnl Where do you live, libevent?  And how do we call you?
 247
 248 if test "$bwin32" = true; then
 249   TOR_LIB_WS32=-lws2_32
 250   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 251   # think it's actually necessary.
 252   TOR_LIB_GDI=-lgdi32
 253 else
 254   TOR_LIB_WS32=
 255   TOR_LIB_GDI=
 256 fi
 257 AC_SUBST(TOR_LIB_WS32)
 258 AC_SUBST(TOR_LIB_GDI)
 259
 260 dnl We need to do this before we try our disgusting hack below.
 261 AC_CHECK_HEADERS([sys/types.h])
 262
 263 dnl This is a disgusting hack so we safely include older libevent headers.
 264 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 265 AC_CHECK_TYPE(u_int32_t, unsigned long)
 266 AC_CHECK_TYPE(u_int16_t, unsigned short)
 267 AC_CHECK_TYPE(u_int8_t, unsigned char)
 268
 269 tor_libevent_pkg_redhat="libevent"
 270 tor_libevent_pkg_debian="libevent-dev"
 271 tor_libevent_devpkg_redhat="libevent-devel"
 272 tor_libevent_devpkg_debian="libevent-dev"
 273
 274 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 275 dnl linking for static builds.
 276 STATIC_LIBEVENT_FLAGS=""
 277 if test "$enable_static_libevent" = "yes"; then
 278     dnl Determine if we have clock_gettime in librt
 279     AC_SEARCH_LIBS([clock_gettime], [rt],
 280         [have_rt=yes])
 281     if test "$have_rt" = yes; then
 282       STATIC_LIBEVENT_FLAGS=" -lrt "
 283     else
 284       STATIC_LIBEVENT_FLAGS=""
 285     fi
 286 fi
 287
 288 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 289 #ifdef WIN32
 290 #include <winsock2.h>
 291 #endif
 292 #include <stdlib.h>
 293 #include <sys/time.h>
 294 #include <sys/types.h>
 295 #include <event.h>], [
 296 #ifdef WIN32
 297 #include <winsock2.h>
 298 #endif
 299 void exit(int); void *event_init(void);],
 300     [
 301 #ifdef WIN32
 302 {WSADATA d; WSAStartup(0x101,&d); }
 303 #endif
 304 event_init(); exit(0);
 305 ], [--with-libevent-dir], [/opt/libevent])
 306
 307 dnl Now check for particular libevent functions.
 308 save_LIBS="$LIBS"
 309 save_LDFLAGS="$LDFLAGS"
 310 save_CPPFLAGS="$CPPFLAGS"
 311 LIBS="-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $LIBS"
 312 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 313 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 314 AC_CHECK_FUNCS(event_get_version event_get_version_number event_get_method event_set_log_callback evdns_set_outgoing_bind_address event_base_loopexit)
 315 AC_CHECK_MEMBERS([struct event.min_heap_idx], , ,
 316 [#include <event.h>
 317 ])
 318
 319 AC_CHECK_HEADERS(event2/event.h event2/dns.h)
 320
 321 LIBS="$save_LIBS"
 322 LDFLAGS="$save_LDFLAGS"
 323 CPPFLAGS="$save_CPPFLAGS"
 324
 325
 326 AM_CONDITIONAL(USE_EXTERNAL_EVDNS, test x$ac_cv_header_event2_dns_h = xyes)
 327
 328 if test "$enable_static_libevent" = "yes"; then
 329    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 330      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 331    else
 332      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 333    fi
 334 else
 335      TOR_LIBEVENT_LIBS="-levent"
 336 fi
 337 AC_SUBST(TOR_LIBEVENT_LIBS)
 338
 339
 340 dnl ------------------------------------------------------
 341 dnl Where do you live, openssl?  And how do we call you?
 342
 343 tor_openssl_pkg_redhat="openssl"
 344 tor_openssl_pkg_debian="libssl"
 345 tor_openssl_devpkg_redhat="openssl-devel"
 346 tor_openssl_devpkg_debian="libssl-dev"
 347
 348 ALT_openssl_WITHVAL=""
 349 AC_ARG_WITH(ssl-dir,
 350   [  --with-ssl-dir=PATH    Obsolete alias for --with-openssl-dir ],
 351   [
 352       if test "x$withval" != xno && test "x$withval" != "x" ; then
 353          ALT_openssl_WITHVAL="$withval"
 354       fi
 355   ])
 356
 357 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 358     [#include <openssl/rand.h>],
 359     [void RAND_add(const void *buf, int num, double entropy);],
 360     [RAND_add((void*)0,0,0); exit(0);], [],
 361     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 362
 363 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 364
 365 echo "tor_cv_library_openssl_dir is $tor_cv_library_openssl_dir"
 366 if test "$enable_static_openssl" = "yes"; then
 367    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 368      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 369    else
 370      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 371    fi
 372 else
 373      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 374 fi
 375 AC_SUBST(TOR_OPENSSL_LIBS)
 376
 377 dnl ------------------------------------------------------
 378 dnl Where do you live, zlib?  And how do we call you?
 379
 380 tor_openssl_pkg_redhat="zlib"
 381 tor_openssl_pkg_debian="zlib1g"
 382 tor_openssl_devpkg_redhat="zlib-devel"
 383 tor_openssl_devpkg_debian="zlib1g-dev"
 384
 385 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 386     [#include <zlib.h>],
 387     [const char * zlibVersion(void);],
 388     [zlibVersion(); exit(0);], [--with-zlib-dir],
 389     [/opt/zlib])
 390
 391 if test "$enable_static_zlib" = "yes"; then
 392    if test "$tor_cv_library_zlib_dir" = "(system)"; then
 393      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
 394  using --enable-static-zlib")
 395    else
 396      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
 397      echo "$TOR_LIBDIR_zlib/libz.a"
 398    fi
 399 else
 400      TOR_ZLIB_LIBS="-lz"
 401 fi
 402 AC_SUBST(TOR_ZLIB_LIBS)
 403
 404 dnl Make sure to enable support for large off_t if available.
 405
 406 AC_SYS_LARGEFILE
 407
 408 AC_CHECK_HEADERS(unistd.h string.h signal.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 409
 410 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h sys/uio.h)
 411
 412 dnl These headers are not essential
 413
 414 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h linux/types.h sys/file.h malloc_np.h sys/prctl.h)
 415
 416 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 417 [#ifdef HAVE_MALLOC_H
 418 #include <malloc.h>
 419 #endif
 420 #ifdef HAVE_MALLOC_MALLOC_H
 421 #include <malloc/malloc.h>
 422 #endif])
 423
 424 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 425 [#ifdef HAVE_SYS_TYPES_H
 426 #include <sys/types.h>
 427 #endif
 428 #ifdef HAVE_SYS_SOCKET_H
 429 #include <sys/socket.h>
 430 #endif])
 431 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 432 [#ifdef HAVE_SYS_TYPES_H
 433 #include <sys/types.h>
 434 #endif
 435 #ifdef HAVE_SYS_SOCKET_H
 436 #include <sys/socket.h>
 437 #endif
 438 #ifdef HAVE_NET_IF_H
 439 #include <net/if.h>
 440 #endif])
 441 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 442         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 443 [#ifdef HAVE_SYS_TYPES_H
 444 #include <sys/types.h>
 445 #endif
 446 #ifdef HAVE_SYS_SOCKET_H
 447 #include <sys/socket.h>
 448 #endif
 449 #ifdef HAVE_LIMITS_H
 450 #include <limits.h>
 451 #endif
 452 #ifdef HAVE_LINUX_TYPES_H
 453 #include <linux/types.h>
 454 #endif
 455 #ifdef HAVE_NETINET_IN6_H
 456 #include <netinet/in6.h>
 457 #endif
 458 #ifdef HAVE_NETINET_IN_H
 459 #include <netinet/in.h>
 460 #endif])
 461
 462 if test x$transparent = xtrue ; then
 463    transparent_ok=0
 464    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 465      transparent_ok=1
 466    fi
 467    if test x$linux_netfilter_ipv4 = x1 ; then
 468      transparent_ok=1
 469    fi
 470    if test x$transparent_ok = x1 ; then
 471      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 472      case $host in
 473        *-*-openbsd*)
 474          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 475      esac
 476    else
 477      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 478    fi
 479 fi
 480
 481 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 482 [#ifdef HAVE_SYS_TYPES_H
 483 #include <sys/types.h>
 484 #endif
 485 #ifdef HAVE_SYS_TIME_H
 486 #include <sys/time.h>
 487 #endif])
 488
 489 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 490 dnl Watch out.
 491
 492 AC_CHECK_SIZEOF(int8_t)
 493 AC_CHECK_SIZEOF(int16_t)
 494 AC_CHECK_SIZEOF(int32_t)
 495 AC_CHECK_SIZEOF(int64_t)
 496 AC_CHECK_SIZEOF(uint8_t)
 497 AC_CHECK_SIZEOF(uint16_t)
 498 AC_CHECK_SIZEOF(uint32_t)
 499 AC_CHECK_SIZEOF(uint64_t)
 500 AC_CHECK_SIZEOF(intptr_t)
 501 AC_CHECK_SIZEOF(uintptr_t)
 502
 503 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 504
 505 AC_CHECK_SIZEOF(char)
 506 AC_CHECK_SIZEOF(short)
 507 AC_CHECK_SIZEOF(int)
 508 AC_CHECK_SIZEOF(long)
 509 AC_CHECK_SIZEOF(long long)
 510 AC_CHECK_SIZEOF(__int64)
 511 AC_CHECK_SIZEOF(void *)
 512 AC_CHECK_SIZEOF(time_t)
 513 AC_CHECK_SIZEOF(size_t)
 514
 515 AC_CHECK_TYPES([uint, u_char, ssize_t])
 516
 517 dnl used to include sockaddr_storage, but everybody has that.
 518 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
 519 [#ifdef HAVE_SYS_TYPES_H
 520 #include <sys/types.h>
 521 #endif
 522 #ifdef HAVE_NETINET_IN_H
 523 #include <netinet/in.h>
 524 #endif
 525 #ifdef HAVE_NETINET_IN6_H
 526 #include <netinet/in6.h>
 527 #endif
 528 #ifdef HAVE_SYS_SOCKET_H
 529 #include <sys/socket.h>
 530 #endif
 531 #ifdef MS_WINDOWS
 532 #define WIN32_WINNT 0x400
 533 #define _WIN32_WINNT 0x400
 534 #define WIN32_LEAN_AND_MEAN
 535 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 536 #include <winsock.h>
 537 #else
 538 #include <winsock2.h>
 539 #include <ws2tcpip.h>
 540 #endif
 541 #endif
 542 ])
 543 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
 544 [#ifdef HAVE_SYS_TYPES_H
 545 #include <sys/types.h>
 546 #endif
 547 #ifdef HAVE_NETINET_IN_H
 548 #include <netinet/in.h>
 549 #endif
 550 #ifdef HAVE_NETINET_IN6_H
 551 #include <netinet/in6.h>
 552 #endif
 553 #ifdef HAVE_SYS_SOCKET_H
 554 #include <sys/socket.h>
 555 #endif
 556 #ifdef MS_WINDOWS
 557 #define WIN32_WINNT 0x400
 558 #define _WIN32_WINNT 0x400
 559 #define WIN32_LEAN_AND_MEAN
 560 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 561 #include <winsock.h>
 562 #else
 563 #include <winsock2.h>
 564 #include <ws2tcpip.h>
 565 #endif
 566 #endif
 567 ])
 568
 569 AC_CHECK_TYPES([rlim_t], , ,
 570 [#ifdef HAVE_SYS_TYPES_H
 571 #include <sys/types.h>
 572 #endif
 573 #ifdef HAVE_SYS_TIME_H
 574 #include <sys/time.h>
 575 #endif
 576 #ifdef HAVE_SYS_RESOURCE_H
 577 #include <sys/resource.h>
 578 #endif
 579 ])
 580
 581 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 582 AC_RUN_IFELSE([AC_LANG_SOURCE([
 583 #ifdef HAVE_SYS_TYPES_H
 584 #include <sys/types.h>
 585 #endif
 586 #ifdef HAVE_SYS_TIME_H
 587 #include <sys/time.h>
 588 #endif
 589 #ifdef HAVE_TIME_H
 590 #include <time.h>
 591 #endif
 592 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }])],
 593   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 594 ])
 595
 596 if test "$tor_cv_time_t_signed" = cross; then
 597   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 598 fi
 599
 600 if test "$tor_cv_time_t_signed" != no; then
 601   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 602             [Define to 1 iff time_t is signed])
 603 fi
 604
 605 AC_CACHE_CHECK([whether size_t is signed], tor_cv_size_t_signed, [
 606 AC_RUN_IFELSE([AC_LANG_SOURCE([
 607 #ifdef HAVE_SYS_TYPES_H
 608 #include <sys/types.h>
 609 #endif
 610 int main(int c, char**v) { if (((size_t)-1)<0) return 1; else return 0; }])],
 611   tor_cv_size_t_signed=no, tor_cv_size_t_signed=yes, tor_cv_size_t_signed=cross)
 612 ])
 613
 614 if test "$tor_cv_size_t_signed" = cross; then
 615   AC_MSG_NOTICE([Cross compiling: assuming that size_t is not signed.])
 616 fi
 617
 618 if test "$tor_cv_size_t_signed" = yes; then
 619   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
 620 fi
 621
 622 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 623 #ifdef HAVE_SYS_SOCKET_H
 624 #include <sys/socket.h>
 625 #endif
 626 ])
 627
 628 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 629
 630 AC_CHECK_SIZEOF(cell_t)
 631
 632 # Now make sure that NULL can be represented as zero bytes.
 633 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 634 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 635 [[#include <stdlib.h>
 636 #include <string.h>
 637 #include <stdio.h>
 638 #ifdef HAVE_STDDEF_H
 639 #include <stddef.h>
 640 #endif
 641 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 642 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 643        [tor_cv_null_is_zero=yes],
 644        [tor_cv_null_is_zero=no],
 645        [tor_cv_null_is_zero=cross])])
 646
 647 if test "$tor_cv_null_is_zero" = cross ; then
 648   # Cross-compiling; let's hope that the target isn't raving mad.
 649   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 650 fi
 651
 652 if test "$tor_cv_null_is_zero" != no; then
 653   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 654             [Define to 1 iff memset(0) sets pointers to NULL])
 655 fi
 656
 657 # And what happens when we malloc zero?
 658 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 659 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 660 [[#include <stdlib.h>
 661 #include <string.h>
 662 #include <stdio.h>
 663 #ifdef HAVE_STDDEF_H
 664 #include <stddef.h>
 665 #endif
 666 int main () { return malloc(0)?0:1; }]])],
 667        [tor_cv_malloc_zero_works=yes],
 668        [tor_cv_malloc_zero_works=no],
 669        [tor_cv_malloc_zero_works=cross])])
 670
 671 if test "$tor_cv_malloc_zero_works" = cross; then
 672   # Cross-compiling; let's hope that the target isn't raving mad.
 673   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 674 fi
 675
 676 if test "$tor_cv_malloc_zero_works" = yes; then
 677   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 678             [Define to 1 iff malloc(0) returns a pointer])
 679 fi
 680
 681 # whether we seem to be in a 2s-complement world.
 682 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 683 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 684 [[int main () { int problem = ((-99) != (~99)+1);
 685 return problem ? 1 : 0; }]])],
 686        [tor_cv_twos_complement=yes],
 687        [tor_cv_twos_complement=no],
 688        [tor_cv_twos_complement=cross])])
 689
 690 if test "$tor_cv_twos_complement" = cross ; then
 691   # Cross-compiling; let's hope that the target isn't raving mad.
 692   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 693 fi
 694
 695 if test "$tor_cv_twos_complement" != no ; then
 696   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 697             [Define to 1 iff we represent negative integers with two's complement])
 698 fi
 699
 700 # Whether we should use the dmalloc memory allocation debugging library.
 701 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 702 AC_ARG_WITH(dmalloc,
 703 [  --with-dmalloc          Use debug memory allocation library. ],
 704 [if [[ "$withval" = "yes" ]]; then
 705   dmalloc=1
 706   AC_MSG_RESULT(yes)
 707 else
 708   dmalloc=1
 709   AC_MSG_RESULT(no)
 710 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 711 )
 712
 713 if [[ $dmalloc -eq 1 ]]; then
 714   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 715   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 716   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 717   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 718   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 719 fi
 720
 721 AC_ARG_WITH(tcmalloc,
 722 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 723 [ tcmalloc=yes ], [ tcmalloc=no ])
 724
 725 if test x$tcmalloc = xyes ; then
 726    LDFLAGS="-ltcmalloc $LDFLAGS"
 727 fi
 728
 729 # By default, we're going to assume we don't have mlockall()
 730 # bionic and other platforms have various broken mlockall subsystems.
 731 # Some systems don't have a working mlockall, some aren't linkable,
 732 # and some have it but don't declare it.
 733 AC_CHECK_FUNCS(mlockall)
 734 AC_CHECK_DECLS([mlockall], , , [
 735 #ifdef HAVE_SYS_MMAN_H
 736 #include <sys/mman.h>
 737 #endif])
 738
 739 # Allow user to specify an alternate syslog facility
 740 AC_ARG_WITH(syslog-facility,
 741 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 742 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 743 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 744 AC_SUBST(LOGFACILITY)
 745
 746 # Check if we have getresuid and getresgid
 747 AC_CHECK_FUNCS(getresuid getresgid)
 748
 749 # Check for gethostbyname_r in all its glorious incompatible versions.
 750 #   (This logic is based on that in Python's configure.in)
 751 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 752   [Define this if you have any gethostbyname_r()])
 753
 754 AC_CHECK_FUNC(gethostbyname_r, [
 755   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 756   OLD_CFLAGS=$CFLAGS
 757   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 758   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 759 #include <netdb.h>
 760   ], [[
 761     char *cp1, *cp2;
 762     struct hostent *h1, *h2;
 763     int i1, i2;
 764     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 765   ]])],[
 766     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 767     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 768      [Define this if gethostbyname_r takes 6 arguments])
 769     AC_MSG_RESULT(6)
 770   ], [
 771     AC_TRY_COMPILE([
 772 #include <netdb.h>
 773     ], [
 774       char *cp1, *cp2;
 775       struct hostent *h1;
 776       int i1, i2;
 777       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 778     ], [
 779       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 780       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 781         [Define this if gethostbyname_r takes 5 arguments])
 782       AC_MSG_RESULT(5)
 783    ], [
 784       AC_TRY_COMPILE([
 785 #include <netdb.h>
 786      ], [
 787        char *cp1;
 788        struct hostent *h1;
 789        struct hostent_data hd;
 790        (void) gethostbyname_r(cp1,h1,&hd);
 791      ], [
 792        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 793        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 794          [Define this if gethostbyname_r takes 3 arguments])
 795        AC_MSG_RESULT(3)
 796      ], [
 797        AC_MSG_RESULT(0)
 798      ])
 799   ])
 800  ])
 801  CFLAGS=$OLD_CFLAGS
 802 ])
 803
 804 AC_CACHE_CHECK([whether the C compiler supports __func__],
 805   tor_cv_have_func_macro,
 806   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 807 #include <stdio.h>
 808 int main(int c, char **v) { puts(__func__); }])],
 809   tor_cv_have_func_macro=yes,
 810   tor_cv_have_func_macro=no))
 811
 812 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 813   tor_cv_have_FUNC_macro,
 814   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 815 #include <stdio.h>
 816 int main(int c, char **v) { puts(__FUNC__); }])],
 817   tor_cv_have_FUNC_macro=yes,
 818   tor_cv_have_FUNC_macro=no))
 819
 820 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 821   tor_cv_have_FUNCTION_macro,
 822   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 823 #include <stdio.h>
 824 int main(int c, char **v) { puts(__FUNCTION__); }])],
 825   tor_cv_have_FUNCTION_macro=yes,
 826   tor_cv_have_FUNCTION_macro=no))
 827
 828 if test "$tor_cv_have_func_macro" = 'yes'; then
 829   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 830 fi
 831
 832 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 833   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 834 fi
 835
 836 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 837   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 838            [Defined if the compiler supports __FUNCTION__])
 839 fi
 840
 841 # $prefix stores the value of the --prefix command line option, or
 842 # NONE if the option wasn't set.  In the case that it wasn't set, make
 843 # it be the default, so that we can use it to expand directories now.
 844 if test "x$prefix" = "xNONE"; then
 845   prefix=$ac_default_prefix
 846 fi
 847
 848 # and similarly for $exec_prefix
 849 if test "x$exec_prefix" = "xNONE"; then
 850   exec_prefix=$prefix
 851 fi
 852
 853 if test "x$CONFDIR" = "x"; then
 854   CONFDIR=`eval echo $sysconfdir/tor`
 855 fi
 856 AC_SUBST(CONFDIR)
 857 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 858 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 859
 860 BINDIR=`eval echo $bindir`
 861 AC_SUBST(BINDIR)
 862 LOCALSTATEDIR=`eval echo $localstatedir`
 863 AC_SUBST(LOCALSTATEDIR)
 864
 865 if test "$bwin32" = true; then
 866   # Test if the linker supports the --nxcompat and --dynamicbase options
 867   # for Windows
 868   save_LDFLAGS="$LDFLAGS"
 869   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
 870   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
 871   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 872     [AC_MSG_RESULT([yes])]
 873     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
 874     [AC_MSG_RESULT([no])]
 875   )
 876   LDFLAGS="$save_LDFLAGS"
 877 fi
 878
 879 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 880 # than autoconf's macros like.
 881 if test "$GCC" = yes; then
 882   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
 883   # accident waiting to happen.
 884   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
 885 else
 886   # Autoconf sets -g -O2 by default. Override optimization level
 887   # for non-gcc compilers
 888   CFLAGS="$CFLAGS -O"
 889   enable_gcc_warnings=no
 890   enable_gcc_warnings_advisory=no
 891 fi
 892
 893 # Add some more warnings which we use in development but not in the
 894 # released versions.  (Some relevant gcc versions can't handle these.)
 895 if test x$enable_gcc_warnings = xyes || test x$enable_gcc_warnings_advisory = xyes; then
 896
 897   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 898 #if !defined(__GNUC__) || (__GNUC__ < 4)
 899 #error
 900 #endif])], have_gcc4=yes, have_gcc4=no)
 901
 902   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 903 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 904 #error
 905 #endif])], have_gcc42=yes, have_gcc42=no)
 906
 907   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 908 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
 909 #error
 910 #endif])], have_gcc43=yes, have_gcc43=no)
 911
 912   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 913 #if !defined(__clang__) || (__clang_major__ > 2) || (__clang_major__ == 2 && __clang_minor__ > 9)
 914 #error
 915 #endif])], have_clang29orlower=yes, have_clang29orlower=no)
 916
 917   save_CFLAGS="$CFLAGS"
 918   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 919   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], have_shorten64_flag=yes,
 920                     have_shorten64_flag=no)
 921   CFLAGS="$save_CFLAGS"
 922
 923   case $host in
 924     *-*-openbsd*)
 925       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
 926       # That's fine, except that the headers don't pass -Wredundant-decls.
 927       # Therefore, let's disable -Wsystem-headers when we're building
 928       # with maximal warnings on OpenBSD.
 929       CFLAGS="$CFLAGS -Wno-system-headers" ;;
 930   esac
 931
 932   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum"
 933   if test x$enable_gcc_warnings = xyes; then
 934     CFLAGS="$CFLAGS -Werror"
 935   fi
 936
 937   # Disabled, so we can use mallinfo(): -Waggregate-return
 938
 939   if test x$have_gcc4 = xyes ; then
 940     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 941     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 942   fi
 943
 944   if test x$have_gcc42 = xyes ; then
 945     # These warnings break gcc 4.0.2 and work on gcc 4.2
 946     # XXXX020 See if any of these work with earlier versions.
 947     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wstrict-overflow=1"
 948
 949     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
 950   fi
 951
 952   if test x$have_gcc42 = xyes && test x$have_clang29orlower = xno; then
 953     # These warnings break gcc 4.0.2 and clang, but work on gcc 4.2
 954     # We only disable these for clang 2.9 and lower, in case they are
 955     # supported in later versions.
 956     CFLAGS="$CFLAGS -Wnormalized=id -Woverride-init"
 957   fi
 958
 959   if test x$have_gcc43 = xyes ; then
 960     # These warnings break gcc 4.2 and work on gcc 4.3
 961     # XXXX020 See if any of these work with earlier versions.
 962     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
 963   fi
 964
 965   if test x$have_shorten64_flag = xyes ; then
 966     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 967   fi
 968
 969 ##This will break the world on some 64-bit architectures
 970 # CFLAGS="$CFLAGS -Winline"
 971 fi
 972
 973
 974
 975 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 976
 977 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile src/config/torrc.sample src/Makefile doc/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/test/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 978 AC_OUTPUT
 979
 980 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 981   ./contrib/updateVersions.pl
 982 fi
 983