release/src/router/mysql/cmd-line-utils/libedit/makelist

   1 #!/bin/sh -
   2 #       $NetBSD: makelist,v 1.16 2010/04/18 21:17:05 christos Exp $
   3 #
   4 # Copyright (c) 1992, 1993
   5 #       The Regents of the University of California.  All rights reserved.
   6 #
   7 # This code is derived from software contributed to Berkeley by
   8 # Christos Zoulas of Cornell University.
   9 #
  10 # Redistribution and use in source and binary forms, with or without
  11 # modification, are permitted provided that the following conditions
  12 # are met:
  13 # 1. Redistributions of source code must retain the above copyright
  14 #    notice, this list of conditions and the following disclaimer.
  15 # 2. Redistributions in binary form must reproduce the above copyright
  16 #    notice, this list of conditions and the following disclaimer in the
  17 #    documentation and/or other materials provided with the distribution.
  18 # 3. Neither the name of the University nor the names of its contributors
  19 #    may be used to endorse or promote products derived from this software
  20 #    without specific prior written permission.
  21 #
  22 # THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23 # ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24 # IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25 # ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26 # FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27 # DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28 # OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30 # LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31 # OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32 # SUCH DAMAGE.
  33 #
  34 #       @(#)makelist    5.3 (Berkeley) 6/4/93
  35
  36 # makelist.sh: Automatically generate header files...
  37
  38 AWK=gawk
  39 USAGE="Usage: $0 -n|-h|-e|-fc|-fh|-bc|-bh|-m <filenames>"
  40
  41 if [ "x$1" = "x" ]
  42 then
  43     echo $USAGE 1>&2
  44     exit 1
  45 fi
  46
  47 FLAG="$1"
  48 shift
  49
  50 FILES="$@"
  51
  52 case $FLAG in
  53
  54 #       generate foo.h file from foo.c
  55 #
  56 -n)
  57     cat << _EOF
  58 #undef WIDECHAR
  59 #define NARROWCHAR
  60 #include "${FILES}"
  61 _EOF
  62     ;;
  63
  64 -h)
  65     set - `echo $FILES | sed -e 's/\\./_/g'`
  66     hdr="_h_`basename $1`"
  67     cat $FILES | $AWK '
  68         BEGIN {
  69             printf("/* Automatically generated file, do not edit */\n");
  70             printf("#ifndef %s\n#define %s\n", "'$hdr'", "'$hdr'");
  71         }
  72         /\(\):/ {
  73             pr = substr($2, 1, 2);
  74             if (pr == "vi" || pr == "em" || pr == "ed") {
  75                 # XXXMYSQL: support CRLF
  76                 name = substr($2, 1, index($2,"(") - 1);
  77 #
  78 # XXX:  need a space between name and prototype so that -fc and -fh
  79 #       parsing is much easier
  80 #
  81                 printf("protected el_action_t\t%s (EditLine *, Int);\n", name);
  82             }
  83         }
  84         END {
  85             printf("#endif /* %s */\n", "'$hdr'");
  86         }'
  87         ;;
  88
  89 #       generate help.c from various .c files
  90 #
  91 -bc)
  92     cat $FILES | $AWK '
  93         BEGIN {
  94             printf("/* Automatically generated file, do not edit */\n");
  95             printf("#include \"config.h\"\n#include \"el.h\"\n");
  96             printf("#include \"chartype.h\"\n");
  97             printf("private const struct el_bindings_t el_func_help[] = {\n");
  98             low = "abcdefghijklmnopqrstuvwxyz_";
  99             high = "ABCDEFGHIJKLMNOPQRSTUVWXYZ_";
 100             for (i = 1; i <= length(low); i++)
 101                 tr[substr(low, i, 1)] = substr(high, i, 1);
 102         }
 103         /\(\):/ {
 104             pr = substr($2, 1, 2);
 105             if (pr == "vi" || pr == "em" || pr == "ed") {
 106                 # XXXMYSQL: support CRLF
 107                 name = substr($2, 1, index($2,"(") - 1);
 108                 uname = "";
 109                 fname = "";
 110                 for (i = 1; i <= length(name); i++) {
 111                     s = substr(name, i, 1);
 112                     uname = uname tr[s];
 113                     if (s == "_")
 114                         s = "-";
 115                     fname = fname s;
 116                 }
 117
 118                 printf("    { %-30.30s %-30.30s\n","STR(\"" fname "\"),", uname ",");
 119                 ok = 1;
 120             }
 121         }
 122         /^ \*/ {
 123             if (ok) {
 124                 printf("      STR(\"");
 125                 for (i = 2; i < NF; i++)
 126                     printf("%s ", $i);
 127         # XXXMYSQL: support CRLF
 128                 sub("\r", "", $i);
 129                 printf("%s\") },\n", $i);
 130                 ok = 0;
 131             }
 132         }
 133         END {
 134             printf("};\n");
 135             printf("\nprotected const el_bindings_t* help__get()");
 136             printf("{ return el_func_help; }\n");
 137         }'
 138         ;;
 139
 140 #       generate help.h from various .c files
 141 #
 142 -bh)
 143     $AWK '
 144         BEGIN {
 145             printf("/* Automatically generated file, do not edit */\n");
 146             printf("#ifndef _h_help_c\n#define _h_help_c\n");
 147             printf("protected const el_bindings_t *help__get(void);\n");
 148             printf("#endif /* _h_help_c */\n");
 149         }' /dev/null
 150         ;;
 151
 152 #       generate fcns.h from various .h files
 153 #
 154 # XXXMYSQL: use portable tr syntax
 155 -fh)
 156     cat $FILES | $AWK '/el_action_t/ { print $3 }' | \
 157     sort | tr abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ | $AWK '
 158         BEGIN {
 159             printf("/* Automatically generated file, do not edit */\n");
 160             printf("#ifndef _h_fcns_c\n#define _h_fcns_c\n");
 161             count = 0;
 162         }
 163         {
 164             printf("#define\t%-30.30s\t%3d\n", $1, count++);
 165         }
 166         END {
 167             printf("#define\t%-30.30s\t%3d\n", "EL_NUM_FCNS", count);
 168
 169             printf("typedef el_action_t (*el_func_t)(EditLine *, Int);");
 170             printf("\nprotected const el_func_t* func__get(void);\n");
 171             printf("#endif /* _h_fcns_c */\n");
 172         }'
 173         ;;
 174
 175 #       generate fcns.c from various .h files
 176 #
 177 -fc)
 178     cat $FILES | $AWK '/el_action_t/ { print $3 }' | sort | $AWK '
 179         BEGIN {
 180             printf("/* Automatically generated file, do not edit */\n");
 181             printf("#include \"config.h\"\n#include \"el.h\"\n");
 182             printf("private const el_func_t el_func[] = {");
 183             maxlen = 80;
 184             needn = 1;
 185             len = 0;
 186         }
 187         {
 188             clen = 25 + 2;
 189             len += clen;
 190             if (len >= maxlen)
 191                 needn = 1;
 192             if (needn) {
 193                 printf("\n    ");
 194                 needn = 0;
 195                 len = 4 + clen;
 196             }
 197             s = $1 ",";
 198             printf("%-26.26s ", s);
 199         }
 200         END {
 201             printf("\n};\n");
 202             printf("\nprotected const el_func_t* func__get() { return el_func; }\n");
 203         }'
 204         ;;
 205
 206 #       generate editline.c from various .c files
 207 #
 208 -e)
 209         echo "$FILES" | tr ' ' '\012' | $AWK '
 210         BEGIN {
 211             printf("/* Automatically generated file, do not edit */\n");
 212             printf("#define protected static\n");
 213             printf("#define SCCSID\n");
 214         }
 215         {
 216             printf("#include \"%s\"\n", $1);
 217         }'
 218         ;;
 219
 220 #       generate man page fragment from various .c files
 221 #
 222 -m)
 223     cat $FILES | $AWK '
 224         BEGIN {
 225             printf(".\\\" Section automatically generated with makelist\n");
 226             printf(".Bl -tag -width 4n\n");
 227         }
 228         /\(\):/ {
 229             pr = substr($2, 1, 2);
 230             if (pr == "vi" || pr == "em" || pr == "ed") {
 231                 # XXXMYSQL: support CRLF
 232                 name = substr($2, 1, index($2, "(") - 1);
 233                 fname = "";
 234                 for (i = 1; i <= length(name); i++) {
 235                     s = substr(name, i, 1);
 236                     if (s == "_")
 237                         s = "-";
 238                     fname = fname s;
 239                 }
 240
 241                 printf(".It Ic %s\n", fname);
 242                 ok = 1;
 243             }
 244         }
 245         /^ \*/ {
 246             if (ok) {
 247                 for (i = 2; i < NF; i++)
 248                     printf("%s ", $i);
 249                 printf("%s.\n", $i);
 250                 ok = 0;
 251             }
 252         }
 253         END {
 254             printf(".El\n");
 255             printf(".\\\" End of section automatically generated with makelist\n");
 256         }'
 257         ;;
 258
 259 *)
 260     echo $USAGE 1>&2
 261     exit 1
 262     ;;
 263
 264 esac