meson.build

   1 project('qemu', ['c'], meson_version: '>=0.59.3',
   2         default_options: ['warning_level=1', 'c_std=gnu11', 'cpp_std=gnu++11', 'b_colorout=auto',
   3                           'b_staticpic=false', 'stdsplit=false', 'optimization=2', 'b_pie=true'],
   4         version: files('VERSION'))
   5
   6 add_test_setup('quick', exclude_suites: ['slow', 'thorough'], is_default: true)
   7 add_test_setup('slow', exclude_suites: ['thorough'], env: ['G_TEST_SLOW=1', 'SPEED=slow'])
   8 add_test_setup('thorough', env: ['G_TEST_SLOW=1', 'SPEED=thorough'])
   9
  10 meson.add_postconf_script(find_program('scripts/symlink-install-tree.py'))
  11
  12 not_found = dependency('', required: false)
  13 keyval = import('keyval')
  14 ss = import('sourceset')
  15 fs = import('fs')
  16
  17 sh = find_program('sh')
  18 cc = meson.get_compiler('c')
  19 config_host = keyval.load(meson.current_build_dir() / 'config-host.mak')
  20 enable_modules = 'CONFIG_MODULES' in config_host
  21 enable_static = 'CONFIG_STATIC' in config_host
  22
  23 # Allow both shared and static libraries unless --enable-static
  24 static_kwargs = enable_static ? {'static': true} : {}
  25
  26 # Temporary directory used for files created while
  27 # configure runs. Since it is in the build directory
  28 # we can safely blow away any previous version of it
  29 # (and we need not jump through hoops to try to delete
  30 # it when configure exits.)
  31 tmpdir = meson.current_build_dir() / 'meson-private/temp'
  32
  33 if get_option('qemu_suffix').startswith('/')
  34   error('qemu_suffix cannot start with a /')
  35 endif
  36
  37 qemu_confdir = get_option('sysconfdir') / get_option('qemu_suffix')
  38 qemu_datadir = get_option('datadir') / get_option('qemu_suffix')
  39 qemu_docdir = get_option('docdir') / get_option('qemu_suffix')
  40 qemu_moddir = get_option('libdir') / get_option('qemu_suffix')
  41
  42 qemu_desktopdir = get_option('datadir') / 'applications'
  43 qemu_icondir = get_option('datadir') / 'icons'
  44
  45 config_host_data = configuration_data()
  46 genh = []
  47 qapi_trace_events = []
  48
  49 bsd_oses = ['gnu/kfreebsd', 'freebsd', 'netbsd', 'openbsd', 'dragonfly', 'darwin']
  50 supported_oses = ['windows', 'freebsd', 'netbsd', 'openbsd', 'darwin', 'sunos', 'linux']
  51 supported_cpus = ['ppc', 'ppc64', 's390x', 'riscv', 'x86', 'x86_64',
  52   'arm', 'aarch64', 'loongarch64', 'mips', 'mips64', 'sparc', 'sparc64']
  53
  54 cpu = host_machine.cpu_family()
  55
  56 # Unify riscv* to a single family.
  57 if cpu in ['riscv32', 'riscv64']
  58   cpu = 'riscv'
  59 endif
  60
  61 targetos = host_machine.system()
  62
  63 target_dirs = config_host['TARGET_DIRS'].split()
  64 have_linux_user = false
  65 have_bsd_user = false
  66 have_system = false
  67 foreach target : target_dirs
  68   have_linux_user = have_linux_user or target.endswith('linux-user')
  69   have_bsd_user = have_bsd_user or target.endswith('bsd-user')
  70   have_system = have_system or target.endswith('-softmmu')
  71 endforeach
  72 have_user = have_linux_user or have_bsd_user
  73 have_tools = get_option('tools') \
  74   .disable_auto_if(not have_system) \
  75   .allowed()
  76 have_ga = get_option('guest_agent') \
  77   .disable_auto_if(not have_system and not have_tools) \
  78   .require(targetos in ['sunos', 'linux', 'windows'],
  79            error_message: 'unsupported OS for QEMU guest agent') \
  80   .allowed()
  81 have_block = have_system or have_tools
  82
  83 python = import('python').find_installation()
  84
  85 if cpu not in supported_cpus
  86   host_arch = 'unknown'
  87 elif cpu == 'x86'
  88   host_arch = 'i386'
  89 elif cpu == 'mips64'
  90   host_arch = 'mips'
  91 else
  92   host_arch = cpu
  93 endif
  94
  95 if cpu in ['x86', 'x86_64']
  96   kvm_targets = ['i386-softmmu', 'x86_64-softmmu']
  97 elif cpu == 'aarch64'
  98   kvm_targets = ['aarch64-softmmu']
  99 elif cpu == 's390x'
 100   kvm_targets = ['s390x-softmmu']
 101 elif cpu in ['ppc', 'ppc64']
 102   kvm_targets = ['ppc-softmmu', 'ppc64-softmmu']
 103 elif cpu in ['mips', 'mips64']
 104   kvm_targets = ['mips-softmmu', 'mipsel-softmmu', 'mips64-softmmu', 'mips64el-softmmu']
 105 elif cpu in ['riscv']
 106   kvm_targets = ['riscv32-softmmu', 'riscv64-softmmu']
 107 else
 108   kvm_targets = []
 109 endif
 110
 111 kvm_targets_c = '""'
 112 if get_option('kvm').allowed() and targetos == 'linux'
 113   kvm_targets_c = '"' + '" ,"'.join(kvm_targets) + '"'
 114 endif
 115 config_host_data.set('CONFIG_KVM_TARGETS', kvm_targets_c)
 116
 117 accelerator_targets = { 'CONFIG_KVM': kvm_targets }
 118
 119 if cpu in ['aarch64']
 120   accelerator_targets += {
 121     'CONFIG_HVF': ['aarch64-softmmu']
 122   }
 123 endif
 124
 125 if cpu in ['x86', 'x86_64', 'arm', 'aarch64']
 126   # i386 emulator provides xenpv machine type for multiple architectures
 127   accelerator_targets += {
 128     'CONFIG_XEN': ['i386-softmmu', 'x86_64-softmmu'],
 129   }
 130 endif
 131 if cpu in ['x86', 'x86_64']
 132   accelerator_targets += {
 133     'CONFIG_HAX': ['i386-softmmu', 'x86_64-softmmu'],
 134     'CONFIG_HVF': ['x86_64-softmmu'],
 135     'CONFIG_NVMM': ['i386-softmmu', 'x86_64-softmmu'],
 136     'CONFIG_WHPX': ['i386-softmmu', 'x86_64-softmmu'],
 137   }
 138 endif
 139
 140 modular_tcg = []
 141 # Darwin does not support references to thread-local variables in modules
 142 if targetos != 'darwin'
 143   modular_tcg = ['i386-softmmu', 'x86_64-softmmu']
 144 endif
 145
 146 edk2_targets = [ 'arm-softmmu', 'aarch64-softmmu', 'i386-softmmu', 'x86_64-softmmu' ]
 147 unpack_edk2_blobs = false
 148 foreach target : edk2_targets
 149   if target in target_dirs
 150     bzip2 = find_program('bzip2', required: get_option('install_blobs'))
 151     unpack_edk2_blobs = bzip2.found()
 152     break
 153   endif
 154 endforeach
 155
 156 dtrace = not_found
 157 stap = not_found
 158 if 'dtrace' in get_option('trace_backends')
 159   dtrace = find_program('dtrace', required: true)
 160   stap = find_program('stap', required: false)
 161   if stap.found()
 162     # Workaround to avoid dtrace(1) producing a file with 'hidden' symbol
 163     # visibility. Define STAP_SDT_V2 to produce 'default' symbol visibility
 164     # instead. QEMU --enable-modules depends on this because the SystemTap
 165     # semaphores are linked into the main binary and not the module's shared
 166     # object.
 167     add_global_arguments('-DSTAP_SDT_V2',
 168                          native: false, language: ['c', 'cpp', 'objc'])
 169   endif
 170 endif
 171
 172 if get_option('iasl') == ''
 173   iasl = find_program('iasl', required: false)
 174 else
 175   iasl = find_program(get_option('iasl'), required: true)
 176 endif
 177
 178 ##################
 179 # Compiler flags #
 180 ##################
 181
 182 qemu_cflags = config_host['QEMU_CFLAGS'].split()
 183 qemu_cxxflags = config_host['QEMU_CXXFLAGS'].split()
 184 qemu_objcflags = config_host['QEMU_OBJCFLAGS'].split()
 185 qemu_ldflags = config_host['QEMU_LDFLAGS'].split()
 186
 187 if targetos == 'windows'
 188   qemu_ldflags += cc.get_supported_link_arguments('-Wl,--no-seh', '-Wl,--nxcompat')
 189   # Disable ASLR for debug builds to allow debugging with gdb
 190   if get_option('optimization') == '0'
 191     qemu_ldflags += cc.get_supported_link_arguments('-Wl,--dynamicbase')
 192   endif
 193 endif
 194
 195 if get_option('gprof')
 196   qemu_cflags += ['-p']
 197   qemu_cxxflags += ['-p']
 198   qemu_objcflags += ['-p']
 199   qemu_ldflags += ['-p']
 200 endif
 201
 202 # Specify linker-script with add_project_link_arguments so that it is not placed
 203 # within a linker --start-group/--end-group pair
 204 if get_option('fuzzing')
 205   add_project_link_arguments(['-Wl,-T,',
 206                               (meson.current_source_dir() / 'tests/qtest/fuzz/fork_fuzz.ld')],
 207                              native: false, language: ['c', 'cpp', 'objc'])
 208
 209   # Specify a filter to only instrument code that is directly related to
 210   # virtual-devices.
 211   configure_file(output: 'instrumentation-filter',
 212                  input: 'scripts/oss-fuzz/instrumentation-filter-template',
 213                  copy: true)
 214
 215   if cc.compiles('int main () { return 0; }',
 216                   name: '-fsanitize-coverage-allowlist=/dev/null',
 217                  args: ['-fsanitize-coverage-allowlist=/dev/null',
 218                         '-fsanitize-coverage=trace-pc'] )
 219     add_global_arguments('-fsanitize-coverage-allowlist=instrumentation-filter',
 220                          native: false, language: ['c', 'cpp', 'objc'])
 221   endif
 222
 223   if get_option('fuzzing_engine') == ''
 224     # Add CFLAGS to tell clang to add fuzzer-related instrumentation to all the
 225     # compiled code.  To build non-fuzzer binaries with --enable-fuzzing, link
 226     # everything with fsanitize=fuzzer-no-link. Otherwise, the linker will be
 227     # unable to bind the fuzzer-related callbacks added by instrumentation.
 228     add_global_arguments('-fsanitize=fuzzer-no-link',
 229                          native: false, language: ['c', 'cpp', 'objc'])
 230     add_global_link_arguments('-fsanitize=fuzzer-no-link',
 231                               native: false, language: ['c', 'cpp', 'objc'])
 232     # For the actual fuzzer binaries, we need to link against the libfuzzer
 233     # library. They need to be configurable, to support OSS-Fuzz
 234     fuzz_exe_ldflags = ['-fsanitize=fuzzer']
 235   else
 236     # LIB_FUZZING_ENGINE was set; assume we are running on OSS-Fuzz, and
 237     # the needed CFLAGS have already been provided
 238     fuzz_exe_ldflags = get_option('fuzzing_engine').split()
 239   endif
 240 endif
 241
 242 add_global_arguments(qemu_cflags, native: false, language: ['c'])
 243 add_global_arguments(qemu_cxxflags, native: false, language: ['cpp'])
 244 add_global_arguments(qemu_objcflags, native: false, language: ['objc'])
 245 add_global_link_arguments(qemu_ldflags, native: false, language: ['c', 'cpp', 'objc'])
 246
 247 if targetos == 'linux'
 248   add_project_arguments('-isystem', meson.current_source_dir() / 'linux-headers',
 249                         '-isystem', 'linux-headers',
 250                         language: ['c', 'cpp'])
 251 endif
 252
 253 add_project_arguments('-iquote', '.',
 254                       '-iquote', meson.current_source_dir(),
 255                       '-iquote', meson.current_source_dir() / 'include',
 256                       language: ['c', 'cpp', 'objc'])
 257
 258 link_language = meson.get_external_property('link_language', 'cpp')
 259 if link_language == 'cpp'
 260   add_languages('cpp', required: true, native: false)
 261   cxx = meson.get_compiler('cpp')
 262   linker = cxx
 263 else
 264   linker = cc
 265 endif
 266 if host_machine.system() == 'darwin'
 267   add_languages('objc', required: false, native: false)
 268 endif
 269
 270 sparse = find_program('cgcc', required: get_option('sparse'))
 271 if sparse.found()
 272   run_target('sparse',
 273              command: [find_program('scripts/check_sparse.py'),
 274                        'compile_commands.json', sparse.full_path(), '-Wbitwise',
 275                        '-Wno-transparent-union', '-Wno-old-initializer',
 276                        '-Wno-non-pointer-null'])
 277 endif
 278
 279 ###########################################
 280 # Target-specific checks and dependencies #
 281 ###########################################
 282
 283 # Fuzzing
 284 if get_option('fuzzing') and get_option('fuzzing_engine') == '' and \
 285     not cc.links('''
 286           #include <stdint.h>
 287           #include <sys/types.h>
 288           int LLVMFuzzerTestOneInput(const uint8_t *Data, size_t Size);
 289           int LLVMFuzzerTestOneInput(const uint8_t *Data, size_t Size) { return 0; }
 290         ''',
 291         args: ['-Werror', '-fsanitize=fuzzer'])
 292   error('Your compiler does not support -fsanitize=fuzzer')
 293 endif
 294
 295 # Tracing backends
 296 if 'ftrace' in get_option('trace_backends') and targetos != 'linux'
 297   error('ftrace is supported only on Linux')
 298 endif
 299 if 'syslog' in get_option('trace_backends') and not cc.compiles('''
 300     #include <syslog.h>
 301     int main(void) {
 302         openlog("qemu", LOG_PID, LOG_DAEMON);
 303         syslog(LOG_INFO, "configure");
 304         return 0;
 305     }''')
 306   error('syslog is not supported on this system')
 307 endif
 308
 309 # Miscellaneous Linux-only features
 310 get_option('mpath') \
 311   .require(targetos == 'linux', error_message: 'Multipath is supported only on Linux')
 312
 313 multiprocess_allowed = get_option('multiprocess') \
 314   .require(targetos == 'linux', error_message: 'Multiprocess QEMU is supported only on Linux') \
 315   .allowed()
 316
 317 vfio_user_server_allowed = get_option('vfio_user_server') \
 318   .require(targetos == 'linux', error_message: 'vfio-user server is supported only on Linux') \
 319   .allowed()
 320
 321 have_tpm = get_option('tpm') \
 322   .require(targetos != 'windows', error_message: 'TPM emulation only available on POSIX systems') \
 323   .allowed()
 324
 325 # vhost
 326 have_vhost_user = get_option('vhost_user') \
 327   .disable_auto_if(targetos != 'linux') \
 328   .require(targetos != 'windows',
 329            error_message: 'vhost-user is not available on Windows').allowed()
 330 have_vhost_vdpa = get_option('vhost_vdpa') \
 331   .require(targetos == 'linux',
 332            error_message: 'vhost-vdpa is only available on Linux').allowed()
 333 have_vhost_kernel = get_option('vhost_kernel') \
 334   .require(targetos == 'linux',
 335            error_message: 'vhost-kernel is only available on Linux').allowed()
 336 have_vhost_user_crypto = get_option('vhost_crypto') \
 337   .require(have_vhost_user,
 338            error_message: 'vhost-crypto requires vhost-user to be enabled').allowed()
 339
 340 have_vhost = have_vhost_user or have_vhost_vdpa or have_vhost_kernel
 341
 342 have_vhost_net_user = have_vhost_user and get_option('vhost_net').allowed()
 343 have_vhost_net_vdpa = have_vhost_vdpa and get_option('vhost_net').allowed()
 344 have_vhost_net_kernel = have_vhost_kernel and get_option('vhost_net').allowed()
 345 have_vhost_net = have_vhost_net_kernel or have_vhost_net_user or have_vhost_net_vdpa
 346
 347 # Target-specific libraries and flags
 348 libm = cc.find_library('m', required: false)
 349 threads = dependency('threads')
 350 util = cc.find_library('util', required: false)
 351 winmm = []
 352 socket = []
 353 version_res = []
 354 coref = []
 355 iokit = []
 356 emulator_link_args = []
 357 nvmm =not_found
 358 hvf = not_found
 359 midl = not_found
 360 widl = not_found
 361 pathcch = not_found
 362 host_dsosuf = '.so'
 363 if targetos == 'windows'
 364   midl = find_program('midl', required: false)
 365   widl = find_program('widl', required: false)
 366   pathcch = cc.find_library('pathcch')
 367   socket = cc.find_library('ws2_32')
 368   winmm = cc.find_library('winmm')
 369
 370   win = import('windows')
 371   version_res = win.compile_resources('version.rc',
 372                                       depend_files: files('pc-bios/qemu-nsis.ico'),
 373                                       include_directories: include_directories('.'))
 374   host_dsosuf = '.dll'
 375 elif targetos == 'darwin'
 376   coref = dependency('appleframeworks', modules: 'CoreFoundation')
 377   iokit = dependency('appleframeworks', modules: 'IOKit', required: false)
 378   host_dsosuf = '.dylib'
 379 elif targetos == 'sunos'
 380   socket = [cc.find_library('socket'),
 381             cc.find_library('nsl'),
 382             cc.find_library('resolv')]
 383 elif targetos == 'haiku'
 384   socket = [cc.find_library('posix_error_mapper'),
 385             cc.find_library('network'),
 386             cc.find_library('bsd')]
 387 elif targetos == 'openbsd'
 388   if get_option('tcg').allowed() and target_dirs.length() > 0
 389     # Disable OpenBSD W^X if available
 390     emulator_link_args = cc.get_supported_link_arguments('-Wl,-z,wxneeded')
 391   endif
 392 endif
 393
 394 # Target-specific configuration of accelerators
 395 accelerators = []
 396 if get_option('kvm').allowed() and targetos == 'linux'
 397   accelerators += 'CONFIG_KVM'
 398 endif
 399 if get_option('whpx').allowed() and targetos == 'windows'
 400   if get_option('whpx').enabled() and host_machine.cpu() != 'x86_64'
 401     error('WHPX requires 64-bit host')
 402   elif cc.has_header('WinHvPlatform.h', required: get_option('whpx')) and \
 403        cc.has_header('WinHvEmulation.h', required: get_option('whpx'))
 404     accelerators += 'CONFIG_WHPX'
 405   endif
 406 endif
 407 if get_option('hvf').allowed()
 408   hvf = dependency('appleframeworks', modules: 'Hypervisor',
 409                    required: get_option('hvf'))
 410   if hvf.found()
 411     accelerators += 'CONFIG_HVF'
 412   endif
 413 endif
 414 if get_option('hax').allowed()
 415   if get_option('hax').enabled() or targetos in ['windows', 'darwin', 'netbsd']
 416     accelerators += 'CONFIG_HAX'
 417   endif
 418 endif
 419 if targetos == 'netbsd'
 420   nvmm = cc.find_library('nvmm', required: get_option('nvmm'))
 421   if nvmm.found()
 422     accelerators += 'CONFIG_NVMM'
 423   endif
 424 endif
 425
 426 tcg_arch = host_arch
 427 if get_option('tcg').allowed()
 428   if host_arch == 'unknown'
 429     if get_option('tcg_interpreter')
 430       warning('Unsupported CPU @0@, will use TCG with TCI (slow)'.format(cpu))
 431     else
 432       error('Unsupported CPU @0@, try --enable-tcg-interpreter'.format(cpu))
 433     endif
 434   elif get_option('tcg_interpreter')
 435     warning('Use of the TCG interpreter is not recommended on this host')
 436     warning('architecture. There is a native TCG execution backend available')
 437     warning('which provides substantially better performance and reliability.')
 438     warning('It is strongly recommended to remove the --enable-tcg-interpreter')
 439     warning('configuration option on this architecture to use the native')
 440     warning('backend.')
 441   endif
 442   if get_option('tcg_interpreter')
 443     tcg_arch = 'tci'
 444   elif host_arch == 'sparc64'
 445     tcg_arch = 'sparc'
 446   elif host_arch == 'x86_64'
 447     tcg_arch = 'i386'
 448   elif host_arch == 'ppc64'
 449     tcg_arch = 'ppc'
 450   endif
 451   add_project_arguments('-iquote', meson.current_source_dir() / 'tcg' / tcg_arch,
 452                         language: ['c', 'cpp', 'objc'])
 453
 454   accelerators += 'CONFIG_TCG'
 455   config_host += { 'CONFIG_TCG': 'y' }
 456 endif
 457
 458 if 'CONFIG_KVM' not in accelerators and get_option('kvm').enabled()
 459   error('KVM not available on this platform')
 460 endif
 461 if 'CONFIG_HVF' not in accelerators and get_option('hvf').enabled()
 462   error('HVF not available on this platform')
 463 endif
 464 if 'CONFIG_NVMM' not in accelerators and get_option('nvmm').enabled()
 465   error('NVMM not available on this platform')
 466 endif
 467 if 'CONFIG_WHPX' not in accelerators and get_option('whpx').enabled()
 468   error('WHPX not available on this platform')
 469 endif
 470
 471 ################
 472 # Dependencies #
 473 ################
 474
 475 # The path to glib.h is added to all compilation commands.  This was
 476 # grandfathered in from the QEMU Makefiles.
 477 add_project_arguments(config_host['GLIB_CFLAGS'].split(),
 478                       native: false, language: ['c', 'cpp', 'objc'])
 479 glib = declare_dependency(compile_args: config_host['GLIB_CFLAGS'].split(),
 480                           link_args: config_host['GLIB_LIBS'].split(),
 481                           version: config_host['GLIB_VERSION'],
 482                           variables: {
 483                             'bindir': config_host['GLIB_BINDIR'],
 484                           })
 485 # override glib dep with the configure results (for subprojects)
 486 meson.override_dependency('glib-2.0', glib)
 487
 488 gio = not_found
 489 gdbus_codegen = not_found
 490 if not get_option('gio').auto() or have_system
 491   gio = dependency('gio-2.0', required: get_option('gio'),
 492                    method: 'pkg-config', kwargs: static_kwargs)
 493   if gio.found() and not cc.links('''
 494     #include <gio/gio.h>
 495     int main(void)
 496     {
 497       g_dbus_proxy_new_sync(0, 0, 0, 0, 0, 0, 0, 0);
 498       return 0;
 499     }''', dependencies: [glib, gio])
 500     if get_option('gio').enabled()
 501       error('The installed libgio is broken for static linking')
 502     endif
 503     gio = not_found
 504   endif
 505   if gio.found()
 506     gdbus_codegen = find_program(gio.get_variable('gdbus_codegen'),
 507                                  required: get_option('gio'))
 508     gio_unix = dependency('gio-unix-2.0', required: get_option('gio'),
 509                           method: 'pkg-config', kwargs: static_kwargs)
 510     gio = declare_dependency(dependencies: [gio, gio_unix],
 511                              version: gio.version())
 512   endif
 513 endif
 514
 515 lttng = not_found
 516 if 'ust' in get_option('trace_backends')
 517   lttng = dependency('lttng-ust', required: true, version: '>= 2.1',
 518                      method: 'pkg-config', kwargs: static_kwargs)
 519 endif
 520 pixman = not_found
 521 if have_system or have_tools
 522   pixman = dependency('pixman-1', required: have_system, version:'>=0.21.8',
 523                       method: 'pkg-config', kwargs: static_kwargs)
 524 endif
 525 zlib = dependency('zlib', required: true, kwargs: static_kwargs)
 526
 527 libaio = not_found
 528 if not get_option('linux_aio').auto() or have_block
 529   libaio = cc.find_library('aio', has_headers: ['libaio.h'],
 530                            required: get_option('linux_aio'),
 531                            kwargs: static_kwargs)
 532 endif
 533
 534 linux_io_uring_test = '''
 535   #include <liburing.h>
 536   #include <linux/errqueue.h>
 537
 538   int main(void) { return 0; }'''
 539
 540 linux_io_uring = not_found
 541 if not get_option('linux_io_uring').auto() or have_block
 542   linux_io_uring = dependency('liburing', version: '>=0.3',
 543                               required: get_option('linux_io_uring'),
 544                               method: 'pkg-config', kwargs: static_kwargs)
 545   if not cc.links(linux_io_uring_test)
 546     linux_io_uring = not_found
 547   endif
 548 endif
 549
 550 libnfs = not_found
 551 if not get_option('libnfs').auto() or have_block
 552   libnfs = dependency('libnfs', version: '>=1.9.3',
 553                       required: get_option('libnfs'),
 554                       method: 'pkg-config', kwargs: static_kwargs)
 555 endif
 556
 557 libattr_test = '''
 558   #include <stddef.h>
 559   #include <sys/types.h>
 560   #ifdef CONFIG_LIBATTR
 561   #include <attr/xattr.h>
 562   #else
 563   #include <sys/xattr.h>
 564   #endif
 565   int main(void) { getxattr(NULL, NULL, NULL, 0); setxattr(NULL, NULL, NULL, 0, 0); return 0; }'''
 566
 567 libattr = not_found
 568 have_old_libattr = false
 569 if get_option('attr').allowed()
 570   if cc.links(libattr_test)
 571     libattr = declare_dependency()
 572   else
 573     libattr = cc.find_library('attr', has_headers: ['attr/xattr.h'],
 574                               required: get_option('attr'),
 575                               kwargs: static_kwargs)
 576     if libattr.found() and not \
 577       cc.links(libattr_test, dependencies: libattr, args: '-DCONFIG_LIBATTR')
 578       libattr = not_found
 579       if get_option('attr').enabled()
 580         error('could not link libattr')
 581       else
 582         warning('could not link libattr, disabling')
 583       endif
 584     else
 585       have_old_libattr = libattr.found()
 586     endif
 587   endif
 588 endif
 589
 590 cocoa = dependency('appleframeworks', modules: 'Cocoa', required: get_option('cocoa'))
 591 if cocoa.found() and get_option('sdl').enabled()
 592   error('Cocoa and SDL cannot be enabled at the same time')
 593 endif
 594 if cocoa.found() and get_option('gtk').enabled()
 595   error('Cocoa and GTK+ cannot be enabled at the same time')
 596 endif
 597
 598 vmnet = dependency('appleframeworks', modules: 'vmnet', required: get_option('vmnet'))
 599 if vmnet.found() and not cc.has_header_symbol('vmnet/vmnet.h',
 600                                               'VMNET_BRIDGED_MODE',
 601                                               dependencies: vmnet)
 602   vmnet = not_found
 603   if get_option('vmnet').enabled()
 604     error('vmnet.framework API is outdated')
 605   else
 606     warning('vmnet.framework API is outdated, disabling')
 607   endif
 608 endif
 609
 610 seccomp = not_found
 611 if not get_option('seccomp').auto() or have_system or have_tools
 612   seccomp = dependency('libseccomp', version: '>=2.3.0',
 613                        required: get_option('seccomp'),
 614                        method: 'pkg-config', kwargs: static_kwargs)
 615 endif
 616
 617 libcap_ng = not_found
 618 if not get_option('cap_ng').auto() or have_system or have_tools
 619   libcap_ng = cc.find_library('cap-ng', has_headers: ['cap-ng.h'],
 620                               required: get_option('cap_ng'),
 621                               kwargs: static_kwargs)
 622 endif
 623 if libcap_ng.found() and not cc.links('''
 624    #include <cap-ng.h>
 625    int main(void)
 626    {
 627      capng_capability_to_name(CAPNG_EFFECTIVE);
 628      return 0;
 629    }''', dependencies: libcap_ng)
 630   libcap_ng = not_found
 631   if get_option('cap_ng').enabled()
 632     error('could not link libcap-ng')
 633   else
 634     warning('could not link libcap-ng, disabling')
 635   endif
 636 endif
 637
 638 if get_option('xkbcommon').auto() and not have_system and not have_tools
 639   xkbcommon = not_found
 640 else
 641   xkbcommon = dependency('xkbcommon', required: get_option('xkbcommon'),
 642                          method: 'pkg-config', kwargs: static_kwargs)
 643 endif
 644
 645 vde = not_found
 646 if not get_option('vde').auto() or have_system or have_tools
 647   vde = cc.find_library('vdeplug', has_headers: ['libvdeplug.h'],
 648                            required: get_option('vde'),
 649                            kwargs: static_kwargs)
 650 endif
 651 if vde.found() and not cc.links('''
 652    #include <libvdeplug.h>
 653    int main(void)
 654    {
 655      struct vde_open_args a = {0, 0, 0};
 656      char s[] = "";
 657      vde_open(s, s, &a);
 658      return 0;
 659    }''', dependencies: vde)
 660   vde = not_found
 661   if get_option('cap_ng').enabled()
 662     error('could not link libvdeplug')
 663   else
 664     warning('could not link libvdeplug, disabling')
 665   endif
 666 endif
 667
 668 pulse = not_found
 669 if not get_option('pa').auto() or (targetos == 'linux' and have_system)
 670   pulse = dependency('libpulse', required: get_option('pa'),
 671                      method: 'pkg-config', kwargs: static_kwargs)
 672 endif
 673 alsa = not_found
 674 if not get_option('alsa').auto() or (targetos == 'linux' and have_system)
 675   alsa = dependency('alsa', required: get_option('alsa'),
 676                     method: 'pkg-config', kwargs: static_kwargs)
 677 endif
 678 jack = not_found
 679 if not get_option('jack').auto() or have_system
 680   jack = dependency('jack', required: get_option('jack'),
 681                     method: 'pkg-config', kwargs: static_kwargs)
 682 endif
 683
 684 spice_protocol = not_found
 685 if not get_option('spice_protocol').auto() or have_system
 686   spice_protocol = dependency('spice-protocol', version: '>=0.12.3',
 687                               required: get_option('spice_protocol'),
 688                               method: 'pkg-config', kwargs: static_kwargs)
 689 endif
 690 spice = not_found
 691 if not get_option('spice').auto() or have_system
 692   spice = dependency('spice-server', version: '>=0.12.5',
 693                      required: get_option('spice'),
 694                      method: 'pkg-config', kwargs: static_kwargs)
 695 endif
 696 spice_headers = spice.partial_dependency(compile_args: true, includes: true)
 697
 698 rt = cc.find_library('rt', required: false)
 699
 700 libiscsi = not_found
 701 if not get_option('libiscsi').auto() or have_block
 702   libiscsi = dependency('libiscsi', version: '>=1.9.0',
 703                          required: get_option('libiscsi'),
 704                          method: 'pkg-config', kwargs: static_kwargs)
 705 endif
 706 zstd = not_found
 707 if not get_option('zstd').auto() or have_block
 708   zstd = dependency('libzstd', version: '>=1.4.0',
 709                     required: get_option('zstd'),
 710                     method: 'pkg-config', kwargs: static_kwargs)
 711 endif
 712 virgl = not_found
 713
 714 have_vhost_user_gpu = have_tools and targetos == 'linux' and pixman.found()
 715 if not get_option('virglrenderer').auto() or have_system or have_vhost_user_gpu
 716   virgl = dependency('virglrenderer',
 717                      method: 'pkg-config',
 718                      required: get_option('virglrenderer'),
 719                      kwargs: static_kwargs)
 720 endif
 721 curl = not_found
 722 if not get_option('curl').auto() or have_block
 723   curl = dependency('libcurl', version: '>=7.29.0',
 724                     method: 'pkg-config',
 725                     required: get_option('curl'),
 726                     kwargs: static_kwargs)
 727 endif
 728 libudev = not_found
 729 if targetos == 'linux' and (have_system or have_tools)
 730   libudev = dependency('libudev',
 731                        method: 'pkg-config',
 732                        required: get_option('libudev'),
 733                        kwargs: static_kwargs)
 734 endif
 735
 736 mpathlibs = [libudev]
 737 mpathpersist = not_found
 738 mpathpersist_new_api = false
 739 if targetos == 'linux' and have_tools and get_option('mpath').allowed()
 740   mpath_test_source_new = '''
 741     #include <libudev.h>
 742     #include <mpath_persist.h>
 743     unsigned mpath_mx_alloc_len = 1024;
 744     int logsink;
 745     static struct config *multipath_conf;
 746     extern struct udev *udev;
 747     extern struct config *get_multipath_config(void);
 748     extern void put_multipath_config(struct config *conf);
 749     struct udev *udev;
 750     struct config *get_multipath_config(void) { return multipath_conf; }
 751     void put_multipath_config(struct config *conf) { }
 752     int main(void) {
 753         udev = udev_new();
 754         multipath_conf = mpath_lib_init();
 755         return 0;
 756     }'''
 757   mpath_test_source_old = '''
 758       #include <libudev.h>
 759       #include <mpath_persist.h>
 760       unsigned mpath_mx_alloc_len = 1024;
 761       int logsink;
 762       int main(void) {
 763           struct udev *udev = udev_new();
 764           mpath_lib_init(udev);
 765           return 0;
 766       }'''
 767   libmpathpersist = cc.find_library('mpathpersist',
 768                                     required: get_option('mpath'),
 769                                     kwargs: static_kwargs)
 770   if libmpathpersist.found()
 771     mpathlibs += libmpathpersist
 772     if enable_static
 773       mpathlibs += cc.find_library('devmapper',
 774                                      required: get_option('mpath'),
 775                                      kwargs: static_kwargs)
 776     endif
 777     mpathlibs += cc.find_library('multipath',
 778                                  required: get_option('mpath'),
 779                                  kwargs: static_kwargs)
 780     foreach lib: mpathlibs
 781       if not lib.found()
 782         mpathlibs = []
 783         break
 784       endif
 785     endforeach
 786     if mpathlibs.length() == 0
 787       msg = 'Dependencies missing for libmpathpersist'
 788     elif cc.links(mpath_test_source_new, dependencies: mpathlibs)
 789       mpathpersist = declare_dependency(dependencies: mpathlibs)
 790       mpathpersist_new_api = true
 791     elif cc.links(mpath_test_source_old, dependencies: mpathlibs)
 792       mpathpersist = declare_dependency(dependencies: mpathlibs)
 793     else
 794       msg = 'Cannot detect libmpathpersist API'
 795     endif
 796     if not mpathpersist.found()
 797       if get_option('mpath').enabled()
 798         error(msg)
 799       else
 800         warning(msg + ', disabling')
 801       endif
 802     endif
 803   endif
 804 endif
 805
 806 iconv = not_found
 807 curses = not_found
 808 if have_system and get_option('curses').allowed()
 809   curses_test = '''
 810     #if defined(__APPLE__) || defined(__OpenBSD__)
 811     #define _XOPEN_SOURCE_EXTENDED 1
 812     #endif
 813     #include <locale.h>
 814     #include <curses.h>
 815     #include <wchar.h>
 816     int main(void) {
 817       wchar_t wch = L'w';
 818       setlocale(LC_ALL, "");
 819       resize_term(0, 0);
 820       addwstr(L"wide chars\n");
 821       addnwstr(&wch, 1);
 822       add_wch(WACS_DEGREE);
 823       return 0;
 824     }'''
 825
 826   curses_dep_list = targetos == 'windows' ? ['ncurses', 'ncursesw'] : ['ncursesw']
 827   foreach curses_dep : curses_dep_list
 828     if not curses.found()
 829       curses = dependency(curses_dep,
 830                           required: false,
 831                           method: 'pkg-config',
 832                           kwargs: static_kwargs)
 833     endif
 834   endforeach
 835   msg = get_option('curses').enabled() ? 'curses library not found' : ''
 836   curses_compile_args = ['-DNCURSES_WIDECHAR=1']
 837   if curses.found()
 838     if cc.links(curses_test, args: curses_compile_args, dependencies: [curses])
 839       curses = declare_dependency(compile_args: curses_compile_args, dependencies: [curses])
 840     else
 841       msg = 'curses package not usable'
 842       curses = not_found
 843     endif
 844   endif
 845   if not curses.found()
 846     has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
 847     if targetos != 'windows' and not has_curses_h
 848       message('Trying with /usr/include/ncursesw')
 849       curses_compile_args += ['-I/usr/include/ncursesw']
 850       has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
 851     endif
 852     if has_curses_h
 853       curses_libname_list = (targetos == 'windows' ? ['pdcurses'] : ['ncursesw', 'cursesw'])
 854       foreach curses_libname : curses_libname_list
 855         libcurses = cc.find_library(curses_libname,
 856                                     required: false,
 857                                     kwargs: static_kwargs)
 858         if libcurses.found()
 859           if cc.links(curses_test, args: curses_compile_args, dependencies: libcurses)
 860             curses = declare_dependency(compile_args: curses_compile_args,
 861                                         dependencies: [libcurses])
 862             break
 863           else
 864             msg = 'curses library not usable'
 865           endif
 866         endif
 867       endforeach
 868     endif
 869   endif
 870   if get_option('iconv').allowed()
 871     foreach link_args : [ ['-liconv'], [] ]
 872       # Programs will be linked with glib and this will bring in libiconv on FreeBSD.
 873       # We need to use libiconv if available because mixing libiconv's headers with
 874       # the system libc does not work.
 875       # However, without adding glib to the dependencies -L/usr/local/lib will not be
 876       # included in the command line and libiconv will not be found.
 877       if cc.links('''
 878         #include <iconv.h>
 879         int main(void) {
 880           iconv_t conv = iconv_open("WCHAR_T", "UCS-2");
 881           return conv != (iconv_t) -1;
 882         }''', args: config_host['GLIB_CFLAGS'].split() + config_host['GLIB_LIBS'].split() + link_args)
 883         iconv = declare_dependency(link_args: link_args, dependencies: glib)
 884         break
 885       endif
 886     endforeach
 887   endif
 888   if curses.found() and not iconv.found()
 889     if get_option('iconv').enabled()
 890       error('iconv not available')
 891     endif
 892     msg = 'iconv required for curses UI but not available'
 893     curses = not_found
 894   endif
 895   if not curses.found() and msg != ''
 896     if get_option('curses').enabled()
 897       error(msg)
 898     else
 899       warning(msg + ', disabling')
 900     endif
 901   endif
 902 endif
 903
 904 brlapi = not_found
 905 if not get_option('brlapi').auto() or have_system
 906   brlapi = cc.find_library('brlapi', has_headers: ['brlapi.h'],
 907                          required: get_option('brlapi'),
 908                          kwargs: static_kwargs)
 909   if brlapi.found() and not cc.links('''
 910      #include <brlapi.h>
 911      #include <stddef.h>
 912      int main(void) { return brlapi__openConnection (NULL, NULL, NULL); }''', dependencies: brlapi)
 913     brlapi = not_found
 914     if get_option('brlapi').enabled()
 915       error('could not link brlapi')
 916     else
 917       warning('could not link brlapi, disabling')
 918     endif
 919   endif
 920 endif
 921
 922 sdl = not_found
 923 if not get_option('sdl').auto() or (have_system and not cocoa.found())
 924   sdl = dependency('sdl2', required: get_option('sdl'), kwargs: static_kwargs)
 925   sdl_image = not_found
 926 endif
 927 if sdl.found()
 928   # work around 2.0.8 bug
 929   sdl = declare_dependency(compile_args: '-Wno-undef',
 930                            dependencies: sdl)
 931   sdl_image = dependency('SDL2_image', required: get_option('sdl_image'),
 932                          method: 'pkg-config', kwargs: static_kwargs)
 933 else
 934   if get_option('sdl_image').enabled()
 935     error('sdl-image required, but SDL was @0@'.format(
 936           get_option('sdl').disabled() ? 'disabled' : 'not found'))
 937   endif
 938   sdl_image = not_found
 939 endif
 940
 941 rbd = not_found
 942 if not get_option('rbd').auto() or have_block
 943   librados = cc.find_library('rados', required: get_option('rbd'),
 944                              kwargs: static_kwargs)
 945   librbd = cc.find_library('rbd', has_headers: ['rbd/librbd.h'],
 946                            required: get_option('rbd'),
 947                            kwargs: static_kwargs)
 948   if librados.found() and librbd.found()
 949     if cc.links('''
 950       #include <stdio.h>
 951       #include <rbd/librbd.h>
 952       int main(void) {
 953         rados_t cluster;
 954         rados_create(&cluster, NULL);
 955         #if LIBRBD_VERSION_CODE < LIBRBD_VERSION(1, 12, 0)
 956         #error
 957         #endif
 958         return 0;
 959       }''', dependencies: [librbd, librados])
 960       rbd = declare_dependency(dependencies: [librbd, librados])
 961     elif get_option('rbd').enabled()
 962       error('librbd >= 1.12.0 required')
 963     else
 964       warning('librbd >= 1.12.0 not found, disabling')
 965     endif
 966   endif
 967 endif
 968
 969 glusterfs = not_found
 970 glusterfs_ftruncate_has_stat = false
 971 glusterfs_iocb_has_stat = false
 972 if not get_option('glusterfs').auto() or have_block
 973   glusterfs = dependency('glusterfs-api', version: '>=3',
 974                          required: get_option('glusterfs'),
 975                          method: 'pkg-config', kwargs: static_kwargs)
 976   if glusterfs.found()
 977     glusterfs_ftruncate_has_stat = cc.links('''
 978       #include <glusterfs/api/glfs.h>
 979
 980       int
 981       main(void)
 982       {
 983           /* new glfs_ftruncate() passes two additional args */
 984           return glfs_ftruncate(NULL, 0, NULL, NULL);
 985       }
 986     ''', dependencies: glusterfs)
 987     glusterfs_iocb_has_stat = cc.links('''
 988       #include <glusterfs/api/glfs.h>
 989
 990       /* new glfs_io_cbk() passes two additional glfs_stat structs */
 991       static void
 992       glusterfs_iocb(glfs_fd_t *fd, ssize_t ret, struct glfs_stat *prestat, struct glfs_stat *poststat, void *data)
 993       {}
 994
 995       int
 996       main(void)
 997       {
 998           glfs_io_cbk iocb = &glusterfs_iocb;
 999           iocb(NULL, 0 , NULL, NULL, NULL);
1000           return 0;
1001       }
1002     ''', dependencies: glusterfs)
1003   endif
1004 endif
1005
1006 libssh = not_found
1007 if not get_option('libssh').auto() or have_block
1008   libssh = dependency('libssh', version: '>=0.8.7',
1009                     method: 'pkg-config',
1010                     required: get_option('libssh'),
1011                     kwargs: static_kwargs)
1012 endif
1013
1014 libbzip2 = not_found
1015 if not get_option('bzip2').auto() or have_block
1016   libbzip2 = cc.find_library('bz2', has_headers: ['bzlib.h'],
1017                              required: get_option('bzip2'),
1018                              kwargs: static_kwargs)
1019   if libbzip2.found() and not cc.links('''
1020      #include <bzlib.h>
1021      int main(void) { BZ2_bzlibVersion(); return 0; }''', dependencies: libbzip2)
1022     libbzip2 = not_found
1023     if get_option('bzip2').enabled()
1024       error('could not link libbzip2')
1025     else
1026       warning('could not link libbzip2, disabling')
1027     endif
1028   endif
1029 endif
1030
1031 liblzfse = not_found
1032 if not get_option('lzfse').auto() or have_block
1033   liblzfse = cc.find_library('lzfse', has_headers: ['lzfse.h'],
1034                              required: get_option('lzfse'),
1035                              kwargs: static_kwargs)
1036 endif
1037 if liblzfse.found() and not cc.links('''
1038    #include <lzfse.h>
1039    int main(void) { lzfse_decode_scratch_size(); return 0; }''', dependencies: liblzfse)
1040   liblzfse = not_found
1041   if get_option('lzfse').enabled()
1042     error('could not link liblzfse')
1043   else
1044     warning('could not link liblzfse, disabling')
1045   endif
1046 endif
1047
1048 oss = not_found
1049 if get_option('oss').allowed() and have_system
1050   if not cc.has_header('sys/soundcard.h')
1051     # not found
1052   elif targetos == 'netbsd'
1053     oss = cc.find_library('ossaudio', required: get_option('oss'),
1054                           kwargs: static_kwargs)
1055   else
1056     oss = declare_dependency()
1057   endif
1058
1059   if not oss.found()
1060     if get_option('oss').enabled()
1061       error('OSS not found')
1062     endif
1063   endif
1064 endif
1065 dsound = not_found
1066 if not get_option('dsound').auto() or (targetos == 'windows' and have_system)
1067   if cc.has_header('dsound.h')
1068     dsound = declare_dependency(link_args: ['-lole32', '-ldxguid'])
1069   endif
1070
1071   if not dsound.found()
1072     if get_option('dsound').enabled()
1073       error('DirectSound not found')
1074     endif
1075   endif
1076 endif
1077
1078 coreaudio = not_found
1079 if not get_option('coreaudio').auto() or (targetos == 'darwin' and have_system)
1080   coreaudio = dependency('appleframeworks', modules: 'CoreAudio',
1081                          required: get_option('coreaudio'))
1082 endif
1083
1084 opengl = not_found
1085 if not get_option('opengl').auto() or have_system or have_vhost_user_gpu
1086   epoxy = dependency('epoxy', method: 'pkg-config',
1087                       required: get_option('opengl'), kwargs: static_kwargs)
1088   if cc.has_header('epoxy/egl.h', dependencies: epoxy)
1089     opengl = epoxy
1090   elif get_option('opengl').enabled()
1091     error('epoxy/egl.h not found')
1092   endif
1093 endif
1094 gbm = not_found
1095 if (have_system or have_tools) and (virgl.found() or opengl.found())
1096   gbm = dependency('gbm', method: 'pkg-config', required: false,
1097                    kwargs: static_kwargs)
1098 endif
1099 have_vhost_user_gpu = have_vhost_user_gpu and virgl.found() and gbm.found()
1100
1101 gnutls = not_found
1102 gnutls_crypto = not_found
1103 if get_option('gnutls').enabled() or (get_option('gnutls').auto() and have_system)
1104   # For general TLS support our min gnutls matches
1105   # that implied by our platform support matrix
1106   #
1107   # For the crypto backends, we look for a newer
1108   # gnutls:
1109   #
1110   #   Version 3.6.8  is needed to get XTS
1111   #   Version 3.6.13 is needed to get PBKDF
1112   #   Version 3.6.14 is needed to get HW accelerated XTS
1113   #
1114   # If newer enough gnutls isn't available, we can
1115   # still use a different crypto backend to satisfy
1116   # the platform support requirements
1117   gnutls_crypto = dependency('gnutls', version: '>=3.6.14',
1118                              method: 'pkg-config',
1119                              required: false,
1120                              kwargs: static_kwargs)
1121   if gnutls_crypto.found()
1122     gnutls = gnutls_crypto
1123   else
1124     # Our min version if all we need is TLS
1125     gnutls = dependency('gnutls', version: '>=3.5.18',
1126                         method: 'pkg-config',
1127                         required: get_option('gnutls'),
1128                         kwargs: static_kwargs)
1129   endif
1130 endif
1131
1132 # We prefer use of gnutls for crypto, unless the options
1133 # explicitly asked for nettle or gcrypt.
1134 #
1135 # If gnutls isn't available for crypto, then we'll prefer
1136 # gcrypt over nettle for performance reasons.
1137 gcrypt = not_found
1138 nettle = not_found
1139 hogweed = not_found
1140 xts = 'none'
1141
1142 if get_option('nettle').enabled() and get_option('gcrypt').enabled()
1143   error('Only one of gcrypt & nettle can be enabled')
1144 endif
1145
1146 # Explicit nettle/gcrypt request, so ignore gnutls for crypto
1147 if get_option('nettle').enabled() or get_option('gcrypt').enabled()
1148   gnutls_crypto = not_found
1149 endif
1150
1151 if not gnutls_crypto.found()
1152   if (not get_option('gcrypt').auto() or have_system) and not get_option('nettle').enabled()
1153     gcrypt = dependency('libgcrypt', version: '>=1.8',
1154                         method: 'config-tool',
1155                         required: get_option('gcrypt'),
1156                         kwargs: static_kwargs)
1157     # Debian has removed -lgpg-error from libgcrypt-config
1158     # as it "spreads unnecessary dependencies" which in
1159     # turn breaks static builds...
1160     if gcrypt.found() and enable_static
1161       gcrypt = declare_dependency(dependencies: [
1162         gcrypt,
1163         cc.find_library('gpg-error', required: true, kwargs: static_kwargs)])
1164     endif
1165   endif
1166   if (not get_option('nettle').auto() or have_system) and not gcrypt.found()
1167     nettle = dependency('nettle', version: '>=3.4',
1168                         method: 'pkg-config',
1169                         required: get_option('nettle'),
1170                         kwargs: static_kwargs)
1171     if nettle.found() and not cc.has_header('nettle/xts.h', dependencies: nettle)
1172       xts = 'private'
1173     endif
1174   endif
1175 endif
1176
1177 gmp = dependency('gmp', required: false, method: 'pkg-config', kwargs: static_kwargs)
1178 if nettle.found() and gmp.found()
1179   hogweed = dependency('hogweed', version: '>=3.4',
1180                        method: 'pkg-config',
1181                        required: get_option('nettle'),
1182                        kwargs: static_kwargs)
1183 endif
1184
1185
1186 gtk = not_found
1187 gtkx11 = not_found
1188 vte = not_found
1189 if not get_option('gtk').auto() or (have_system and not cocoa.found())
1190   gtk = dependency('gtk+-3.0', version: '>=3.22.0',
1191                    method: 'pkg-config',
1192                    required: get_option('gtk'),
1193                    kwargs: static_kwargs)
1194   if gtk.found()
1195     gtkx11 = dependency('gtk+-x11-3.0', version: '>=3.22.0',
1196                         method: 'pkg-config',
1197                         required: false,
1198                         kwargs: static_kwargs)
1199     gtk = declare_dependency(dependencies: [gtk, gtkx11])
1200
1201     if not get_option('vte').auto() or have_system
1202       vte = dependency('vte-2.91',
1203                        method: 'pkg-config',
1204                        required: get_option('vte'),
1205                        kwargs: static_kwargs)
1206     endif
1207   endif
1208 endif
1209
1210 x11 = not_found
1211 if gtkx11.found()
1212   x11 = dependency('x11', method: 'pkg-config', required: gtkx11.found(),
1213                    kwargs: static_kwargs)
1214 endif
1215 png = not_found
1216 if get_option('png').allowed() and have_system
1217    png = dependency('libpng', version: '>=1.6.34', required: get_option('png'),
1218                     method: 'pkg-config', kwargs: static_kwargs)
1219 endif
1220 vnc = not_found
1221 jpeg = not_found
1222 sasl = not_found
1223 if get_option('vnc').allowed() and have_system
1224   vnc = declare_dependency() # dummy dependency
1225   jpeg = dependency('libjpeg', required: get_option('vnc_jpeg'),
1226                     method: 'pkg-config', kwargs: static_kwargs)
1227   sasl = cc.find_library('sasl2', has_headers: ['sasl/sasl.h'],
1228                          required: get_option('vnc_sasl'),
1229                          kwargs: static_kwargs)
1230   if sasl.found()
1231     sasl = declare_dependency(dependencies: sasl,
1232                               compile_args: '-DSTRUCT_IOVEC_DEFINED')
1233   endif
1234 endif
1235
1236 pam = not_found
1237 if not get_option('auth_pam').auto() or have_system
1238   pam = cc.find_library('pam', has_headers: ['security/pam_appl.h'],
1239                         required: get_option('auth_pam'),
1240                         kwargs: static_kwargs)
1241 endif
1242 if pam.found() and not cc.links('''
1243    #include <stddef.h>
1244    #include <security/pam_appl.h>
1245    int main(void) {
1246      const char *service_name = "qemu";
1247      const char *user = "frank";
1248      const struct pam_conv pam_conv = { 0 };
1249      pam_handle_t *pamh = NULL;
1250      pam_start(service_name, user, &pam_conv, &pamh);
1251      return 0;
1252    }''', dependencies: pam)
1253   pam = not_found
1254   if get_option('auth_pam').enabled()
1255     error('could not link libpam')
1256   else
1257     warning('could not link libpam, disabling')
1258   endif
1259 endif
1260
1261 snappy = not_found
1262 if not get_option('snappy').auto() or have_system
1263   snappy = cc.find_library('snappy', has_headers: ['snappy-c.h'],
1264                            required: get_option('snappy'),
1265                            kwargs: static_kwargs)
1266 endif
1267 if snappy.found() and not linker.links('''
1268    #include <snappy-c.h>
1269    int main(void) { snappy_max_compressed_length(4096); return 0; }''', dependencies: snappy)
1270   snappy = not_found
1271   if get_option('snappy').enabled()
1272     error('could not link libsnappy')
1273   else
1274     warning('could not link libsnappy, disabling')
1275   endif
1276 endif
1277
1278 lzo = not_found
1279 if not get_option('lzo').auto() or have_system
1280   lzo = cc.find_library('lzo2', has_headers: ['lzo/lzo1x.h'],
1281                         required: get_option('lzo'),
1282                         kwargs: static_kwargs)
1283 endif
1284 if lzo.found() and not cc.links('''
1285    #include <lzo/lzo1x.h>
1286    int main(void) { lzo_version(); return 0; }''', dependencies: lzo)
1287   lzo = not_found
1288   if get_option('lzo').enabled()
1289     error('could not link liblzo2')
1290   else
1291     warning('could not link liblzo2, disabling')
1292   endif
1293 endif
1294
1295 numa = not_found
1296 if not get_option('numa').auto() or have_system or have_tools
1297   numa = cc.find_library('numa', has_headers: ['numa.h'],
1298                               required: get_option('numa'),
1299                               kwargs: static_kwargs)
1300 endif
1301 if numa.found() and not cc.links('''
1302    #include <numa.h>
1303    int main(void) { return numa_available(); }
1304    ''', dependencies: numa)
1305   numa = not_found
1306   if get_option('numa').enabled()
1307     error('could not link numa')
1308   else
1309     warning('could not link numa, disabling')
1310   endif
1311 endif
1312
1313 rdma = not_found
1314 if not get_option('rdma').auto() or have_system
1315   libumad = cc.find_library('ibumad', required: get_option('rdma'))
1316   rdma_libs = [cc.find_library('rdmacm', has_headers: ['rdma/rdma_cma.h'],
1317                                required: get_option('rdma'),
1318                                kwargs: static_kwargs),
1319                cc.find_library('ibverbs', required: get_option('rdma'),
1320                                kwargs: static_kwargs),
1321                libumad]
1322   rdma = declare_dependency(dependencies: rdma_libs)
1323   foreach lib: rdma_libs
1324     if not lib.found()
1325       rdma = not_found
1326     endif
1327   endforeach
1328 endif
1329
1330 xen = not_found
1331 if get_option('xen').enabled() or (get_option('xen').auto() and have_system)
1332   xencontrol = dependency('xencontrol', required: false,
1333                           method: 'pkg-config', kwargs: static_kwargs)
1334   if xencontrol.found()
1335     xen_pc = declare_dependency(version: xencontrol.version(),
1336       dependencies: [
1337         xencontrol,
1338         # disabler: true makes xen_pc.found() return false if any is not found
1339         dependency('xenstore', required: false,
1340                    method: 'pkg-config', kwargs: static_kwargs,
1341                    disabler: true),
1342         dependency('xenforeignmemory', required: false,
1343                    method: 'pkg-config', kwargs: static_kwargs,
1344                    disabler: true),
1345         dependency('xengnttab', required: false,
1346                    method: 'pkg-config', kwargs: static_kwargs,
1347                    disabler: true),
1348         dependency('xenevtchn', required: false,
1349                    method: 'pkg-config', kwargs: static_kwargs,
1350                    disabler: true),
1351         dependency('xendevicemodel', required: false,
1352                    method: 'pkg-config', kwargs: static_kwargs,
1353                    disabler: true),
1354         # optional, no "disabler: true"
1355         dependency('xentoolcore', required: false,
1356                    method: 'pkg-config', kwargs: static_kwargs)])
1357     if xen_pc.found()
1358       xen = xen_pc
1359     endif
1360   endif
1361   if not xen.found()
1362     xen_tests = [ '4.11.0', '4.10.0', '4.9.0', '4.8.0', '4.7.1', '4.6.0', '4.5.0', '4.2.0' ]
1363     xen_libs = {
1364       '4.11.0': [ 'xenstore', 'xenctrl', 'xendevicemodel', 'xenforeignmemory', 'xengnttab', 'xenevtchn', 'xentoolcore' ],
1365       '4.10.0': [ 'xenstore', 'xenctrl', 'xendevicemodel', 'xenforeignmemory', 'xengnttab', 'xenevtchn', 'xentoolcore' ],
1366       '4.9.0': [ 'xenstore', 'xenctrl', 'xendevicemodel', 'xenforeignmemory', 'xengnttab', 'xenevtchn' ],
1367       '4.8.0': [ 'xenstore', 'xenctrl', 'xenforeignmemory', 'xengnttab', 'xenevtchn' ],
1368       '4.7.1': [ 'xenstore', 'xenctrl', 'xenforeignmemory', 'xengnttab', 'xenevtchn' ],
1369       '4.6.0': [ 'xenstore', 'xenctrl' ],
1370       '4.5.0': [ 'xenstore', 'xenctrl' ],
1371       '4.2.0': [ 'xenstore', 'xenctrl' ],
1372     }
1373     xen_deps = {}
1374     foreach ver: xen_tests
1375       # cache the various library tests to avoid polluting the logs
1376       xen_test_deps = []
1377       foreach l: xen_libs[ver]
1378         if l not in xen_deps
1379           xen_deps += { l: cc.find_library(l, required: false) }
1380         endif
1381         xen_test_deps += xen_deps[l]
1382       endforeach
1383
1384       # Use -D to pick just one of the test programs in scripts/xen-detect.c
1385       xen_version = ver.split('.')
1386       xen_ctrl_version = xen_version[0] + \
1387         ('0' + xen_version[1]).substring(-2) + \
1388         ('0' + xen_version[2]).substring(-2)
1389       if cc.links(files('scripts/xen-detect.c'),
1390                   args: '-DCONFIG_XEN_CTRL_INTERFACE_VERSION=' + xen_ctrl_version,
1391                   dependencies: xen_test_deps)
1392         xen = declare_dependency(version: ver, dependencies: xen_test_deps)
1393         break
1394       endif
1395     endforeach
1396   endif
1397   if xen.found()
1398     accelerators += 'CONFIG_XEN'
1399   elif get_option('xen').enabled()
1400     error('could not compile and link Xen test program')
1401   endif
1402 endif
1403 have_xen_pci_passthrough = get_option('xen_pci_passthrough') \
1404   .require(xen.found(),
1405            error_message: 'Xen PCI passthrough requested but Xen not enabled') \
1406   .require(targetos == 'linux',
1407            error_message: 'Xen PCI passthrough not available on this platform') \
1408   .allowed()
1409
1410
1411 cacard = not_found
1412 if not get_option('smartcard').auto() or have_system
1413   cacard = dependency('libcacard', required: get_option('smartcard'),
1414                       version: '>=2.5.1', method: 'pkg-config',
1415                       kwargs: static_kwargs)
1416 endif
1417 u2f = not_found
1418 if have_system
1419   u2f = dependency('u2f-emu', required: get_option('u2f'),
1420                    method: 'pkg-config',
1421                    kwargs: static_kwargs)
1422 endif
1423 canokey = not_found
1424 if have_system
1425   canokey = dependency('canokey-qemu', required: get_option('canokey'),
1426                    method: 'pkg-config',
1427                    kwargs: static_kwargs)
1428 endif
1429 usbredir = not_found
1430 if not get_option('usb_redir').auto() or have_system
1431   usbredir = dependency('libusbredirparser-0.5', required: get_option('usb_redir'),
1432                         version: '>=0.6', method: 'pkg-config',
1433                         kwargs: static_kwargs)
1434 endif
1435 libusb = not_found
1436 if not get_option('libusb').auto() or have_system
1437   libusb = dependency('libusb-1.0', required: get_option('libusb'),
1438                       version: '>=1.0.13', method: 'pkg-config',
1439                       kwargs: static_kwargs)
1440 endif
1441
1442 libpmem = not_found
1443 if not get_option('libpmem').auto() or have_system
1444   libpmem = dependency('libpmem', required: get_option('libpmem'),
1445                        method: 'pkg-config', kwargs: static_kwargs)
1446 endif
1447 libdaxctl = not_found
1448 if not get_option('libdaxctl').auto() or have_system
1449   libdaxctl = dependency('libdaxctl', required: get_option('libdaxctl'),
1450                          version: '>=57', method: 'pkg-config',
1451                          kwargs: static_kwargs)
1452 endif
1453 tasn1 = not_found
1454 if gnutls.found()
1455   tasn1 = dependency('libtasn1',
1456                      method: 'pkg-config',
1457                      kwargs: static_kwargs)
1458 endif
1459 keyutils = dependency('libkeyutils', required: false,
1460                       method: 'pkg-config', kwargs: static_kwargs)
1461
1462 has_gettid = cc.has_function('gettid')
1463
1464 # libselinux
1465 selinux = dependency('libselinux',
1466                      required: get_option('selinux'),
1467                      method: 'pkg-config', kwargs: static_kwargs)
1468
1469 # Malloc tests
1470
1471 malloc = []
1472 if get_option('malloc') == 'system'
1473   has_malloc_trim = \
1474     get_option('malloc_trim').allowed() and \
1475     cc.links('''#include <malloc.h>
1476                 int main(void) { malloc_trim(0); return 0; }''')
1477 else
1478   has_malloc_trim = false
1479   malloc = cc.find_library(get_option('malloc'), required: true)
1480 endif
1481 if not has_malloc_trim and get_option('malloc_trim').enabled()
1482   if get_option('malloc') == 'system'
1483     error('malloc_trim not available on this platform.')
1484   else
1485     error('malloc_trim not available with non-libc memory allocator')
1486   endif
1487 endif
1488
1489 # Check whether the glibc provides statx()
1490
1491 gnu_source_prefix = '''
1492   #ifndef _GNU_SOURCE
1493   #define _GNU_SOURCE
1494   #endif
1495 '''
1496 statx_test = gnu_source_prefix + '''
1497   #include <sys/stat.h>
1498   int main(void) {
1499     struct statx statxbuf;
1500     statx(0, "", 0, STATX_BASIC_STATS, &statxbuf);
1501     return 0;
1502   }'''
1503
1504 has_statx = cc.links(statx_test)
1505
1506 # Check whether statx() provides mount ID information
1507
1508 statx_mnt_id_test = gnu_source_prefix + '''
1509   #include <sys/stat.h>
1510   int main(void) {
1511     struct statx statxbuf;
1512     statx(0, "", 0, STATX_BASIC_STATS | STATX_MNT_ID, &statxbuf);
1513     return statxbuf.stx_mnt_id;
1514   }'''
1515
1516 has_statx_mnt_id = cc.links(statx_mnt_id_test)
1517
1518 have_vhost_user_blk_server = get_option('vhost_user_blk_server') \
1519   .require(targetos == 'linux',
1520            error_message: 'vhost_user_blk_server requires linux') \
1521   .require(have_vhost_user,
1522            error_message: 'vhost_user_blk_server requires vhost-user support') \
1523   .disable_auto_if(not have_tools and not have_system) \
1524   .allowed()
1525
1526 if get_option('fuse').disabled() and get_option('fuse_lseek').enabled()
1527   error('Cannot enable fuse-lseek while fuse is disabled')
1528 endif
1529
1530 fuse = dependency('fuse3', required: get_option('fuse'),
1531                   version: '>=3.1', method: 'pkg-config',
1532                   kwargs: static_kwargs)
1533
1534 fuse_lseek = not_found
1535 if get_option('fuse_lseek').allowed()
1536   if fuse.version().version_compare('>=3.8')
1537     # Dummy dependency
1538     fuse_lseek = declare_dependency()
1539   elif get_option('fuse_lseek').enabled()
1540     if fuse.found()
1541       error('fuse-lseek requires libfuse >=3.8, found ' + fuse.version())
1542     else
1543       error('fuse-lseek requires libfuse, which was not found')
1544     endif
1545   endif
1546 endif
1547
1548 have_libvduse = (targetos == 'linux')
1549 if get_option('libvduse').enabled()
1550     if targetos != 'linux'
1551         error('libvduse requires linux')
1552     endif
1553 elif get_option('libvduse').disabled()
1554     have_libvduse = false
1555 endif
1556
1557 have_vduse_blk_export = (have_libvduse and targetos == 'linux')
1558 if get_option('vduse_blk_export').enabled()
1559     if targetos != 'linux'
1560         error('vduse_blk_export requires linux')
1561     elif not have_libvduse
1562         error('vduse_blk_export requires libvduse support')
1563     endif
1564 elif get_option('vduse_blk_export').disabled()
1565     have_vduse_blk_export = false
1566 endif
1567
1568 # libbpf
1569 libbpf = dependency('libbpf', required: get_option('bpf'), method: 'pkg-config')
1570 if libbpf.found() and not cc.links('''
1571    #include <bpf/libbpf.h>
1572    int main(void)
1573    {
1574      bpf_object__destroy_skeleton(NULL);
1575      return 0;
1576    }''', dependencies: libbpf)
1577   libbpf = not_found
1578   if get_option('bpf').enabled()
1579     error('libbpf skeleton test failed')
1580   else
1581     warning('libbpf skeleton test failed, disabling')
1582   endif
1583 endif
1584
1585 #################
1586 # config-host.h #
1587 #################
1588
1589 audio_drivers_selected = []
1590 if have_system
1591   audio_drivers_available = {
1592     'alsa': alsa.found(),
1593     'coreaudio': coreaudio.found(),
1594     'dsound': dsound.found(),
1595     'jack': jack.found(),
1596     'oss': oss.found(),
1597     'pa': pulse.found(),
1598     'sdl': sdl.found(),
1599   }
1600   foreach k, v: audio_drivers_available
1601     config_host_data.set('CONFIG_AUDIO_' + k.to_upper(), v)
1602   endforeach
1603
1604   # Default to native drivers first, OSS second, SDL third
1605   audio_drivers_priority = \
1606     [ 'pa', 'coreaudio', 'dsound', 'oss' ] + \
1607     (targetos == 'linux' ? [] : [ 'sdl' ])
1608   audio_drivers_default = []
1609   foreach k: audio_drivers_priority
1610     if audio_drivers_available[k]
1611       audio_drivers_default += k
1612     endif
1613   endforeach
1614
1615   foreach k: get_option('audio_drv_list')
1616     if k == 'default'
1617       audio_drivers_selected += audio_drivers_default
1618     elif not audio_drivers_available[k]
1619       error('Audio driver "@0@" not available.'.format(k))
1620     else
1621       audio_drivers_selected += k
1622     endif
1623   endforeach
1624 endif
1625 config_host_data.set('CONFIG_AUDIO_DRIVERS',
1626                      '"' + '", "'.join(audio_drivers_selected) + '", ')
1627
1628 if get_option('cfi')
1629   cfi_flags=[]
1630   # Check for dependency on LTO
1631   if not get_option('b_lto')
1632     error('Selected Control-Flow Integrity but LTO is disabled')
1633   endif
1634   if config_host.has_key('CONFIG_MODULES')
1635     error('Selected Control-Flow Integrity is not compatible with modules')
1636   endif
1637   # Check for cfi flags. CFI requires LTO so we can't use
1638   # get_supported_arguments, but need a more complex "compiles" which allows
1639   # custom arguments
1640   if cc.compiles('int main () { return 0; }', name: '-fsanitize=cfi-icall',
1641                  args: ['-flto', '-fsanitize=cfi-icall'] )
1642     cfi_flags += '-fsanitize=cfi-icall'
1643   else
1644     error('-fsanitize=cfi-icall is not supported by the compiler')
1645   endif
1646   if cc.compiles('int main () { return 0; }',
1647                  name: '-fsanitize-cfi-icall-generalize-pointers',
1648                  args: ['-flto', '-fsanitize=cfi-icall',
1649                         '-fsanitize-cfi-icall-generalize-pointers'] )
1650     cfi_flags += '-fsanitize-cfi-icall-generalize-pointers'
1651   else
1652     error('-fsanitize-cfi-icall-generalize-pointers is not supported by the compiler')
1653   endif
1654   if get_option('cfi_debug')
1655     if cc.compiles('int main () { return 0; }',
1656                    name: '-fno-sanitize-trap=cfi-icall',
1657                    args: ['-flto', '-fsanitize=cfi-icall',
1658                           '-fno-sanitize-trap=cfi-icall'] )
1659       cfi_flags += '-fno-sanitize-trap=cfi-icall'
1660     else
1661       error('-fno-sanitize-trap=cfi-icall is not supported by the compiler')
1662     endif
1663   endif
1664   add_global_arguments(cfi_flags, native: false, language: ['c', 'cpp', 'objc'])
1665   add_global_link_arguments(cfi_flags, native: false, language: ['c', 'cpp', 'objc'])
1666 endif
1667
1668 have_host_block_device = (targetos != 'darwin' or
1669     cc.has_header('IOKit/storage/IOMedia.h'))
1670
1671 # FIXME enable_modules shouldn't be necessary, but: https://github.com/mesonbuild/meson/issues/8333
1672 dbus_display = get_option('dbus_display') \
1673   .require(gio.version().version_compare('>=2.64'),
1674            error_message: '-display dbus requires glib>=2.64') \
1675   .require(enable_modules,
1676            error_message: '-display dbus requires --enable-modules') \
1677   .require(gdbus_codegen.found(),
1678            error_message: '-display dbus requires gdbus-codegen') \
1679   .require(opengl.found(),
1680            error_message: '-display dbus requires epoxy/egl') \
1681   .allowed()
1682
1683 have_virtfs = get_option('virtfs') \
1684     .require(targetos == 'linux' or targetos == 'darwin',
1685              error_message: 'virtio-9p (virtfs) requires Linux or macOS') \
1686     .require(targetos == 'linux' or cc.has_function('pthread_fchdir_np'),
1687              error_message: 'virtio-9p (virtfs) on macOS requires the presence of pthread_fchdir_np') \
1688     .require(targetos == 'darwin' or (libattr.found() and libcap_ng.found()),
1689              error_message: 'virtio-9p (virtfs) on Linux requires libcap-ng-devel and libattr-devel') \
1690     .disable_auto_if(not have_tools and not have_system) \
1691     .allowed()
1692
1693 have_virtfs_proxy_helper = targetos != 'darwin' and have_virtfs and have_tools
1694
1695 if get_option('block_drv_ro_whitelist') == ''
1696   config_host_data.set('CONFIG_BDRV_RO_WHITELIST', '')
1697 else
1698   config_host_data.set('CONFIG_BDRV_RO_WHITELIST',
1699         '"' + get_option('block_drv_ro_whitelist').replace(',', '", "') + '", ')
1700 endif
1701 if get_option('block_drv_rw_whitelist') == ''
1702   config_host_data.set('CONFIG_BDRV_RW_WHITELIST', '')
1703 else
1704   config_host_data.set('CONFIG_BDRV_RW_WHITELIST',
1705         '"' + get_option('block_drv_rw_whitelist').replace(',', '", "') + '", ')
1706 endif
1707
1708 foreach k : get_option('trace_backends')
1709   config_host_data.set('CONFIG_TRACE_' + k.to_upper(), true)
1710 endforeach
1711 config_host_data.set_quoted('CONFIG_TRACE_FILE', get_option('trace_file'))
1712 config_host_data.set_quoted('CONFIG_TLS_PRIORITY', get_option('tls_priority'))
1713 if iasl.found()
1714   config_host_data.set_quoted('CONFIG_IASL', iasl.full_path())
1715 endif
1716 config_host_data.set_quoted('CONFIG_BINDIR', get_option('prefix') / get_option('bindir'))
1717 config_host_data.set_quoted('CONFIG_PREFIX', get_option('prefix'))
1718 config_host_data.set_quoted('CONFIG_QEMU_CONFDIR', get_option('prefix') / qemu_confdir)
1719 config_host_data.set_quoted('CONFIG_QEMU_DATADIR', get_option('prefix') / qemu_datadir)
1720 config_host_data.set_quoted('CONFIG_QEMU_DESKTOPDIR', get_option('prefix') / qemu_desktopdir)
1721
1722 qemu_firmwarepath = ''
1723 foreach k : get_option('qemu_firmwarepath')
1724   qemu_firmwarepath += '"' + get_option('prefix') / k + '", '
1725 endforeach
1726 config_host_data.set('CONFIG_QEMU_FIRMWAREPATH', qemu_firmwarepath)
1727
1728 config_host_data.set_quoted('CONFIG_QEMU_HELPERDIR', get_option('prefix') / get_option('libexecdir'))
1729 config_host_data.set_quoted('CONFIG_QEMU_ICONDIR', get_option('prefix') / qemu_icondir)
1730 config_host_data.set_quoted('CONFIG_QEMU_LOCALEDIR', get_option('prefix') / get_option('localedir'))
1731 config_host_data.set_quoted('CONFIG_QEMU_LOCALSTATEDIR', get_option('prefix') / get_option('localstatedir'))
1732 config_host_data.set_quoted('CONFIG_QEMU_MODDIR', get_option('prefix') / qemu_moddir)
1733 config_host_data.set_quoted('CONFIG_SYSCONFDIR', get_option('prefix') / get_option('sysconfdir'))
1734
1735 if config_host.has_key('CONFIG_MODULES')
1736   config_host_data.set('CONFIG_STAMP', run_command(
1737       meson.current_source_dir() / 'scripts/qemu-stamp.py',
1738       meson.project_version(), get_option('pkgversion'), '--',
1739       meson.current_source_dir() / 'configure',
1740       capture: true, check: true).stdout().strip())
1741 endif
1742
1743 have_slirp_smbd = get_option('slirp_smbd') \
1744   .require(targetos != 'windows', error_message: 'Host smbd not supported on this platform.') \
1745   .allowed()
1746 if have_slirp_smbd
1747   smbd_path = get_option('smbd')
1748   if smbd_path == ''
1749     smbd_path = (targetos == 'solaris' ? '/usr/sfw/sbin/smbd' : '/usr/sbin/smbd')
1750   endif
1751   config_host_data.set_quoted('CONFIG_SMBD_COMMAND', smbd_path)
1752 endif
1753
1754 config_host_data.set('HOST_' + host_arch.to_upper(), 1)
1755
1756 if get_option('module_upgrades') and not enable_modules
1757   error('Cannot enable module-upgrades as modules are not enabled')
1758 endif
1759 config_host_data.set('CONFIG_MODULE_UPGRADES', get_option('module_upgrades'))
1760
1761 config_host_data.set('CONFIG_ATTR', libattr.found())
1762 config_host_data.set('CONFIG_BDRV_WHITELIST_TOOLS', get_option('block_drv_whitelist_in_tools'))
1763 config_host_data.set('CONFIG_BRLAPI', brlapi.found())
1764 config_host_data.set('CONFIG_COCOA', cocoa.found())
1765 config_host_data.set('CONFIG_FUZZ', get_option('fuzzing'))
1766 config_host_data.set('CONFIG_GCOV', get_option('b_coverage'))
1767 config_host_data.set('CONFIG_LIBUDEV', libudev.found())
1768 config_host_data.set('CONFIG_LZO', lzo.found())
1769 config_host_data.set('CONFIG_MPATH', mpathpersist.found())
1770 config_host_data.set('CONFIG_MPATH_NEW_API', mpathpersist_new_api)
1771 config_host_data.set('CONFIG_CURL', curl.found())
1772 config_host_data.set('CONFIG_CURSES', curses.found())
1773 config_host_data.set('CONFIG_GBM', gbm.found())
1774 config_host_data.set('CONFIG_GIO', gio.found())
1775 config_host_data.set('CONFIG_GLUSTERFS', glusterfs.found())
1776 if glusterfs.found()
1777   config_host_data.set('CONFIG_GLUSTERFS_XLATOR_OPT', glusterfs.version().version_compare('>=4'))
1778   config_host_data.set('CONFIG_GLUSTERFS_DISCARD', glusterfs.version().version_compare('>=5'))
1779   config_host_data.set('CONFIG_GLUSTERFS_FALLOCATE', glusterfs.version().version_compare('>=6'))
1780   config_host_data.set('CONFIG_GLUSTERFS_ZEROFILL', glusterfs.version().version_compare('>=6'))
1781   config_host_data.set('CONFIG_GLUSTERFS_FTRUNCATE_HAS_STAT', glusterfs_ftruncate_has_stat)
1782   config_host_data.set('CONFIG_GLUSTERFS_IOCB_HAS_STAT', glusterfs_iocb_has_stat)
1783 endif
1784 config_host_data.set('CONFIG_GTK', gtk.found())
1785 config_host_data.set('CONFIG_VTE', vte.found())
1786 config_host_data.set('CONFIG_LIBATTR', have_old_libattr)
1787 config_host_data.set('CONFIG_LIBCAP_NG', libcap_ng.found())
1788 config_host_data.set('CONFIG_EBPF', libbpf.found())
1789 config_host_data.set('CONFIG_LIBDAXCTL', libdaxctl.found())
1790 config_host_data.set('CONFIG_LIBISCSI', libiscsi.found())
1791 config_host_data.set('CONFIG_LIBNFS', libnfs.found())
1792 config_host_data.set('CONFIG_LIBSSH', libssh.found())
1793 config_host_data.set('CONFIG_LINUX_AIO', libaio.found())
1794 config_host_data.set('CONFIG_LINUX_IO_URING', linux_io_uring.found())
1795 config_host_data.set('CONFIG_LIBURING_REGISTER_RING_FD', cc.has_function('io_uring_register_ring_fd', prefix: '#include <liburing.h>', dependencies:linux_io_uring))
1796 config_host_data.set('CONFIG_LIBPMEM', libpmem.found())
1797 config_host_data.set('CONFIG_NUMA', numa.found())
1798 config_host_data.set('CONFIG_OPENGL', opengl.found())
1799 config_host_data.set('CONFIG_PROFILER', get_option('profiler'))
1800 config_host_data.set('CONFIG_RBD', rbd.found())
1801 config_host_data.set('CONFIG_RDMA', rdma.found())
1802 config_host_data.set('CONFIG_SDL', sdl.found())
1803 config_host_data.set('CONFIG_SDL_IMAGE', sdl_image.found())
1804 config_host_data.set('CONFIG_SECCOMP', seccomp.found())
1805 config_host_data.set('CONFIG_SNAPPY', snappy.found())
1806 config_host_data.set('CONFIG_TPM', have_tpm)
1807 config_host_data.set('CONFIG_USB_LIBUSB', libusb.found())
1808 config_host_data.set('CONFIG_VDE', vde.found())
1809 config_host_data.set('CONFIG_VHOST_NET', have_vhost_net)
1810 config_host_data.set('CONFIG_VHOST_NET_USER', have_vhost_net_user)
1811 config_host_data.set('CONFIG_VHOST_NET_VDPA', have_vhost_net_vdpa)
1812 config_host_data.set('CONFIG_VHOST_KERNEL', have_vhost_kernel)
1813 config_host_data.set('CONFIG_VHOST_USER', have_vhost_user)
1814 config_host_data.set('CONFIG_VHOST_CRYPTO', have_vhost_user_crypto)
1815 config_host_data.set('CONFIG_VHOST_VDPA', have_vhost_vdpa)
1816 config_host_data.set('CONFIG_VMNET', vmnet.found())
1817 config_host_data.set('CONFIG_VHOST_USER_BLK_SERVER', have_vhost_user_blk_server)
1818 config_host_data.set('CONFIG_VDUSE_BLK_EXPORT', have_vduse_blk_export)
1819 config_host_data.set('CONFIG_PNG', png.found())
1820 config_host_data.set('CONFIG_VNC', vnc.found())
1821 config_host_data.set('CONFIG_VNC_JPEG', jpeg.found())
1822 config_host_data.set('CONFIG_VNC_SASL', sasl.found())
1823 config_host_data.set('CONFIG_VIRTFS', have_virtfs)
1824 config_host_data.set('CONFIG_VTE', vte.found())
1825 config_host_data.set('CONFIG_XKBCOMMON', xkbcommon.found())
1826 config_host_data.set('CONFIG_KEYUTILS', keyutils.found())
1827 config_host_data.set('CONFIG_GETTID', has_gettid)
1828 config_host_data.set('CONFIG_GNUTLS', gnutls.found())
1829 config_host_data.set('CONFIG_GNUTLS_CRYPTO', gnutls_crypto.found())
1830 config_host_data.set('CONFIG_TASN1', tasn1.found())
1831 config_host_data.set('CONFIG_GCRYPT', gcrypt.found())
1832 config_host_data.set('CONFIG_NETTLE', nettle.found())
1833 config_host_data.set('CONFIG_HOGWEED', hogweed.found())
1834 config_host_data.set('CONFIG_QEMU_PRIVATE_XTS', xts == 'private')
1835 config_host_data.set('CONFIG_MALLOC_TRIM', has_malloc_trim)
1836 config_host_data.set('CONFIG_STATX', has_statx)
1837 config_host_data.set('CONFIG_STATX_MNT_ID', has_statx_mnt_id)
1838 config_host_data.set('CONFIG_ZSTD', zstd.found())
1839 config_host_data.set('CONFIG_FUSE', fuse.found())
1840 config_host_data.set('CONFIG_FUSE_LSEEK', fuse_lseek.found())
1841 config_host_data.set('CONFIG_SPICE_PROTOCOL', spice_protocol.found())
1842 if spice_protocol.found()
1843 config_host_data.set('CONFIG_SPICE_PROTOCOL_MAJOR', spice_protocol.version().split('.')[0])
1844 config_host_data.set('CONFIG_SPICE_PROTOCOL_MINOR', spice_protocol.version().split('.')[1])
1845 config_host_data.set('CONFIG_SPICE_PROTOCOL_MICRO', spice_protocol.version().split('.')[2])
1846 endif
1847 config_host_data.set('CONFIG_SPICE', spice.found())
1848 config_host_data.set('CONFIG_X11', x11.found())
1849 config_host_data.set('CONFIG_DBUS_DISPLAY', dbus_display)
1850 config_host_data.set('CONFIG_CFI', get_option('cfi'))
1851 config_host_data.set('CONFIG_SELINUX', selinux.found())
1852 config_host_data.set('CONFIG_XEN_BACKEND', xen.found())
1853 if xen.found()
1854   # protect from xen.version() having less than three components
1855   xen_version = xen.version().split('.') + ['0', '0']
1856   xen_ctrl_version = xen_version[0] + \
1857     ('0' + xen_version[1]).substring(-2) + \
1858     ('0' + xen_version[2]).substring(-2)
1859   config_host_data.set('CONFIG_XEN_CTRL_INTERFACE_VERSION', xen_ctrl_version)
1860 endif
1861 config_host_data.set('QEMU_VERSION', '"@0@"'.format(meson.project_version()))
1862 config_host_data.set('QEMU_VERSION_MAJOR', meson.project_version().split('.')[0])
1863 config_host_data.set('QEMU_VERSION_MINOR', meson.project_version().split('.')[1])
1864 config_host_data.set('QEMU_VERSION_MICRO', meson.project_version().split('.')[2])
1865
1866 config_host_data.set_quoted('CONFIG_HOST_DSOSUF', host_dsosuf)
1867 config_host_data.set('HAVE_HOST_BLOCK_DEVICE', have_host_block_device)
1868
1869 have_coroutine_pool = get_option('coroutine_pool')
1870 if get_option('debug_stack_usage') and have_coroutine_pool
1871   message('Disabling coroutine pool to measure stack usage')
1872   have_coroutine_pool = false
1873 endif
1874 config_host_data.set10('CONFIG_COROUTINE_POOL', have_coroutine_pool)
1875 config_host_data.set('CONFIG_DEBUG_MUTEX', get_option('debug_mutex'))
1876 config_host_data.set('CONFIG_DEBUG_STACK_USAGE', get_option('debug_stack_usage'))
1877 config_host_data.set('CONFIG_GPROF', get_option('gprof'))
1878 config_host_data.set('CONFIG_LIVE_BLOCK_MIGRATION', get_option('live_block_migration').allowed())
1879 config_host_data.set('CONFIG_QOM_CAST_DEBUG', get_option('qom_cast_debug'))
1880 config_host_data.set('CONFIG_REPLICATION', get_option('live_block_migration').allowed())
1881
1882 # has_header
1883 config_host_data.set('CONFIG_EPOLL', cc.has_header('sys/epoll.h'))
1884 config_host_data.set('CONFIG_LINUX_MAGIC_H', cc.has_header('linux/magic.h'))
1885 config_host_data.set('CONFIG_VALGRIND_H', cc.has_header('valgrind/valgrind.h'))
1886 config_host_data.set('HAVE_BTRFS_H', cc.has_header('linux/btrfs.h'))
1887 config_host_data.set('HAVE_DRM_H', cc.has_header('libdrm/drm.h'))
1888 config_host_data.set('HAVE_PTY_H', cc.has_header('pty.h'))
1889 config_host_data.set('HAVE_SYS_DISK_H', cc.has_header('sys/disk.h'))
1890 config_host_data.set('HAVE_SYS_IOCCOM_H', cc.has_header('sys/ioccom.h'))
1891 config_host_data.set('HAVE_SYS_KCOV_H', cc.has_header('sys/kcov.h'))
1892
1893 # has_function
1894 config_host_data.set('CONFIG_ACCEPT4', cc.has_function('accept4'))
1895 config_host_data.set('CONFIG_CLOCK_ADJTIME', cc.has_function('clock_adjtime'))
1896 config_host_data.set('CONFIG_DUP3', cc.has_function('dup3'))
1897 config_host_data.set('CONFIG_FALLOCATE', cc.has_function('fallocate'))
1898 config_host_data.set('CONFIG_POSIX_FALLOCATE', cc.has_function('posix_fallocate'))
1899 # Note that we need to specify prefix: here to avoid incorrectly
1900 # thinking that Windows has posix_memalign()
1901 config_host_data.set('CONFIG_POSIX_MEMALIGN', cc.has_function('posix_memalign', prefix: '#include <stdlib.h>'))
1902 config_host_data.set('CONFIG_ALIGNED_MALLOC', cc.has_function('_aligned_malloc'))
1903 config_host_data.set('CONFIG_VALLOC', cc.has_function('valloc'))
1904 config_host_data.set('CONFIG_MEMALIGN', cc.has_function('memalign'))
1905 config_host_data.set('CONFIG_PPOLL', cc.has_function('ppoll'))
1906 config_host_data.set('CONFIG_PREADV', cc.has_function('preadv', prefix: '#include <sys/uio.h>'))
1907 config_host_data.set('CONFIG_PTHREAD_FCHDIR_NP', cc.has_function('pthread_fchdir_np'))
1908 config_host_data.set('CONFIG_SENDFILE', cc.has_function('sendfile'))
1909 config_host_data.set('CONFIG_SETNS', cc.has_function('setns') and cc.has_function('unshare'))
1910 config_host_data.set('CONFIG_SYNCFS', cc.has_function('syncfs'))
1911 config_host_data.set('CONFIG_SYNC_FILE_RANGE', cc.has_function('sync_file_range'))
1912 config_host_data.set('CONFIG_TIMERFD', cc.has_function('timerfd_create'))
1913 config_host_data.set('HAVE_COPY_FILE_RANGE', cc.has_function('copy_file_range'))
1914 config_host_data.set('HAVE_GETIFADDRS', cc.has_function('getifaddrs'))
1915 config_host_data.set('HAVE_OPENPTY', cc.has_function('openpty', dependencies: util))
1916 config_host_data.set('HAVE_STRCHRNUL', cc.has_function('strchrnul'))
1917 config_host_data.set('HAVE_SYSTEM_FUNCTION', cc.has_function('system', prefix: '#include <stdlib.h>'))
1918 if rbd.found()
1919   config_host_data.set('HAVE_RBD_NAMESPACE_EXISTS',
1920                        cc.has_function('rbd_namespace_exists',
1921                                        dependencies: rbd,
1922                                        prefix: '#include <rbd/librbd.h>'))
1923 endif
1924 if rdma.found()
1925   config_host_data.set('HAVE_IBV_ADVISE_MR',
1926                        cc.has_function('ibv_advise_mr',
1927                                        dependencies: rdma,
1928                                        prefix: '#include <infiniband/verbs.h>'))
1929 endif
1930
1931 # has_header_symbol
1932 config_host_data.set('CONFIG_BYTESWAP_H',
1933                      cc.has_header_symbol('byteswap.h', 'bswap_32'))
1934 config_host_data.set('CONFIG_EPOLL_CREATE1',
1935                      cc.has_header_symbol('sys/epoll.h', 'epoll_create1'))
1936 config_host_data.set('CONFIG_FALLOCATE_PUNCH_HOLE',
1937                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_PUNCH_HOLE') and
1938                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_KEEP_SIZE'))
1939 config_host_data.set('CONFIG_FALLOCATE_ZERO_RANGE',
1940                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_ZERO_RANGE'))
1941 config_host_data.set('CONFIG_FIEMAP',
1942                      cc.has_header('linux/fiemap.h') and
1943                      cc.has_header_symbol('linux/fs.h', 'FS_IOC_FIEMAP'))
1944 config_host_data.set('CONFIG_GETRANDOM',
1945                      cc.has_function('getrandom') and
1946                      cc.has_header_symbol('sys/random.h', 'GRND_NONBLOCK'))
1947 config_host_data.set('CONFIG_INOTIFY',
1948                      cc.has_header_symbol('sys/inotify.h', 'inotify_init'))
1949 config_host_data.set('CONFIG_INOTIFY1',
1950                      cc.has_header_symbol('sys/inotify.h', 'inotify_init1'))
1951 config_host_data.set('CONFIG_MACHINE_BSWAP_H',
1952                      cc.has_header_symbol('machine/bswap.h', 'bswap32',
1953                                           prefix: '''#include <sys/endian.h>
1954                                                      #include <sys/types.h>'''))
1955 config_host_data.set('CONFIG_PRCTL_PR_SET_TIMERSLACK',
1956                      cc.has_header_symbol('sys/prctl.h', 'PR_SET_TIMERSLACK'))
1957 config_host_data.set('CONFIG_RTNETLINK',
1958                      cc.has_header_symbol('linux/rtnetlink.h', 'IFLA_PROTO_DOWN'))
1959 config_host_data.set('CONFIG_SYSMACROS',
1960                      cc.has_header_symbol('sys/sysmacros.h', 'makedev'))
1961 config_host_data.set('HAVE_OPTRESET',
1962                      cc.has_header_symbol('getopt.h', 'optreset'))
1963 config_host_data.set('HAVE_IPPROTO_MPTCP',
1964                      cc.has_header_symbol('netinet/in.h', 'IPPROTO_MPTCP'))
1965
1966 # has_member
1967 config_host_data.set('HAVE_SIGEV_NOTIFY_THREAD_ID',
1968                      cc.has_member('struct sigevent', 'sigev_notify_thread_id',
1969                                    prefix: '#include <signal.h>'))
1970 config_host_data.set('HAVE_STRUCT_STAT_ST_ATIM',
1971                      cc.has_member('struct stat', 'st_atim',
1972                                    prefix: '#include <sys/stat.h>'))
1973
1974 # has_type
1975 config_host_data.set('CONFIG_IOVEC',
1976                      cc.has_type('struct iovec',
1977                                  prefix: '#include <sys/uio.h>'))
1978 config_host_data.set('HAVE_UTMPX',
1979                      cc.has_type('struct utmpx',
1980                                  prefix: '#include <utmpx.h>'))
1981
1982 config_host_data.set('CONFIG_EVENTFD', cc.links('''
1983   #include <sys/eventfd.h>
1984   int main(void) { return eventfd(0, EFD_NONBLOCK | EFD_CLOEXEC); }'''))
1985 config_host_data.set('CONFIG_FDATASYNC', cc.links(gnu_source_prefix + '''
1986   #include <unistd.h>
1987   int main(void) {
1988   #if defined(_POSIX_SYNCHRONIZED_IO) && _POSIX_SYNCHRONIZED_IO > 0
1989   return fdatasync(0);
1990   #else
1991   #error Not supported
1992   #endif
1993   }'''))
1994
1995 has_madvise = cc.links(gnu_source_prefix + '''
1996   #include <sys/types.h>
1997   #include <sys/mman.h>
1998   #include <stddef.h>
1999   int main(void) { return madvise(NULL, 0, MADV_DONTNEED); }''')
2000 missing_madvise_proto = false
2001 if has_madvise
2002   # Some platforms (illumos and Solaris before Solaris 11) provide madvise()
2003   # but forget to prototype it. In this case, has_madvise will be true (the
2004   # test program links despite a compile warning). To detect the
2005   # missing-prototype case, we try again with a definitely-bogus prototype.
2006   # This will only compile if the system headers don't provide the prototype;
2007   # otherwise the conflicting prototypes will cause a compiler error.
2008   missing_madvise_proto = cc.links(gnu_source_prefix + '''
2009     #include <sys/types.h>
2010     #include <sys/mman.h>
2011     #include <stddef.h>
2012     extern int madvise(int);
2013     int main(void) { return madvise(0); }''')
2014 endif
2015 config_host_data.set('CONFIG_MADVISE', has_madvise)
2016 config_host_data.set('HAVE_MADVISE_WITHOUT_PROTOTYPE', missing_madvise_proto)
2017
2018 config_host_data.set('CONFIG_MEMFD', cc.links(gnu_source_prefix + '''
2019   #include <sys/mman.h>
2020   int main(void) { return memfd_create("foo", MFD_ALLOW_SEALING); }'''))
2021 config_host_data.set('CONFIG_OPEN_BY_HANDLE', cc.links(gnu_source_prefix + '''
2022   #include <fcntl.h>
2023   #if !defined(AT_EMPTY_PATH)
2024   # error missing definition
2025   #else
2026   int main(void) { struct file_handle fh; return open_by_handle_at(0, &fh, 0); }
2027   #endif'''))
2028 config_host_data.set('CONFIG_PIPE2', cc.links(gnu_source_prefix + '''
2029   #include <unistd.h>
2030   #include <fcntl.h>
2031
2032   int main(void)
2033   {
2034       int pipefd[2];
2035       return pipe2(pipefd, O_CLOEXEC);
2036   }'''))
2037 config_host_data.set('CONFIG_POSIX_MADVISE', cc.links(gnu_source_prefix + '''
2038   #include <sys/mman.h>
2039   #include <stddef.h>
2040   int main(void) { return posix_madvise(NULL, 0, POSIX_MADV_DONTNEED); }'''))
2041
2042 config_host_data.set('CONFIG_PTHREAD_SETNAME_NP_W_TID', cc.links(gnu_source_prefix + '''
2043   #include <pthread.h>
2044
2045   static void *f(void *p) { return NULL; }
2046   int main(void)
2047   {
2048     pthread_t thread;
2049     pthread_create(&thread, 0, f, 0);
2050     pthread_setname_np(thread, "QEMU");
2051     return 0;
2052   }''', dependencies: threads))
2053 config_host_data.set('CONFIG_PTHREAD_SETNAME_NP_WO_TID', cc.links(gnu_source_prefix + '''
2054   #include <pthread.h>
2055
2056   static void *f(void *p) { pthread_setname_np("QEMU"); return NULL; }
2057   int main(void)
2058   {
2059     pthread_t thread;
2060     pthread_create(&thread, 0, f, 0);
2061     return 0;
2062   }''', dependencies: threads))
2063 config_host_data.set('CONFIG_PTHREAD_CONDATTR_SETCLOCK', cc.links(gnu_source_prefix + '''
2064   #include <pthread.h>
2065   #include <time.h>
2066
2067   int main(void)
2068   {
2069     pthread_condattr_t attr
2070     pthread_condattr_init(&attr);
2071     pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);
2072     return 0;
2073   }''', dependencies: threads))
2074
2075 config_host_data.set('CONFIG_SIGNALFD', cc.links(gnu_source_prefix + '''
2076   #include <sys/signalfd.h>
2077   #include <stddef.h>
2078   int main(void) { return signalfd(-1, NULL, SFD_CLOEXEC); }'''))
2079 config_host_data.set('CONFIG_SPLICE', cc.links(gnu_source_prefix + '''
2080   #include <unistd.h>
2081   #include <fcntl.h>
2082   #include <limits.h>
2083
2084   int main(void)
2085   {
2086     int len, fd = 0;
2087     len = tee(STDIN_FILENO, STDOUT_FILENO, INT_MAX, SPLICE_F_NONBLOCK);
2088     splice(STDIN_FILENO, NULL, fd, NULL, len, SPLICE_F_MOVE);
2089     return 0;
2090   }'''))
2091
2092 config_host_data.set('HAVE_MLOCKALL', cc.links(gnu_source_prefix + '''
2093   #include <sys/mman.h>
2094   int main(int argc, char *argv[]) {
2095     return mlockall(MCL_FUTURE);
2096   }'''))
2097
2098 have_l2tpv3 = false
2099 if get_option('l2tpv3').allowed() and have_system
2100   have_l2tpv3 = cc.has_type('struct mmsghdr',
2101     prefix: gnu_source_prefix + '''
2102       #include <sys/socket.h>
2103       #include <linux/ip.h>''')
2104 endif
2105 config_host_data.set('CONFIG_L2TPV3', have_l2tpv3)
2106
2107 have_netmap = false
2108 if get_option('netmap').allowed() and have_system
2109   have_netmap = cc.compiles('''
2110     #include <inttypes.h>
2111     #include <net/if.h>
2112     #include <net/netmap.h>
2113     #include <net/netmap_user.h>
2114     #if (NETMAP_API < 11) || (NETMAP_API > 15)
2115     #error
2116     #endif
2117     int main(void) { return 0; }''')
2118   if not have_netmap and get_option('netmap').enabled()
2119     error('Netmap headers not available')
2120   endif
2121 endif
2122 config_host_data.set('CONFIG_NETMAP', have_netmap)
2123
2124 # Work around a system header bug with some kernel/XFS header
2125 # versions where they both try to define 'struct fsxattr':
2126 # xfs headers will not try to redefine structs from linux headers
2127 # if this macro is set.
2128 config_host_data.set('HAVE_FSXATTR', cc.links('''
2129   #include <linux/fs.h>
2130   struct fsxattr foo;
2131   int main(void) {
2132     return 0;
2133   }'''))
2134
2135 # Some versions of Mac OS X incorrectly define SIZE_MAX
2136 config_host_data.set('HAVE_BROKEN_SIZE_MAX', not cc.compiles('''
2137     #include <stdint.h>
2138     #include <stdio.h>
2139     int main(int argc, char *argv[]) {
2140         return printf("%zu", SIZE_MAX);
2141     }''', args: ['-Werror']))
2142
2143 atomic_test = '''
2144   #include <stdint.h>
2145   int main(void)
2146   {
2147     @0@ x = 0, y = 0;
2148     y = __atomic_load_n(&x, __ATOMIC_RELAXED);
2149     __atomic_store_n(&x, y, __ATOMIC_RELAXED);
2150     __atomic_compare_exchange_n(&x, &y, x, 0, __ATOMIC_RELAXED, __ATOMIC_RELAXED);
2151     __atomic_exchange_n(&x, y, __ATOMIC_RELAXED);
2152     __atomic_fetch_add(&x, y, __ATOMIC_RELAXED);
2153     return 0;
2154   }'''
2155
2156 # See if 64-bit atomic operations are supported.
2157 # Note that without __atomic builtins, we can only
2158 # assume atomic loads/stores max at pointer size.
2159 config_host_data.set('CONFIG_ATOMIC64', cc.links(atomic_test.format('uint64_t')))
2160
2161 has_int128 = cc.links('''
2162   __int128_t a;
2163   __uint128_t b;
2164   int main (void) {
2165     a = a + b;
2166     b = a * b;
2167     a = a * a;
2168     return 0;
2169   }''')
2170
2171 config_host_data.set('CONFIG_INT128', has_int128)
2172
2173 if has_int128
2174   # "do we have 128-bit atomics which are handled inline and specifically not
2175   # via libatomic". The reason we can't use libatomic is documented in the
2176   # comment starting "GCC is a house divided" in include/qemu/atomic128.h.
2177   has_atomic128 = cc.links(atomic_test.format('unsigned __int128'))
2178
2179   config_host_data.set('CONFIG_ATOMIC128', has_atomic128)
2180
2181   if not has_atomic128
2182     has_cmpxchg128 = cc.links('''
2183       int main(void)
2184       {
2185         unsigned __int128 x = 0, y = 0;
2186         __sync_val_compare_and_swap_16(&x, y, x);
2187         return 0;
2188       }
2189     ''')
2190
2191     config_host_data.set('CONFIG_CMPXCHG128', has_cmpxchg128)
2192   endif
2193 endif
2194
2195 config_host_data.set('CONFIG_GETAUXVAL', cc.links(gnu_source_prefix + '''
2196   #include <sys/auxv.h>
2197   int main(void) {
2198     return getauxval(AT_HWCAP) == 0;
2199   }'''))
2200
2201 config_host_data.set('CONFIG_USBFS', have_linux_user and cc.compiles('''
2202   #include <linux/usbdevice_fs.h>
2203
2204   #ifndef USBDEVFS_GET_CAPABILITIES
2205   #error "USBDEVFS_GET_CAPABILITIES undefined"
2206   #endif
2207
2208   #ifndef USBDEVFS_DISCONNECT_CLAIM
2209   #error "USBDEVFS_DISCONNECT_CLAIM undefined"
2210   #endif
2211
2212   int main(void) { return 0; }'''))
2213
2214 have_keyring = get_option('keyring') \
2215   .require(targetos == 'linux', error_message: 'keyring is only available on Linux') \
2216   .require(cc.compiles('''
2217     #include <errno.h>
2218     #include <asm/unistd.h>
2219     #include <linux/keyctl.h>
2220     #include <sys/syscall.h>
2221     #include <unistd.h>
2222     int main(void) {
2223         return syscall(__NR_keyctl, KEYCTL_READ, 0, NULL, NULL, 0);
2224     }'''), error_message: 'keyctl syscall not available on this system').allowed()
2225 config_host_data.set('CONFIG_SECRET_KEYRING', have_keyring)
2226
2227 have_cpuid_h = cc.links('''
2228   #include <cpuid.h>
2229   int main(void) {
2230     unsigned a, b, c, d;
2231     unsigned max = __get_cpuid_max(0, 0);
2232
2233     if (max >= 1) {
2234         __cpuid(1, a, b, c, d);
2235     }
2236
2237     if (max >= 7) {
2238         __cpuid_count(7, 0, a, b, c, d);
2239     }
2240
2241     return 0;
2242   }''')
2243 config_host_data.set('CONFIG_CPUID_H', have_cpuid_h)
2244
2245 config_host_data.set('CONFIG_AVX2_OPT', get_option('avx2') \
2246   .require(have_cpuid_h, error_message: 'cpuid.h not available, cannot enable AVX2') \
2247   .require(cc.links('''
2248     #pragma GCC push_options
2249     #pragma GCC target("avx2")
2250     #include <cpuid.h>
2251     #include <immintrin.h>
2252     static int bar(void *a) {
2253       __m256i x = *(__m256i *)a;
2254       return _mm256_testz_si256(x, x);
2255     }
2256     int main(int argc, char *argv[]) { return bar(argv[0]); }
2257   '''), error_message: 'AVX2 not available').allowed())
2258
2259 config_host_data.set('CONFIG_AVX512F_OPT', get_option('avx512f') \
2260   .require(have_cpuid_h, error_message: 'cpuid.h not available, cannot enable AVX512F') \
2261   .require(cc.links('''
2262     #pragma GCC push_options
2263     #pragma GCC target("avx512f")
2264     #include <cpuid.h>
2265     #include <immintrin.h>
2266     static int bar(void *a) {
2267       __m512i x = *(__m512i *)a;
2268       return _mm512_test_epi64_mask(x, x);
2269     }
2270     int main(int argc, char *argv[]) { return bar(argv[0]); }
2271   '''), error_message: 'AVX512F not available').allowed())
2272
2273 have_pvrdma = get_option('pvrdma') \
2274   .require(rdma.found(), error_message: 'PVRDMA requires OpenFabrics libraries') \
2275   .require(cc.compiles(gnu_source_prefix + '''
2276     #include <sys/mman.h>
2277     int main(void)
2278     {
2279       char buf = 0;
2280       void *addr = &buf;
2281       addr = mremap(addr, 0, 1, MREMAP_MAYMOVE | MREMAP_FIXED);
2282
2283       return 0;
2284     }'''), error_message: 'PVRDMA requires mremap').allowed()
2285
2286 if have_pvrdma
2287   config_host_data.set('LEGACY_RDMA_REG_MR', not cc.links('''
2288     #include <infiniband/verbs.h>
2289     int main(void)
2290     {
2291       struct ibv_mr *mr;
2292       struct ibv_pd *pd = NULL;
2293       size_t length = 10;
2294       uint64_t iova = 0;
2295       int access = 0;
2296       void *addr = NULL;
2297
2298       mr = ibv_reg_mr_iova(pd, addr, length, iova, access);
2299       ibv_dereg_mr(mr);
2300       return 0;
2301     }'''))
2302 endif
2303
2304 if get_option('membarrier').disabled()
2305   have_membarrier = false
2306 elif targetos == 'windows'
2307   have_membarrier = true
2308 elif targetos == 'linux'
2309   have_membarrier = cc.compiles('''
2310     #include <linux/membarrier.h>
2311     #include <sys/syscall.h>
2312     #include <unistd.h>
2313     #include <stdlib.h>
2314     int main(void) {
2315         syscall(__NR_membarrier, MEMBARRIER_CMD_QUERY, 0);
2316         syscall(__NR_membarrier, MEMBARRIER_CMD_SHARED, 0);
2317         exit(0);
2318     }''')
2319 endif
2320 config_host_data.set('CONFIG_MEMBARRIER', get_option('membarrier') \
2321   .require(have_membarrier, error_message: 'membarrier system call not available') \
2322   .allowed())
2323
2324 have_afalg = get_option('crypto_afalg') \
2325   .require(cc.compiles(gnu_source_prefix + '''
2326     #include <errno.h>
2327     #include <sys/types.h>
2328     #include <sys/socket.h>
2329     #include <linux/if_alg.h>
2330     int main(void) {
2331       int sock;
2332       sock = socket(AF_ALG, SOCK_SEQPACKET, 0);
2333       return sock;
2334     }
2335   '''), error_message: 'AF_ALG requested but could not be detected').allowed()
2336 config_host_data.set('CONFIG_AF_ALG', have_afalg)
2337
2338 config_host_data.set('CONFIG_AF_VSOCK', cc.has_header_symbol(
2339   'linux/vm_sockets.h', 'AF_VSOCK',
2340   prefix: '#include <sys/socket.h>',
2341 ))
2342
2343 have_vss = false
2344 have_vss_sdk = false # old xp/2003 SDK
2345 if targetos == 'windows' and link_language == 'cpp'
2346   have_vss = cxx.compiles('''
2347     #define __MIDL_user_allocate_free_DEFINED__
2348     #include <vss.h>
2349     int main(void) { return VSS_CTX_BACKUP; }''')
2350   have_vss_sdk = cxx.has_header('vscoordint.h')
2351 endif
2352 config_host_data.set('HAVE_VSS_SDK', have_vss_sdk)
2353
2354 foreach k, v: config_host
2355   if k.startswith('CONFIG_')
2356     config_host_data.set(k, v == 'y' ? 1 : v)
2357   endif
2358 endforeach
2359
2360 # Older versions of MinGW do not import _lock_file and _unlock_file properly.
2361 # This was fixed for v6.0.0 with commit b48e3ac8969d.
2362 if targetos == 'windows'
2363   config_host_data.set('HAVE__LOCK_FILE', cc.links('''
2364     #include <stdio.h>
2365     int main(void) {
2366       _lock_file(NULL);
2367       _unlock_file(NULL);
2368       return 0;
2369     }''', name: '_lock_file and _unlock_file'))
2370 endif
2371
2372 ########################
2373 # Target configuration #
2374 ########################
2375
2376 minikconf = find_program('scripts/minikconf.py')
2377 config_all = {}
2378 config_all_devices = {}
2379 config_all_disas = {}
2380 config_devices_mak_list = []
2381 config_devices_h = {}
2382 config_target_h = {}
2383 config_target_mak = {}
2384
2385 disassemblers = {
2386   'alpha' : ['CONFIG_ALPHA_DIS'],
2387   'avr' : ['CONFIG_AVR_DIS'],
2388   'cris' : ['CONFIG_CRIS_DIS'],
2389   'hexagon' : ['CONFIG_HEXAGON_DIS'],
2390   'hppa' : ['CONFIG_HPPA_DIS'],
2391   'i386' : ['CONFIG_I386_DIS'],
2392   'x86_64' : ['CONFIG_I386_DIS'],
2393   'm68k' : ['CONFIG_M68K_DIS'],
2394   'microblaze' : ['CONFIG_MICROBLAZE_DIS'],
2395   'mips' : ['CONFIG_MIPS_DIS'],
2396   'nios2' : ['CONFIG_NIOS2_DIS'],
2397   'or1k' : ['CONFIG_OPENRISC_DIS'],
2398   'ppc' : ['CONFIG_PPC_DIS'],
2399   'riscv' : ['CONFIG_RISCV_DIS'],
2400   'rx' : ['CONFIG_RX_DIS'],
2401   's390' : ['CONFIG_S390_DIS'],
2402   'sh4' : ['CONFIG_SH4_DIS'],
2403   'sparc' : ['CONFIG_SPARC_DIS'],
2404   'xtensa' : ['CONFIG_XTENSA_DIS'],
2405   'loongarch' : ['CONFIG_LOONGARCH_DIS'],
2406 }
2407 if link_language == 'cpp'
2408   disassemblers += {
2409     'mips' : [ 'CONFIG_MIPS_DIS', 'CONFIG_NANOMIPS_DIS'],
2410   }
2411 endif
2412
2413 have_ivshmem = config_host_data.get('CONFIG_EVENTFD')
2414 host_kconfig = \
2415   (get_option('fuzzing') ? ['CONFIG_FUZZ=y'] : []) + \
2416   (have_tpm ? ['CONFIG_TPM=y'] : []) + \
2417   (spice.found() ? ['CONFIG_SPICE=y'] : []) + \
2418   (have_ivshmem ? ['CONFIG_IVSHMEM=y'] : []) + \
2419   (opengl.found() ? ['CONFIG_OPENGL=y'] : []) + \
2420   (x11.found() ? ['CONFIG_X11=y'] : []) + \
2421   (have_vhost_user ? ['CONFIG_VHOST_USER=y'] : []) + \
2422   (have_vhost_vdpa ? ['CONFIG_VHOST_VDPA=y'] : []) + \
2423   (have_vhost_kernel ? ['CONFIG_VHOST_KERNEL=y'] : []) + \
2424   (have_virtfs ? ['CONFIG_VIRTFS=y'] : []) + \
2425   ('CONFIG_LINUX' in config_host ? ['CONFIG_LINUX=y'] : []) + \
2426   (have_pvrdma ? ['CONFIG_PVRDMA=y'] : []) + \
2427   (multiprocess_allowed ? ['CONFIG_MULTIPROCESS_ALLOWED=y'] : []) + \
2428   (vfio_user_server_allowed ? ['CONFIG_VFIO_USER_SERVER_ALLOWED=y'] : [])
2429
2430 ignored = [ 'TARGET_XML_FILES', 'TARGET_ABI_DIR', 'TARGET_ARCH' ]
2431
2432 default_targets = 'CONFIG_DEFAULT_TARGETS' in config_host
2433 actual_target_dirs = []
2434 fdt_required = []
2435 foreach target : target_dirs
2436   config_target = { 'TARGET_NAME': target.split('-')[0] }
2437   if target.endswith('linux-user')
2438     if targetos != 'linux'
2439       if default_targets
2440         continue
2441       endif
2442       error('Target @0@ is only available on a Linux host'.format(target))
2443     endif
2444     config_target += { 'CONFIG_LINUX_USER': 'y' }
2445   elif target.endswith('bsd-user')
2446     if 'CONFIG_BSD' not in config_host
2447       if default_targets
2448         continue
2449       endif
2450       error('Target @0@ is only available on a BSD host'.format(target))
2451     endif
2452     config_target += { 'CONFIG_BSD_USER': 'y' }
2453   elif target.endswith('softmmu')
2454     config_target += { 'CONFIG_SOFTMMU': 'y' }
2455   endif
2456   if target.endswith('-user')
2457     config_target += {
2458       'CONFIG_USER_ONLY': 'y',
2459       'CONFIG_QEMU_INTERP_PREFIX':
2460         get_option('interp_prefix').replace('%M', config_target['TARGET_NAME'])
2461     }
2462   endif
2463
2464   accel_kconfig = []
2465   foreach sym: accelerators
2466     if sym == 'CONFIG_TCG' or target in accelerator_targets.get(sym, [])
2467       config_target += { sym: 'y' }
2468       config_all += { sym: 'y' }
2469       if sym == 'CONFIG_TCG' and tcg_arch == 'tci'
2470         config_target += { 'CONFIG_TCG_INTERPRETER': 'y' }
2471       endif
2472       if target in modular_tcg
2473         config_target += { 'CONFIG_TCG_MODULAR': 'y' }
2474       else
2475         config_target += { 'CONFIG_TCG_BUILTIN': 'y' }
2476       endif
2477       accel_kconfig += [ sym + '=y' ]
2478     endif
2479   endforeach
2480   if accel_kconfig.length() == 0
2481     if default_targets
2482       continue
2483     endif
2484     error('No accelerator available for target @0@'.format(target))
2485   endif
2486
2487   actual_target_dirs += target
2488   config_target += keyval.load('configs/targets' / target + '.mak')
2489   config_target += { 'TARGET_' + config_target['TARGET_ARCH'].to_upper(): 'y' }
2490
2491   if 'TARGET_NEED_FDT' in config_target
2492     fdt_required += target
2493   endif
2494
2495   # Add default keys
2496   if 'TARGET_BASE_ARCH' not in config_target
2497     config_target += {'TARGET_BASE_ARCH': config_target['TARGET_ARCH']}
2498   endif
2499   if 'TARGET_ABI_DIR' not in config_target
2500     config_target += {'TARGET_ABI_DIR': config_target['TARGET_ARCH']}
2501   endif
2502   if 'TARGET_BIG_ENDIAN' not in config_target
2503     config_target += {'TARGET_BIG_ENDIAN': 'n'}
2504   endif
2505
2506   foreach k, v: disassemblers
2507     if host_arch.startswith(k) or config_target['TARGET_BASE_ARCH'].startswith(k)
2508       foreach sym: v
2509         config_target += { sym: 'y' }
2510         config_all_disas += { sym: 'y' }
2511       endforeach
2512     endif
2513   endforeach
2514
2515   config_target_data = configuration_data()
2516   foreach k, v: config_target
2517     if not k.startswith('TARGET_') and not k.startswith('CONFIG_')
2518       # do nothing
2519     elif ignored.contains(k)
2520       # do nothing
2521     elif k == 'TARGET_BASE_ARCH'
2522       # Note that TARGET_BASE_ARCH ends up in config-target.h but it is
2523       # not used to select files from sourcesets.
2524       config_target_data.set('TARGET_' + v.to_upper(), 1)
2525     elif k == 'TARGET_NAME' or k == 'CONFIG_QEMU_INTERP_PREFIX'
2526       config_target_data.set_quoted(k, v)
2527     elif v == 'y'
2528       config_target_data.set(k, 1)
2529     elif v == 'n'
2530       config_target_data.set(k, 0)
2531     else
2532       config_target_data.set(k, v)
2533     endif
2534   endforeach
2535   config_target_data.set('QEMU_ARCH',
2536                          'QEMU_ARCH_' + config_target['TARGET_BASE_ARCH'].to_upper())
2537   config_target_h += {target: configure_file(output: target + '-config-target.h',
2538                                                configuration: config_target_data)}
2539
2540   if target.endswith('-softmmu')
2541     config_input = meson.get_external_property(target, 'default')
2542     config_devices_mak = target + '-config-devices.mak'
2543     config_devices_mak = configure_file(
2544       input: ['configs/devices' / target / config_input + '.mak', 'Kconfig'],
2545       output: config_devices_mak,
2546       depfile: config_devices_mak + '.d',
2547       capture: true,
2548       command: [minikconf,
2549                 get_option('default_devices') ? '--defconfig' : '--allnoconfig',
2550                 config_devices_mak, '@DEPFILE@', '@INPUT@',
2551                 host_kconfig, accel_kconfig,
2552                 'CONFIG_' + config_target['TARGET_ARCH'].to_upper() + '=y'])
2553
2554     config_devices_data = configuration_data()
2555     config_devices = keyval.load(config_devices_mak)
2556     foreach k, v: config_devices
2557       config_devices_data.set(k, 1)
2558     endforeach
2559     config_devices_mak_list += config_devices_mak
2560     config_devices_h += {target: configure_file(output: target + '-config-devices.h',
2561                                                 configuration: config_devices_data)}
2562     config_target += config_devices
2563     config_all_devices += config_devices
2564   endif
2565   config_target_mak += {target: config_target}
2566 endforeach
2567 target_dirs = actual_target_dirs
2568
2569 # This configuration is used to build files that are shared by
2570 # multiple binaries, and then extracted out of the "common"
2571 # static_library target.
2572 #
2573 # We do not use all_sources()/all_dependencies(), because it would
2574 # build literally all source files, including devices only used by
2575 # targets that are not built for this compilation.  The CONFIG_ALL
2576 # pseudo symbol replaces it.
2577
2578 config_all += config_all_devices
2579 config_all += config_host
2580 config_all += config_all_disas
2581 config_all += {
2582   'CONFIG_XEN': xen.found(),
2583   'CONFIG_SOFTMMU': have_system,
2584   'CONFIG_USER_ONLY': have_user,
2585   'CONFIG_ALL': true,
2586 }
2587
2588 target_configs_h = []
2589 foreach target: target_dirs
2590   target_configs_h += config_target_h[target]
2591   target_configs_h += config_devices_h.get(target, [])
2592 endforeach
2593 genh += custom_target('config-poison.h',
2594                       input: [target_configs_h],
2595                       output: 'config-poison.h',
2596                       capture: true,
2597                       command: [find_program('scripts/make-config-poison.sh'),
2598                                 target_configs_h])
2599
2600 ##############
2601 # Submodules #
2602 ##############
2603
2604 capstone = not_found
2605 if not get_option('capstone').auto() or have_system or have_user
2606   capstone = dependency('capstone', version: '>=3.0.5',
2607                         kwargs: static_kwargs, method: 'pkg-config',
2608                         required: get_option('capstone'))
2609
2610   # Some versions of capstone have broken pkg-config file
2611   # that reports a wrong -I path, causing the #include to
2612   # fail later. If the system has such a broken version
2613   # do not use it.
2614   if capstone.found() and not cc.compiles('#include <capstone.h>',
2615                                           dependencies: [capstone])
2616     capstone = not_found
2617     if get_option('capstone').enabled()
2618       error('capstone requested, but it does not appear to work')
2619     endif
2620   endif
2621 endif
2622
2623 slirp = not_found
2624 slirp_opt = 'disabled'
2625 if have_system
2626   slirp_opt = get_option('slirp')
2627   if slirp_opt in ['enabled', 'auto', 'system']
2628     have_internal = fs.exists(meson.current_source_dir() / 'slirp/meson.build')
2629     slirp_dep_required = (slirp_opt == 'system' or
2630                           slirp_opt == 'enabled' and not have_internal)
2631     slirp = dependency('slirp', kwargs: static_kwargs,
2632                        method: 'pkg-config', version: '>=4.1.0',
2633                        required: slirp_dep_required)
2634     # slirp <4.7 is incompatible with CFI support in QEMU.  This is because
2635     # it passes function pointers within libslirp as callbacks for timers.
2636     # When using a system-wide shared libslirp, the type information for the
2637     # callback is missing and the timer call produces a false positive with CFI.
2638     # Do not use the "version" keyword argument to produce a better error.
2639     # with control-flow integrity.
2640     if get_option('cfi') and slirp.found() and slirp.version().version_compare('<4.7')
2641       if slirp_dep_required
2642         error('Control-Flow Integrity requires libslirp 4.7.')
2643       else
2644         warning('Control-Flow Integrity requires libslirp 4.7, not using system-wide libslirp.')
2645         slirp = not_found
2646       endif
2647     endif
2648     if slirp.found()
2649       slirp_opt = 'system'
2650     elif have_internal
2651       slirp_opt = 'internal'
2652     else
2653       slirp_opt = 'disabled'
2654     endif
2655   endif
2656   if slirp_opt == 'internal'
2657     slirp_deps = []
2658     if targetos == 'windows'
2659       slirp_deps = cc.find_library('iphlpapi')
2660     elif targetos == 'darwin'
2661       slirp_deps = cc.find_library('resolv')
2662     endif
2663     slirp_conf = configuration_data()
2664     slirp_conf.set('SLIRP_MAJOR_VERSION', meson.project_version().split('.')[0])
2665     slirp_conf.set('SLIRP_MINOR_VERSION', meson.project_version().split('.')[1])
2666     slirp_conf.set('SLIRP_MICRO_VERSION', meson.project_version().split('.')[2])
2667     slirp_conf.set_quoted('SLIRP_VERSION_STRING', meson.project_version())
2668     slirp_cargs = ['-DG_LOG_DOMAIN="Slirp"']
2669     slirp_files = [
2670       'slirp/src/arp_table.c',
2671       'slirp/src/bootp.c',
2672       'slirp/src/cksum.c',
2673       'slirp/src/dhcpv6.c',
2674       'slirp/src/dnssearch.c',
2675       'slirp/src/if.c',
2676       'slirp/src/ip6_icmp.c',
2677       'slirp/src/ip6_input.c',
2678       'slirp/src/ip6_output.c',
2679       'slirp/src/ip_icmp.c',
2680       'slirp/src/ip_input.c',
2681       'slirp/src/ip_output.c',
2682       'slirp/src/mbuf.c',
2683       'slirp/src/misc.c',
2684       'slirp/src/ncsi.c',
2685       'slirp/src/ndp_table.c',
2686       'slirp/src/sbuf.c',
2687       'slirp/src/slirp.c',
2688       'slirp/src/socket.c',
2689       'slirp/src/state.c',
2690       'slirp/src/stream.c',
2691       'slirp/src/tcp_input.c',
2692       'slirp/src/tcp_output.c',
2693       'slirp/src/tcp_subr.c',
2694       'slirp/src/tcp_timer.c',
2695       'slirp/src/tftp.c',
2696       'slirp/src/udp.c',
2697       'slirp/src/udp6.c',
2698       'slirp/src/util.c',
2699       'slirp/src/version.c',
2700       'slirp/src/vmstate.c',
2701     ]
2702
2703     configure_file(
2704       input : 'slirp/src/libslirp-version.h.in',
2705       output : 'libslirp-version.h',
2706       configuration: slirp_conf)
2707
2708     slirp_inc = include_directories('slirp', 'slirp/src')
2709     libslirp = static_library('slirp',
2710                               build_by_default: false,
2711                               sources: slirp_files,
2712                               c_args: slirp_cargs,
2713                               include_directories: slirp_inc)
2714     slirp = declare_dependency(link_with: libslirp,
2715                                dependencies: slirp_deps,
2716                                include_directories: slirp_inc)
2717   endif
2718 endif
2719
2720 libvfio_user_dep = not_found
2721 if have_system and vfio_user_server_allowed
2722   have_internal = fs.exists(meson.current_source_dir() / 'subprojects/libvfio-user/meson.build')
2723
2724   if not have_internal
2725     error('libvfio-user source not found - please pull git submodule')
2726   endif
2727
2728   libvfio_user_proj = subproject('libvfio-user')
2729
2730   libvfio_user_lib = libvfio_user_proj.get_variable('libvfio_user_dep')
2731
2732   libvfio_user_dep = declare_dependency(dependencies: [libvfio_user_lib])
2733 endif
2734
2735 fdt = not_found
2736 if have_system
2737   fdt_opt = get_option('fdt')
2738   if fdt_opt in ['enabled', 'auto', 'system']
2739     have_internal = fs.exists(meson.current_source_dir() / 'dtc/libfdt/Makefile.libfdt')
2740     fdt = cc.find_library('fdt', kwargs: static_kwargs,
2741                           required: fdt_opt == 'system' or
2742                                     fdt_opt == 'enabled' and not have_internal)
2743     if fdt.found() and cc.links('''
2744        #include <libfdt.h>
2745        #include <libfdt_env.h>
2746        int main(void) { fdt_find_max_phandle(NULL, NULL); return 0; }''',
2747          dependencies: fdt)
2748       fdt_opt = 'system'
2749     elif fdt_opt == 'system'
2750        error('system libfdt requested, but it is too old (1.5.1 or newer required)')
2751     elif have_internal
2752       fdt_opt = 'internal'
2753     else
2754       fdt_opt = 'disabled'
2755       fdt = not_found
2756     endif
2757   endif
2758   if fdt_opt == 'internal'
2759     fdt_files = files(
2760       'dtc/libfdt/fdt.c',
2761       'dtc/libfdt/fdt_ro.c',
2762       'dtc/libfdt/fdt_wip.c',
2763       'dtc/libfdt/fdt_sw.c',
2764       'dtc/libfdt/fdt_rw.c',
2765       'dtc/libfdt/fdt_strerror.c',
2766       'dtc/libfdt/fdt_empty_tree.c',
2767       'dtc/libfdt/fdt_addresses.c',
2768       'dtc/libfdt/fdt_overlay.c',
2769       'dtc/libfdt/fdt_check.c',
2770     )
2771
2772     fdt_inc = include_directories('dtc/libfdt')
2773     libfdt = static_library('fdt',
2774                             build_by_default: false,
2775                             sources: fdt_files,
2776                             include_directories: fdt_inc)
2777     fdt = declare_dependency(link_with: libfdt,
2778                              include_directories: fdt_inc)
2779   endif
2780 else
2781   fdt_opt = 'disabled'
2782 endif
2783 if not fdt.found() and fdt_required.length() > 0
2784   error('fdt not available but required by targets ' + ', '.join(fdt_required))
2785 endif
2786
2787 config_host_data.set('CONFIG_CAPSTONE', capstone.found())
2788 config_host_data.set('CONFIG_FDT', fdt.found())
2789 config_host_data.set('CONFIG_SLIRP', slirp.found())
2790
2791 #####################
2792 # Generated sources #
2793 #####################
2794
2795 genh += configure_file(output: 'config-host.h', configuration: config_host_data)
2796
2797 hxtool = find_program('scripts/hxtool')
2798 shaderinclude = find_program('scripts/shaderinclude.pl')
2799 qapi_gen = find_program('scripts/qapi-gen.py')
2800 qapi_gen_depends = [ meson.current_source_dir() / 'scripts/qapi/__init__.py',
2801                      meson.current_source_dir() / 'scripts/qapi/commands.py',
2802                      meson.current_source_dir() / 'scripts/qapi/common.py',
2803                      meson.current_source_dir() / 'scripts/qapi/error.py',
2804                      meson.current_source_dir() / 'scripts/qapi/events.py',
2805                      meson.current_source_dir() / 'scripts/qapi/expr.py',
2806                      meson.current_source_dir() / 'scripts/qapi/gen.py',
2807                      meson.current_source_dir() / 'scripts/qapi/introspect.py',
2808                      meson.current_source_dir() / 'scripts/qapi/parser.py',
2809                      meson.current_source_dir() / 'scripts/qapi/schema.py',
2810                      meson.current_source_dir() / 'scripts/qapi/source.py',
2811                      meson.current_source_dir() / 'scripts/qapi/types.py',
2812                      meson.current_source_dir() / 'scripts/qapi/visit.py',
2813                      meson.current_source_dir() / 'scripts/qapi/common.py',
2814                      meson.current_source_dir() / 'scripts/qapi-gen.py'
2815 ]
2816
2817 tracetool = [
2818   python, files('scripts/tracetool.py'),
2819    '--backend=' + ','.join(get_option('trace_backends'))
2820 ]
2821 tracetool_depends = files(
2822   'scripts/tracetool/backend/log.py',
2823   'scripts/tracetool/backend/__init__.py',
2824   'scripts/tracetool/backend/dtrace.py',
2825   'scripts/tracetool/backend/ftrace.py',
2826   'scripts/tracetool/backend/simple.py',
2827   'scripts/tracetool/backend/syslog.py',
2828   'scripts/tracetool/backend/ust.py',
2829   'scripts/tracetool/format/ust_events_c.py',
2830   'scripts/tracetool/format/ust_events_h.py',
2831   'scripts/tracetool/format/__init__.py',
2832   'scripts/tracetool/format/d.py',
2833   'scripts/tracetool/format/simpletrace_stap.py',
2834   'scripts/tracetool/format/c.py',
2835   'scripts/tracetool/format/h.py',
2836   'scripts/tracetool/format/log_stap.py',
2837   'scripts/tracetool/format/stap.py',
2838   'scripts/tracetool/__init__.py',
2839   'scripts/tracetool/transform.py',
2840   'scripts/tracetool/vcpu.py'
2841 )
2842
2843 qemu_version_cmd = [find_program('scripts/qemu-version.sh'),
2844                     meson.current_source_dir(),
2845                     get_option('pkgversion'), meson.project_version()]
2846 qemu_version = custom_target('qemu-version.h',
2847                              output: 'qemu-version.h',
2848                              command: qemu_version_cmd,
2849                              capture: true,
2850                              build_by_default: true,
2851                              build_always_stale: true)
2852 genh += qemu_version
2853
2854 hxdep = []
2855 hx_headers = [
2856   ['qemu-options.hx', 'qemu-options.def'],
2857   ['qemu-img-cmds.hx', 'qemu-img-cmds.h'],
2858 ]
2859 if have_system
2860   hx_headers += [
2861     ['hmp-commands.hx', 'hmp-commands.h'],
2862     ['hmp-commands-info.hx', 'hmp-commands-info.h'],
2863   ]
2864 endif
2865 foreach d : hx_headers
2866   hxdep += custom_target(d[1],
2867                 input: files(d[0]),
2868                 output: d[1],
2869                 capture: true,
2870                 build_by_default: true, # to be removed when added to a target
2871                 command: [hxtool, '-h', '@INPUT0@'])
2872 endforeach
2873 genh += hxdep
2874
2875 ###################
2876 # Collect sources #
2877 ###################
2878
2879 authz_ss = ss.source_set()
2880 blockdev_ss = ss.source_set()
2881 block_ss = ss.source_set()
2882 chardev_ss = ss.source_set()
2883 common_ss = ss.source_set()
2884 crypto_ss = ss.source_set()
2885 hwcore_ss = ss.source_set()
2886 io_ss = ss.source_set()
2887 qmp_ss = ss.source_set()
2888 qom_ss = ss.source_set()
2889 softmmu_ss = ss.source_set()
2890 specific_fuzz_ss = ss.source_set()
2891 specific_ss = ss.source_set()
2892 stub_ss = ss.source_set()
2893 trace_ss = ss.source_set()
2894 user_ss = ss.source_set()
2895 util_ss = ss.source_set()
2896
2897 # accel modules
2898 qtest_module_ss = ss.source_set()
2899 tcg_module_ss = ss.source_set()
2900
2901 modules = {}
2902 target_modules = {}
2903 hw_arch = {}
2904 target_arch = {}
2905 target_softmmu_arch = {}
2906 target_user_arch = {}
2907
2908 ###############
2909 # Trace files #
2910 ###############
2911
2912 # TODO: add each directory to the subdirs from its own meson.build, once
2913 # we have those
2914 trace_events_subdirs = [
2915   'crypto',
2916   'qapi',
2917   'qom',
2918   'monitor',
2919   'util',
2920 ]
2921 if have_linux_user
2922   trace_events_subdirs += [ 'linux-user' ]
2923 endif
2924 if have_bsd_user
2925   trace_events_subdirs += [ 'bsd-user' ]
2926 endif
2927 if have_block
2928   trace_events_subdirs += [
2929     'authz',
2930     'block',
2931     'io',
2932     'nbd',
2933     'scsi',
2934   ]
2935 endif
2936 if have_system
2937   trace_events_subdirs += [
2938     'accel/kvm',
2939     'audio',
2940     'backends',
2941     'backends/tpm',
2942     'chardev',
2943     'ebpf',
2944     'hw/9pfs',
2945     'hw/acpi',
2946     'hw/adc',
2947     'hw/alpha',
2948     'hw/arm',
2949     'hw/audio',
2950     'hw/block',
2951     'hw/block/dataplane',
2952     'hw/char',
2953     'hw/display',
2954     'hw/dma',
2955     'hw/hyperv',
2956     'hw/i2c',
2957     'hw/i386',
2958     'hw/i386/xen',
2959     'hw/ide',
2960     'hw/input',
2961     'hw/intc',
2962     'hw/isa',
2963     'hw/mem',
2964     'hw/mips',
2965     'hw/misc',
2966     'hw/misc/macio',
2967     'hw/net',
2968     'hw/net/can',
2969     'hw/nubus',
2970     'hw/nvme',
2971     'hw/nvram',
2972     'hw/pci',
2973     'hw/pci-host',
2974     'hw/ppc',
2975     'hw/rdma',
2976     'hw/rdma/vmw',
2977     'hw/rtc',
2978     'hw/s390x',
2979     'hw/scsi',
2980     'hw/sd',
2981     'hw/sh4',
2982     'hw/sparc',
2983     'hw/sparc64',
2984     'hw/ssi',
2985     'hw/timer',
2986     'hw/tpm',
2987     'hw/usb',
2988     'hw/vfio',
2989     'hw/virtio',
2990     'hw/watchdog',
2991     'hw/xen',
2992     'hw/gpio',
2993     'migration',
2994     'net',
2995     'softmmu',
2996     'ui',
2997     'hw/remote',
2998   ]
2999 endif
3000 if have_system or have_user
3001   trace_events_subdirs += [
3002     'accel/tcg',
3003     'hw/core',
3004     'target/arm',
3005     'target/arm/hvf',
3006     'target/hppa',
3007     'target/i386',
3008     'target/i386/kvm',
3009     'target/mips/tcg',
3010     'target/nios2',
3011     'target/ppc',
3012     'target/riscv',
3013     'target/s390x',
3014     'target/s390x/kvm',
3015     'target/sparc',
3016   ]
3017 endif
3018
3019 vhost_user = not_found
3020 if targetos == 'linux' and have_vhost_user
3021   libvhost_user = subproject('libvhost-user')
3022   vhost_user = libvhost_user.get_variable('vhost_user_dep')
3023 endif
3024
3025 libvduse = not_found
3026 if have_libvduse
3027   libvduse_proj = subproject('libvduse')
3028   libvduse = libvduse_proj.get_variable('libvduse_dep')
3029 endif
3030
3031 # NOTE: the trace/ subdirectory needs the qapi_trace_events variable
3032 # that is filled in by qapi/.
3033 subdir('qapi')
3034 subdir('qobject')
3035 subdir('stubs')
3036 subdir('trace')
3037 subdir('util')
3038 subdir('qom')
3039 subdir('authz')
3040 subdir('crypto')
3041 subdir('ui')
3042 subdir('hw')
3043
3044
3045 if enable_modules
3046   libmodulecommon = static_library('module-common', files('module-common.c') + genh, pic: true, c_args: '-DBUILD_DSO')
3047   modulecommon = declare_dependency(link_whole: libmodulecommon, compile_args: '-DBUILD_DSO')
3048 endif
3049
3050 qom_ss = qom_ss.apply(config_host, strict: false)
3051 libqom = static_library('qom', qom_ss.sources() + genh,
3052                         dependencies: [qom_ss.dependencies()],
3053                         name_suffix: 'fa')
3054 qom = declare_dependency(link_whole: libqom)
3055
3056 event_loop_base = files('event-loop-base.c')
3057 event_loop_base = static_library('event-loop-base', sources: event_loop_base + genh,
3058                                  build_by_default: true)
3059 event_loop_base = declare_dependency(link_whole: event_loop_base,
3060                                      dependencies: [qom])
3061
3062 stub_ss = stub_ss.apply(config_all, strict: false)
3063
3064 util_ss.add_all(trace_ss)
3065 util_ss = util_ss.apply(config_all, strict: false)
3066 libqemuutil = static_library('qemuutil',
3067                              sources: util_ss.sources() + stub_ss.sources() + genh,
3068                              dependencies: [util_ss.dependencies(), libm, threads, glib, socket, malloc, pixman])
3069 qemuutil = declare_dependency(link_with: libqemuutil,
3070                               sources: genh + version_res,
3071                               dependencies: [event_loop_base])
3072
3073 if have_system or have_user
3074   decodetree = generator(find_program('scripts/decodetree.py'),
3075                          output: 'decode-@BASENAME@.c.inc',
3076                          arguments: ['@INPUT@', '@EXTRA_ARGS@', '-o', '@OUTPUT@'])
3077   subdir('libdecnumber')
3078   subdir('target')
3079 endif
3080
3081 subdir('audio')
3082 subdir('io')
3083 subdir('chardev')
3084 subdir('fsdev')
3085 subdir('dump')
3086
3087 if have_block
3088   block_ss.add(files(
3089     'block.c',
3090     'blockjob.c',
3091     'job.c',
3092     'qemu-io-cmds.c',
3093   ))
3094   if config_host_data.get('CONFIG_REPLICATION')
3095     block_ss.add(files('replication.c'))
3096   endif
3097
3098   subdir('nbd')
3099   subdir('scsi')
3100   subdir('block')
3101
3102   blockdev_ss.add(files(
3103     'blockdev.c',
3104     'blockdev-nbd.c',
3105     'iothread.c',
3106     'job-qmp.c',
3107   ), gnutls)
3108
3109   # os-posix.c contains POSIX-specific functions used by qemu-storage-daemon,
3110   # os-win32.c does not
3111   blockdev_ss.add(when: 'CONFIG_POSIX', if_true: files('os-posix.c'))
3112   softmmu_ss.add(when: 'CONFIG_WIN32', if_true: [files('os-win32.c')])
3113 endif
3114
3115 common_ss.add(files('cpus-common.c'))
3116
3117 subdir('softmmu')
3118
3119 common_ss.add(capstone)
3120 specific_ss.add(files('cpu.c', 'disas.c', 'gdbstub.c'), capstone)
3121
3122 # Work around a gcc bug/misfeature wherein constant propagation looks
3123 # through an alias:
3124 #   https://gcc.gnu.org/bugzilla/show_bug.cgi?id=99696
3125 # to guess that a const variable is always zero.  Without lto, this is
3126 # impossible, as the alias is restricted to page-vary-common.c.  Indeed,
3127 # without lto, not even the alias is required -- we simply use different
3128 # declarations in different compilation units.
3129 pagevary = files('page-vary-common.c')
3130 if get_option('b_lto')
3131   pagevary_flags = ['-fno-lto']
3132   if get_option('cfi')
3133     pagevary_flags += '-fno-sanitize=cfi-icall'
3134   endif
3135   pagevary = static_library('page-vary-common', sources: pagevary + genh,
3136                             c_args: pagevary_flags)
3137   pagevary = declare_dependency(link_with: pagevary)
3138 endif
3139 common_ss.add(pagevary)
3140 specific_ss.add(files('page-vary.c'))
3141
3142 subdir('backends')
3143 subdir('disas')
3144 subdir('migration')
3145 subdir('monitor')
3146 subdir('net')
3147 subdir('replay')
3148 subdir('semihosting')
3149 subdir('tcg')
3150 subdir('fpu')
3151 subdir('accel')
3152 subdir('plugins')
3153 subdir('ebpf')
3154
3155 common_user_inc = []
3156
3157 subdir('common-user')
3158 subdir('bsd-user')
3159 subdir('linux-user')
3160
3161 # needed for fuzzing binaries
3162 subdir('tests/qtest/libqos')
3163 subdir('tests/qtest/fuzz')
3164
3165 # accel modules
3166 tcg_real_module_ss = ss.source_set()
3167 tcg_real_module_ss.add_all(when: 'CONFIG_TCG_MODULAR', if_true: tcg_module_ss)
3168 specific_ss.add_all(when: 'CONFIG_TCG_BUILTIN', if_true: tcg_module_ss)
3169 target_modules += { 'accel' : { 'qtest': qtest_module_ss,
3170                                 'tcg': tcg_real_module_ss }}
3171
3172 ########################
3173 # Library dependencies #
3174 ########################
3175
3176 modinfo_collect = find_program('scripts/modinfo-collect.py')
3177 modinfo_generate = find_program('scripts/modinfo-generate.py')
3178 modinfo_files = []
3179
3180 block_mods = []
3181 softmmu_mods = []
3182 foreach d, list : modules
3183   foreach m, module_ss : list
3184     if enable_modules and targetos != 'windows'
3185       module_ss = module_ss.apply(config_all, strict: false)
3186       sl = static_library(d + '-' + m, [genh, module_ss.sources()],
3187                           dependencies: [modulecommon, module_ss.dependencies()], pic: true)
3188       if d == 'block'
3189         block_mods += sl
3190       else
3191         softmmu_mods += sl
3192       endif
3193       if module_ss.sources() != []
3194         # FIXME: Should use sl.extract_all_objects(recursive: true) as
3195         # input. Sources can be used multiple times but objects are
3196         # unique when it comes to lookup in compile_commands.json.
3197         # Depnds on a mesion version with
3198         # https://github.com/mesonbuild/meson/pull/8900
3199         modinfo_files += custom_target(d + '-' + m + '.modinfo',
3200                                        output: d + '-' + m + '.modinfo',
3201                                        input: module_ss.sources() + genh,
3202                                        capture: true,
3203                                        command: [modinfo_collect, module_ss.sources()])
3204       endif
3205     else
3206       if d == 'block'
3207         block_ss.add_all(module_ss)
3208       else
3209         softmmu_ss.add_all(module_ss)
3210       endif
3211     endif
3212   endforeach
3213 endforeach
3214
3215 foreach d, list : target_modules
3216   foreach m, module_ss : list
3217     if enable_modules and targetos != 'windows'
3218       foreach target : target_dirs
3219         if target.endswith('-softmmu')
3220           config_target = config_target_mak[target]
3221           config_target += config_host
3222           target_inc = [include_directories('target' / config_target['TARGET_BASE_ARCH'])]
3223           c_args = ['-DNEED_CPU_H',
3224                     '-DCONFIG_TARGET="@0@-config-target.h"'.format(target),
3225                     '-DCONFIG_DEVICES="@0@-config-devices.h"'.format(target)]
3226           target_module_ss = module_ss.apply(config_target, strict: false)
3227           if target_module_ss.sources() != []
3228             module_name = d + '-' + m + '-' + config_target['TARGET_NAME']
3229             sl = static_library(module_name,
3230                                 [genh, target_module_ss.sources()],
3231                                 dependencies: [modulecommon, target_module_ss.dependencies()],
3232                                 include_directories: target_inc,
3233                                 c_args: c_args,
3234                                 pic: true)
3235             softmmu_mods += sl
3236             # FIXME: Should use sl.extract_all_objects(recursive: true) too.
3237             modinfo_files += custom_target(module_name + '.modinfo',
3238                                            output: module_name + '.modinfo',
3239                                            input: target_module_ss.sources() + genh,
3240                                            capture: true,
3241                                            command: [modinfo_collect, '--target', target, target_module_ss.sources()])
3242           endif
3243         endif
3244       endforeach
3245     else
3246       specific_ss.add_all(module_ss)
3247     endif
3248   endforeach
3249 endforeach
3250
3251 if enable_modules
3252   foreach target : target_dirs
3253     if target.endswith('-softmmu')
3254       config_target = config_target_mak[target]
3255       config_devices_mak = target + '-config-devices.mak'
3256       modinfo_src = custom_target('modinfo-' + target + '.c',
3257                                   output: 'modinfo-' + target + '.c',
3258                                   input: modinfo_files,
3259                                   command: [modinfo_generate, '--devices', config_devices_mak, '@INPUT@'],
3260                                   capture: true)
3261
3262       modinfo_lib = static_library('modinfo-' + target + '.c', modinfo_src)
3263       modinfo_dep = declare_dependency(link_with: modinfo_lib)
3264
3265       arch = config_target['TARGET_NAME'] == 'sparc64' ? 'sparc64' : config_target['TARGET_BASE_ARCH']
3266       hw_arch[arch].add(modinfo_dep)
3267     endif
3268   endforeach
3269 endif
3270
3271 nm = find_program('nm')
3272 undefsym = find_program('scripts/undefsym.py')
3273 block_syms = custom_target('block.syms', output: 'block.syms',
3274                              input: [libqemuutil, block_mods],
3275                              capture: true,
3276                              command: [undefsym, nm, '@INPUT@'])
3277 qemu_syms = custom_target('qemu.syms', output: 'qemu.syms',
3278                              input: [libqemuutil, softmmu_mods],
3279                              capture: true,
3280                              command: [undefsym, nm, '@INPUT@'])
3281
3282 authz_ss = authz_ss.apply(config_host, strict: false)
3283 libauthz = static_library('authz', authz_ss.sources() + genh,
3284                           dependencies: [authz_ss.dependencies()],
3285                           name_suffix: 'fa',
3286                           build_by_default: false)
3287
3288 authz = declare_dependency(link_whole: libauthz,
3289                            dependencies: qom)
3290
3291 crypto_ss = crypto_ss.apply(config_host, strict: false)
3292 libcrypto = static_library('crypto', crypto_ss.sources() + genh,
3293                            dependencies: [crypto_ss.dependencies()],
3294                            name_suffix: 'fa',
3295                            build_by_default: false)
3296
3297 crypto = declare_dependency(link_whole: libcrypto,
3298                             dependencies: [authz, qom])
3299
3300 io_ss = io_ss.apply(config_host, strict: false)
3301 libio = static_library('io', io_ss.sources() + genh,
3302                        dependencies: [io_ss.dependencies()],
3303                        link_with: libqemuutil,
3304                        name_suffix: 'fa',
3305                        build_by_default: false)
3306
3307 io = declare_dependency(link_whole: libio, dependencies: [crypto, qom])
3308
3309 libmigration = static_library('migration', sources: migration_files + genh,
3310                               name_suffix: 'fa',
3311                               build_by_default: false)
3312 migration = declare_dependency(link_with: libmigration,
3313                                dependencies: [zlib, qom, io])
3314 softmmu_ss.add(migration)
3315
3316 block_ss = block_ss.apply(config_host, strict: false)
3317 libblock = static_library('block', block_ss.sources() + genh,
3318                           dependencies: block_ss.dependencies(),
3319                           link_depends: block_syms,
3320                           name_suffix: 'fa',
3321                           build_by_default: false)
3322
3323 block = declare_dependency(link_whole: [libblock],
3324                            link_args: '@block.syms',
3325                            dependencies: [crypto, io])
3326
3327 blockdev_ss = blockdev_ss.apply(config_host, strict: false)
3328 libblockdev = static_library('blockdev', blockdev_ss.sources() + genh,
3329                              dependencies: blockdev_ss.dependencies(),
3330                              name_suffix: 'fa',
3331                              build_by_default: false)
3332
3333 blockdev = declare_dependency(link_whole: [libblockdev],
3334                               dependencies: [block, event_loop_base])
3335
3336 qmp_ss = qmp_ss.apply(config_host, strict: false)
3337 libqmp = static_library('qmp', qmp_ss.sources() + genh,
3338                         dependencies: qmp_ss.dependencies(),
3339                         name_suffix: 'fa',
3340                         build_by_default: false)
3341
3342 qmp = declare_dependency(link_whole: [libqmp])
3343
3344 libchardev = static_library('chardev', chardev_ss.sources() + genh,
3345                             name_suffix: 'fa',
3346                             dependencies: chardev_ss.dependencies(),
3347                             build_by_default: false)
3348
3349 chardev = declare_dependency(link_whole: libchardev)
3350
3351 hwcore_ss = hwcore_ss.apply(config_host, strict: false)
3352 libhwcore = static_library('hwcore', sources: hwcore_ss.sources() + genh,
3353                            name_suffix: 'fa',
3354                            build_by_default: false)
3355 hwcore = declare_dependency(link_whole: libhwcore)
3356 common_ss.add(hwcore)
3357
3358 ###########
3359 # Targets #
3360 ###########
3361
3362 emulator_modules = []
3363 foreach m : block_mods + softmmu_mods
3364   emulator_modules += shared_module(m.name(),
3365                 build_by_default: true,
3366                 name_prefix: '',
3367                 link_whole: m,
3368                 install: true,
3369                 install_dir: qemu_moddir)
3370 endforeach
3371 if emulator_modules.length() > 0
3372   alias_target('modules', emulator_modules)
3373 endif
3374
3375 softmmu_ss.add(authz, blockdev, chardev, crypto, io, qmp)
3376 common_ss.add(qom, qemuutil)
3377
3378 common_ss.add_all(when: 'CONFIG_SOFTMMU', if_true: [softmmu_ss])
3379 common_ss.add_all(when: 'CONFIG_USER_ONLY', if_true: user_ss)
3380
3381 common_all = common_ss.apply(config_all, strict: false)
3382 common_all = static_library('common',
3383                             build_by_default: false,
3384                             sources: common_all.sources() + genh,
3385                             include_directories: common_user_inc,
3386                             implicit_include_directories: false,
3387                             dependencies: common_all.dependencies(),
3388                             name_suffix: 'fa')
3389
3390 feature_to_c = find_program('scripts/feature_to_c.sh')
3391
3392 if targetos == 'darwin'
3393   entitlement = find_program('scripts/entitlement.sh')
3394 endif
3395
3396 emulators = {}
3397 foreach target : target_dirs
3398   config_target = config_target_mak[target]
3399   target_name = config_target['TARGET_NAME']
3400   target_base_arch = config_target['TARGET_BASE_ARCH']
3401   arch_srcs = [config_target_h[target]]
3402   arch_deps = []
3403   c_args = ['-DNEED_CPU_H',
3404             '-DCONFIG_TARGET="@0@-config-target.h"'.format(target),
3405             '-DCONFIG_DEVICES="@0@-config-devices.h"'.format(target)]
3406   link_args = emulator_link_args
3407
3408   config_target += config_host
3409   target_inc = [include_directories('target' / config_target['TARGET_BASE_ARCH'])]
3410   if targetos == 'linux'
3411     target_inc += include_directories('linux-headers', is_system: true)
3412   endif
3413   if target.endswith('-softmmu')
3414     qemu_target_name = 'qemu-system-' + target_name
3415     target_type='system'
3416     t = target_softmmu_arch[target_base_arch].apply(config_target, strict: false)
3417     arch_srcs += t.sources()
3418     arch_deps += t.dependencies()
3419
3420     hw_dir = target_name == 'sparc64' ? 'sparc64' : target_base_arch
3421     hw = hw_arch[hw_dir].apply(config_target, strict: false)
3422     arch_srcs += hw.sources()
3423     arch_deps += hw.dependencies()
3424
3425     arch_srcs += config_devices_h[target]
3426     link_args += ['@block.syms', '@qemu.syms']
3427   else
3428     abi = config_target['TARGET_ABI_DIR']
3429     target_type='user'
3430     target_inc += common_user_inc
3431     qemu_target_name = 'qemu-' + target_name
3432     if target_base_arch in target_user_arch
3433       t = target_user_arch[target_base_arch].apply(config_target, strict: false)
3434       arch_srcs += t.sources()
3435       arch_deps += t.dependencies()
3436     endif
3437     if 'CONFIG_LINUX_USER' in config_target
3438       base_dir = 'linux-user'
3439     endif
3440     if 'CONFIG_BSD_USER' in config_target
3441       base_dir = 'bsd-user'
3442       target_inc += include_directories('bsd-user/' / targetos)
3443       target_inc += include_directories('bsd-user/host/' / host_arch)
3444       dir = base_dir / abi
3445       arch_srcs += files(dir / 'signal.c', dir / 'target_arch_cpu.c')
3446     endif
3447     target_inc += include_directories(
3448       base_dir,
3449       base_dir / abi,
3450     )
3451     if 'CONFIG_LINUX_USER' in config_target
3452       dir = base_dir / abi
3453       arch_srcs += files(dir / 'signal.c', dir / 'cpu_loop.c')
3454       if config_target.has_key('TARGET_SYSTBL_ABI')
3455         arch_srcs += \
3456           syscall_nr_generators[abi].process(base_dir / abi / config_target['TARGET_SYSTBL'],
3457                                              extra_args : config_target['TARGET_SYSTBL_ABI'])
3458       endif
3459     endif
3460   endif
3461
3462   if 'TARGET_XML_FILES' in config_target
3463     gdbstub_xml = custom_target(target + '-gdbstub-xml.c',
3464                                 output: target + '-gdbstub-xml.c',
3465                                 input: files(config_target['TARGET_XML_FILES'].split()),
3466                                 command: [feature_to_c, '@INPUT@'],
3467                                 capture: true)
3468     arch_srcs += gdbstub_xml
3469   endif
3470
3471   t = target_arch[target_base_arch].apply(config_target, strict: false)
3472   arch_srcs += t.sources()
3473   arch_deps += t.dependencies()
3474
3475   target_common = common_ss.apply(config_target, strict: false)
3476   objects = common_all.extract_objects(target_common.sources())
3477   deps = target_common.dependencies()
3478
3479   target_specific = specific_ss.apply(config_target, strict: false)
3480   arch_srcs += target_specific.sources()
3481   arch_deps += target_specific.dependencies()
3482
3483   lib = static_library('qemu-' + target,
3484                  sources: arch_srcs + genh,
3485                  dependencies: arch_deps,
3486                  objects: objects,
3487                  include_directories: target_inc,
3488                  c_args: c_args,
3489                  build_by_default: false,
3490                  name_suffix: 'fa')
3491
3492   if target.endswith('-softmmu')
3493     execs = [{
3494       'name': 'qemu-system-' + target_name,
3495       'win_subsystem': 'console',
3496       'sources': files('softmmu/main.c'),
3497       'dependencies': []
3498     }]
3499     if targetos == 'windows' and (sdl.found() or gtk.found())
3500       execs += [{
3501         'name': 'qemu-system-' + target_name + 'w',
3502         'win_subsystem': 'windows',
3503         'sources': files('softmmu/main.c'),
3504         'dependencies': []
3505       }]
3506     endif
3507     if get_option('fuzzing')
3508       specific_fuzz = specific_fuzz_ss.apply(config_target, strict: false)
3509       execs += [{
3510         'name': 'qemu-fuzz-' + target_name,
3511         'win_subsystem': 'console',
3512         'sources': specific_fuzz.sources(),
3513         'dependencies': specific_fuzz.dependencies(),
3514       }]
3515     endif
3516   else
3517     execs = [{
3518       'name': 'qemu-' + target_name,
3519       'win_subsystem': 'console',
3520       'sources': [],
3521       'dependencies': []
3522     }]
3523   endif
3524   foreach exe: execs
3525     exe_name = exe['name']
3526     if targetos == 'darwin'
3527       exe_name += '-unsigned'
3528     endif
3529
3530     emulator = executable(exe_name, exe['sources'],
3531                install: true,
3532                c_args: c_args,
3533                dependencies: arch_deps + deps + exe['dependencies'],
3534                objects: lib.extract_all_objects(recursive: true),
3535                link_language: link_language,
3536                link_depends: [block_syms, qemu_syms] + exe.get('link_depends', []),
3537                link_args: link_args,
3538                win_subsystem: exe['win_subsystem'])
3539
3540     if targetos == 'darwin'
3541       icon = 'pc-bios/qemu.rsrc'
3542       build_input = [emulator, files(icon)]
3543       install_input = [
3544         get_option('bindir') / exe_name,
3545         meson.current_source_dir() / icon
3546       ]
3547       if 'CONFIG_HVF' in config_target
3548         entitlements = 'accel/hvf/entitlements.plist'
3549         build_input += files(entitlements)
3550         install_input += meson.current_source_dir() / entitlements
3551       endif
3552
3553       emulators += {exe['name'] : custom_target(exe['name'],
3554                    input: build_input,
3555                    output: exe['name'],
3556                    command: [entitlement, '@OUTPUT@', '@INPUT@'])
3557       }
3558
3559       meson.add_install_script(entitlement, '--install',
3560                                get_option('bindir') / exe['name'],
3561                                install_input)
3562     else
3563       emulators += {exe['name']: emulator}
3564     endif
3565
3566     if stap.found()
3567       foreach stp: [
3568         {'ext': '.stp-build', 'fmt': 'stap', 'bin': meson.current_build_dir() / exe['name'], 'install': false},
3569         {'ext': '.stp', 'fmt': 'stap', 'bin': get_option('prefix') / get_option('bindir') / exe['name'], 'install': true},
3570         {'ext': '-simpletrace.stp', 'fmt': 'simpletrace-stap', 'bin': '', 'install': true},
3571         {'ext': '-log.stp', 'fmt': 'log-stap', 'bin': '', 'install': true},
3572       ]
3573         custom_target(exe['name'] + stp['ext'],
3574                       input: trace_events_all,
3575                       output: exe['name'] + stp['ext'],
3576                       install: stp['install'],
3577                       install_dir: get_option('datadir') / 'systemtap/tapset',
3578                       command: [
3579                         tracetool, '--group=all', '--format=' + stp['fmt'],
3580                         '--binary=' + stp['bin'],
3581                         '--target-name=' + target_name,
3582                         '--target-type=' + target_type,
3583                         '--probe-prefix=qemu.' + target_type + '.' + target_name,
3584                         '@INPUT@', '@OUTPUT@'
3585                       ],
3586                       depend_files: tracetool_depends)
3587       endforeach
3588     endif
3589   endforeach
3590 endforeach
3591
3592 # Other build targets
3593
3594 if 'CONFIG_PLUGIN' in config_host
3595   install_headers('include/qemu/qemu-plugin.h')
3596 endif
3597
3598 subdir('qga')
3599
3600 # Don't build qemu-keymap if xkbcommon is not explicitly enabled
3601 # when we don't build tools or system
3602 if xkbcommon.found()
3603   # used for the update-keymaps target, so include rules even if !have_tools
3604   qemu_keymap = executable('qemu-keymap', files('qemu-keymap.c', 'ui/input-keymap.c') + genh,
3605                            dependencies: [qemuutil, xkbcommon], install: have_tools)
3606 endif
3607
3608 if have_tools
3609   qemu_img = executable('qemu-img', [files('qemu-img.c'), hxdep],
3610              dependencies: [authz, block, crypto, io, qom, qemuutil], install: true)
3611   qemu_io = executable('qemu-io', files('qemu-io.c'),
3612              dependencies: [block, qemuutil], install: true)
3613   qemu_nbd = executable('qemu-nbd', files('qemu-nbd.c'),
3614                dependencies: [blockdev, qemuutil, gnutls, selinux],
3615                install: true)
3616
3617   subdir('storage-daemon')
3618   subdir('contrib/rdmacm-mux')
3619   subdir('contrib/elf2dmp')
3620
3621   executable('qemu-edid', files('qemu-edid.c', 'hw/display/edid-generate.c'),
3622              dependencies: qemuutil,
3623              install: true)
3624
3625   if have_vhost_user
3626     subdir('contrib/vhost-user-blk')
3627     subdir('contrib/vhost-user-gpu')
3628     subdir('contrib/vhost-user-input')
3629     subdir('contrib/vhost-user-scsi')
3630   endif
3631
3632   if targetos == 'linux'
3633     executable('qemu-bridge-helper', files('qemu-bridge-helper.c'),
3634                dependencies: [qemuutil, libcap_ng],
3635                install: true,
3636                install_dir: get_option('libexecdir'))
3637
3638     executable('qemu-pr-helper', files('scsi/qemu-pr-helper.c', 'scsi/utils.c'),
3639                dependencies: [authz, crypto, io, qom, qemuutil,
3640                               libcap_ng, mpathpersist],
3641                install: true)
3642   endif
3643
3644   if have_ivshmem
3645     subdir('contrib/ivshmem-client')
3646     subdir('contrib/ivshmem-server')
3647   endif
3648 endif
3649
3650 subdir('scripts')
3651 subdir('tools')
3652 subdir('pc-bios')
3653 subdir('docs')
3654 subdir('tests')
3655 if gtk.found()
3656   subdir('po')
3657 endif
3658
3659 if host_machine.system() == 'windows'
3660   nsis_cmd = [
3661     find_program('scripts/nsis.py'),
3662     '@OUTPUT@',
3663     get_option('prefix'),
3664     meson.current_source_dir(),
3665     host_machine.cpu(),
3666     '--',
3667     '-DDISPLAYVERSION=' + meson.project_version(),
3668   ]
3669   if build_docs
3670     nsis_cmd += '-DCONFIG_DOCUMENTATION=y'
3671   endif
3672   if gtk.found()
3673     nsis_cmd += '-DCONFIG_GTK=y'
3674   endif
3675
3676   nsis = custom_target('nsis',
3677                        output: 'qemu-setup-' + meson.project_version() + '.exe',
3678                        input: files('qemu.nsi'),
3679                        build_always_stale: true,
3680                        command: nsis_cmd + ['@INPUT@'])
3681   alias_target('installer', nsis)
3682 endif
3683
3684 #########################
3685 # Configuration summary #
3686 #########################
3687
3688 # Directories
3689 summary_info = {}
3690 summary_info += {'Install prefix':    get_option('prefix')}
3691 summary_info += {'BIOS directory':    qemu_datadir}
3692 pathsep = targetos == 'windows' ? ';' : ':'
3693 summary_info += {'firmware path':     pathsep.join(get_option('qemu_firmwarepath'))}
3694 summary_info += {'binary directory':  get_option('prefix') / get_option('bindir')}
3695 summary_info += {'library directory': get_option('prefix') / get_option('libdir')}
3696 summary_info += {'module directory':  qemu_moddir}
3697 summary_info += {'libexec directory': get_option('prefix') / get_option('libexecdir')}
3698 summary_info += {'include directory': get_option('prefix') / get_option('includedir')}
3699 summary_info += {'config directory':  get_option('prefix') / get_option('sysconfdir')}
3700 if targetos != 'windows'
3701   summary_info += {'local state directory': get_option('prefix') / get_option('localstatedir')}
3702   summary_info += {'Manual directory':      get_option('prefix') / get_option('mandir')}
3703 else
3704   summary_info += {'local state directory': 'queried at runtime'}
3705 endif
3706 summary_info += {'Doc directory':     get_option('prefix') / get_option('docdir')}
3707 summary_info += {'Build directory':   meson.current_build_dir()}
3708 summary_info += {'Source path':       meson.current_source_dir()}
3709 summary_info += {'GIT submodules':    config_host['GIT_SUBMODULES']}
3710 summary(summary_info, bool_yn: true, section: 'Directories')
3711
3712 # Host binaries
3713 summary_info = {}
3714 summary_info += {'git':               config_host['GIT']}
3715 summary_info += {'make':              config_host['MAKE']}
3716 summary_info += {'python':            '@0@ (version: @1@)'.format(python.full_path(), python.language_version())}
3717 summary_info += {'sphinx-build':      sphinx_build}
3718 if config_host.has_key('HAVE_GDB_BIN')
3719   summary_info += {'gdb':             config_host['HAVE_GDB_BIN']}
3720 endif
3721 summary_info += {'iasl':              iasl}
3722 summary_info += {'genisoimage':       config_host['GENISOIMAGE']}
3723 if targetos == 'windows' and have_ga
3724   summary_info += {'wixl':            wixl}
3725 endif
3726 if slirp_opt != 'disabled' and have_system
3727   summary_info += {'smbd':            have_slirp_smbd ? smbd_path : false}
3728 endif
3729 summary(summary_info, bool_yn: true, section: 'Host binaries')
3730
3731 # Configurable features
3732 summary_info = {}
3733 summary_info += {'Documentation':     build_docs}
3734 summary_info += {'system-mode emulation': have_system}
3735 summary_info += {'user-mode emulation': have_user}
3736 summary_info += {'block layer':       have_block}
3737 summary_info += {'Install blobs':     get_option('install_blobs')}
3738 summary_info += {'module support':    config_host.has_key('CONFIG_MODULES')}
3739 if config_host.has_key('CONFIG_MODULES')
3740   summary_info += {'alternative module path': get_option('module_upgrades')}
3741 endif
3742 summary_info += {'fuzzing support':   get_option('fuzzing')}
3743 if have_system
3744   summary_info += {'Audio drivers':     ' '.join(audio_drivers_selected)}
3745 endif
3746 summary_info += {'Trace backends':    ','.join(get_option('trace_backends'))}
3747 if 'simple' in get_option('trace_backends')
3748   summary_info += {'Trace output file': get_option('trace_file') + '-<pid>'}
3749 endif
3750 summary_info += {'D-Bus display':     dbus_display}
3751 summary_info += {'QOM debugging':     get_option('qom_cast_debug')}
3752 summary_info += {'vhost-kernel support': have_vhost_kernel}
3753 summary_info += {'vhost-net support': have_vhost_net}
3754 summary_info += {'vhost-user support': have_vhost_user}
3755 summary_info += {'vhost-user-crypto support': have_vhost_user_crypto}
3756 summary_info += {'vhost-user-blk server support': have_vhost_user_blk_server}
3757 summary_info += {'vhost-vdpa support': have_vhost_vdpa}
3758 summary_info += {'build guest agent': have_ga}
3759 summary(summary_info, bool_yn: true, section: 'Configurable features')
3760
3761 # Compilation information
3762 summary_info = {}
3763 summary_info += {'host CPU':          cpu}
3764 summary_info += {'host endianness':   build_machine.endian()}
3765 summary_info += {'C compiler':        ' '.join(meson.get_compiler('c').cmd_array())}
3766 summary_info += {'Host C compiler':   ' '.join(meson.get_compiler('c', native: true).cmd_array())}
3767 if link_language == 'cpp'
3768   summary_info += {'C++ compiler':    ' '.join(meson.get_compiler('cpp').cmd_array())}
3769 else
3770   summary_info += {'C++ compiler':      false}
3771 endif
3772 if targetos == 'darwin'
3773   summary_info += {'Objective-C compiler': ' '.join(meson.get_compiler('objc').cmd_array())}
3774 endif
3775 summary_info += {'CFLAGS':            ' '.join(get_option('c_args')
3776                                                + ['-O' + get_option('optimization')]
3777                                                + (get_option('debug') ? ['-g'] : []))}
3778 if link_language == 'cpp'
3779   summary_info += {'CXXFLAGS':        ' '.join(get_option('cpp_args')
3780                                                + ['-O' + get_option('optimization')]
3781                                                + (get_option('debug') ? ['-g'] : []))}
3782 endif
3783 if targetos == 'darwin'
3784   summary_info += {'OBJCFLAGS':       ' '.join(get_option('objc_args')
3785                                                + ['-O' + get_option('optimization')]
3786                                                + (get_option('debug') ? ['-g'] : []))}
3787 endif
3788 link_args = get_option(link_language + '_link_args')
3789 if link_args.length() > 0
3790   summary_info += {'LDFLAGS':         ' '.join(link_args)}
3791 endif
3792 summary_info += {'QEMU_CFLAGS':       ' '.join(qemu_cflags)}
3793 summary_info += {'QEMU_CXXFLAGS':     ' '.join(qemu_cxxflags)}
3794 summary_info += {'QEMU_OBJCFLAGS':    ' '.join(qemu_objcflags)}
3795 summary_info += {'QEMU_LDFLAGS':      ' '.join(qemu_ldflags)}
3796 summary_info += {'profiler':          get_option('profiler')}
3797 summary_info += {'link-time optimization (LTO)': get_option('b_lto')}
3798 summary_info += {'PIE':               get_option('b_pie')}
3799 summary_info += {'static build':      config_host.has_key('CONFIG_STATIC')}
3800 summary_info += {'malloc trim support': has_malloc_trim}
3801 summary_info += {'membarrier':        have_membarrier}
3802 summary_info += {'debug stack usage': get_option('debug_stack_usage')}
3803 summary_info += {'mutex debugging':   get_option('debug_mutex')}
3804 summary_info += {'memory allocator':  get_option('malloc')}
3805 summary_info += {'avx2 optimization': config_host_data.get('CONFIG_AVX2_OPT')}
3806 summary_info += {'avx512f optimization': config_host_data.get('CONFIG_AVX512F_OPT')}
3807 summary_info += {'gprof enabled':     get_option('gprof')}
3808 summary_info += {'gcov':              get_option('b_coverage')}
3809 summary_info += {'thread sanitizer':  config_host.has_key('CONFIG_TSAN')}
3810 summary_info += {'CFI support':       get_option('cfi')}
3811 if get_option('cfi')
3812   summary_info += {'CFI debug support': get_option('cfi_debug')}
3813 endif
3814 summary_info += {'strip binaries':    get_option('strip')}
3815 summary_info += {'sparse':            sparse}
3816 summary_info += {'mingw32 support':   targetos == 'windows'}
3817 summary(summary_info, bool_yn: true, section: 'Compilation')
3818
3819 # snarf the cross-compilation information for tests
3820 summary_info = {}
3821 have_cross = false
3822 foreach target: target_dirs
3823   tcg_mak = meson.current_build_dir() / 'tests/tcg' / 'config-' + target + '.mak'
3824   if fs.exists(tcg_mak)
3825     config_cross_tcg = keyval.load(tcg_mak)
3826     if 'CC' in config_cross_tcg
3827       summary_info += {config_cross_tcg['TARGET_NAME']: config_cross_tcg['CC']}
3828       have_cross = true
3829     endif
3830   endif
3831 endforeach
3832 if have_cross
3833   summary(summary_info, bool_yn: true, section: 'Cross compilers')
3834 endif
3835
3836 # Targets and accelerators
3837 summary_info = {}
3838 if have_system
3839   summary_info += {'KVM support':       config_all.has_key('CONFIG_KVM')}
3840   summary_info += {'HAX support':       config_all.has_key('CONFIG_HAX')}
3841   summary_info += {'HVF support':       config_all.has_key('CONFIG_HVF')}
3842   summary_info += {'WHPX support':      config_all.has_key('CONFIG_WHPX')}
3843   summary_info += {'NVMM support':      config_all.has_key('CONFIG_NVMM')}
3844   summary_info += {'Xen support':       xen.found()}
3845   if xen.found()
3846     summary_info += {'xen ctrl version':  xen.version()}
3847   endif
3848 endif
3849 summary_info += {'TCG support':       config_all.has_key('CONFIG_TCG')}
3850 if config_all.has_key('CONFIG_TCG')
3851   if get_option('tcg_interpreter')
3852     summary_info += {'TCG backend':   'TCI (TCG with bytecode interpreter, slow)'}
3853   else
3854     summary_info += {'TCG backend':   'native (@0@)'.format(cpu)}
3855   endif
3856   summary_info += {'TCG plugins': config_host.has_key('CONFIG_PLUGIN')}
3857   summary_info += {'TCG debug enabled': config_host.has_key('CONFIG_DEBUG_TCG')}
3858 endif
3859 summary_info += {'target list':       ' '.join(target_dirs)}
3860 if have_system
3861   summary_info += {'default devices':   get_option('default_devices')}
3862   summary_info += {'out of process emulation': multiprocess_allowed}
3863   summary_info += {'vfio-user server': vfio_user_server_allowed}
3864 endif
3865 summary(summary_info, bool_yn: true, section: 'Targets and accelerators')
3866
3867 # Block layer
3868 summary_info = {}
3869 summary_info += {'coroutine backend': config_host['CONFIG_COROUTINE_BACKEND']}
3870 summary_info += {'coroutine pool':    have_coroutine_pool}
3871 if have_block
3872   summary_info += {'Block whitelist (rw)': get_option('block_drv_rw_whitelist')}
3873   summary_info += {'Block whitelist (ro)': get_option('block_drv_ro_whitelist')}
3874   summary_info += {'Use block whitelist in tools': get_option('block_drv_whitelist_in_tools')}
3875   summary_info += {'VirtFS support':    have_virtfs}
3876   summary_info += {'build virtiofs daemon': have_virtiofsd}
3877   summary_info += {'Live block migration': config_host_data.get('CONFIG_LIVE_BLOCK_MIGRATION')}
3878   summary_info += {'replication support': config_host_data.get('CONFIG_REPLICATION')}
3879   summary_info += {'bochs support':     get_option('bochs').allowed()}
3880   summary_info += {'cloop support':     get_option('cloop').allowed()}
3881   summary_info += {'dmg support':       get_option('dmg').allowed()}
3882   summary_info += {'qcow v1 support':   get_option('qcow1').allowed()}
3883   summary_info += {'vdi support':       get_option('vdi').allowed()}
3884   summary_info += {'vvfat support':     get_option('vvfat').allowed()}
3885   summary_info += {'qed support':       get_option('qed').allowed()}
3886   summary_info += {'parallels support': get_option('parallels').allowed()}
3887   summary_info += {'FUSE exports':      fuse}
3888   summary_info += {'VDUSE block exports': have_vduse_blk_export}
3889 endif
3890 summary(summary_info, bool_yn: true, section: 'Block layer support')
3891
3892 # Crypto
3893 summary_info = {}
3894 summary_info += {'TLS priority':      get_option('tls_priority')}
3895 summary_info += {'GNUTLS support':    gnutls}
3896 if gnutls.found()
3897   summary_info += {'  GNUTLS crypto':   gnutls_crypto.found()}
3898 endif
3899 summary_info += {'libgcrypt':         gcrypt}
3900 summary_info += {'nettle':            nettle}
3901 if nettle.found()
3902    summary_info += {'  XTS':             xts != 'private'}
3903 endif
3904 summary_info += {'AF_ALG support':    have_afalg}
3905 summary_info += {'rng-none':          get_option('rng_none')}
3906 summary_info += {'Linux keyring':     have_keyring}
3907 summary(summary_info, bool_yn: true, section: 'Crypto')
3908
3909 # Libraries
3910 summary_info = {}
3911 if targetos == 'darwin'
3912   summary_info += {'Cocoa support':           cocoa}
3913   summary_info += {'vmnet.framework support': vmnet}
3914 endif
3915 summary_info += {'SDL support':       sdl}
3916 summary_info += {'SDL image support': sdl_image}
3917 summary_info += {'GTK support':       gtk}
3918 summary_info += {'pixman':            pixman}
3919 summary_info += {'VTE support':       vte}
3920 summary_info += {'slirp support':     slirp_opt == 'internal' ? slirp_opt : slirp}
3921 summary_info += {'libtasn1':          tasn1}
3922 summary_info += {'PAM':               pam}
3923 summary_info += {'iconv support':     iconv}
3924 summary_info += {'curses support':    curses}
3925 summary_info += {'virgl support':     virgl}
3926 summary_info += {'curl support':      curl}
3927 summary_info += {'Multipath support': mpathpersist}
3928 summary_info += {'PNG support':       png}
3929 summary_info += {'VNC support':       vnc}
3930 if vnc.found()
3931   summary_info += {'VNC SASL support':  sasl}
3932   summary_info += {'VNC JPEG support':  jpeg}
3933 endif
3934 if targetos not in ['darwin', 'haiku', 'windows']
3935   summary_info += {'OSS support':     oss}
3936 elif targetos == 'darwin'
3937   summary_info += {'CoreAudio support': coreaudio}
3938 elif targetos == 'windows'
3939   summary_info += {'DirectSound support': dsound}
3940 endif
3941 if targetos == 'linux'
3942   summary_info += {'ALSA support':    alsa}
3943   summary_info += {'PulseAudio support': pulse}
3944 endif
3945 summary_info += {'JACK support':      jack}
3946 summary_info += {'brlapi support':    brlapi}
3947 summary_info += {'vde support':       vde}
3948 summary_info += {'netmap support':    have_netmap}
3949 summary_info += {'l2tpv3 support':    have_l2tpv3}
3950 summary_info += {'Linux AIO support': libaio}
3951 summary_info += {'Linux io_uring support': linux_io_uring}
3952 summary_info += {'ATTR/XATTR support': libattr}
3953 summary_info += {'RDMA support':      rdma}
3954 summary_info += {'PVRDMA support':    have_pvrdma}
3955 summary_info += {'fdt support':       fdt_opt == 'disabled' ? false : fdt_opt}
3956 summary_info += {'libcap-ng support': libcap_ng}
3957 summary_info += {'bpf support':       libbpf}
3958 summary_info += {'spice protocol support': spice_protocol}
3959 if spice_protocol.found()
3960   summary_info += {'  spice server support': spice}
3961 endif
3962 summary_info += {'rbd support':       rbd}
3963 summary_info += {'smartcard support': cacard}
3964 summary_info += {'U2F support':       u2f}
3965 summary_info += {'libusb':            libusb}
3966 summary_info += {'usb net redir':     usbredir}
3967 summary_info += {'OpenGL support (epoxy)': opengl}
3968 summary_info += {'GBM':               gbm}
3969 summary_info += {'libiscsi support':  libiscsi}
3970 summary_info += {'libnfs support':    libnfs}
3971 if targetos == 'windows'
3972   if have_ga
3973     summary_info += {'QGA VSS support':   have_qga_vss}
3974   endif
3975 endif
3976 summary_info += {'seccomp support':   seccomp}
3977 summary_info += {'GlusterFS support': glusterfs}
3978 summary_info += {'TPM support':       have_tpm}
3979 summary_info += {'libssh support':    libssh}
3980 summary_info += {'lzo support':       lzo}
3981 summary_info += {'snappy support':    snappy}
3982 summary_info += {'bzip2 support':     libbzip2}
3983 summary_info += {'lzfse support':     liblzfse}
3984 summary_info += {'zstd support':      zstd}
3985 summary_info += {'NUMA host support': numa}
3986 summary_info += {'capstone':          capstone}
3987 summary_info += {'libpmem support':   libpmem}
3988 summary_info += {'libdaxctl support': libdaxctl}
3989 summary_info += {'libudev':           libudev}
3990 # Dummy dependency, keep .found()
3991 summary_info += {'FUSE lseek':        fuse_lseek.found()}
3992 summary_info += {'selinux':           selinux}
3993 summary(summary_info, bool_yn: true, section: 'Dependencies')
3994
3995 if not supported_cpus.contains(cpu)
3996   message()
3997   warning('SUPPORT FOR THIS HOST CPU WILL GO AWAY IN FUTURE RELEASES!')
3998   message()
3999   message('CPU host architecture ' + cpu + ' support is not currently maintained.')
4000   message('The QEMU project intends to remove support for this host CPU in')
4001   message('a future release if nobody volunteers to maintain it and to')
4002   message('provide a build host for our continuous integration setup.')
4003   message('configure has succeeded and you can continue to build, but')
4004   message('if you care about QEMU on this platform you should contact')
4005   message('us upstream at qemu-devel@nongnu.org.')
4006 endif
4007
4008 if not supported_oses.contains(targetos)
4009   message()
4010   warning('WARNING: SUPPORT FOR THIS HOST OS WILL GO AWAY IN FUTURE RELEASES!')
4011   message()
4012   message('Host OS ' + targetos + 'support is not currently maintained.')
4013   message('The QEMU project intends to remove support for this host OS in')
4014   message('a future release if nobody volunteers to maintain it and to')
4015   message('provide a build host for our continuous integration setup.')
4016   message('configure has succeeded and you can continue to build, but')
4017   message('if you care about QEMU on this platform you should contact')
4018   message('us upstream at qemu-devel@nongnu.org.')
4019 endif