rules.d/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1-or-later
   2
   3 install_data(
   4         'README',
   5         install_dir : udevrulesdir)
   6
   7 rules = [
   8         [files('60-autosuspend.rules',
   9                '60-block.rules',
  10                '60-cdrom_id.rules',
  11                '60-dmi-id.rules',
  12                '60-drm.rules',
  13                '60-evdev.rules',
  14                '60-fido-id.rules',
  15                '60-infiniband.rules',
  16                '60-input-id.rules',
  17                '60-persistent-alsa.rules',
  18                '60-persistent-input.rules',
  19                '60-persistent-storage-tape.rules',
  20                '60-persistent-v4l.rules',
  21                '60-sensor.rules',
  22                '60-serial.rules',
  23                '70-camera.rules',
  24                '70-joystick.rules',
  25                '70-mouse.rules',
  26                '70-touchpad.rules',
  27                '75-net-description.rules',
  28                '75-probe_mtd.rules',
  29                '78-sound-card.rules',
  30                '80-net-setup-link.rules',
  31                '81-net-dhcp.rules',
  32                '90-iocost.rules',
  33               )],
  34
  35         [files('80-drivers.rules'),
  36          conf.get('HAVE_KMOD') == 1],
  37
  38         [files('70-memory.rules'),
  39          dmi_arches.contains(host_machine.cpu_family())],
  40
  41         [files('70-power-switch.rules'),
  42          enable_logind],
  43 ]
  44
  45 all_rules = []
  46
  47 foreach tuple : rules
  48         if tuple.length() == 1 or tuple[1]
  49                 install_data(tuple[0],
  50                              install_dir : udevrulesdir)
  51                 all_rules += tuple[0]
  52         endif
  53 endforeach
  54
  55 rules_in = [
  56         ['50-udev-default.rules'],
  57         ['60-persistent-storage.rules'],
  58         ['64-btrfs.rules'],
  59         ['99-systemd.rules'],
  60
  61         ['70-uaccess.rules',   enable_logind and conf.get('HAVE_ACL') == 1],
  62         ['71-seat.rules',      enable_logind],
  63         ['73-seat-late.rules', enable_logind],
  64
  65         ['90-vconsole.rules',  conf.get('ENABLE_VCONSOLE') == 1],
  66 ]
  67
  68 foreach tuple : rules_in
  69         want = tuple.length() == 1 or tuple[1]
  70
  71         rule = custom_target(
  72                 tuple[0],
  73                 input : tuple[0] + '.in',
  74                 output: tuple[0],
  75                 command : [jinja2_cmdline, '@INPUT@', '@OUTPUT@'],
  76                 install : want,
  77                 install_dir : udevrulesdir)
  78
  79         if want
  80                 all_rules += rule
  81         endif
  82 endforeach