configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.69])
   3
   4 AC_CONFIG_MACRO_DIRS([m4])
   5
   6 dnl Use 'VERSION' files to get version.
   7 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   8
   9 dnl Strip off newline characters.
  10 m4_define([SIPE_VERSION],
  11         m4_substr(SIPE_VERSION_DATA,
  12                   [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  13
  14 dnl homepage
  15 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  16
  17 dnl initialize package name, version, bugtracker & homepage
  18 AC_INIT([pidgin-sipe], SIPE_VERSION,
  19         [https://sourceforge.net/p/sipe/bugs/], [],
  20         SIPE_HOMEPAGE)
  21
  22 AC_DEFINE([SIPE_TRANSLATIONS_URL],
  23         ["https://www.transifex.com/stefanb/pidgin-sipe/"],
  24         [URL for submitting translations.])
  25
  26 dnl define optional git commit ID generated by autogen.sh
  27 m4_define([SIPE_GIT_COMMIT], m4_sinclude([GITVERSION]))
  28 AS_IF([test "x"SIPE_GIT_COMMIT != x],
  29         [AC_MSG_NOTICE([set git commit])
  30          AC_DEFINE(PACKAGE_GIT_COMMIT, "SIPE_GIT_COMMIT", [Define to the git commit for this package.])
  31 ])
  32
  33 dnl setup automake and require recent enough version
  34 AM_INIT_AUTOMAKE([1.16 dist-bzip2 dist-xz no-define tar-ustar])
  35
  36 AC_CANONICAL_HOST
  37
  38 dnl set PACKAGE_URL for autoconf < 2.64
  39 AS_IF([test "x${PACKAGE_URL}" = x],
  40         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  41          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  42 ])
  43
  44 dnl set programming language
  45 AC_LANG(C)
  46 AM_PROG_CC_C_O
  47 AM_PROG_LEX
  48 AC_HEADER_STDC
  49
  50 dnl setup shared library generation
  51 LT_INIT([disable-static])
  52
  53 dnl checks for tools
  54 IT_PROG_INTLTOOL([0.41.0])
  55 AC_PROG_INSTALL
  56
  57 dnl ******************************
  58 dnl Win32
  59 dnl ******************************
  60 AC_MSG_CHECKING([for Win32])
  61 AS_CASE(["$host"],
  62                 [*-mingw*], [os_win32=yes],
  63                 [os_win32=no])
  64 AC_MSG_RESULT([$os_win32])
  65 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  66
  67 dnl checks for header files
  68 AC_CHECK_HEADERS([])
  69
  70 dnl checks for library functions
  71 AC_CHECK_FUNCS([])
  72
  73 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  74 dnl as that is likely where libpurple will be found if it is not in the default
  75 dnl pkgconfig path
  76 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  77 export PKG_CONFIG_PATH
  78
  79 dnl debug mode
  80 AC_ARG_ENABLE(debug,
  81         [AS_HELP_STRING([--enable-debug],
  82                         [compile with debugging support @<:@default=no@:>@])],
  83         [],
  84         [enable_debug=no])
  85
  86 AS_IF([test "x$enable_debug" = xyes],
  87         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  88 AC_SUBST(DEBUG_CFLAGS)
  89
  90 dnl
  91 dnl Quality check mode - try to find bugs instead of hiding them
  92 dnl
  93 dnl Developers & contributors:
  94 dnl
  95 dnl     You are *NOT* allowed to commit code to SIPE repository that only
  96 dnl     builds with --disable-quality-check!
  97 dnl
  98 dnl Distro package maintainers:
  99 dnl
 100 dnl     You may choose to add --disable-quality-check to the package build
 101 dnl     specification if you can't fix all build dependencies properly.
 102 dnl
 103 AC_ARG_ENABLE(quality-check,
 104         [AS_HELP_STRING([--enable-quality-check],
 105                         [compile with compiler checks enabled @<:@default=yes@:>@])],
 106         [],
 107         [enable_quality_check=yes])
 108
 109 dnl default quality configuration
 110 QUALITY_CFLAGS="$QUALITY_CFLAGS -Wall"
 111
 112 dnl convert warnings to errors
 113 AS_IF([test "x$enable_quality_check" = xyes],
 114         [QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror"])
 115
 116 dnl enable warnings supported by the GCC on the build system
 117 dnl @TODO: not included in -Wall: "-Wwrite-strings" \
 118 for newflag in \
 119         "-Wextra" \
 120         "-Waggregate-return" \
 121         "-Wcast-align" \
 122         "-Wcast-function-type" \
 123         "-Wdeclaration-after-statement" \
 124         "-Wdeprecated-declarations" \
 125         "-Wduplicate-decl-specifier" \
 126         "-Winit-self" \
 127         "-Wmaybe-uninitialized" \
 128         "-Wmissing-declarations" \
 129         "-Wmissing-prototypes" \
 130         "-Wnested-externs" \
 131         "-Wpointer-arith" \
 132         "-Wundef" \
 133         "-Wunused-but-set-variable" \
 134 ; do
 135         ac_save_CFLAGS="$CFLAGS"
 136         AC_MSG_CHECKING([if $CC supports $newflag])
 137         CFLAGS="$CFLAGS $newflag"
 138         AC_COMPILE_IFELSE(
 139                 [AC_LANG_SOURCE([[]])],
 140                 [AC_MSG_RESULT(yes)
 141                         QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 142                 [AC_MSG_RESULT(no)]
 143         )
 144         CFLAGS="$ac_save_CFLAGS"
 145 done
 146 AC_SUBST(QUALITY_CFLAGS)
 147
 148 dnl check for availability of addition linker flags
 149 for newflag in \
 150         "-Wl,-Bsymbolic-functions" \
 151 ; do
 152         ac_save_LDFLAGS="$LDFLAGS"
 153         AC_MSG_CHECKING([if $CC supports $newflag])
 154         LDFLAGS="$LDFLAGS $ADDITIONAL_LDFLAGS $newflag"
 155         AC_LINK_IFELSE(
 156                 [AC_LANG_SOURCE([[
 157 int main(int argc, char *argv[])
 158 {
 159         return(0);
 160 }
 161                  ]])],
 162                 [AC_MSG_RESULT(yes)
 163                  ADDITIONAL_LDFLAGS="$ADDITIONAL_LDFLAGS $newflag"],
 164                 [AC_MSG_RESULT(no)]
 165         )
 166         LDFLAGS="$ac_save_LDFLAGS"
 167 done
 168 AC_SUBST(ADDITIONAL_LDFLAGS)
 169
 170 dnl Check for pkg-config before using it
 171 PKG_PROG_PKG_CONFIG
 172
 173 dnl check for valgrind (optional, only needed for debugging)
 174 PKG_CHECK_MODULES(VALGRIND, [valgrind],
 175         [AC_DEFINE(HAVE_VALGRIND, 1, [Define to 1 if you have the valgrind headers])],
 176         [AC_MSG_RESULT(no)])
 177
 178 dnl build option: with AppStream support
 179 AC_ARG_WITH(appstream,
 180         [AC_HELP_STRING([--with-appstream],
 181                 [install AppStream XML file @<:@default=yes@:>@])],
 182         [AS_IF([test "x$withval" = xno], [with_appstream=no])],
 183         [with_appstream=yes])
 184 AM_CONDITIONAL(SIPE_WITH_APPSTREAM, [test "x$with_appstream" != xno])
 185
 186 dnl build option: with voice & video support (for all backends)
 187 AC_ARG_WITH(vv,
 188         [AC_HELP_STRING([--with-vv],
 189                 [compile with voice and video support @<:@default=check@:>@])],
 190         [AS_IF([test "x$withval" = xyes], [with_vv=yes])],
 191         [with_vv=check])
 192
 193 dnl check for Kerberos 5 support
 194 AC_ARG_WITH([krb5],
 195         [AC_HELP_STRING([--with-krb5],
 196                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 197         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 198         [with_krb5=check])
 199
 200 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 201       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 202         [AC_MSG_CHECKING(if Kerberos 5 is available)
 203          AS_IF([AC_RUN_LOG([krb5-config --version])],
 204                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 205                  KRB5_LDFLAGS=""
 206
 207                  dnl same as AC_CHECK_LIB()
 208                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"],
 209                 [AC_MSG_RESULT(no)
 210                  with_krb5=no])],
 211       [                               dnl path specified by user
 212         KRB5_CFLAGS="-I${with_krb5}/include"
 213         KRB5_LDFLAGS="-L${with_krb5}/lib"
 214       ])
 215 AS_IF([test "x$with_krb5" != xno],
 216       [ac_save_CFLAGS="$CFLAGS"
 217        ac_save_LDFLAGS="$LDFLAGS"
 218        CFLAGS="$CFLAGS $KRB5_CFLAGS"
 219        LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 220        AC_CHECK_HEADERS([gssapi/gssapi.h gssapi/gssapi_krb5.h],
 221                         [],
 222                         [AC_ERROR([GSSAPI headers not found])])
 223        AC_CHECK_FUNC([gss_init_sec_context],
 224                      [],
 225                      [AC_ERROR([GSSAPI libraries not found])])
 226
 227        dnl older GSSAPI releases don't have gss_acquire_cred_with_passwd()
 228        AC_CHECK_HEADER([gssapi/gssapi_ext.h],
 229                        [AC_CHECK_FUNC([gss_acquire_cred_with_password],
 230                                       [AC_DEFINE(HAVE_GSSAPI_PASSWORD_SUPPORT, 1, [Define to 1 if gssapi has gss_acquire_cred_with_passwd()])],
 231                                       [AC_MSG_NOTICE([gss_acquire_cred_with_passwd() required: disabling GSSAPI non-SSO support])])],
 232                        [AC_MSG_NOTICE([gssapi/gssapi_ext.h required: disabling GSSAPI non-SSO support])])
 233
 234        CFLAGS="$ac_save_CFLAGS"
 235        LDFLAGS="$ac_save_LDFLAGS"
 236       ])
 237
 238 AM_CONDITIONAL(SIP_SEC_GSSAPI, [test "x$with_krb5" != xno])
 239 AC_SUBST(KRB5_CFLAGS)
 240 AC_SUBST(KRB5_LDFLAGS)
 241
 242 dnl check for DBUS support
 243 AC_ARG_WITH([dbus],
 244         [AC_HELP_STRING([--with-dbus],
 245                 [compile with D-BUS support @<:@default=check@:>@])],
 246         [AS_IF([test "x$withval" = xyes], [with_dbus=check])],
 247         [with_dbus=check])
 248
 249 AS_IF([test "x$with_dbus" = xno], [], dnl disabled by user
 250       [test "x$with_dbus" = xcheck],  dnl autodetect with pkg-config
 251         [PKG_CHECK_MODULES(DBUS, [dbus-1],
 252                 [with_dbus=yes],
 253                 [with_dbus=no])
 254         ])
 255 AM_CONDITIONAL(SIPE_DBUS, [test "x$with_dbus" = xyes])
 256 AS_IF([test "x$with_dbus" = xyes],
 257         [AC_DEFINE(HAVE_DBUS, 1, [Define if D-BUS should be used in sipe.])])
 258
 259 AC_ARG_ENABLE(gssapi_only,
 260         [AS_HELP_STRING([--enable-gssapi-only],
 261                         [disable all internal authentication code and only use
 262                          GSSAPI for authentication @<:@default=yes@:>@])],
 263         [],
 264         dnl requires Kerberos which provides GSSAPI
 265         [enable_gssapi_only=$with_krb5])
 266 AS_IF([test "x$enable_gssapi_only" != xno],
 267         [AC_CHECK_HEADER([gssapi/gssapi_ntlmssp.h],
 268                        [AC_DEFINE(HAVE_GSSAPI_ONLY, 1, [Define to 1 to enable GSSAPI-only mode])],
 269                        [AC_MSG_NOTICE([gssapi/gssapi_ntlm.h required: falling back to internal authentication implementation])
 270                         enable_gssapi_only=no])
 271         ])
 272 AM_CONDITIONAL(SIP_SEC_GSSAPI_ONLY, [test "x$enable_gssapi_only" != xno])
 273
 274 dnl
 275 dnl oldest supported LTS release vs. package versions
 276 dnl
 277 dnl last checked: Jun-2019
 278 dnl
 279 dnl package        | Debian  | RHEL    | SLES    | Ubuntu  | win32  |
 280 dnl                | 8.0     | 6.10    | 12 SP4  | 16.04   | 2.13.x |
 281 dnl            EOL | 07/2020 | 12/2020 | 11/2024 | 04/2021 |    N/A |
 282 dnl ---------------|---------|---------|---------|---------|--------|
 283 dnl glib-2.0       |  2.42.x |  2.28.x |  2.48.x |  2.48.x | 2.18.x |
 284 dnl gmime-2.6      |     YES |      NO |     YES |     YES |     NO |
 285 dnl gss-ntlmssp    |      NO |      NO |      NO |   0.7.x |    N/A |
 286 dnl intltool       |  0.50.2 |  0.41.0 |  0.51.0 |  0.51.0 | 0.40.4 |
 287 dnl nice           | TOO OLD | TOO OLD |  0.1.13 |  0.1.13 |    N/A |
 288 dnl purple         |  2.11.x |   2.7.x |  2.12.x |  2.10.x | 2.13.x |
 289 dnl telepathy-glib |  0.24.x |      NO |  0.24.x |  0.24.x |    N/A |
 290 dnl
 291
 292 dnl check for glib
 293 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.18.0])
 294 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.18.0])
 295
 296 dnl check for gmime
 297 PKG_CHECK_MODULES(GMIME, [gmime-3.0 >= 3.0.0],
 298         [ac_have_gmime=yes],
 299         [PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.6.0],
 300                 [ac_have_gmime=yes],
 301                 [ac_have_gmime=no])
 302         ])
 303 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 304 AS_IF([test "x$ac_have_gmime" = xyes],
 305         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 306
 307 dnl check for NSS
 308 AC_ARG_ENABLE(nss,
 309         [AS_HELP_STRING([--enable-nss],
 310                         [use NSS as crypto backend @<:@default=yes@:>@])],
 311         [],
 312         [enable_nss=yes])
 313 AS_IF([test "x$enable_nss" != xno],
 314         [PKG_CHECK_MODULES(NSS, [nss],
 315                 [],
 316                 [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 317                         [],
 318                         [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 319                                 [],
 320                                 [enable_nss=no])
 321                         ])
 322                 ])
 323         ])
 324
 325 dnl check for OpenSSL
 326 AC_ARG_ENABLE(openssl,
 327         [AS_HELP_STRING([--enable-openssl],
 328                         [use OpenSSL as crypto backend @<:@default=yes@:>@])],
 329         [],
 330         [enable_openssl=yes])
 331 AS_IF([test "x$enable_openssl" != xno],
 332         [PKG_CHECK_MODULES(OPENSSL, [libcrypto],
 333                    [],
 334                    [enable_openssl=no])
 335         ])
 336 AS_IF(
 337         [test "x$enable_nss" != xno],
 338                 [ dnl NSS has priority over OpenSSL
 339                   enable_openssl=no
 340                   AC_MSG_NOTICE([using NSS as crypto backend.])],
 341         [test "x$enable_openssl" != xno],
 342                 [AC_MSG_NOTICE([using OpenSSL as crypto backend.])],
 343         [AC_ERROR([nss, mozilla-nss, microb-engine-nss or libcrypto package is required])])
 344 AM_CONDITIONAL(SIPE_OPENSSL, [test "x$enable_openssl" != xno])
 345
 346 dnl check for libxml2
 347 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 348
 349 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 350 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 351 ac_save_CFLAGS="$CFLAGS"
 352 dnl NOTE: including $QUALITY_CFLAGS can lead to false negative configure checks!
 353 CFLAGS="$CFLAGS $GLIB_CFLAGS"
 354 dnl note the [[[ quoting: our code contains []!
 355 AC_RUN_IFELSE(
 356         [AC_LANG_PROGRAM(
 357                 [[
 358 #include <glib.h>
 359 #include <stdio.h>
 360
 361 /* Copied from uuid.c */
 362 typedef struct {
 363    guint32 time_low;
 364    guint16 time_mid;
 365    guint16 time_hi_and_version;
 366    guint8  clock_seq_hi_and_reserved;
 367    guint8  clock_seq_low;
 368    guint8  node[6];
 369 } uuid_t;
 370                 ]],
 371                 [[if (sizeof(uuid_t) == 16) {
 372                         return(0);
 373                  } else {
 374                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 375                         return(1);
 376                  }]])],
 377         [AC_MSG_RESULT(yes)],
 378         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 379
 380 Please notify the SIPE developers.
 381
 382 Copy & paste all lines starting with the line
 383
 384   checking that sizeof(uuid_t) is 16...
 385
 386 to the report and attach the file "config.log".
 387
 388 Compiler information:
 389
 390  host:     $host
 391  build:    $build
 392  compiler: $CC
 393 ])],
 394         [AC_MSG_WARN([cross compiling: not checking])])
 395 CFLAGS="$ac_save_CFLAGS"
 396
 397 dnl build option: OCS2005 client hack
 398 AC_ARG_ENABLE([ocs2005-message-hack],
 399         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 400                                                           which causes "false" not delivered error messages
 401                                                           @<:@default=no@:>@])],
 402         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 403                    [Define to 1 to disable SIP MESSAGE timeout feature.
 404                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 405                     disabling the timeout suppresses "false" error messages])])
 406
 407 dnl build option: purple backend
 408 AC_ARG_ENABLE([purple],
 409         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 410         [],
 411         [enable_purple=yes])
 412 ac_have_appshare=no
 413 ac_have_appshare_server=no
 414 ac_have_xdata=no
 415 with_purple_vv=no
 416 AS_IF([test "x$enable_purple" != xno],
 417         [PKG_CHECK_MODULES(PURPLE, [purple-3],
 418                 [purple_pkgconfig=purple-3],
 419                 [PKG_CHECK_MODULES(PURPLE, [purple >= 2.7.0],
 420                         [purple_pkgconfig=purple],
 421                         [enable_purple=no])])
 422
 423          AS_IF([test "x$enable_purple" != xno],
 424                 [AC_MSG_NOTICE([using package "$purple_pkgconfig".])
 425
 426                  dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 427                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion $purple_pkgconfig | cut -d. -f 1`
 428                  AC_SUBST(PURPLE_MAJOR_VERSION)
 429
 430                  ac_save_CFLAGS="$CFLAGS"
 431                  ac_save_LIBS="$LIBS"
 432                  dnl NOTE: including $QUALITY_CFLAGS can lead to false negative configure checks!
 433                  CFLAGS="$CFLAGS $PURPLE_CFLAGS"
 434                  LIBS="$LIBS $PURPLE_LIBS"
 435
 436                  dnl check whether enable voice and video support
 437                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 438                        [AC_MSG_CHECKING(for purple voice and video support)
 439                         purple_has_media=no
 440                         AC_RUN_IFELSE(
 441                                 [AC_LANG_PROGRAM([[
 442 #include <media.h>
 443                                         ]],
 444                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
 445                                 )],
 446                                 [purple_has_media=yes
 447                                  AC_MSG_RESULT(ok)
 448                                 ],
 449                                 [AC_MSG_RESULT([no - your purple hasn't been compiled with voice and video support.])],
 450                                 [AS_IF([test "x$with_vv" = xyes],
 451                                        [purple_has_media=yes
 452                                         AC_MSG_RESULT([yes - enabling voice and video support for cross compiling on users' request.])],
 453                                        [AC_MSG_RESULT([no - disabled for cross compiling.])])
 454                                 ]
 455                         )
 456                         AS_IF([test "x$purple_has_media" = xyes],
 457                                 [PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 458                                         dnl sipe-media.c uses g_slist_free_full()
 459                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [$purple_pkgconfig >= 2.8.0],
 460                                                 dnl check purple pkgconfig for gstreamer version
 461                                                 [gstreamer_pkgconfig=`$PKG_CONFIG --variable=gstreamer $purple_pkgconfig`
 462                                                 AS_IF([test "x$gstreamer_pkgconfig" == x],
 463                                                         [AS_IF([test "x$purple_pkgconfig" == xpurple-3],
 464                                                                 [gstreamer_pkgconfig=1.0])])
 465                                                 AS_IF([test "x$gstreamer_pkgconfig" == x1.0],
 466                                                         [gstreamer_pkgconfig="gstreamer-$gstreamer_pkgconfig gstreamer-rtp-$gstreamer_pkgconfig"
 467
 468                                                         AC_MSG_NOTICE([using packages "$gstreamer_pkgconfig".])
 469                                                         PKG_CHECK_MODULES(GSTREAMER, [$gstreamer_pkgconfig],
 470                                                                 [PKG_CHECK_MODULES(FARSTREAM, [farstream-0.2],
 471                                                                         [with_purple_vv=yes
 472
 473                                                                          AC_COMPILE_IFELSE(
 474                                                                                  [AC_LANG_PROGRAM([[
 475 #include <media.h>
 476                                                                                         ]],
 477                                                                                         [[return (PURPLE_MEDIA_NETWORK_PROTOCOL_TCP_PASSIVE);]]
 478                                                                                  )],
 479                                                                                  [AC_DEFINE(HAVE_PURPLE_NEW_TCP_ENUMS, 1, [Define if libpurple has new TCP enums in media backend.])]
 480                                                                         )],
 481                                                                         [AC_MSG_NOTICE(Farstream required: disabling purple voice and video support)])],
 482                                                                 [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 483                                                         [AC_MSG_NOTICE(your purple hasn't been compiled against GStreamer 1.0: disabling purple voice and video support)])],
 484                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 required: disabling purple voice and video support)])],
 485                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])
 486                                 ])
 487                        ])
 488
 489                  dnl SRTP and XDATA require media backend
 490                  AS_IF([test "x$with_purple_vv" != xno],
 491                         [AC_LINK_IFELSE(
 492                                 [AC_LANG_PROGRAM([[
 493 #include <media.h>
 494                                         ]],
 495                                         [[purple_media_set_encryption_parameters(NULL, "", "", "", "", 0);
 496                                           purple_media_set_decryption_parameters(NULL, "", "", "", "", "", 0);]]
 497                                  )],
 498                                  [AC_DEFINE(HAVE_SRTP, 1, [Define if we have SRTP support in media backend.])]
 499                          )
 500
 501                          AC_COMPILE_IFELSE(
 502                                 [AC_LANG_PROGRAM([[
 503 #include <media.h>
 504                                         ]],
 505                                         [[return (PURPLE_MEDIA_APPLICATION);]]
 506                                  )],
 507                                  [dnl libpurple supports raw data RTP connections
 508                                   ac_have_xdata=yes
 509
 510                                   dnl gio-2.0 is mandatory for application sharing support
 511                                   PKG_CHECK_MODULES(GIO, [gio-2.0],
 512                                         [ac_have_appshare=yes
 513
 514                                          dnl freerdp-shadow2 & winpr2 is mandatory for appshare server support
 515                                          PKG_CHECK_MODULES(FREERDP_SHADOW, [freerdp-shadow2 winpr2],
 516                                                 [ac_have_appshare_server=yes],
 517                                                 [ac_have_appshare_server=no])
 518                                    ])
 519                                  ]
 520                          )
 521                         ],
 522                         [AS_IF([test "x$with_vv" = xyes], dnl explicitly requested by user
 523                                 [AC_ERROR([Voice and video support explicitly requested, but not available])]
 524                          )]
 525                  )
 526
 527                  CFLAGS="$ac_save_CFLAGS"
 528                  LIBS="$ac_save_LIBS"])])
 529 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 530 AM_CONDITIONAL(SIPE_PURPLE3, [test "x$purple_pkgconfig" = xpurple-3])
 531
 532 dnl build option: telepathy backend
 533 AC_ARG_ENABLE([telepathy],
 534         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 535         [],
 536         [enable_telepathy=yes])
 537 AS_IF([test "x$enable_telepathy" != xno],
 538         [PKG_CHECK_MODULES(TELEPATHY_GLIB, [telepathy-glib >= 0.24.0],
 539                 [dnl GMIME is a build requirement
 540                  AS_IF([test "x$ac_have_gmime" = xyes],
 541                         [],
 542                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 543
 544                  dnl telepathy is based on GObject & D-Bus GLib
 545                  PKG_CHECK_MODULES(GOBJECT, [gobject-2.0])
 546                  PKG_CHECK_MODULES(DBUS_GLIB, [dbus-glib-1])
 547
 548                  dnl telepathy uses from gio:
 549                  dnl  - GIOStream      (>= 2.22.0)
 550                  dnl  - GResolver      (>= 2.22.0)
 551                  dnl  - GSocketClient  (>= 2.32.0)
 552                  dnl  - GTlsConnection (>= 2.28.0)
 553                  PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.32.0])
 554
 555                 ],
 556                 [enable_telepathy=no])])
 557 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 558
 559 dnl sanity check
 560 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 561         [AC_ERROR(at least one plugin must be selected
 562
 563 If you didn't use a --enable option then please check that you have
 564 the headers for the packages "purple" or "telepathy-glib" installed.
 565 )],
 566         [])
 567
 568 dnl enable voice & video support if any backend supports it
 569 AS_IF([test "x$with_purple_vv" != xno],
 570         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 571 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 572
 573 dnl raw data RTP streams enable Lync file transfer
 574 AM_CONDITIONAL(SIPE_HAVE_XDATA, [test "x$ac_have_xdata" == xyes])
 575 AS_IF([test "x$ac_have_xdata" == xyes],
 576         [AC_DEFINE(HAVE_XDATA, 1, [Define if we have raw data RTP in media backend.])])
 577
 578 dnl enable appshare support
 579 AM_CONDITIONAL(SIPE_HAVE_APPSHARE, [test "x$ac_have_appshare" == xyes])
 580 AS_IF([test "x$ac_have_appshare" == xyes],
 581         [AC_DEFINE(HAVE_APPSHARE, 1, [Define to 1 if we have appshare support.])])
 582
 583 dnl RDP server for sharing local desktop
 584 AM_CONDITIONAL(SIPE_HAVE_APPSHARE_SERVER, [test "x$ac_have_appshare_server" = xyes])
 585 AS_IF([test "x$ac_have_appshare_server" == xyes],
 586         [AC_DEFINE(HAVE_APPSHARE_SERVER, 1, [Define if appshare server is enabled.])])
 587
 588 dnl libpurple API relies on GParameter (deprecated in glib-2.0 >= 2.62.0)
 589 AS_IF([test "x$enable_purple" != xno],
 590         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_60,
 591                    [We need GParameter for which no replacement is available])
 592         ])
 593 dnl telepathy code parts rely on interfaces that require GValueArray. This
 594 dnl type has been declared "deprectated" in glib-2.0 >= 2.32.0, but there
 595 dnl is no backward compatible replacement implementation possible
 596 dnl telepathy-glib API relies on GTimeVal (deprecated in glib-2.0 >= 2.62.0)
 597 AS_IF([test "x$enable_telepathy" != xno],
 598         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_30,
 599                    [We need GValueArray for which no replacement is available])
 600         ])
 601 dnl libpurple 2.x API relies on G_CONST_RETURN (deprecated in glib-2.0 >= 2.30.0)
 602 AS_IF([test "x$purple_pkgconfig" == xpurple],
 603         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_28,
 604                    [libpurple 2.x API uses G_CONST_RETURN])
 605         ])
 606
 607 dnl i18n
 608 AC_MSG_CHECKING([locale_CPPFLAGS])
 609 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 610 AC_SUBST([LOCALE_CPPFLAGS])
 611 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 612 AM_GNU_GETTEXT([external])
 613 AM_GNU_GETTEXT_VERSION([0.19.8])
 614 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 615
 616 dnl substitutions and generated files
 617 AC_CONFIG_HEADERS([config.h])
 618 AC_CONFIG_FILES([
 619         Makefile
 620         pixmaps/Makefile
 621         po/Makefile.in
 622         pixmaps/16/Makefile
 623         pixmaps/22/Makefile
 624         pixmaps/24/Makefile
 625         pixmaps/32/Makefile
 626         pixmaps/48/Makefile
 627         pixmaps/scalable/Makefile
 628         src/Makefile
 629         src/core/Makefile
 630         src/api/Makefile
 631         src/purple/Makefile
 632         src/telepathy/Makefile
 633         src/telepathy/data/Makefile
 634         ])
 635
 636 dnl generate files
 637 AC_OUTPUT()
 638
 639 dnl additional info for the user
 640 AS_ECHO()
 641 AS_IF([test "x$enable_purple" = xno],
 642         [AS_ECHO("Not building purple plugin")],
 643         [AS_ECHO("Build purple plugin")
 644          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 645          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 646          AS_ECHO_N("Voice and video: ")
 647          AS_IF([test "x$with_purple_vv" = xno],
 648           [AS_ECHO("disabled")],
 649           [AS_ECHO("enabled")])
 650         ])
 651 AS_ECHO()
 652 AS_IF([test "x$enable_telepathy" = xno],
 653         [AS_ECHO("Not building telepathy plugin")],
 654         [AS_ECHO("Build telepathy plugin")
 655          AS_ECHO("TELEPATHY_GLIB_CFLAGS: $TELEPATHY_GLIB_CFLAGS")
 656          AS_ECHO("TELEPATHY_GLIB_LIBS  : $TELEPATHY_GLIB_LIBS")])
 657 AS_ECHO()
 658 AS_IF([test "x$with_krb5" = xno],
 659         [AS_ECHO("Not building with Kerberos 5 support")],
 660         [AS_ECHO("Build with Kerberos 5 support")
 661          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 662          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 663 AS_ECHO()
 664 AS_IF([test "x$enable_gssapi_only" = xno],
 665         [AS_ECHO("Using internal authentication implementation")],
 666         [AS_ECHO("Using only GSSAPI for authentication")])
 667 AS_ECHO()
 668 AS_IF([test "x$enable_debug" = xno],
 669         [AS_ECHO("Debugging not enabled")],
 670         [AS_ECHO("Build with debugging enabled")
 671          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 672 AS_ECHO()
 673 AS_IF([test "x$QUALITY_CFLAGS" = x],
 674         [AS_ECHO("Compiler checks disabled")],
 675         [AS_ECHO("Build with compiler checks enabled")
 676          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 677 AS_ECHO()
 678 AS_ECHO("configure complete. Now run 'make'")
 679 AS_ECHO()
 680
 681 dnl The End.