contrib/tor-mingw.nsi.in

   1 ;tor.nsi - A basic win32 installer for Tor
   2 ; Originally written by J Doe.
   3 ; Modified by Steve Topletz, Andrew Lewman
   4 ; See the Tor LICENSE for licensing information
   5 ;-----------------------------------------
   6 ;
   7 !include "MUI.nsh"
   8 !include "LogicLib.nsh"
   9 !include "FileFunc.nsh"
  10 !insertmacro GetParameters
  11 !define VERSION "0.2.2.10-alpha-dev"
  12 !define INSTALLER "tor-${VERSION}-win32.exe"
  13 !define WEBSITE "https://www.torproject.org/"
  14 !define LICENSE "LICENSE"
  15 !define BIN "..\bin" ;BIN is where it expects to find tor.exe, tor-resolve.exe
  16
  17
  18 SetCompressor /SOLID LZMA ;Tighter compression
  19 RequestExecutionLevel user ;Updated for Vista compatibility
  20 OutFile ${INSTALLER}
  21 InstallDir $PROGRAMFILES\Tor
  22 SetOverWrite ifnewer
  23 Name "Tor"
  24 Caption "Tor ${VERSION} Setup"
  25 BrandingText "The Onion Router"
  26 CRCCheck on
  27 XPStyle on
  28 VIProductVersion "${VERSION}"
  29 VIAddVersionKey "ProductName" "The Onion Router: Tor"
  30 VIAddVersionKey "Comments" "${WEBSITE}"
  31 VIAddVersionKey "LegalTrademarks" "Three line BSD"
  32 VIAddVersionKey "LegalCopyright" "©2004-2008, Roger Dingledine, Nick Mathewson"
  33 VIAddVersionKey "FileDescription" "Tor is an implementation of Onion Routing. You can read more at ${WEBSITE}"
  34 VIAddVersionKey "FileVersion" "${VERSION}"
  35
  36 !define MUI_WELCOMEPAGE_TITLE "Welcome to the Tor Setup Wizard"
  37 !define MUI_WELCOMEPAGE_TEXT "This wizard will guide you through the installation of Tor ${VERSION}.\r\n\r\nIf you have previously installed Tor and it is currently running, please exit Tor first before continuing this installation.\r\n\r\n$_CLICK"
  38 !define MUI_ABORTWARNING
  39 !define MUI_ICON "${NSISDIR}\Contrib\Graphics\Icons\win-install.ico"
  40 !define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\win-uninstall.ico"
  41 !define MUI_HEADERIMAGE_BITMAP "${NSISDIR}\Contrib\Graphics\Header\win.bmp"
  42 !define MUI_FINISHPAGE_RUN "$INSTDIR\tor.exe"
  43 !define MUI_FINISHPAGE_LINK "Visit the Tor website for the latest updates."
  44 !define MUI_FINISHPAGE_LINK_LOCATION ${WEBSITE}
  45
  46 !insertmacro MUI_PAGE_WELCOME
  47 ; There's no point in having a clickthrough license: Our license adds
  48 ; certain rights, but doesn't remove them.
  49 ; !insertmacro MUI_PAGE_LICENSE "${LICENSE}"
  50 !insertmacro MUI_PAGE_COMPONENTS
  51 !insertmacro MUI_PAGE_DIRECTORY
  52 !insertmacro MUI_PAGE_INSTFILES
  53 !insertmacro MUI_PAGE_FINISH
  54 !insertmacro MUI_UNPAGE_WELCOME
  55 !insertmacro MUI_UNPAGE_CONFIRM
  56 !insertmacro MUI_UNPAGE_INSTFILES
  57 !insertmacro MUI_UNPAGE_FINISH
  58 !insertmacro MUI_LANGUAGE "English"
  59
  60 Var CONFIGDIR
  61 Var CONFIGFILE
  62
  63 Function .onInit
  64         Call ParseCmdLine
  65 FunctionEnd
  66
  67 ;Sections
  68 ;--------
  69
  70 Section "Tor" Tor
  71 ;Files that have to be installed for tor to run and that the user
  72 ;cannot choose not to install
  73         SectionIn RO
  74         SetOutPath $INSTDIR
  75         Call ExtractBinaries
  76         Call ExtractIcon
  77         WriteINIStr "$INSTDIR\Tor Website.url" "InternetShortcut" "URL" ${WEBSITE}
  78
  79         StrCpy $CONFIGFILE "torrc"
  80         StrCpy $CONFIGDIR $APPDATA\Tor
  81 ;   ;If $APPDATA isn't valid here (Early win95 releases with no updated
  82 ;   ; shfolder.dll) then we put it in the program directory instead.
  83 ;   StrCmp $APPDATA "" "" +2
  84 ;      StrCpy $CONFIGDIR $INSTDIR
  85         SetOutPath $CONFIGDIR
  86         ;If there's already a torrc config file, ask if they want to
  87         ;overwrite it with the new one.
  88         ${If} ${FileExists} "$CONFIGDIR\torrc"
  89                 MessageBox MB_ICONQUESTION|MB_YESNO "You already have a Tor config file.$\r$\nDo you want to overwrite it with the default sample config file?" IDYES Yes IDNO No
  90                 Yes:
  91                         Delete $CONFIGDIR\torrc
  92                         Goto Next
  93                 No:
  94                         StrCpy $CONFIGFILE "torrc.sample"
  95                 Next:
  96         ${EndIf}
  97         File /oname=$CONFIGFILE "..\src\config\torrc.sample"
  98
  99 ; the geoip file needs to be included and stuffed into the right directory
 100 ; otherwise tor is unhappy
 101         SetOutPath $APPDATA\Tor
 102         Call ExtractGEOIP
 103 SectionEnd
 104
 105 Section "Documents" Docs
 106         Call ExtractDocuments
 107 SectionEnd
 108
 109 SubSection /e "Shortcuts" Shortcuts
 110
 111 Section "Start Menu" StartMenu
 112   SetOutPath $INSTDIR
 113   ${If} ${FileExists} "$SMPROGRAMS\Tor\*.*"
 114     RMDir /r "$SMPROGRAMS\Tor"
 115   ${EndIf}
 116   Call CreateTorLinks
 117   ${If} ${FileExists} "$INSTDIR\Documents\*.*"
 118     Call CreateDocLinks
 119   ${EndIf}
 120 SectionEnd
 121
 122 Section "Desktop" Desktop
 123    SetOutPath $INSTDIR
 124    CreateShortCut "$DESKTOP\Tor.lnk" "$INSTDIR\tor.exe" "" "$INSTDIR\tor.ico"
 125 SectionEnd
 126
 127 Section /o "Run at startup" Startup
 128    SetOutPath $INSTDIR
 129    CreateShortCut "$SMSTARTUP\Tor.lnk" "$INSTDIR\tor.exe" "" "$INSTDIR\tor.ico" "" SW_SHOWMINIMIZED
 130 SectionEnd
 131
 132 SubSectionEnd
 133
 134 Section "Uninstall"
 135    Call un.InstallPackage
 136 SectionEnd
 137
 138 Section -End
 139     WriteUninstaller "$INSTDIR\Uninstall.exe"
 140     ;The registry entries simply add the Tor uninstaller to the Windows
 141     ;uninstall list.
 142     WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Tor" "DisplayName" "Tor (remove only)"
 143     WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Tor" "UninstallString" '"$INSTDIR\Uninstall.exe"'
 144 SectionEnd
 145
 146 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 147 !insertmacro MUI_DESCRIPTION_TEXT ${Tor} "The core executable and config files needed for Tor to run."
 148 !insertmacro MUI_DESCRIPTION_TEXT ${Docs} "Documentation about Tor."
 149 !insertmacro MUI_DESCRIPTION_TEXT ${ShortCuts} "Shortcuts to easily start Tor"
 150 !insertmacro MUI_DESCRIPTION_TEXT ${StartMenu} "Shortcuts to access Tor and it's documentation from the Start Menu"
 151 !insertmacro MUI_DESCRIPTION_TEXT ${Desktop} "A shortcut to start Tor from the desktop"
 152 !insertmacro MUI_DESCRIPTION_TEXT ${Startup} "Launches Tor automatically at startup in a minimized window"
 153 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 154
 155 ;####################Functions#########################
 156
 157 Function ExtractBinaries
 158         File "${BIN}\tor.exe"
 159         File "${BIN}\tor-resolve.exe"
 160 FunctionEnd
 161
 162 Function ExtractGEOIP
 163         File "${BIN}\geoip"
 164 FunctionEnd
 165
 166 Function ExtractIcon
 167         File "${BIN}\tor.ico"
 168 FunctionEnd
 169
 170 Function ExtractSpecs
 171         File "..\doc\HACKING"
 172         File "..\doc\spec\address-spec.txt"
 173         File "..\doc\spec\control-spec.txt"
 174         File "..\doc\spec\control-spec-v0.txt"
 175         File "..\doc\spec\dir-spec.txt"
 176         File "..\doc\spec\dir-spec-v1.txt"
 177         File "..\doc\spec\path-spec.txt"
 178         File "..\doc\spec\rend-spec.txt"
 179         File "..\doc\spec\socks-extensions.txt"
 180         File "..\doc\spec\tor-spec.txt"
 181         File "..\doc\spec\version-spec.txt"
 182 FunctionEnd
 183
 184 Function ExtractHTML
 185         File "..\doc\tor-resolve.html"
 186         File "..\doc\tor-reference.html"
 187 FunctionEnd
 188
 189 Function ExtractDesignDocs
 190         File "..\doc\design-paper\tor-design.pdf"
 191 FunctionEnd
 192
 193 Function ExtractReleaseDocs
 194         File "..\README"
 195         File "..\AUTHORS"
 196         File "..\ChangeLog"
 197         File "..\LICENSE"
 198 FunctionEnd
 199
 200 Function ExtractDocuments
 201         SetOutPath "$INSTDIR\Documents"
 202         Call ExtractSpecs
 203         Call ExtractHTML
 204         Call ExtractDesignDocs
 205         Call ExtractReleaseDocs
 206 FunctionEnd
 207
 208 Function un.InstallFiles
 209         Delete "$DESKTOP\Tor.lnk"
 210         Delete "$INSTDIR\tor.exe"
 211         Delete "$INSTDIR\tor-resolve.exe"
 212         Delete "$INSTDIR\Tor Website.url"
 213         Delete "$INSTDIR\torrc"
 214         Delete "$INSTDIR\torrc.sample"
 215         Delete "$INSTDIR\tor.ico"
 216         Delete "$SMSTARTUP\Tor.lnk"
 217         Delete "$INSTDIR\Uninstall.exe"
 218     Delete "$INSTDIR\geoip"
 219 FunctionEnd
 220
 221 Function un.InstallDirectories
 222         ${If} $CONFIGDIR == $INSTDIR
 223                 RMDir /r $CONFIGDIR
 224         ${EndIf}
 225         RMDir /r "$INSTDIR\Documents"
 226         RMDir $INSTDIR
 227         RMDir /r "$SMPROGRAMS\Tor"
 228         RMDir /r "$APPDATA\Tor"
 229 FunctionEnd
 230
 231 Function un.WriteRegistry
 232         DeleteRegKey HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Tor"
 233 FunctionEnd
 234
 235 Function un.InstallPackage
 236         Call un.InstallFiles
 237         Call un.InstallDirectories
 238         Call un.WriteRegistry
 239 FunctionEnd
 240
 241 Function CreateTorLinks
 242         CreateDirectory "$SMPROGRAMS\Tor"
 243         CreateShortCut "$SMPROGRAMS\Tor\Tor.lnk" "$INSTDIR\tor.exe" "" "$INSTDIR\tor.ico"
 244         CreateShortCut "$SMPROGRAMS\Tor\Torrc.lnk" "Notepad.exe" "$CONFIGDIR\torrc"
 245         CreateShortCut "$SMPROGRAMS\Tor\Tor Website.lnk" "$INSTDIR\Tor Website.url"
 246         CreateShortCut "$SMPROGRAMS\Tor\Uninstall.lnk" "$INSTDIR\Uninstall.exe"
 247 FunctionEnd
 248
 249 Function CreateDocLinks
 250         CreateDirectory "$SMPROGRAMS\Tor\Documents"
 251         CreateShortCut "$SMPROGRAMS\Tor\Documents\Tor Manual.lnk" "$INSTDIR\Documents\tor-reference.html"
 252         CreateShortCut "$SMPROGRAMS\Tor\Documents\Tor Documentation.lnk" "$INSTDIR\Documents"
 253         CreateShortCut "$SMPROGRAMS\Tor\Documents\Tor Specification.lnk" "$INSTDIR\Documents\tor-spec.txt"
 254 FunctionEnd
 255
 256 Function ParseCmdLine
 257         ${GetParameters} $1
 258         ${If} $1 == "-x" ;Extract All Files
 259                 StrCpy $INSTDIR $EXEDIR
 260                 Call ExtractBinaries
 261                 Call ExtractDocuments
 262                 Quit
 263         ${ElseIf} $1 == "-b" ;Extract Binaries Only
 264                 StrCpy $INSTDIR $EXEDIR
 265                 Call ExtractBinaries
 266                 Quit
 267         ${ElseIf} $1 != ""
 268                 MessageBox MB_OK|MB_TOPMOST `${Installer} [-x|-b]$\r$\n$\r$\n  -x    Extract all files$\r$\n  -b    Extract binary files only`
 269                 Quit
 270         ${EndIf}
 271 FunctionEnd
 272