configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2005 Roger Dingledine
   3 dnl Copyright (c) 2004-2005 Nick Mathewson
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT
   7 AM_INIT_AUTOMAKE(tor, 0.1.1.12-alpha-cvs)
   8 AM_CONFIG_HEADER(orconfig.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 if test -f /etc/redhat-release; then
  13     CFLAGS="$CFLAGS -I/usr/kerberos/include"
  14 fi
  15
  16 AC_ARG_ENABLE(debug,
  17  AC_HELP_STRING(--enable-debug, compile with debugging info),
  18 [if test x$enableval = xyes; then
  19     CFLAGS="$CFLAGS -g"
  20 fi])
  21
  22 AC_ARG_ENABLE(threads,
  23      AC_HELP_STRING(--disable-threads, disable multi-threading support))
  24
  25 if test x$enable_threads = x; then
  26    case $host in
  27     *-*-netbsd* | *-*-openbsd* )
  28      # Don't try multithreading on netbsd -- there is no threadsafe DNS
  29      # lookup function there.
  30      AC_MSG_NOTICE([You are running OpenBSD or NetBSD; I am assuming that
  31 getaddrinfo is not threadsafe here, so I will disable threads.])
  32      enable_threads="no";;
  33     *-*-solaris* )
  34      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  35      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  36 cpu workers lock up here, so I will disable threads.])
  37      enable_threads="no";;
  38     *)
  39      enable_threads="yes";;
  40    esac
  41 fi
  42
  43 if test $enable_threads = "yes"; then
  44   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  45 fi
  46
  47 case $host in
  48    *-*-solaris* )
  49      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  50      ;;
  51 esac
  52
  53 AC_PROG_CC
  54 AC_PROG_MAKE_SET
  55 AC_PROG_RANLIB
  56
  57 # The big search for OpenSSL
  58 # copied from openssh's configure.ac
  59 AC_ARG_WITH(ssl-dir,
  60         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
  61         [
  62                 if test "x$withval" != "xno" ; then
  63                         tryssldir=$withval
  64                 fi
  65         ]
  66 )
  67
  68 TORUSER=_tor
  69 AC_ARG_WITH(tor-user,
  70         [  --with-tor-user=NAME    Specify username for tor daemon ],
  71         [
  72            TORUSER=$withval
  73         ]
  74 )
  75 AC_SUBST(TORUSER)
  76
  77 TORGROUP=_tor
  78 AC_ARG_WITH(tor-group,
  79         [  --with-tor-group=NAME   Specify group name for tor daemon ],
  80         [
  81            TORGROUP=$withval
  82         ]
  83 )
  84 AC_SUBST(TORGROUP)
  85
  86 AC_SEARCH_LIBS(socket, [socket])
  87 AC_SEARCH_LIBS(gethostbyname, [nsl])
  88 AC_SEARCH_LIBS(dlopen, [dl])
  89
  90 if test $enable_threads = "yes"; then
  91   AC_SEARCH_LIBS(pthread_create, [pthread])
  92   AC_SEARCH_LIBS(pthread_detach, [pthread])
  93 fi
  94
  95 dnl ------------------------------------------------------
  96 dnl Where do you live, libevent?  And how do we call you?
  97
  98
  99 # Step 1. Try to link and run a program using libevent.  If it works,
 100 #         great!  Just add -levent.
 101 AC_CACHE_CHECK([for a normal libevent], ac_cv_libevent_normal, [
 102    saved_LIBS="$LIBS"
 103    LIBS="$LIBS -levent"
 104    AC_TRY_RUN([
 105 void *event_init(void);
 106 int main(void)
 107 {
 108         event_init();
 109         return 0;
 110 }], ac_cv_libevent_normal=yes, ac_cv_libevent_normal=no)
 111    LIBS="$saved_LIBS"
 112 ])
 113
 114 if test "$ac_cv_libevent_normal" = yes; then
 115   LIBS="$LIBS -levent"
 116 else
 117   AC_CACHE_CHECK([for libevent in /usr/local/lib], ac_cv_libevent_local, [
 118      saved_LIBS="$LIBS"
 119      saved_LDFLAGS="$LDFLAGS"
 120      LIBS="$LIBS -levent"
 121      LDFLAGS="$LDFLAGS -L/usr/local/lib"
 122      # Step 2.  Otherwise, check whether adding -L/usr/local/lib allows
 123      #          us to link.  If not, assume we have no libevent at all.
 124      AC_TRY_LINK([], [ void *event_init(void); event_init(); ],
 125         [ libevent_is_in_local=yes ], [ libevent_is_in_local=no ])
 126      if test $libevent_is_in_local = no ; then
 127        ac_cv_libevent_local=no
 128      else
 129        # Step 3.  Does adding -L/usr/local/lib allow us to run, too?
 130        #          If so, all we have to do as adjust LDFLAGS and CFLAGS.
 131        AC_TRY_RUN([
 132 void *event_init(void);
 133 int main(void)
 134 {
 135         event_init();
 136         return 0;
 137 }], [ ac_cv_libevent_local=yes ], [ ac_cv_libevent_local=unlinked ])
 138     fi
 139     if test "$GCC" = yes -a $ac_cv_libevent_local = unlinked ; then
 140        # Step 4.  Okay, so we can link but not run.  This probably means
 141        #          that the dynamic linker doesn't have /usr/local/lib in
 142        #          its search path.  If we're lucky enough to be running
 143        #          GCC on an ELF system, we might have a workaround for that.
 144        #          See whether -Wl,-R/usr/local/lib makes things better.
 145        LDFLAGS="$LDFLAGS -Wl,-R/usr/local/lib"
 146        AC_TRY_RUN([
 147 void *event_init(void);
 148 int main(void)
 149 {
 150         event_init();
 151         return 0;
 152 }], [ ac_cv_libevent_local=unlinked_gcc_elf ])
 153     fi
 154
 155     LIBS="$saved_LIBS"
 156     LDFLAGS="$saved_LDFLAGS" ])
 157
 158   # Now we're done.  ac_vc_libevent_local could be:
 159   #    yes -- Add -L/usr/local/lib and we can link fine.
 160   #    unlinked_gcc_elf -- We can link, but we need to use the GCC-ELF
 161   #        workaround.  Complain a little.
 162   #    unlinked -- We can link, but we can't run.  Complain a lot.
 163   #    no -- we can't link at all.  Give an error and die.
 164
 165   if test $ac_cv_libevent_local != no; then
 166       LIBS="$LIBS -levent"
 167       LDFLAGS="$LDFLAGS -L/usr/local/lib"
 168       CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 169   fi
 170   if test $ac_cv_libevent_local = unlinked_gcc_elf; then
 171       LDFLAGS="$LDFLAGS -Wl,-R/usr/local/lib"
 172       if test -f /etc/ld.so.conf ; then
 173         AC_MSG_NOTICE([
 174 Apparently, you don't have /usr/local/lib in your /etc/ld.so.conf.
 175 Tor is smart enought to deal this now, but other applications aren't.
 176 You might want to add it in.])
 177       fi
 178   fi
 179
 180   if test $ac_cv_libevent_local = unlinked ; then
 181     if test -f /etc/ld.so.conf ; then
 182       AC_MSG_NOTICE([
 183 =================================================
 184 Your libevent library is installed in /usr/local/lib,
 185 but your dynamic linker isn't configured to look for
 186 it there.
 187
 188 Maybe you need to add /usr/local/lib to /etc/ld.so.conf,
 189 and then run ldconfig -v ?
 190 =================================================])
 191     else
 192       AC_MSG_NOTICE([
 193 =================================================
 194 Your libevent library is installed in /usr/local/lib,
 195 but your dynamic linker isn't configured to look for
 196 it there.
 197 =================================================])
 198     fi
 199   fi
 200
 201   if test $ac_cv_libevent_local = no ; then
 202       AC_MSG_ERROR([
 203 Tor requires libevent to build.  You can download the latest
 204 version of libevent from http://monkey.org/~provos/libevent/])
 205   fi
 206
 207 fi
 208
 209 dnl ------------------------------------------------------
 210 dnl Where do you live, OpenSSL?
 211
 212 saved_LIBS="$LIBS"
 213 saved_LDFLAGS="$LDFLAGS"
 214 saved_CPPFLAGS="$CPPFLAGS"
 215 if test "x$prefix" != "xNONE" ; then
 216         tryssldir="$tryssldir $prefix"
 217 fi
 218 AC_CACHE_CHECK([for OpenSSL directory], ac_cv_openssldir, [
 219         for ssldir in $tryssldir "" /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /usr/pkg /opt /opt/openssl ; do
 220                 CPPFLAGS="$saved_CPPFLAGS"
 221                 LDFLAGS="$saved_LDFLAGS"
 222                 LIBS="$saved_LIBS -lssl -lcrypto"
 223
 224                 # Skip directories if they don't exist
 225                 if test ! -z "$ssldir" -a ! -d "$ssldir" ; then
 226                         continue;
 227                 fi
 228                 if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 229                         # Try to use $ssldir/lib if it exists, otherwise
 230                         # $ssldir
 231                         if test -d "$ssldir/lib" ; then
 232                                 LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 233                                 if test ! -z "$need_dash_r" ; then
 234                                         LDFLAGS="-R$ssldir/lib $LDFLAGS"
 235                                 fi
 236                         else
 237                                 LDFLAGS="-L$ssldir $saved_LDFLAGS"
 238                                 if test ! -z "$need_dash_r" ; then
 239                                         LDFLAGS="-R$ssldir $LDFLAGS"
 240                                 fi
 241                         fi
 242                         # Try to use $ssldir/include if it exists, otherwise
 243                         # $ssldir
 244                         if test -d "$ssldir/include" ; then
 245                                 CPPFLAGS="-I$ssldir/include $saved_CPPFLAGS"
 246                         else
 247                                 CPPFLAGS="-I$ssldir $saved_CPPFLAGS"
 248                         fi
 249                 fi
 250
 251                 # Basic test to check for compatible version and correct linking
 252                 # *does not* test for RSA - that comes later.
 253                 AC_TRY_RUN(
 254                         [
 255 #include <string.h>
 256 #include <openssl/rand.h>
 257 int main(void)
 258 {
 259         char a[2048];
 260         memset(a, 0, sizeof(a));
 261         RAND_add(a, sizeof(a), sizeof(a));
 262         return(RAND_status() <= 0);
 263 }
 264                         ],
 265                         [
 266                                 found_crypto=1
 267                                 break;
 268                         ], []
 269                 )
 270
 271                 if test ! -z "$found_crypto" ; then
 272                         break;
 273                 fi
 274         done
 275
 276         if test -z "$found_crypto" ; then
 277                 AC_MSG_ERROR([Could not find working OpenSSL library, please install or check config.log])
 278         fi
 279         if test -z "$ssldir" ; then
 280                 ssldir="(system)"
 281         fi
 282
 283         ac_cv_openssldir=$ssldir
 284 ])
 285 if (test ! -z "$ac_cv_openssldir" && test "x$ac_cv_openssldir" != "x(system)") ;
 286  then
 287         dnl Need to recover ssldir - test above runs in subshell
 288         ssldir=$ac_cv_openssldir
 289         if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 290                 # Try to use $ssldir/lib if it exists, otherwise
 291                 # $ssldir
 292                 if test -d "$ssldir/lib" ; then
 293                         LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 294                         if test ! -z "$need_dash_r" ; then
 295                                 LDFLAGS="-R$ssldir/lib $LDFLAGS"
 296                         fi
 297                 else
 298                         LDFLAGS="-L$ssldir $saved_LDFLAGS"
 299                         if test ! -z "$need_dash_r" ; then
 300                                 LDFLAGS="-R$ssldir $LDFLAGS"
 301                         fi
 302                 fi
 303                 # Try to use $ssldir/include if it exists, otherwise
 304                 # $ssldir
 305                 if test -d "$ssldir/include" ; then
 306                         CPPFLAGS="-I$ssldir/include $saved_CPPFLAGS"
 307                 else
 308                         CPPFLAGS="-I$ssldir $saved_CPPFLAGS"
 309                 fi
 310         fi
 311 fi
 312 LIBS="$saved_LIBS"
 313
 314 AC_SYS_LARGEFILE
 315
 316 dnl The warning message here is no longer strictly accurate.
 317
 318 AC_CHECK_HEADERS(unistd.h string.h signal.h netdb.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/ioctl.h sys/socket.h sys/time.h netinet/in.h arpa/inet.h errno.h assert.h time.h pwd.h grp.h, , AC_MSG_WARN(some headers were not found, compilation may fail))
 319
 320 AC_CHECK_HEADERS(event.h, , AC_MSG_ERROR(Libevent header (event.h) not found. Tor requires libevent to build.))
 321
 322 AC_CHECK_HEADERS(zlib.h, , AC_MSG_ERROR(Zlib header (zlib.h) not found. Tor requires zlib to build. You may need to install a zlib development package.))
 323
 324 dnl These headers are not essential
 325
 326 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h stddef.h inttypes.h utime.h sys/utime.h)
 327
 328 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit setrlimit strlcat strlcpy strtoull getpwnam getpwuid ftello getaddrinfo localtime_r gmtime_r event_get_version event_get_method event_set_log_callback memmem)
 329
 330 if test $enable_threads = "yes"; then
 331   AC_CHECK_HEADERS(pthread.h)
 332   AC_CHECK_FUNCS(pthread_create)
 333 fi
 334
 335 AC_FUNC_FSEEKO
 336
 337 AC_CHECK_MEMBERS([struct timeval.tv_sec])
 338
 339 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 340 dnl Watch out.
 341
 342 AC_CHECK_SIZEOF(int8_t)
 343 AC_CHECK_SIZEOF(int16_t)
 344 AC_CHECK_SIZEOF(int32_t)
 345 AC_CHECK_SIZEOF(int64_t)
 346 AC_CHECK_SIZEOF(uint8_t)
 347 AC_CHECK_SIZEOF(uint16_t)
 348 AC_CHECK_SIZEOF(uint32_t)
 349 AC_CHECK_SIZEOF(uint64_t)
 350 AC_CHECK_SIZEOF(intptr_t)
 351 AC_CHECK_SIZEOF(uintptr_t)
 352
 353 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 354
 355 AC_CHECK_SIZEOF(char)
 356 AC_CHECK_SIZEOF(short)
 357 AC_CHECK_SIZEOF(int)
 358 AC_CHECK_SIZEOF(long)
 359 AC_CHECK_SIZEOF(long long)
 360 AC_CHECK_SIZEOF(__int64)
 361 AC_CHECK_SIZEOF(void *)
 362 AC_CHECK_SIZEOF(time_t)
 363 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 364 AC_TRY_RUN([
 365 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }],
 366   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes)
 367 ])
 368
 369 if test $tor_cv_time_t_signed = yes; then
 370   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 371             [Define to 1 iff time_t is signed])
 372 fi
 373
 374 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 375 #ifdef HAVE_SYS_SOCKET_H
 376 #include <sys/socket.h>
 377 #endif
 378 ])
 379
 380 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 381
 382 AC_CHECK_SIZEOF(cell_t)
 383
 384 # Now, let's see about alignment requirements.  On some platforms, we override
 385 # the default.
 386 case $host in
 387  ia64-*-* | arm-*-* | sparc-*-* | sparc64-*-* )
 388     tor_cv_unaligned_ok=no
 389     ;;
 390  # On the following architectures unaligned access works, but is not done in
 391  # hardware.  This means that when you try to do unaligned access the kernel
 392  # gets to sort out an exception and then work around to somehow make your
 393  # reqest work, which is quite expensive.  Therefore it's probably better to
 394  # not even do it.
 395  alpha-*-* | mips-*-* | mipsel-*-* )
 396     tor_cv_unaligned_ok=no
 397     ;;
 398  *)
 399 AC_CACHE_CHECK([whether unaligned int access is allowed], tor_cv_unaligned_ok,
 400 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 401 [[int main () { char s[] = "A\x00\x00\x00\x00\x00\x00\x00";
 402 return *(int*)(&s[1]); }]])],
 403        [tor_cv_unaligned_ok=yes],
 404        [tor_cv_unaligned_ok=no],
 405        [tor_cv_unaligned_ok=cross])])
 406 esac
 407
 408 if test $tor_cv_unaligned_ok = yes; then
 409   AC_DEFINE([UNALIGNED_INT_ACCESS_OK], 1,
 410             [Define to 1 iff unaligned int access is allowed])
 411 fi
 412
 413 # Now make sure that NULL can be represented as zero bytes.
 414 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 415 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 416 [[#include <stdlib.h>
 417 #include <string.h>
 418 #include <stdio.h>
 419 #ifdef HAVE_STDDEF_H
 420 #include <stddef.h>
 421 #endif
 422 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 423 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 424        [tor_cv_null_is_zero=yes],
 425        [tor_cv_null_is_zero=no],
 426        [tor_cv_null_is_zero=cross])])
 427
 428 if test $tor_cv_null_is_zero = yes; then
 429   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 430             [Define to 1 iff memset(0) sets pointers to NULL])
 431 fi
 432
 433 # Whether we should use the dmalloc memory allocation debugging library.
 434 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 435 AC_ARG_WITH(dmalloc,
 436 [  --with-dmalloc          Use debug memory allocation library. ],
 437 [if [[ "$withval" = "yes" ]]; then
 438   dmalloc=1
 439   AC_MSG_RESULT(yes)
 440 else
 441   dmalloc=1
 442   AC_MSG_RESULT(no)
 443 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 444 )
 445
 446 if [[ $dmalloc -eq 1 ]]; then
 447   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 448   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 449   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 450   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 451 fi
 452
 453 # Check for gethostbyname_r in all its glorious incompatible versions.
 454 #   (This logic is based on that in Python's configure.in)
 455 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 456   [Define this if you have any gethostbyname_r()])
 457
 458 AC_CHECK_FUNC(gethostbyname_r, [
 459   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 460   OLD_CFLAGS=$CFLAGS
 461   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 462   AC_TRY_COMPILE([
 463 #include <netdb.h>
 464   ], [
 465     char *cp1, *cp2;
 466     struct hostent *h1, *h2;
 467     int i1, i2;
 468     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 469   ], [
 470     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 471     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 472      [Define this if gethostbyname_r takes 6 arguments])
 473     AC_MSG_RESULT(6)
 474   ], [
 475     AC_TRY_COMPILE([
 476 #include <netdb.h>
 477     ], [
 478       char *cp1, *cp2;
 479       struct hostent *h1;
 480       int i1, i2;
 481       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 482     ], [
 483       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 484       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 485         [Define this if gethostbyname_r takes 5 arguments])
 486       AC_MSG_RESULT(5)
 487    ], [
 488       AC_TRY_COMPILE([
 489 #include <netdb.h>
 490      ], [
 491        char *cp1;
 492        struct hostent *h1;
 493        struct hostent_data hd;
 494        (void) gethostbyname_r(cp1,h1,&hd);
 495      ], [
 496        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 497        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 498          [Define this if gethostbyname_r takes 3 arguments])
 499        AC_MSG_RESULT(3)
 500      ], [
 501        AC_MSG_RESULT(0)
 502      ])
 503   ])
 504  ])
 505  CFLAGS=$OLD_CFLAGS
 506 ])
 507
 508 # $prefix stores the value of the --prefix command line option, or
 509 # NONE if the option wasn't set.  In the case that it wasn't set, make
 510 # it be the default, so that we can use it to expand directories now.
 511 if test "x$prefix" = "xNONE"; then
 512   prefix=$ac_default_prefix
 513 fi
 514
 515 # and similarly for $exec_prefix
 516 if test "x$exec_prefix" = "xNONE"; then
 517   exec_prefix=$prefix
 518 fi
 519
 520 CONFDIR=`eval echo $sysconfdir/tor`
 521 AC_SUBST(CONFDIR)
 522 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 523 AC_DEFINE([CONFDIR], [], [tor's configuration directory])
 524
 525 BINDIR=`eval echo $bindir`
 526 AC_SUBST(BINDIR)
 527
 528 LOCALSTATEDIR=`eval echo $localstatedir`
 529 AC_SUBST(LOCALSTATEDIR)
 530 AC_DEFINE_UNQUOTED(LOCALSTATEDIR,"$LOCALSTATEDIR")
 531 AC_DEFINE([LOCALSTATEDIR], [], [Default location to store state files.])
 532
 533 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 534 # than autoconf's macros like.
 535 CFLAGS="$CFLAGS -Wall -g -O2"
 536 # Add some more warnings which we use in the cvs version but not in the
 537 # released versions.  (Some relevant gcc versions can't handle these.)
 538 #CFLAGS="$CFLAGS -W -Wno-unused-parameter -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Winit-self -Wwrite-strings -Waggregate-return -Wmissing-declarations -Wmissing-field-initializers -Wredundant-decls -Winline"
 539 # Add these in when you feel like fun.
 540 #CFLAGS="$CFLAGS -Wbad-function-cast -Werror -Wdeclaration-after-statement -Wold-style-definition"
 541
 542 echo "confdir: $CONFDIR"
 543
 544 AC_OUTPUT(Makefile tor.spec contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile)
 545
 546 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 547   ./contrib/updateVersions.pl
 548 fi
 549