meson.build

   1 project('qemu', ['c'], meson_version: '>=0.55.0',
   2         default_options: ['warning_level=1', 'c_std=gnu99', 'cpp_std=gnu++11', 'b_colorout=auto'] +
   3                          (meson.version().version_compare('>=0.56.0') ? [ 'b_staticpic=false' ] : []),
   4         version: run_command('head', meson.source_root() / 'VERSION').stdout().strip())
   5
   6 not_found = dependency('', required: false)
   7 if meson.version().version_compare('>=0.56.0')
   8   keyval = import('keyval')
   9 else
  10   keyval = import('unstable-keyval')
  11 endif
  12 ss = import('sourceset')
  13 fs = import('fs')
  14
  15 sh = find_program('sh')
  16 cc = meson.get_compiler('c')
  17 config_host = keyval.load(meson.current_build_dir() / 'config-host.mak')
  18 enable_modules = 'CONFIG_MODULES' in config_host
  19 enable_static = 'CONFIG_STATIC' in config_host
  20
  21 # Temporary directory used for files created while
  22 # configure runs. Since it is in the build directory
  23 # we can safely blow away any previous version of it
  24 # (and we need not jump through hoops to try to delete
  25 # it when configure exits.)
  26 tmpdir = meson.current_build_dir() / 'meson-private/temp'
  27
  28 if get_option('qemu_suffix').startswith('/')
  29   error('qemu_suffix cannot start with a /')
  30 endif
  31
  32 qemu_confdir = get_option('sysconfdir') / get_option('qemu_suffix')
  33 qemu_datadir = get_option('datadir') / get_option('qemu_suffix')
  34 qemu_docdir = get_option('docdir') / get_option('qemu_suffix')
  35 qemu_moddir = get_option('libdir') / get_option('qemu_suffix')
  36
  37 qemu_desktopdir = get_option('datadir') / 'applications'
  38 qemu_icondir = get_option('datadir') / 'icons'
  39
  40 config_host_data = configuration_data()
  41 genh = []
  42
  43 target_dirs = config_host['TARGET_DIRS'].split()
  44 have_user = false
  45 have_system = false
  46 foreach target : target_dirs
  47   have_user = have_user or target.endswith('-user')
  48   have_system = have_system or target.endswith('-softmmu')
  49 endforeach
  50 have_tools = 'CONFIG_TOOLS' in config_host
  51 have_block = have_system or have_tools
  52
  53 python = import('python').find_installation()
  54
  55 supported_oses = ['windows', 'freebsd', 'netbsd', 'openbsd', 'darwin', 'sunos', 'linux']
  56 supported_cpus = ['ppc', 'ppc64', 's390x', 'riscv32', 'riscv64', 'x86', 'x86_64',
  57   'arm', 'aarch64', 'mips', 'mips64', 'sparc', 'sparc64']
  58
  59 cpu = host_machine.cpu_family()
  60 targetos = host_machine.system()
  61
  62 if cpu in ['x86', 'x86_64']
  63   kvm_targets = ['i386-softmmu', 'x86_64-softmmu']
  64 elif cpu == 'aarch64'
  65   kvm_targets = ['aarch64-softmmu']
  66 elif cpu == 's390x'
  67   kvm_targets = ['s390x-softmmu']
  68 elif cpu in ['ppc', 'ppc64']
  69   kvm_targets = ['ppc-softmmu', 'ppc64-softmmu']
  70 elif cpu in ['mips', 'mips64']
  71   kvm_targets = ['mips-softmmu', 'mipsel-softmmu', 'mips64-softmmu', 'mips64el-softmmu']
  72 else
  73   kvm_targets = []
  74 endif
  75
  76 accelerator_targets = { 'CONFIG_KVM': kvm_targets }
  77 if cpu in ['x86', 'x86_64', 'arm', 'aarch64']
  78   # i368 emulator provides xenpv machine type for multiple architectures
  79   accelerator_targets += {
  80     'CONFIG_XEN': ['i386-softmmu', 'x86_64-softmmu'],
  81   }
  82 endif
  83 if cpu in ['x86', 'x86_64']
  84   accelerator_targets += {
  85     'CONFIG_HAX': ['i386-softmmu', 'x86_64-softmmu'],
  86     'CONFIG_HVF': ['x86_64-softmmu'],
  87     'CONFIG_WHPX': ['i386-softmmu', 'x86_64-softmmu'],
  88   }
  89 endif
  90
  91 ##################
  92 # Compiler flags #
  93 ##################
  94
  95 # Specify linker-script with add_project_link_arguments so that it is not placed
  96 # within a linker --start-group/--end-group pair
  97 if 'CONFIG_FUZZ' in config_host
  98    add_project_link_arguments(['-Wl,-T,',
  99                                (meson.current_source_dir() / 'tests/qtest/fuzz/fork_fuzz.ld')],
 100                               native: false, language: ['c', 'cpp', 'objc'])
 101 endif
 102
 103 add_project_arguments(config_host['QEMU_CFLAGS'].split(),
 104                       native: false, language: ['c', 'objc'])
 105 add_project_arguments(config_host['QEMU_CXXFLAGS'].split(),
 106                       native: false, language: 'cpp')
 107 add_project_link_arguments(config_host['QEMU_LDFLAGS'].split(),
 108                            native: false, language: ['c', 'cpp', 'objc'])
 109
 110 if targetos == 'linux'
 111   add_project_arguments('-isystem', meson.current_source_dir() / 'linux-headers',
 112                         '-isystem', 'linux-headers',
 113                         language: ['c', 'cpp'])
 114 endif
 115
 116 if 'CONFIG_TCG_INTERPRETER' in config_host
 117   tcg_arch = 'tci'
 118 elif config_host['ARCH'] == 'sparc64'
 119   tcg_arch = 'sparc'
 120 elif config_host['ARCH'] == 's390x'
 121   tcg_arch = 's390'
 122 elif config_host['ARCH'] in ['x86_64', 'x32']
 123   tcg_arch = 'i386'
 124 elif config_host['ARCH'] == 'ppc64'
 125   tcg_arch = 'ppc'
 126 elif config_host['ARCH'] in ['riscv32', 'riscv64']
 127   tcg_arch = 'riscv'
 128 else
 129   tcg_arch = config_host['ARCH']
 130 endif
 131 add_project_arguments('-iquote', meson.current_source_dir() / 'tcg' / tcg_arch,
 132                       '-iquote', '.',
 133                       '-iquote', meson.current_source_dir(),
 134                       '-iquote', meson.current_source_dir() / 'accel/tcg',
 135                       '-iquote', meson.current_source_dir() / 'include',
 136                       '-iquote', meson.current_source_dir() / 'disas/libvixl',
 137                       language: ['c', 'cpp', 'objc'])
 138
 139 link_language = meson.get_external_property('link_language', 'cpp')
 140 if link_language == 'cpp'
 141   add_languages('cpp', required: true, native: false)
 142 endif
 143 if host_machine.system() == 'darwin'
 144   add_languages('objc', required: false, native: false)
 145 endif
 146
 147 sparse = find_program('cgcc', required: get_option('sparse'))
 148 if sparse.found()
 149   run_target('sparse',
 150              command: [find_program('scripts/check_sparse.py'),
 151                        'compile_commands.json', sparse.full_path(), '-Wbitwise',
 152                        '-Wno-transparent-union', '-Wno-old-initializer',
 153                        '-Wno-non-pointer-null'])
 154 endif
 155
 156 ###########################################
 157 # Target-specific checks and dependencies #
 158 ###########################################
 159
 160 if targetos != 'linux' and get_option('mpath').enabled()
 161   error('Multipath is supported only on Linux')
 162 endif
 163
 164 m = cc.find_library('m', required: false)
 165 util = cc.find_library('util', required: false)
 166 winmm = []
 167 socket = []
 168 version_res = []
 169 coref = []
 170 iokit = []
 171 emulator_link_args = []
 172 cocoa = not_found
 173 hvf = not_found
 174 if targetos == 'windows'
 175   socket = cc.find_library('ws2_32')
 176   winmm = cc.find_library('winmm')
 177
 178   win = import('windows')
 179   version_res = win.compile_resources('version.rc',
 180                                       depend_files: files('pc-bios/qemu-nsis.ico'),
 181                                       include_directories: include_directories('.'))
 182 elif targetos == 'darwin'
 183   coref = dependency('appleframeworks', modules: 'CoreFoundation')
 184   iokit = dependency('appleframeworks', modules: 'IOKit')
 185   cocoa = dependency('appleframeworks', modules: 'Cocoa', required: get_option('cocoa'))
 186 elif targetos == 'sunos'
 187   socket = [cc.find_library('socket'),
 188             cc.find_library('nsl'),
 189             cc.find_library('resolv')]
 190 elif targetos == 'haiku'
 191   socket = [cc.find_library('posix_error_mapper'),
 192             cc.find_library('network'),
 193             cc.find_library('bsd')]
 194 elif targetos == 'openbsd'
 195   if not get_option('tcg').disabled() and target_dirs.length() > 0
 196     # Disable OpenBSD W^X if available
 197     emulator_link_args = cc.get_supported_link_arguments('-Wl,-z,wxneeded')
 198   endif
 199 endif
 200
 201 accelerators = []
 202 if not get_option('kvm').disabled() and targetos == 'linux'
 203   accelerators += 'CONFIG_KVM'
 204 endif
 205 if not get_option('xen').disabled() and 'CONFIG_XEN_BACKEND' in config_host
 206   accelerators += 'CONFIG_XEN'
 207   have_xen_pci_passthrough = not get_option('xen_pci_passthrough').disabled() and targetos == 'linux'
 208 else
 209   have_xen_pci_passthrough = false
 210 endif
 211 if not get_option('whpx').disabled() and targetos == 'windows'
 212   if get_option('whpx').enabled() and host_machine.cpu() != 'x86_64'
 213     error('WHPX requires 64-bit host')
 214   elif cc.has_header('WinHvPlatform.h', required: get_option('whpx')) and \
 215        cc.has_header('WinHvEmulation.h', required: get_option('whpx'))
 216     accelerators += 'CONFIG_WHPX'
 217   endif
 218 endif
 219 if not get_option('hvf').disabled()
 220   hvf = dependency('appleframeworks', modules: 'Hypervisor',
 221                    required: get_option('hvf'))
 222   if hvf.found()
 223     accelerators += 'CONFIG_HVF'
 224   endif
 225 endif
 226 if not get_option('hax').disabled()
 227   if get_option('hax').enabled() or targetos in ['windows', 'darwin', 'netbsd']
 228     accelerators += 'CONFIG_HAX'
 229   endif
 230 endif
 231 if not get_option('tcg').disabled()
 232   if cpu not in supported_cpus
 233     if 'CONFIG_TCG_INTERPRETER' in config_host
 234       warning('Unsupported CPU @0@, will use TCG with TCI (experimental)'.format(cpu))
 235     else
 236       error('Unsupported CPU @0@, try --enable-tcg-interpreter'.format(cpu))
 237     endif
 238   endif
 239   accelerators += 'CONFIG_TCG'
 240   config_host += { 'CONFIG_TCG': 'y' }
 241 endif
 242
 243 if 'CONFIG_KVM' not in accelerators and get_option('kvm').enabled()
 244   error('KVM not available on this platform')
 245 endif
 246 if 'CONFIG_HVF' not in accelerators and get_option('hvf').enabled()
 247   error('HVF not available on this platform')
 248 endif
 249 if 'CONFIG_WHPX' not in accelerators and get_option('whpx').enabled()
 250   error('WHPX not available on this platform')
 251 endif
 252 if not have_xen_pci_passthrough and get_option('xen_pci_passthrough').enabled()
 253   if 'CONFIG_XEN' in accelerators
 254     error('Xen PCI passthrough not available on this platform')
 255   else
 256     error('Xen PCI passthrough requested but Xen not enabled')
 257   endif
 258 endif
 259 if not cocoa.found() and get_option('cocoa').enabled()
 260   error('Cocoa not available on this platform')
 261 endif
 262
 263 ################
 264 # Dependencies #
 265 ################
 266
 267 # The path to glib.h is added to all compilation commands.  This was
 268 # grandfathered in from the QEMU Makefiles.
 269 add_project_arguments(config_host['GLIB_CFLAGS'].split(),
 270                       native: false, language: ['c', 'cpp', 'objc'])
 271 glib = declare_dependency(link_args: config_host['GLIB_LIBS'].split())
 272 gio = not_found
 273 if 'CONFIG_GIO' in config_host
 274   gio = declare_dependency(compile_args: config_host['GIO_CFLAGS'].split(),
 275                            link_args: config_host['GIO_LIBS'].split())
 276 endif
 277 lttng = not_found
 278 if 'CONFIG_TRACE_UST' in config_host
 279   lttng = declare_dependency(link_args: config_host['LTTNG_UST_LIBS'].split())
 280 endif
 281 urcubp = not_found
 282 if 'CONFIG_TRACE_UST' in config_host
 283   urcubp = declare_dependency(link_args: config_host['URCU_BP_LIBS'].split())
 284 endif
 285 gcrypt = not_found
 286 if 'CONFIG_GCRYPT' in config_host
 287   gcrypt = declare_dependency(compile_args: config_host['GCRYPT_CFLAGS'].split(),
 288                               link_args: config_host['GCRYPT_LIBS'].split())
 289 endif
 290 nettle = not_found
 291 if 'CONFIG_NETTLE' in config_host
 292   nettle = declare_dependency(compile_args: config_host['NETTLE_CFLAGS'].split(),
 293                               link_args: config_host['NETTLE_LIBS'].split())
 294 endif
 295 gnutls = not_found
 296 if 'CONFIG_GNUTLS' in config_host
 297   gnutls = declare_dependency(compile_args: config_host['GNUTLS_CFLAGS'].split(),
 298                               link_args: config_host['GNUTLS_LIBS'].split())
 299 endif
 300 pixman = not_found
 301 if have_system or have_tools
 302   pixman = dependency('pixman-1', required: have_system, version:'>=0.21.8',
 303                       method: 'pkg-config', static: enable_static)
 304 endif
 305 pam = not_found
 306 if 'CONFIG_AUTH_PAM' in config_host
 307   pam = cc.find_library('pam')
 308 endif
 309 libaio = cc.find_library('aio', required: false)
 310 zlib = dependency('zlib', required: true, static: enable_static)
 311 linux_io_uring = not_found
 312 if 'CONFIG_LINUX_IO_URING' in config_host
 313   linux_io_uring = declare_dependency(compile_args: config_host['LINUX_IO_URING_CFLAGS'].split(),
 314                                       link_args: config_host['LINUX_IO_URING_LIBS'].split())
 315 endif
 316 libxml2 = not_found
 317 if 'CONFIG_LIBXML2' in config_host
 318   libxml2 = declare_dependency(compile_args: config_host['LIBXML2_CFLAGS'].split(),
 319                                link_args: config_host['LIBXML2_LIBS'].split())
 320 endif
 321 libnfs = not_found
 322 if 'CONFIG_LIBNFS' in config_host
 323   libnfs = declare_dependency(link_args: config_host['LIBNFS_LIBS'].split())
 324 endif
 325 libattr = not_found
 326 if 'CONFIG_ATTR' in config_host
 327   libattr = declare_dependency(link_args: config_host['LIBATTR_LIBS'].split())
 328 endif
 329 seccomp = not_found
 330 if 'CONFIG_SECCOMP' in config_host
 331   seccomp = declare_dependency(compile_args: config_host['SECCOMP_CFLAGS'].split(),
 332                                link_args: config_host['SECCOMP_LIBS'].split())
 333 endif
 334 libcap_ng = not_found
 335 if 'CONFIG_LIBCAP_NG' in config_host
 336   libcap_ng = declare_dependency(link_args: config_host['LIBCAP_NG_LIBS'].split())
 337 endif
 338 if get_option('xkbcommon').auto() and not have_system and not have_tools
 339   xkbcommon = not_found
 340 else
 341   xkbcommon = dependency('xkbcommon', required: get_option('xkbcommon'),
 342                          method: 'pkg-config', static: enable_static)
 343 endif
 344 vde = not_found
 345 if config_host.has_key('CONFIG_VDE')
 346   vde = declare_dependency(link_args: config_host['VDE_LIBS'].split())
 347 endif
 348 pulse = not_found
 349 if 'CONFIG_LIBPULSE' in config_host
 350   pulse = declare_dependency(compile_args: config_host['PULSE_CFLAGS'].split(),
 351                              link_args: config_host['PULSE_LIBS'].split())
 352 endif
 353 alsa = not_found
 354 if 'CONFIG_ALSA' in config_host
 355   alsa = declare_dependency(compile_args: config_host['ALSA_CFLAGS'].split(),
 356                             link_args: config_host['ALSA_LIBS'].split())
 357 endif
 358 jack = not_found
 359 if 'CONFIG_LIBJACK' in config_host
 360   jack = declare_dependency(link_args: config_host['JACK_LIBS'].split())
 361 endif
 362 spice = not_found
 363 spice_headers = not_found
 364 if 'CONFIG_SPICE' in config_host
 365   spice = declare_dependency(compile_args: config_host['SPICE_CFLAGS'].split(),
 366                              link_args: config_host['SPICE_LIBS'].split())
 367   spice_headers = declare_dependency(compile_args: config_host['SPICE_CFLAGS'].split())
 368 endif
 369 rt = cc.find_library('rt', required: false)
 370 libdl = not_found
 371 if 'CONFIG_PLUGIN' in config_host
 372   libdl = cc.find_library('dl', required: true)
 373 endif
 374 libiscsi = not_found
 375 if 'CONFIG_LIBISCSI' in config_host
 376   libiscsi = declare_dependency(compile_args: config_host['LIBISCSI_CFLAGS'].split(),
 377                                 link_args: config_host['LIBISCSI_LIBS'].split())
 378 endif
 379 zstd = not_found
 380 if 'CONFIG_ZSTD' in config_host
 381   zstd = declare_dependency(compile_args: config_host['ZSTD_CFLAGS'].split(),
 382                             link_args: config_host['ZSTD_LIBS'].split())
 383 endif
 384 gbm = not_found
 385 if 'CONFIG_GBM' in config_host
 386   gbm = declare_dependency(compile_args: config_host['GBM_CFLAGS'].split(),
 387                            link_args: config_host['GBM_LIBS'].split())
 388 endif
 389 virgl = not_found
 390 if 'CONFIG_VIRGL' in config_host
 391   virgl = declare_dependency(compile_args: config_host['VIRGL_CFLAGS'].split(),
 392                              link_args: config_host['VIRGL_LIBS'].split())
 393 endif
 394 curl = not_found
 395 if 'CONFIG_CURL' in config_host
 396   curl = declare_dependency(compile_args: config_host['CURL_CFLAGS'].split(),
 397                             link_args: config_host['CURL_LIBS'].split())
 398 endif
 399 libudev = not_found
 400 if targetos == 'linux' and (have_system or have_tools)
 401   libudev = dependency('libudev',
 402                        required: get_option('libudev'),
 403                        static: enable_static)
 404 endif
 405
 406 mpathlibs = [libudev]
 407 mpathpersist = not_found
 408 mpathpersist_new_api = false
 409 if targetos == 'linux' and have_tools and not get_option('mpath').disabled()
 410   mpath_test_source_new = '''
 411     #include <libudev.h>
 412     #include <mpath_persist.h>
 413     unsigned mpath_mx_alloc_len = 1024;
 414     int logsink;
 415     static struct config *multipath_conf;
 416     extern struct udev *udev;
 417     extern struct config *get_multipath_config(void);
 418     extern void put_multipath_config(struct config *conf);
 419     struct udev *udev;
 420     struct config *get_multipath_config(void) { return multipath_conf; }
 421     void put_multipath_config(struct config *conf) { }
 422     int main(void) {
 423         udev = udev_new();
 424         multipath_conf = mpath_lib_init();
 425         return 0;
 426     }'''
 427   mpath_test_source_old = '''
 428       #include <libudev.h>
 429       #include <mpath_persist.h>
 430       unsigned mpath_mx_alloc_len = 1024;
 431       int logsink;
 432       int main(void) {
 433           struct udev *udev = udev_new();
 434           mpath_lib_init(udev);
 435           return 0;
 436       }'''
 437   libmpathpersist = cc.find_library('mpathpersist',
 438                                     required: get_option('mpath'),
 439                                     static: enable_static)
 440   if libmpathpersist.found()
 441     mpathlibs += libmpathpersist
 442     if enable_static
 443       mpathlibs += cc.find_library('devmapper',
 444                                      required: get_option('mpath'),
 445                                      static: enable_static)
 446     endif
 447     mpathlibs += cc.find_library('multipath',
 448                                  required: get_option('mpath'),
 449                                  static: enable_static)
 450     foreach lib: mpathlibs
 451       if not lib.found()
 452         mpathlibs = []
 453         break
 454       endif
 455     endforeach
 456     if mpathlibs.length() == 0
 457       msg = 'Dependencies missing for libmpathpersist'
 458     elif cc.links(mpath_test_source_new, dependencies: mpathlibs)
 459       mpathpersist = declare_dependency(dependencies: mpathlibs)
 460       mpathpersist_new_api = true
 461     elif cc.links(mpath_test_source_old, dependencies: mpathlibs)
 462       mpathpersist = declare_dependency(dependencies: mpathlibs)
 463     else
 464       msg = 'Cannot detect libmpathpersist API'
 465     endif
 466     if not mpathpersist.found()
 467       if get_option('mpath').enabled()
 468         error(msg)
 469       else
 470         warning(msg + ', disabling')
 471       endif
 472     endif
 473   endif
 474 endif
 475
 476 iconv = not_found
 477 curses = not_found
 478 if have_system and not get_option('curses').disabled()
 479   curses_test = '''
 480     #include <locale.h>
 481     #include <curses.h>
 482     #include <wchar.h>
 483     int main(void) {
 484       wchar_t wch = L'w';
 485       setlocale(LC_ALL, "");
 486       resize_term(0, 0);
 487       addwstr(L"wide chars\n");
 488       addnwstr(&wch, 1);
 489       add_wch(WACS_DEGREE);
 490       return 0;
 491     }'''
 492
 493   curses_dep_list = targetos == 'windows' ? ['ncurses', 'ncursesw'] : ['ncursesw']
 494   foreach curses_dep : curses_dep_list
 495     if not curses.found()
 496       curses = dependency(curses_dep,
 497                           required: false,
 498                           method: 'pkg-config',
 499                           static: enable_static)
 500     endif
 501   endforeach
 502   msg = get_option('curses').enabled() ? 'curses library not found' : ''
 503   if curses.found()
 504     if cc.links(curses_test, dependencies: [curses])
 505       curses = declare_dependency(compile_args: '-DNCURSES_WIDECHAR', dependencies: [curses])
 506     else
 507       msg = 'curses package not usable'
 508       curses = not_found
 509     endif
 510   endif
 511   if not curses.found()
 512     curses_compile_args = ['-DNCURSES_WIDECHAR']
 513     has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
 514     if targetos != 'windows' and not has_curses_h
 515       message('Trying with /usr/include/ncursesw')
 516       curses_compile_args += ['-I/usr/include/ncursesw']
 517       has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
 518     endif
 519     if has_curses_h
 520       curses_libname_list = (targetos == 'windows' ? ['pdcurses'] : ['ncursesw', 'cursesw'])
 521       foreach curses_libname : curses_libname_list
 522         libcurses = cc.find_library(curses_libname,
 523                                     required: false,
 524                                     static: enable_static)
 525         if libcurses.found()
 526           if cc.links(curses_test, args: curses_compile_args, dependencies: libcurses)
 527             curses = declare_dependency(compile_args: curses_compile_args,
 528                                         dependencies: [libcurses])
 529             break
 530           else
 531             msg = 'curses library not usable'
 532           endif
 533         endif
 534       endforeach
 535     endif
 536   endif
 537   if not get_option('iconv').disabled()
 538     foreach link_args : [ ['-liconv'], [] ]
 539       # Programs will be linked with glib and this will bring in libiconv on FreeBSD.
 540       # We need to use libiconv if available because mixing libiconv's headers with
 541       # the system libc does not work.
 542       # However, without adding glib to the dependencies -L/usr/local/lib will not be
 543       # included in the command line and libiconv will not be found.
 544       if cc.links('''
 545         #include <iconv.h>
 546         int main(void) {
 547           iconv_t conv = iconv_open("WCHAR_T", "UCS-2");
 548           return conv != (iconv_t) -1;
 549         }''', args: config_host['GLIB_CFLAGS'].split() + config_host['GLIB_LIBS'].split() + link_args)
 550         iconv = declare_dependency(link_args: link_args, dependencies: glib)
 551         break
 552       endif
 553     endforeach
 554   endif
 555   if curses.found() and not iconv.found()
 556     if get_option('iconv').enabled()
 557       error('iconv not available')
 558     endif
 559     msg = 'iconv required for curses UI but not available'
 560     curses = not_found
 561   endif
 562   if not curses.found() and msg != ''
 563     if get_option('curses').enabled()
 564       error(msg)
 565     else
 566       warning(msg + ', disabling')
 567     endif
 568   endif
 569 endif
 570
 571 brlapi = not_found
 572 if 'CONFIG_BRLAPI' in config_host
 573   brlapi = declare_dependency(link_args: config_host['BRLAPI_LIBS'].split())
 574 endif
 575
 576 sdl = not_found
 577 if have_system
 578   sdl = dependency('sdl2', required: get_option('sdl'), static: enable_static)
 579   sdl_image = not_found
 580 endif
 581 if sdl.found()
 582   # work around 2.0.8 bug
 583   sdl = declare_dependency(compile_args: '-Wno-undef',
 584                            dependencies: sdl)
 585   sdl_image = dependency('SDL2_image', required: get_option('sdl_image'),
 586                          method: 'pkg-config', static: enable_static)
 587 else
 588   if get_option('sdl_image').enabled()
 589     error('sdl-image required, but SDL was @0@'.format(
 590           get_option('sdl').disabled() ? 'disabled' : 'not found'))
 591   endif
 592   sdl_image = not_found
 593 endif
 594
 595 rbd = not_found
 596 if 'CONFIG_RBD' in config_host
 597   rbd = declare_dependency(link_args: config_host['RBD_LIBS'].split())
 598 endif
 599 glusterfs = not_found
 600 if 'CONFIG_GLUSTERFS' in config_host
 601   glusterfs = declare_dependency(compile_args: config_host['GLUSTERFS_CFLAGS'].split(),
 602                                  link_args: config_host['GLUSTERFS_LIBS'].split())
 603 endif
 604 libssh = not_found
 605 if 'CONFIG_LIBSSH' in config_host
 606   libssh = declare_dependency(compile_args: config_host['LIBSSH_CFLAGS'].split(),
 607                               link_args: config_host['LIBSSH_LIBS'].split())
 608 endif
 609 libbzip2 = not_found
 610 if 'CONFIG_BZIP2' in config_host
 611   libbzip2 = declare_dependency(link_args: config_host['BZIP2_LIBS'].split())
 612 endif
 613 liblzfse = not_found
 614 if 'CONFIG_LZFSE' in config_host
 615   liblzfse = declare_dependency(link_args: config_host['LZFSE_LIBS'].split())
 616 endif
 617 oss = not_found
 618 if 'CONFIG_AUDIO_OSS' in config_host
 619   oss = declare_dependency(link_args: config_host['OSS_LIBS'].split())
 620 endif
 621 dsound = not_found
 622 if 'CONFIG_AUDIO_DSOUND' in config_host
 623   dsound = declare_dependency(link_args: config_host['DSOUND_LIBS'].split())
 624 endif
 625 coreaudio = not_found
 626 if 'CONFIG_AUDIO_COREAUDIO' in config_host
 627   coreaudio = declare_dependency(link_args: config_host['COREAUDIO_LIBS'].split())
 628 endif
 629 opengl = not_found
 630 if 'CONFIG_OPENGL' in config_host
 631   opengl = declare_dependency(compile_args: config_host['OPENGL_CFLAGS'].split(),
 632                               link_args: config_host['OPENGL_LIBS'].split())
 633 endif
 634 gtk = not_found
 635 if 'CONFIG_GTK' in config_host
 636   gtk = declare_dependency(compile_args: config_host['GTK_CFLAGS'].split(),
 637                               link_args: config_host['GTK_LIBS'].split())
 638 endif
 639 vte = not_found
 640 if 'CONFIG_VTE' in config_host
 641   vte = declare_dependency(compile_args: config_host['VTE_CFLAGS'].split(),
 642                            link_args: config_host['VTE_LIBS'].split())
 643 endif
 644 x11 = not_found
 645 if 'CONFIG_X11' in config_host
 646   x11 = declare_dependency(compile_args: config_host['X11_CFLAGS'].split(),
 647                            link_args: config_host['X11_LIBS'].split())
 648 endif
 649 vnc = not_found
 650 png = not_found
 651 jpeg = not_found
 652 sasl = not_found
 653 if get_option('vnc').enabled()
 654   vnc = declare_dependency() # dummy dependency
 655   png = dependency('libpng', required: get_option('vnc_png'),
 656                    method: 'pkg-config', static: enable_static)
 657   jpeg = dependency('libjpeg', required: get_option('vnc_jpeg'),
 658                     method: 'pkg-config', static: enable_static)
 659   sasl = cc.find_library('sasl2', has_headers: ['sasl/sasl.h'],
 660                          required: get_option('vnc_sasl'),
 661                          static: enable_static)
 662   if sasl.found()
 663     sasl = declare_dependency(dependencies: sasl,
 664                               compile_args: '-DSTRUCT_IOVEC_DEFINED')
 665   endif
 666 endif
 667 snappy = not_found
 668 if 'CONFIG_SNAPPY' in config_host
 669   snappy = declare_dependency(link_args: config_host['SNAPPY_LIBS'].split())
 670 endif
 671 lzo = not_found
 672 if 'CONFIG_LZO' in config_host
 673   lzo = declare_dependency(link_args: config_host['LZO_LIBS'].split())
 674 endif
 675 rdma = not_found
 676 if 'CONFIG_RDMA' in config_host
 677   rdma = declare_dependency(link_args: config_host['RDMA_LIBS'].split())
 678 endif
 679 numa = not_found
 680 if 'CONFIG_NUMA' in config_host
 681   numa = declare_dependency(link_args: config_host['NUMA_LIBS'].split())
 682 endif
 683 xen = not_found
 684 if 'CONFIG_XEN_BACKEND' in config_host
 685   xen = declare_dependency(compile_args: config_host['XEN_CFLAGS'].split(),
 686                            link_args: config_host['XEN_LIBS'].split())
 687 endif
 688 cacard = not_found
 689 if 'CONFIG_SMARTCARD' in config_host
 690   cacard = declare_dependency(compile_args: config_host['SMARTCARD_CFLAGS'].split(),
 691                               link_args: config_host['SMARTCARD_LIBS'].split())
 692 endif
 693 u2f = not_found
 694 if have_system
 695   u2f = dependency('u2f-emu', required: get_option('u2f'),
 696                    method: 'pkg-config',
 697                    static: enable_static)
 698 endif
 699 usbredir = not_found
 700 if 'CONFIG_USB_REDIR' in config_host
 701   usbredir = declare_dependency(compile_args: config_host['USB_REDIR_CFLAGS'].split(),
 702                                 link_args: config_host['USB_REDIR_LIBS'].split())
 703 endif
 704 libusb = not_found
 705 if 'CONFIG_USB_LIBUSB' in config_host
 706   libusb = declare_dependency(compile_args: config_host['LIBUSB_CFLAGS'].split(),
 707                               link_args: config_host['LIBUSB_LIBS'].split())
 708 endif
 709 libpmem = not_found
 710 if 'CONFIG_LIBPMEM' in config_host
 711   libpmem = declare_dependency(compile_args: config_host['LIBPMEM_CFLAGS'].split(),
 712                                link_args: config_host['LIBPMEM_LIBS'].split())
 713 endif
 714 libdaxctl = not_found
 715 if 'CONFIG_LIBDAXCTL' in config_host
 716   libdaxctl = declare_dependency(link_args: config_host['LIBDAXCTL_LIBS'].split())
 717 endif
 718 tasn1 = not_found
 719 if 'CONFIG_TASN1' in config_host
 720   tasn1 = declare_dependency(compile_args: config_host['TASN1_CFLAGS'].split(),
 721                              link_args: config_host['TASN1_LIBS'].split())
 722 endif
 723 keyutils = dependency('libkeyutils', required: false,
 724                       method: 'pkg-config', static: enable_static)
 725
 726 has_gettid = cc.has_function('gettid')
 727
 728 # Malloc tests
 729
 730 malloc = []
 731 if get_option('malloc') == 'system'
 732   has_malloc_trim = \
 733     not get_option('malloc_trim').disabled() and \
 734     cc.links('''#include <malloc.h>
 735                 int main(void) { malloc_trim(0); return 0; }''')
 736 else
 737   has_malloc_trim = false
 738   malloc = cc.find_library(get_option('malloc'), required: true)
 739 endif
 740 if not has_malloc_trim and get_option('malloc_trim').enabled()
 741   if get_option('malloc') == 'system'
 742     error('malloc_trim not available on this platform.')
 743   else
 744     error('malloc_trim not available with non-libc memory allocator')
 745   endif
 746 endif
 747
 748 # Check whether the glibc provides statx()
 749
 750 statx_test = '''
 751   #ifndef _GNU_SOURCE
 752   #define _GNU_SOURCE
 753   #endif
 754   #include <sys/stat.h>
 755   int main(void) {
 756     struct statx statxbuf;
 757     statx(0, "", 0, STATX_BASIC_STATS, &statxbuf);
 758     return 0;
 759   }'''
 760
 761 has_statx = cc.links(statx_test)
 762
 763 have_vhost_user_blk_server = (targetos == 'linux' and
 764     'CONFIG_VHOST_USER' in config_host)
 765
 766 if get_option('vhost_user_blk_server').enabled()
 767     if targetos != 'linux'
 768         error('vhost_user_blk_server requires linux')
 769     elif 'CONFIG_VHOST_USER' not in config_host
 770         error('vhost_user_blk_server requires vhost-user support')
 771     endif
 772 elif get_option('vhost_user_blk_server').disabled() or not have_system
 773     have_vhost_user_blk_server = false
 774 endif
 775
 776 if get_option('fuse').disabled() and get_option('fuse_lseek').enabled()
 777   error('Cannot enable fuse-lseek while fuse is disabled')
 778 endif
 779
 780 fuse = dependency('fuse3', required: get_option('fuse'),
 781                   version: '>=3.1', method: 'pkg-config',
 782                   static: enable_static)
 783
 784 fuse_lseek = not_found
 785 if not get_option('fuse_lseek').disabled()
 786   if fuse.version().version_compare('>=3.8')
 787     # Dummy dependency
 788     fuse_lseek = declare_dependency()
 789   elif get_option('fuse_lseek').enabled()
 790     if fuse.found()
 791       error('fuse-lseek requires libfuse >=3.8, found ' + fuse.version())
 792     else
 793       error('fuse-lseek requires libfuse, which was not found')
 794     endif
 795   endif
 796 endif
 797
 798 #################
 799 # config-host.h #
 800 #################
 801
 802 config_host_data.set_quoted('CONFIG_BINDIR', get_option('prefix') / get_option('bindir'))
 803 config_host_data.set_quoted('CONFIG_PREFIX', get_option('prefix'))
 804 config_host_data.set_quoted('CONFIG_QEMU_CONFDIR', get_option('prefix') / qemu_confdir)
 805 config_host_data.set_quoted('CONFIG_QEMU_DATADIR', get_option('prefix') / qemu_datadir)
 806 config_host_data.set_quoted('CONFIG_QEMU_DESKTOPDIR', get_option('prefix') / qemu_desktopdir)
 807 config_host_data.set_quoted('CONFIG_QEMU_FIRMWAREPATH', get_option('qemu_firmwarepath'))
 808 config_host_data.set_quoted('CONFIG_QEMU_HELPERDIR', get_option('prefix') / get_option('libexecdir'))
 809 config_host_data.set_quoted('CONFIG_QEMU_ICONDIR', get_option('prefix') / qemu_icondir)
 810 config_host_data.set_quoted('CONFIG_QEMU_LOCALEDIR', get_option('prefix') / get_option('localedir'))
 811 config_host_data.set_quoted('CONFIG_QEMU_LOCALSTATEDIR', get_option('prefix') / get_option('localstatedir'))
 812 config_host_data.set_quoted('CONFIG_QEMU_MODDIR', get_option('prefix') / qemu_moddir)
 813 config_host_data.set_quoted('CONFIG_SYSCONFDIR', get_option('prefix') / get_option('sysconfdir'))
 814
 815 config_host_data.set('CONFIG_COCOA', cocoa.found())
 816 config_host_data.set('CONFIG_LIBUDEV', libudev.found())
 817 config_host_data.set('CONFIG_MPATH', mpathpersist.found())
 818 config_host_data.set('CONFIG_MPATH_NEW_API', mpathpersist_new_api)
 819 config_host_data.set('CONFIG_CURSES', curses.found())
 820 config_host_data.set('CONFIG_SDL', sdl.found())
 821 config_host_data.set('CONFIG_SDL_IMAGE', sdl_image.found())
 822 config_host_data.set('CONFIG_VHOST_USER_BLK_SERVER', have_vhost_user_blk_server)
 823 config_host_data.set('CONFIG_VNC', vnc.found())
 824 config_host_data.set('CONFIG_VNC_JPEG', jpeg.found())
 825 config_host_data.set('CONFIG_VNC_PNG', png.found())
 826 config_host_data.set('CONFIG_VNC_SASL', sasl.found())
 827 config_host_data.set('CONFIG_XKBCOMMON', xkbcommon.found())
 828 config_host_data.set('CONFIG_KEYUTILS', keyutils.found())
 829 config_host_data.set('CONFIG_GETTID', has_gettid)
 830 config_host_data.set('CONFIG_MALLOC_TRIM', has_malloc_trim)
 831 config_host_data.set('CONFIG_STATX', has_statx)
 832 config_host_data.set('CONFIG_FUSE', fuse.found())
 833 config_host_data.set('CONFIG_FUSE_LSEEK', fuse_lseek.found())
 834 config_host_data.set('QEMU_VERSION', '"@0@"'.format(meson.project_version()))
 835 config_host_data.set('QEMU_VERSION_MAJOR', meson.project_version().split('.')[0])
 836 config_host_data.set('QEMU_VERSION_MINOR', meson.project_version().split('.')[1])
 837 config_host_data.set('QEMU_VERSION_MICRO', meson.project_version().split('.')[2])
 838
 839 config_host_data.set('HAVE_DRM_H', cc.has_header('libdrm/drm.h'))
 840 config_host_data.set('HAVE_PTY_H', cc.has_header('pty.h'))
 841 config_host_data.set('HAVE_SYS_IOCCOM_H', cc.has_header('sys/ioccom.h'))
 842
 843 ignored = ['CONFIG_QEMU_INTERP_PREFIX'] # actually per-target
 844 arrays = ['CONFIG_AUDIO_DRIVERS', 'CONFIG_BDRV_RW_WHITELIST', 'CONFIG_BDRV_RO_WHITELIST']
 845 strings = ['HOST_DSOSUF', 'CONFIG_IASL']
 846 foreach k, v: config_host
 847   if ignored.contains(k)
 848     # do nothing
 849   elif arrays.contains(k)
 850     if v != ''
 851       v = '"' + '", "'.join(v.split()) + '", '
 852     endif
 853     config_host_data.set(k, v)
 854   elif k == 'ARCH'
 855     config_host_data.set('HOST_' + v.to_upper(), 1)
 856   elif strings.contains(k)
 857     if not k.startswith('CONFIG_')
 858       k = 'CONFIG_' + k.to_upper()
 859     endif
 860     config_host_data.set_quoted(k, v)
 861   elif k.startswith('CONFIG_') or k.startswith('HAVE_') or k.startswith('HOST_')
 862     config_host_data.set(k, v == 'y' ? 1 : v)
 863   endif
 864 endforeach
 865
 866 ########################
 867 # Target configuration #
 868 ########################
 869
 870 minikconf = find_program('scripts/minikconf.py')
 871 config_all = {}
 872 config_all_devices = {}
 873 config_all_disas = {}
 874 config_devices_mak_list = []
 875 config_devices_h = {}
 876 config_target_h = {}
 877 config_target_mak = {}
 878
 879 disassemblers = {
 880   'alpha' : ['CONFIG_ALPHA_DIS'],
 881   'arm' : ['CONFIG_ARM_DIS'],
 882   'avr' : ['CONFIG_AVR_DIS'],
 883   'cris' : ['CONFIG_CRIS_DIS'],
 884   'hppa' : ['CONFIG_HPPA_DIS'],
 885   'i386' : ['CONFIG_I386_DIS'],
 886   'x86_64' : ['CONFIG_I386_DIS'],
 887   'x32' : ['CONFIG_I386_DIS'],
 888   'lm32' : ['CONFIG_LM32_DIS'],
 889   'm68k' : ['CONFIG_M68K_DIS'],
 890   'microblaze' : ['CONFIG_MICROBLAZE_DIS'],
 891   'mips' : ['CONFIG_MIPS_DIS'],
 892   'moxie' : ['CONFIG_MOXIE_DIS'],
 893   'nios2' : ['CONFIG_NIOS2_DIS'],
 894   'or1k' : ['CONFIG_OPENRISC_DIS'],
 895   'ppc' : ['CONFIG_PPC_DIS'],
 896   'riscv' : ['CONFIG_RISCV_DIS'],
 897   'rx' : ['CONFIG_RX_DIS'],
 898   's390' : ['CONFIG_S390_DIS'],
 899   'sh4' : ['CONFIG_SH4_DIS'],
 900   'sparc' : ['CONFIG_SPARC_DIS'],
 901   'xtensa' : ['CONFIG_XTENSA_DIS'],
 902 }
 903 if link_language == 'cpp'
 904   disassemblers += {
 905     'aarch64' : [ 'CONFIG_ARM_A64_DIS'],
 906     'arm' : [ 'CONFIG_ARM_DIS', 'CONFIG_ARM_A64_DIS'],
 907     'mips' : [ 'CONFIG_MIPS_DIS', 'CONFIG_NANOMIPS_DIS'],
 908   }
 909 endif
 910
 911 kconfig_external_symbols = [
 912   'CONFIG_KVM',
 913   'CONFIG_XEN',
 914   'CONFIG_TPM',
 915   'CONFIG_SPICE',
 916   'CONFIG_IVSHMEM',
 917   'CONFIG_OPENGL',
 918   'CONFIG_X11',
 919   'CONFIG_VHOST_USER',
 920   'CONFIG_VHOST_VDPA',
 921   'CONFIG_VHOST_KERNEL',
 922   'CONFIG_VIRTFS',
 923   'CONFIG_LINUX',
 924   'CONFIG_PVRDMA',
 925 ]
 926 ignored = [ 'TARGET_XML_FILES', 'TARGET_ABI_DIR', 'TARGET_ARCH' ]
 927
 928 default_targets = 'CONFIG_DEFAULT_TARGETS' in config_host
 929 actual_target_dirs = []
 930 fdt_required = []
 931 foreach target : target_dirs
 932   config_target = { 'TARGET_NAME': target.split('-')[0] }
 933   if target.endswith('linux-user')
 934     if targetos != 'linux'
 935       if default_targets
 936         continue
 937       endif
 938       error('Target @0@ is only available on a Linux host'.format(target))
 939     endif
 940     config_target += { 'CONFIG_LINUX_USER': 'y' }
 941   elif target.endswith('bsd-user')
 942     if 'CONFIG_BSD' not in config_host
 943       if default_targets
 944         continue
 945       endif
 946       error('Target @0@ is only available on a BSD host'.format(target))
 947     endif
 948     config_target += { 'CONFIG_BSD_USER': 'y' }
 949   elif target.endswith('softmmu')
 950     config_target += { 'CONFIG_SOFTMMU': 'y' }
 951   endif
 952   if target.endswith('-user')
 953     config_target += {
 954       'CONFIG_USER_ONLY': 'y',
 955       'CONFIG_QEMU_INTERP_PREFIX':
 956         config_host['CONFIG_QEMU_INTERP_PREFIX'].format(config_target['TARGET_NAME'])
 957     }
 958   endif
 959
 960   have_accel = false
 961   foreach sym: accelerators
 962     if sym == 'CONFIG_TCG' or target in accelerator_targets.get(sym, [])
 963       config_target += { sym: 'y' }
 964       config_all += { sym: 'y' }
 965       if sym == 'CONFIG_XEN' and have_xen_pci_passthrough
 966         config_target += { 'CONFIG_XEN_PCI_PASSTHROUGH': 'y' }
 967       endif
 968       have_accel = true
 969     endif
 970   endforeach
 971   if not have_accel
 972     if default_targets
 973       continue
 974     endif
 975     error('No accelerator available for target @0@'.format(target))
 976   endif
 977
 978   actual_target_dirs += target
 979   config_target += keyval.load('default-configs/targets' / target + '.mak')
 980   config_target += { 'TARGET_' + config_target['TARGET_ARCH'].to_upper(): 'y' }
 981
 982   if 'TARGET_NEED_FDT' in config_target
 983     fdt_required += target
 984   endif
 985
 986   # Add default keys
 987   if 'TARGET_BASE_ARCH' not in config_target
 988     config_target += {'TARGET_BASE_ARCH': config_target['TARGET_ARCH']}
 989   endif
 990   if 'TARGET_ABI_DIR' not in config_target
 991     config_target += {'TARGET_ABI_DIR': config_target['TARGET_ARCH']}
 992   endif
 993
 994   foreach k, v: disassemblers
 995     if config_host['ARCH'].startswith(k) or config_target['TARGET_BASE_ARCH'].startswith(k)
 996       foreach sym: v
 997         config_target += { sym: 'y' }
 998         config_all_disas += { sym: 'y' }
 999       endforeach
1000     endif
1001   endforeach
1002
1003   config_target_data = configuration_data()
1004   foreach k, v: config_target
1005     if not k.startswith('TARGET_') and not k.startswith('CONFIG_')
1006       # do nothing
1007     elif ignored.contains(k)
1008       # do nothing
1009     elif k == 'TARGET_BASE_ARCH'
1010       # Note that TARGET_BASE_ARCH ends up in config-target.h but it is
1011       # not used to select files from sourcesets.
1012       config_target_data.set('TARGET_' + v.to_upper(), 1)
1013     elif k == 'TARGET_NAME' or k == 'CONFIG_QEMU_INTERP_PREFIX'
1014       config_target_data.set_quoted(k, v)
1015     elif v == 'y'
1016       config_target_data.set(k, 1)
1017     else
1018       config_target_data.set(k, v)
1019     endif
1020   endforeach
1021   config_target_h += {target: configure_file(output: target + '-config-target.h',
1022                                                configuration: config_target_data)}
1023
1024   if target.endswith('-softmmu')
1025     base_kconfig = []
1026     foreach sym : kconfig_external_symbols
1027       if sym in config_target or sym in config_host
1028         base_kconfig += '@0@=y'.format(sym)
1029       endif
1030     endforeach
1031
1032     config_devices_mak = target + '-config-devices.mak'
1033     config_devices_mak = configure_file(
1034       input: ['default-configs/devices' / target + '.mak', 'Kconfig'],
1035       output: config_devices_mak,
1036       depfile: config_devices_mak + '.d',
1037       capture: true,
1038       command: [minikconf, config_host['CONFIG_MINIKCONF_MODE'],
1039                 config_devices_mak, '@DEPFILE@', '@INPUT@',
1040                 base_kconfig])
1041
1042     config_devices_data = configuration_data()
1043     config_devices = keyval.load(config_devices_mak)
1044     foreach k, v: config_devices
1045       config_devices_data.set(k, 1)
1046     endforeach
1047     config_devices_mak_list += config_devices_mak
1048     config_devices_h += {target: configure_file(output: target + '-config-devices.h',
1049                                                 configuration: config_devices_data)}
1050     config_target += config_devices
1051     config_all_devices += config_devices
1052   endif
1053   config_target_mak += {target: config_target}
1054 endforeach
1055 target_dirs = actual_target_dirs
1056
1057 # This configuration is used to build files that are shared by
1058 # multiple binaries, and then extracted out of the "common"
1059 # static_library target.
1060 #
1061 # We do not use all_sources()/all_dependencies(), because it would
1062 # build literally all source files, including devices only used by
1063 # targets that are not built for this compilation.  The CONFIG_ALL
1064 # pseudo symbol replaces it.
1065
1066 config_all += config_all_devices
1067 config_all += config_host
1068 config_all += config_all_disas
1069 config_all += {
1070   'CONFIG_XEN': config_host.has_key('CONFIG_XEN_BACKEND'),
1071   'CONFIG_SOFTMMU': have_system,
1072   'CONFIG_USER_ONLY': have_user,
1073   'CONFIG_ALL': true,
1074 }
1075
1076 ##############
1077 # Submodules #
1078 ##############
1079
1080 capstone = not_found
1081 capstone_opt = get_option('capstone')
1082 if capstone_opt in ['enabled', 'auto', 'system']
1083   have_internal = fs.exists(meson.current_source_dir() / 'capstone/Makefile')
1084   capstone = dependency('capstone', version: '>=4.0',
1085                         static: enable_static, method: 'pkg-config',
1086                         required: capstone_opt == 'system' or
1087                                   capstone_opt == 'enabled' and not have_internal)
1088   if capstone.found()
1089     capstone_opt = 'system'
1090   elif have_internal
1091     capstone_opt = 'internal'
1092   else
1093     capstone_opt = 'disabled'
1094   endif
1095 endif
1096 if capstone_opt == 'internal'
1097   capstone_data = configuration_data()
1098   capstone_data.set('CAPSTONE_USE_SYS_DYN_MEM', '1')
1099
1100   capstone_files = files(
1101     'capstone/cs.c',
1102     'capstone/MCInst.c',
1103     'capstone/MCInstrDesc.c',
1104     'capstone/MCRegisterInfo.c',
1105     'capstone/SStream.c',
1106     'capstone/utils.c'
1107   )
1108
1109   if 'CONFIG_ARM_DIS' in config_all_disas
1110     capstone_data.set('CAPSTONE_HAS_ARM', '1')
1111     capstone_files += files(
1112       'capstone/arch/ARM/ARMDisassembler.c',
1113       'capstone/arch/ARM/ARMInstPrinter.c',
1114       'capstone/arch/ARM/ARMMapping.c',
1115       'capstone/arch/ARM/ARMModule.c'
1116     )
1117   endif
1118
1119   # FIXME: This config entry currently depends on a c++ compiler.
1120   # Which is needed for building libvixl, but not for capstone.
1121   if 'CONFIG_ARM_A64_DIS' in config_all_disas
1122     capstone_data.set('CAPSTONE_HAS_ARM64', '1')
1123     capstone_files += files(
1124       'capstone/arch/AArch64/AArch64BaseInfo.c',
1125       'capstone/arch/AArch64/AArch64Disassembler.c',
1126       'capstone/arch/AArch64/AArch64InstPrinter.c',
1127       'capstone/arch/AArch64/AArch64Mapping.c',
1128       'capstone/arch/AArch64/AArch64Module.c'
1129     )
1130   endif
1131
1132   if 'CONFIG_PPC_DIS' in config_all_disas
1133     capstone_data.set('CAPSTONE_HAS_POWERPC', '1')
1134     capstone_files += files(
1135       'capstone/arch/PowerPC/PPCDisassembler.c',
1136       'capstone/arch/PowerPC/PPCInstPrinter.c',
1137       'capstone/arch/PowerPC/PPCMapping.c',
1138       'capstone/arch/PowerPC/PPCModule.c'
1139     )
1140   endif
1141
1142   if 'CONFIG_S390_DIS' in config_all_disas
1143     capstone_data.set('CAPSTONE_HAS_SYSZ', '1')
1144     capstone_files += files(
1145       'capstone/arch/SystemZ/SystemZDisassembler.c',
1146       'capstone/arch/SystemZ/SystemZInstPrinter.c',
1147       'capstone/arch/SystemZ/SystemZMapping.c',
1148       'capstone/arch/SystemZ/SystemZModule.c',
1149       'capstone/arch/SystemZ/SystemZMCTargetDesc.c'
1150     )
1151   endif
1152
1153   if 'CONFIG_I386_DIS' in config_all_disas
1154     capstone_data.set('CAPSTONE_HAS_X86', 1)
1155     capstone_files += files(
1156       'capstone/arch/X86/X86Disassembler.c',
1157       'capstone/arch/X86/X86DisassemblerDecoder.c',
1158       'capstone/arch/X86/X86ATTInstPrinter.c',
1159       'capstone/arch/X86/X86IntelInstPrinter.c',
1160       'capstone/arch/X86/X86InstPrinterCommon.c',
1161       'capstone/arch/X86/X86Mapping.c',
1162       'capstone/arch/X86/X86Module.c'
1163     )
1164   endif
1165
1166   configure_file(output: 'capstone-defs.h', configuration: capstone_data)
1167
1168   capstone_cargs = [
1169     # FIXME: There does not seem to be a way to completely replace the c_args
1170     # that come from add_project_arguments() -- we can only add to them.
1171     # So: disable all warnings with a big hammer.
1172     '-Wno-error', '-w',
1173
1174     # Include all configuration defines via a header file, which will wind up
1175     # as a dependency on the object file, and thus changes here will result
1176     # in a rebuild.
1177     '-include', 'capstone-defs.h'
1178   ]
1179
1180   libcapstone = static_library('capstone',
1181                                sources: capstone_files,
1182                                c_args: capstone_cargs,
1183                                include_directories: 'capstone/include')
1184   capstone = declare_dependency(link_with: libcapstone,
1185                                 include_directories: 'capstone/include/capstone')
1186 endif
1187
1188 slirp = not_found
1189 slirp_opt = 'disabled'
1190 if have_system
1191   slirp_opt = get_option('slirp')
1192   if slirp_opt in ['enabled', 'auto', 'system']
1193     have_internal = fs.exists(meson.current_source_dir() / 'slirp/meson.build')
1194     slirp = dependency('slirp', static: enable_static,
1195                        method: 'pkg-config',
1196                        required: slirp_opt == 'system' or
1197                                  slirp_opt == 'enabled' and not have_internal)
1198     if slirp.found()
1199       slirp_opt = 'system'
1200     elif have_internal
1201       slirp_opt = 'internal'
1202     else
1203       slirp_opt = 'disabled'
1204     endif
1205   endif
1206   if slirp_opt == 'internal'
1207     slirp_deps = []
1208     if targetos == 'windows'
1209       slirp_deps = cc.find_library('iphlpapi')
1210     endif
1211     slirp_conf = configuration_data()
1212     slirp_conf.set('SLIRP_MAJOR_VERSION', meson.project_version().split('.')[0])
1213     slirp_conf.set('SLIRP_MINOR_VERSION', meson.project_version().split('.')[1])
1214     slirp_conf.set('SLIRP_MICRO_VERSION', meson.project_version().split('.')[2])
1215     slirp_conf.set_quoted('SLIRP_VERSION_STRING', meson.project_version())
1216     slirp_cargs = ['-DG_LOG_DOMAIN="Slirp"']
1217     slirp_files = [
1218       'slirp/src/arp_table.c',
1219       'slirp/src/bootp.c',
1220       'slirp/src/cksum.c',
1221       'slirp/src/dhcpv6.c',
1222       'slirp/src/dnssearch.c',
1223       'slirp/src/if.c',
1224       'slirp/src/ip6_icmp.c',
1225       'slirp/src/ip6_input.c',
1226       'slirp/src/ip6_output.c',
1227       'slirp/src/ip_icmp.c',
1228       'slirp/src/ip_input.c',
1229       'slirp/src/ip_output.c',
1230       'slirp/src/mbuf.c',
1231       'slirp/src/misc.c',
1232       'slirp/src/ncsi.c',
1233       'slirp/src/ndp_table.c',
1234       'slirp/src/sbuf.c',
1235       'slirp/src/slirp.c',
1236       'slirp/src/socket.c',
1237       'slirp/src/state.c',
1238       'slirp/src/stream.c',
1239       'slirp/src/tcp_input.c',
1240       'slirp/src/tcp_output.c',
1241       'slirp/src/tcp_subr.c',
1242       'slirp/src/tcp_timer.c',
1243       'slirp/src/tftp.c',
1244       'slirp/src/udp.c',
1245       'slirp/src/udp6.c',
1246       'slirp/src/util.c',
1247       'slirp/src/version.c',
1248       'slirp/src/vmstate.c',
1249     ]
1250
1251     configure_file(
1252       input : 'slirp/src/libslirp-version.h.in',
1253       output : 'libslirp-version.h',
1254       configuration: slirp_conf)
1255
1256     slirp_inc = include_directories('slirp', 'slirp/src')
1257     libslirp = static_library('slirp',
1258                               sources: slirp_files,
1259                               c_args: slirp_cargs,
1260                               include_directories: slirp_inc)
1261     slirp = declare_dependency(link_with: libslirp,
1262                                dependencies: slirp_deps,
1263                                include_directories: slirp_inc)
1264   endif
1265 endif
1266
1267 fdt = not_found
1268 fdt_opt = get_option('fdt')
1269 if have_system
1270   if fdt_opt in ['enabled', 'auto', 'system']
1271     have_internal = fs.exists(meson.current_source_dir() / 'dtc/libfdt/Makefile.libfdt')
1272     fdt = cc.find_library('fdt', static: enable_static,
1273                           required: fdt_opt == 'system' or
1274                                     fdt_opt == 'enabled' and not have_internal)
1275     if fdt.found() and cc.links('''
1276        #include <libfdt.h>
1277        #include <libfdt_env.h>
1278        int main(void) { fdt_check_full(NULL, 0); return 0; }''',
1279          dependencies: fdt)
1280       fdt_opt = 'system'
1281     elif have_internal
1282       fdt_opt = 'internal'
1283     else
1284       fdt_opt = 'disabled'
1285     endif
1286   endif
1287   if fdt_opt == 'internal'
1288     fdt_files = files(
1289       'dtc/libfdt/fdt.c',
1290       'dtc/libfdt/fdt_ro.c',
1291       'dtc/libfdt/fdt_wip.c',
1292       'dtc/libfdt/fdt_sw.c',
1293       'dtc/libfdt/fdt_rw.c',
1294       'dtc/libfdt/fdt_strerror.c',
1295       'dtc/libfdt/fdt_empty_tree.c',
1296       'dtc/libfdt/fdt_addresses.c',
1297       'dtc/libfdt/fdt_overlay.c',
1298       'dtc/libfdt/fdt_check.c',
1299     )
1300
1301     fdt_inc = include_directories('dtc/libfdt')
1302     libfdt = static_library('fdt',
1303                             sources: fdt_files,
1304                             include_directories: fdt_inc)
1305     fdt = declare_dependency(link_with: libfdt,
1306                              include_directories: fdt_inc)
1307   endif
1308 endif
1309 if not fdt.found() and fdt_required.length() > 0
1310   error('fdt not available but required by targets ' + ', '.join(fdt_required))
1311 endif
1312
1313 config_host_data.set('CONFIG_CAPSTONE', capstone.found())
1314 config_host_data.set('CONFIG_FDT', fdt.found())
1315 config_host_data.set('CONFIG_SLIRP', slirp.found())
1316
1317 #####################
1318 # Generated sources #
1319 #####################
1320
1321 genh += configure_file(output: 'config-host.h', configuration: config_host_data)
1322
1323 hxtool = find_program('scripts/hxtool')
1324 shaderinclude = find_program('scripts/shaderinclude.pl')
1325 qapi_gen = find_program('scripts/qapi-gen.py')
1326 qapi_gen_depends = [ meson.source_root() / 'scripts/qapi/__init__.py',
1327                      meson.source_root() / 'scripts/qapi/commands.py',
1328                      meson.source_root() / 'scripts/qapi/common.py',
1329                      meson.source_root() / 'scripts/qapi/error.py',
1330                      meson.source_root() / 'scripts/qapi/events.py',
1331                      meson.source_root() / 'scripts/qapi/expr.py',
1332                      meson.source_root() / 'scripts/qapi/gen.py',
1333                      meson.source_root() / 'scripts/qapi/introspect.py',
1334                      meson.source_root() / 'scripts/qapi/parser.py',
1335                      meson.source_root() / 'scripts/qapi/schema.py',
1336                      meson.source_root() / 'scripts/qapi/source.py',
1337                      meson.source_root() / 'scripts/qapi/types.py',
1338                      meson.source_root() / 'scripts/qapi/visit.py',
1339                      meson.source_root() / 'scripts/qapi/common.py',
1340                      meson.source_root() / 'scripts/qapi-gen.py'
1341 ]
1342
1343 tracetool = [
1344   python, files('scripts/tracetool.py'),
1345    '--backend=' + config_host['TRACE_BACKENDS']
1346 ]
1347
1348 qemu_version_cmd = [find_program('scripts/qemu-version.sh'),
1349                     meson.current_source_dir(),
1350                     config_host['PKGVERSION'], meson.project_version()]
1351 qemu_version = custom_target('qemu-version.h',
1352                              output: 'qemu-version.h',
1353                              command: qemu_version_cmd,
1354                              capture: true,
1355                              build_by_default: true,
1356                              build_always_stale: true)
1357 genh += qemu_version
1358
1359 hxdep = []
1360 hx_headers = [
1361   ['qemu-options.hx', 'qemu-options.def'],
1362   ['qemu-img-cmds.hx', 'qemu-img-cmds.h'],
1363 ]
1364 if have_system
1365   hx_headers += [
1366     ['hmp-commands.hx', 'hmp-commands.h'],
1367     ['hmp-commands-info.hx', 'hmp-commands-info.h'],
1368   ]
1369 endif
1370 foreach d : hx_headers
1371   hxdep += custom_target(d[1],
1372                 input: files(d[0]),
1373                 output: d[1],
1374                 capture: true,
1375                 build_by_default: true, # to be removed when added to a target
1376                 command: [hxtool, '-h', '@INPUT0@'])
1377 endforeach
1378 genh += hxdep
1379
1380 ###################
1381 # Collect sources #
1382 ###################
1383
1384 authz_ss = ss.source_set()
1385 blockdev_ss = ss.source_set()
1386 block_ss = ss.source_set()
1387 bsd_user_ss = ss.source_set()
1388 chardev_ss = ss.source_set()
1389 common_ss = ss.source_set()
1390 crypto_ss = ss.source_set()
1391 io_ss = ss.source_set()
1392 linux_user_ss = ss.source_set()
1393 qmp_ss = ss.source_set()
1394 qom_ss = ss.source_set()
1395 softmmu_ss = ss.source_set()
1396 specific_fuzz_ss = ss.source_set()
1397 specific_ss = ss.source_set()
1398 stub_ss = ss.source_set()
1399 trace_ss = ss.source_set()
1400 user_ss = ss.source_set()
1401 util_ss = ss.source_set()
1402
1403 modules = {}
1404 hw_arch = {}
1405 target_arch = {}
1406 target_softmmu_arch = {}
1407
1408 ###############
1409 # Trace files #
1410 ###############
1411
1412 # TODO: add each directory to the subdirs from its own meson.build, once
1413 # we have those
1414 trace_events_subdirs = [
1415   'accel/kvm',
1416   'accel/tcg',
1417   'crypto',
1418   'monitor',
1419 ]
1420 if have_user
1421   trace_events_subdirs += [ 'linux-user' ]
1422 endif
1423 if have_block
1424   trace_events_subdirs += [
1425     'authz',
1426     'block',
1427     'io',
1428     'nbd',
1429     'scsi',
1430   ]
1431 endif
1432 if have_system
1433   trace_events_subdirs += [
1434     'audio',
1435     'backends',
1436     'backends/tpm',
1437     'chardev',
1438     'hw/9pfs',
1439     'hw/acpi',
1440     'hw/alpha',
1441     'hw/arm',
1442     'hw/audio',
1443     'hw/block',
1444     'hw/block/dataplane',
1445     'hw/char',
1446     'hw/display',
1447     'hw/dma',
1448     'hw/hppa',
1449     'hw/hyperv',
1450     'hw/i2c',
1451     'hw/i386',
1452     'hw/i386/xen',
1453     'hw/ide',
1454     'hw/input',
1455     'hw/intc',
1456     'hw/isa',
1457     'hw/mem',
1458     'hw/mips',
1459     'hw/misc',
1460     'hw/misc/macio',
1461     'hw/net',
1462     'hw/net/can',
1463     'hw/nvram',
1464     'hw/pci',
1465     'hw/pci-host',
1466     'hw/ppc',
1467     'hw/rdma',
1468     'hw/rdma/vmw',
1469     'hw/rtc',
1470     'hw/s390x',
1471     'hw/scsi',
1472     'hw/sd',
1473     'hw/sparc',
1474     'hw/sparc64',
1475     'hw/ssi',
1476     'hw/timer',
1477     'hw/tpm',
1478     'hw/usb',
1479     'hw/vfio',
1480     'hw/virtio',
1481     'hw/watchdog',
1482     'hw/xen',
1483     'hw/gpio',
1484     'migration',
1485     'net',
1486     'softmmu',
1487     'ui',
1488   ]
1489 endif
1490 trace_events_subdirs += [
1491   'hw/core',
1492   'qapi',
1493   'qom',
1494   'target/arm',
1495   'target/hppa',
1496   'target/i386',
1497   'target/mips',
1498   'target/ppc',
1499   'target/riscv',
1500   'target/s390x',
1501   'target/sparc',
1502   'util',
1503 ]
1504
1505 vhost_user = not_found
1506 if 'CONFIG_VHOST_USER' in config_host
1507   libvhost_user = subproject('libvhost-user')
1508   vhost_user = libvhost_user.get_variable('vhost_user_dep')
1509 endif
1510
1511 subdir('qapi')
1512 subdir('qobject')
1513 subdir('stubs')
1514 subdir('trace')
1515 subdir('util')
1516 subdir('qom')
1517 subdir('authz')
1518 subdir('crypto')
1519 subdir('ui')
1520
1521
1522 if enable_modules
1523   libmodulecommon = static_library('module-common', files('module-common.c') + genh, pic: true, c_args: '-DBUILD_DSO')
1524   modulecommon = declare_dependency(link_whole: libmodulecommon, compile_args: '-DBUILD_DSO')
1525 endif
1526
1527 stub_ss = stub_ss.apply(config_all, strict: false)
1528
1529 util_ss.add_all(trace_ss)
1530 util_ss = util_ss.apply(config_all, strict: false)
1531 libqemuutil = static_library('qemuutil',
1532                              sources: util_ss.sources() + stub_ss.sources() + genh,
1533                              dependencies: [util_ss.dependencies(), m, glib, socket, malloc])
1534 qemuutil = declare_dependency(link_with: libqemuutil,
1535                               sources: genh + version_res)
1536
1537 decodetree = generator(find_program('scripts/decodetree.py'),
1538                        output: 'decode-@BASENAME@.c.inc',
1539                        arguments: ['@INPUT@', '@EXTRA_ARGS@', '-o', '@OUTPUT@'])
1540
1541 subdir('audio')
1542 subdir('io')
1543 subdir('chardev')
1544 subdir('fsdev')
1545 subdir('libdecnumber')
1546 subdir('target')
1547 subdir('dump')
1548
1549 block_ss.add(files(
1550   'block.c',
1551   'blockjob.c',
1552   'job.c',
1553   'qemu-io-cmds.c',
1554 ))
1555 block_ss.add(when: 'CONFIG_REPLICATION', if_true: files('replication.c'))
1556
1557 subdir('nbd')
1558 subdir('scsi')
1559 subdir('block')
1560
1561 blockdev_ss.add(files(
1562   'blockdev.c',
1563   'blockdev-nbd.c',
1564   'iothread.c',
1565   'job-qmp.c',
1566 ))
1567
1568 # os-posix.c contains POSIX-specific functions used by qemu-storage-daemon,
1569 # os-win32.c does not
1570 blockdev_ss.add(when: 'CONFIG_POSIX', if_true: files('os-posix.c'))
1571 softmmu_ss.add(when: 'CONFIG_WIN32', if_true: [files('os-win32.c')])
1572
1573 common_ss.add(files('cpus-common.c'))
1574
1575 subdir('softmmu')
1576
1577 common_ss.add(capstone)
1578 specific_ss.add(files('cpu.c', 'disas.c', 'gdbstub.c'), capstone)
1579 specific_ss.add(files('exec-vary.c'))
1580 specific_ss.add(when: 'CONFIG_TCG', if_true: files(
1581   'fpu/softfloat.c',
1582   'tcg/optimize.c',
1583   'tcg/tcg-common.c',
1584   'tcg/tcg-op-gvec.c',
1585   'tcg/tcg-op-vec.c',
1586   'tcg/tcg-op.c',
1587   'tcg/tcg.c',
1588 ))
1589 specific_ss.add(when: 'CONFIG_TCG_INTERPRETER', if_true: files('disas/tci.c', 'tcg/tci.c'))
1590
1591 subdir('backends')
1592 subdir('disas')
1593 subdir('migration')
1594 subdir('monitor')
1595 subdir('net')
1596 subdir('replay')
1597 subdir('hw')
1598 subdir('accel')
1599 subdir('plugins')
1600 subdir('bsd-user')
1601 subdir('linux-user')
1602
1603 bsd_user_ss.add(files('gdbstub.c'))
1604 specific_ss.add_all(when: 'CONFIG_BSD_USER', if_true: bsd_user_ss)
1605
1606 linux_user_ss.add(files('gdbstub.c', 'thunk.c'))
1607 specific_ss.add_all(when: 'CONFIG_LINUX_USER', if_true: linux_user_ss)
1608
1609 # needed for fuzzing binaries
1610 subdir('tests/qtest/libqos')
1611 subdir('tests/qtest/fuzz')
1612
1613 ########################
1614 # Library dependencies #
1615 ########################
1616
1617 block_mods = []
1618 softmmu_mods = []
1619 foreach d, list : modules
1620   foreach m, module_ss : list
1621     if enable_modules and targetos != 'windows'
1622       module_ss = module_ss.apply(config_all, strict: false)
1623       sl = static_library(d + '-' + m, [genh, module_ss.sources()],
1624                           dependencies: [modulecommon, module_ss.dependencies()], pic: true)
1625       if d == 'block'
1626         block_mods += sl
1627       else
1628         softmmu_mods += sl
1629       endif
1630     else
1631       if d == 'block'
1632         block_ss.add_all(module_ss)
1633       else
1634         softmmu_ss.add_all(module_ss)
1635       endif
1636     endif
1637   endforeach
1638 endforeach
1639
1640 nm = find_program('nm')
1641 undefsym = find_program('scripts/undefsym.py')
1642 block_syms = custom_target('block.syms', output: 'block.syms',
1643                              input: [libqemuutil, block_mods],
1644                              capture: true,
1645                              command: [undefsym, nm, '@INPUT@'])
1646 qemu_syms = custom_target('qemu.syms', output: 'qemu.syms',
1647                              input: [libqemuutil, softmmu_mods],
1648                              capture: true,
1649                              command: [undefsym, nm, '@INPUT@'])
1650
1651 qom_ss = qom_ss.apply(config_host, strict: false)
1652 libqom = static_library('qom', qom_ss.sources() + genh,
1653                         dependencies: [qom_ss.dependencies()],
1654                         name_suffix: 'fa')
1655
1656 qom = declare_dependency(link_whole: libqom)
1657
1658 authz_ss = authz_ss.apply(config_host, strict: false)
1659 libauthz = static_library('authz', authz_ss.sources() + genh,
1660                           dependencies: [authz_ss.dependencies()],
1661                           name_suffix: 'fa',
1662                           build_by_default: false)
1663
1664 authz = declare_dependency(link_whole: libauthz,
1665                            dependencies: qom)
1666
1667 crypto_ss = crypto_ss.apply(config_host, strict: false)
1668 libcrypto = static_library('crypto', crypto_ss.sources() + genh,
1669                            dependencies: [crypto_ss.dependencies()],
1670                            name_suffix: 'fa',
1671                            build_by_default: false)
1672
1673 crypto = declare_dependency(link_whole: libcrypto,
1674                             dependencies: [authz, qom])
1675
1676 io_ss = io_ss.apply(config_host, strict: false)
1677 libio = static_library('io', io_ss.sources() + genh,
1678                        dependencies: [io_ss.dependencies()],
1679                        link_with: libqemuutil,
1680                        name_suffix: 'fa',
1681                        build_by_default: false)
1682
1683 io = declare_dependency(link_whole: libio, dependencies: [crypto, qom])
1684
1685 libmigration = static_library('migration', sources: migration_files + genh,
1686                               name_suffix: 'fa',
1687                               build_by_default: false)
1688 migration = declare_dependency(link_with: libmigration,
1689                                dependencies: [zlib, qom, io])
1690 softmmu_ss.add(migration)
1691
1692 block_ss = block_ss.apply(config_host, strict: false)
1693 libblock = static_library('block', block_ss.sources() + genh,
1694                           dependencies: block_ss.dependencies(),
1695                           link_depends: block_syms,
1696                           name_suffix: 'fa',
1697                           build_by_default: false)
1698
1699 block = declare_dependency(link_whole: [libblock],
1700                            link_args: '@block.syms',
1701                            dependencies: [crypto, io])
1702
1703 blockdev_ss = blockdev_ss.apply(config_host, strict: false)
1704 libblockdev = static_library('blockdev', blockdev_ss.sources() + genh,
1705                              dependencies: blockdev_ss.dependencies(),
1706                              name_suffix: 'fa',
1707                              build_by_default: false)
1708
1709 blockdev = declare_dependency(link_whole: [libblockdev],
1710                               dependencies: [block])
1711
1712 qmp_ss = qmp_ss.apply(config_host, strict: false)
1713 libqmp = static_library('qmp', qmp_ss.sources() + genh,
1714                         dependencies: qmp_ss.dependencies(),
1715                         name_suffix: 'fa',
1716                         build_by_default: false)
1717
1718 qmp = declare_dependency(link_whole: [libqmp])
1719
1720 libchardev = static_library('chardev', chardev_ss.sources() + genh,
1721                             name_suffix: 'fa',
1722                             build_by_default: false)
1723
1724 chardev = declare_dependency(link_whole: libchardev)
1725
1726 libhwcore = static_library('hwcore', sources: hwcore_files + genh,
1727                            name_suffix: 'fa',
1728                            build_by_default: false)
1729 hwcore = declare_dependency(link_whole: libhwcore)
1730 common_ss.add(hwcore)
1731
1732 ###########
1733 # Targets #
1734 ###########
1735
1736 foreach m : block_mods + softmmu_mods
1737   shared_module(m.name(),
1738                 name_prefix: '',
1739                 link_whole: m,
1740                 install: true,
1741                 install_dir: qemu_moddir)
1742 endforeach
1743
1744 softmmu_ss.add(authz, blockdev, chardev, crypto, io, qmp)
1745 common_ss.add(qom, qemuutil)
1746
1747 common_ss.add_all(when: 'CONFIG_SOFTMMU', if_true: [softmmu_ss])
1748 common_ss.add_all(when: 'CONFIG_USER_ONLY', if_true: user_ss)
1749
1750 common_all = common_ss.apply(config_all, strict: false)
1751 common_all = static_library('common',
1752                             build_by_default: false,
1753                             sources: common_all.sources() + genh,
1754                             dependencies: common_all.dependencies(),
1755                             name_suffix: 'fa')
1756
1757 feature_to_c = find_program('scripts/feature_to_c.sh')
1758
1759 emulators = {}
1760 foreach target : target_dirs
1761   config_target = config_target_mak[target]
1762   target_name = config_target['TARGET_NAME']
1763   arch = config_target['TARGET_BASE_ARCH']
1764   arch_srcs = [config_target_h[target]]
1765   arch_deps = []
1766   c_args = ['-DNEED_CPU_H',
1767             '-DCONFIG_TARGET="@0@-config-target.h"'.format(target),
1768             '-DCONFIG_DEVICES="@0@-config-devices.h"'.format(target)]
1769   link_args = emulator_link_args
1770
1771   config_target += config_host
1772   target_inc = [include_directories('target' / config_target['TARGET_BASE_ARCH'])]
1773   if targetos == 'linux'
1774     target_inc += include_directories('linux-headers', is_system: true)
1775   endif
1776   if target.endswith('-softmmu')
1777     qemu_target_name = 'qemu-system-' + target_name
1778     target_type='system'
1779     t = target_softmmu_arch[arch].apply(config_target, strict: false)
1780     arch_srcs += t.sources()
1781     arch_deps += t.dependencies()
1782
1783     hw_dir = target_name == 'sparc64' ? 'sparc64' : arch
1784     hw = hw_arch[hw_dir].apply(config_target, strict: false)
1785     arch_srcs += hw.sources()
1786     arch_deps += hw.dependencies()
1787
1788     arch_srcs += config_devices_h[target]
1789     link_args += ['@block.syms', '@qemu.syms']
1790   else
1791     abi = config_target['TARGET_ABI_DIR']
1792     target_type='user'
1793     qemu_target_name = 'qemu-' + target_name
1794     if 'CONFIG_LINUX_USER' in config_target
1795       base_dir = 'linux-user'
1796       target_inc += include_directories('linux-user/host/' / config_host['ARCH'])
1797     else
1798       base_dir = 'bsd-user'
1799     endif
1800     target_inc += include_directories(
1801       base_dir,
1802       base_dir / abi,
1803     )
1804     if 'CONFIG_LINUX_USER' in config_target
1805       dir = base_dir / abi
1806       arch_srcs += files(dir / 'signal.c', dir / 'cpu_loop.c')
1807       if config_target.has_key('TARGET_SYSTBL_ABI')
1808         arch_srcs += \
1809           syscall_nr_generators[abi].process(base_dir / abi / config_target['TARGET_SYSTBL'],
1810                                              extra_args : config_target['TARGET_SYSTBL_ABI'])
1811       endif
1812     endif
1813   endif
1814
1815   if 'TARGET_XML_FILES' in config_target
1816     gdbstub_xml = custom_target(target + '-gdbstub-xml.c',
1817                                 output: target + '-gdbstub-xml.c',
1818                                 input: files(config_target['TARGET_XML_FILES'].split()),
1819                                 command: [feature_to_c, '@INPUT@'],
1820                                 capture: true)
1821     arch_srcs += gdbstub_xml
1822   endif
1823
1824   t = target_arch[arch].apply(config_target, strict: false)
1825   arch_srcs += t.sources()
1826   arch_deps += t.dependencies()
1827
1828   target_common = common_ss.apply(config_target, strict: false)
1829   objects = common_all.extract_objects(target_common.sources())
1830   deps = target_common.dependencies()
1831
1832   target_specific = specific_ss.apply(config_target, strict: false)
1833   arch_srcs += target_specific.sources()
1834   arch_deps += target_specific.dependencies()
1835
1836   lib = static_library('qemu-' + target,
1837                  sources: arch_srcs + genh,
1838                  dependencies: arch_deps,
1839                  objects: objects,
1840                  include_directories: target_inc,
1841                  c_args: c_args,
1842                  build_by_default: false,
1843                  name_suffix: 'fa')
1844
1845   if target.endswith('-softmmu')
1846     execs = [{
1847       'name': 'qemu-system-' + target_name,
1848       'gui': false,
1849       'sources': files('softmmu/main.c'),
1850       'dependencies': []
1851     }]
1852     if targetos == 'windows' and (sdl.found() or gtk.found())
1853       execs += [{
1854         'name': 'qemu-system-' + target_name + 'w',
1855         'gui': true,
1856         'sources': files('softmmu/main.c'),
1857         'dependencies': []
1858       }]
1859     endif
1860     if config_host.has_key('CONFIG_FUZZ')
1861       specific_fuzz = specific_fuzz_ss.apply(config_target, strict: false)
1862       execs += [{
1863         'name': 'qemu-fuzz-' + target_name,
1864         'gui': false,
1865         'sources': specific_fuzz.sources(),
1866         'dependencies': specific_fuzz.dependencies(),
1867       }]
1868     endif
1869   else
1870     execs = [{
1871       'name': 'qemu-' + target_name,
1872       'gui': false,
1873       'sources': [],
1874       'dependencies': []
1875     }]
1876   endif
1877   foreach exe: execs
1878     emulators += {exe['name']:
1879          executable(exe['name'], exe['sources'],
1880                install: true,
1881                c_args: c_args,
1882                dependencies: arch_deps + deps + exe['dependencies'],
1883                objects: lib.extract_all_objects(recursive: true),
1884                link_language: link_language,
1885                link_depends: [block_syms, qemu_syms] + exe.get('link_depends', []),
1886                link_args: link_args,
1887                gui_app: exe['gui'])
1888     }
1889
1890     if 'CONFIG_TRACE_SYSTEMTAP' in config_host
1891       foreach stp: [
1892         {'ext': '.stp-build', 'fmt': 'stap', 'bin': meson.current_build_dir() / exe['name'], 'install': false},
1893         {'ext': '.stp', 'fmt': 'stap', 'bin': get_option('prefix') / get_option('bindir') / exe['name'], 'install': true},
1894         {'ext': '-simpletrace.stp', 'fmt': 'simpletrace-stap', 'bin': '', 'install': true},
1895         {'ext': '-log.stp', 'fmt': 'log-stap', 'bin': '', 'install': true},
1896       ]
1897         custom_target(exe['name'] + stp['ext'],
1898                       input: trace_events_all,
1899                       output: exe['name'] + stp['ext'],
1900                       capture: true,
1901                       install: stp['install'],
1902                       install_dir: get_option('datadir') / 'systemtap/tapset',
1903                       command: [
1904                         tracetool, '--group=all', '--format=' + stp['fmt'],
1905                         '--binary=' + stp['bin'],
1906                         '--target-name=' + target_name,
1907                         '--target-type=' + target_type,
1908                         '--probe-prefix=qemu.' + target_type + '.' + target_name,
1909                         '@INPUT@',
1910                       ])
1911       endforeach
1912     endif
1913   endforeach
1914 endforeach
1915
1916 # Other build targets
1917
1918 if 'CONFIG_PLUGIN' in config_host
1919   install_headers('include/qemu/qemu-plugin.h')
1920 endif
1921
1922 if 'CONFIG_GUEST_AGENT' in config_host
1923   subdir('qga')
1924 endif
1925
1926 # Don't build qemu-keymap if xkbcommon is not explicitly enabled
1927 # when we don't build tools or system
1928 if xkbcommon.found()
1929   # used for the update-keymaps target, so include rules even if !have_tools
1930   qemu_keymap = executable('qemu-keymap', files('qemu-keymap.c', 'ui/input-keymap.c') + genh,
1931                            dependencies: [qemuutil, xkbcommon], install: have_tools)
1932 endif
1933
1934 if have_tools
1935   qemu_img = executable('qemu-img', [files('qemu-img.c'), hxdep],
1936              dependencies: [authz, block, crypto, io, qom, qemuutil], install: true)
1937   qemu_io = executable('qemu-io', files('qemu-io.c'),
1938              dependencies: [block, qemuutil], install: true)
1939   qemu_nbd = executable('qemu-nbd', files('qemu-nbd.c'),
1940                dependencies: [blockdev, qemuutil], install: true)
1941
1942   subdir('storage-daemon')
1943   subdir('contrib/rdmacm-mux')
1944   subdir('contrib/elf2dmp')
1945
1946   executable('qemu-edid', files('qemu-edid.c', 'hw/display/edid-generate.c'),
1947              dependencies: qemuutil,
1948              install: true)
1949
1950   if 'CONFIG_VHOST_USER' in config_host
1951     subdir('contrib/vhost-user-blk')
1952     subdir('contrib/vhost-user-gpu')
1953     subdir('contrib/vhost-user-input')
1954     subdir('contrib/vhost-user-scsi')
1955   endif
1956
1957   if targetos == 'linux'
1958     executable('qemu-bridge-helper', files('qemu-bridge-helper.c'),
1959                dependencies: [qemuutil, libcap_ng],
1960                install: true,
1961                install_dir: get_option('libexecdir'))
1962
1963     executable('qemu-pr-helper', files('scsi/qemu-pr-helper.c', 'scsi/utils.c'),
1964                dependencies: [authz, crypto, io, qom, qemuutil,
1965                               libcap_ng, mpathpersist],
1966                install: true)
1967   endif
1968
1969   if 'CONFIG_IVSHMEM' in config_host
1970     subdir('contrib/ivshmem-client')
1971     subdir('contrib/ivshmem-server')
1972   endif
1973 endif
1974
1975 subdir('scripts')
1976 subdir('tools')
1977 subdir('pc-bios')
1978 subdir('docs')
1979 subdir('tests')
1980 if 'CONFIG_GTK' in config_host
1981   subdir('po')
1982 endif
1983
1984 if host_machine.system() == 'windows'
1985   nsis_cmd = [
1986     find_program('scripts/nsis.py'),
1987     '@OUTPUT@',
1988     get_option('prefix'),
1989     meson.current_source_dir(),
1990     host_machine.cpu(),
1991     '--',
1992     '-DDISPLAYVERSION=' + meson.project_version(),
1993   ]
1994   if build_docs
1995     nsis_cmd += '-DCONFIG_DOCUMENTATION=y'
1996   endif
1997   if 'CONFIG_GTK' in config_host
1998     nsis_cmd += '-DCONFIG_GTK=y'
1999   endif
2000
2001   nsis = custom_target('nsis',
2002                        output: 'qemu-setup-' + meson.project_version() + '.exe',
2003                        input: files('qemu.nsi'),
2004                        build_always_stale: true,
2005                        command: nsis_cmd + ['@INPUT@'])
2006   alias_target('installer', nsis)
2007 endif
2008
2009 #########################
2010 # Configuration summary #
2011 #########################
2012
2013 summary_info = {}
2014 summary_info += {'Install prefix':    get_option('prefix')}
2015 summary_info += {'BIOS directory':    qemu_datadir}
2016 summary_info += {'firmware path':     get_option('qemu_firmwarepath')}
2017 summary_info += {'binary directory':  get_option('bindir')}
2018 summary_info += {'library directory': get_option('libdir')}
2019 summary_info += {'module directory':  qemu_moddir}
2020 summary_info += {'libexec directory': get_option('libexecdir')}
2021 summary_info += {'include directory': get_option('includedir')}
2022 summary_info += {'config directory':  get_option('sysconfdir')}
2023 if targetos != 'windows'
2024   summary_info += {'local state directory': get_option('localstatedir')}
2025   summary_info += {'Manual directory':      get_option('mandir')}
2026 else
2027   summary_info += {'local state directory': 'queried at runtime'}
2028 endif
2029 summary_info += {'Doc directory':     get_option('docdir')}
2030 summary_info += {'Build directory':   meson.current_build_dir()}
2031 summary_info += {'Source path':       meson.current_source_dir()}
2032 summary_info += {'GIT binary':        config_host['GIT']}
2033 summary_info += {'GIT submodules':    config_host['GIT_SUBMODULES']}
2034 summary_info += {'C compiler':        meson.get_compiler('c').cmd_array()[0]}
2035 summary_info += {'Host C compiler':   meson.get_compiler('c', native: true).cmd_array()[0]}
2036 if link_language == 'cpp'
2037   summary_info += {'C++ compiler':      meson.get_compiler('cpp').cmd_array()[0]}
2038 else
2039   summary_info += {'C++ compiler':      false}
2040 endif
2041 if targetos == 'darwin'
2042   summary_info += {'Objective-C compiler': meson.get_compiler('objc').cmd_array()[0]}
2043 endif
2044 summary_info += {'ARFLAGS':           config_host['ARFLAGS']}
2045 summary_info += {'CFLAGS':            ' '.join(get_option('c_args')
2046                                                + ['-O' + get_option('optimization')]
2047                                                + (get_option('debug') ? ['-g'] : []))}
2048 if link_language == 'cpp'
2049   summary_info += {'CXXFLAGS':        ' '.join(get_option('cpp_args')
2050                                                + ['-O' + get_option('optimization')]
2051                                                + (get_option('debug') ? ['-g'] : []))}
2052 endif
2053 link_args = get_option(link_language + '_link_args')
2054 if link_args.length() > 0
2055   summary_info += {'LDFLAGS':         ' '.join(link_args)}
2056 endif
2057 summary_info += {'QEMU_CFLAGS':       config_host['QEMU_CFLAGS']}
2058 summary_info += {'QEMU_LDFLAGS':      config_host['QEMU_LDFLAGS']}
2059 summary_info += {'make':              config_host['MAKE']}
2060 summary_info += {'python':            '@0@ (version: @1@)'.format(python.full_path(), python.language_version())}
2061 summary_info += {'sphinx-build':      sphinx_build.found()}
2062 summary_info += {'genisoimage':       config_host['GENISOIMAGE']}
2063 # TODO: add back version
2064 summary_info += {'slirp support':     slirp_opt == 'disabled' ? false : slirp_opt}
2065 if slirp_opt != 'disabled'
2066   summary_info += {'smbd':            config_host['CONFIG_SMBD_COMMAND']}
2067 endif
2068 summary_info += {'module support':    config_host.has_key('CONFIG_MODULES')}
2069 if config_host.has_key('CONFIG_MODULES')
2070   summary_info += {'alternative module path': config_host.has_key('CONFIG_MODULE_UPGRADES')}
2071 endif
2072 summary_info += {'host CPU':          cpu}
2073 summary_info += {'host endianness':   build_machine.endian()}
2074 summary_info += {'target list':       ' '.join(target_dirs)}
2075 summary_info += {'gprof enabled':     config_host.has_key('CONFIG_GPROF')}
2076 summary_info += {'sparse enabled':    sparse.found()}
2077 summary_info += {'strip binaries':    get_option('strip')}
2078 summary_info += {'profiler':          config_host.has_key('CONFIG_PROFILER')}
2079 summary_info += {'static build':      config_host.has_key('CONFIG_STATIC')}
2080 if targetos == 'darwin'
2081   summary_info += {'Cocoa support': config_host.has_key('CONFIG_COCOA')}
2082 endif
2083 # TODO: add back version
2084 summary_info += {'SDL support':       sdl.found()}
2085 summary_info += {'SDL image support': sdl_image.found()}
2086 # TODO: add back version
2087 summary_info += {'GTK support':       config_host.has_key('CONFIG_GTK')}
2088 summary_info += {'GTK GL support':    config_host.has_key('CONFIG_GTK_GL')}
2089 summary_info += {'pixman':            pixman.found()}
2090 # TODO: add back version
2091 summary_info += {'VTE support':       config_host.has_key('CONFIG_VTE')}
2092 summary_info += {'TLS priority':      config_host['CONFIG_TLS_PRIORITY']}
2093 summary_info += {'GNUTLS support':    config_host.has_key('CONFIG_GNUTLS')}
2094 # TODO: add back version
2095 summary_info += {'libgcrypt':         config_host.has_key('CONFIG_GCRYPT')}
2096 if config_host.has_key('CONFIG_GCRYPT')
2097    summary_info += {'  hmac':            config_host.has_key('CONFIG_GCRYPT_HMAC')}
2098    summary_info += {'  XTS':             not config_host.has_key('CONFIG_QEMU_PRIVATE_XTS')}
2099 endif
2100 # TODO: add back version
2101 summary_info += {'nettle':            config_host.has_key('CONFIG_NETTLE')}
2102 if config_host.has_key('CONFIG_NETTLE')
2103    summary_info += {'  XTS':             not config_host.has_key('CONFIG_QEMU_PRIVATE_XTS')}
2104 endif
2105 summary_info += {'libtasn1':          config_host.has_key('CONFIG_TASN1')}
2106 summary_info += {'PAM':               config_host.has_key('CONFIG_AUTH_PAM')}
2107 summary_info += {'iconv support':     iconv.found()}
2108 summary_info += {'curses support':    curses.found()}
2109 # TODO: add back version
2110 summary_info += {'virgl support':     config_host.has_key('CONFIG_VIRGL')}
2111 summary_info += {'curl support':      config_host.has_key('CONFIG_CURL')}
2112 summary_info += {'mingw32 support':   targetos == 'windows'}
2113 summary_info += {'Audio drivers':     config_host['CONFIG_AUDIO_DRIVERS']}
2114 summary_info += {'Block whitelist (rw)': config_host['CONFIG_BDRV_RW_WHITELIST']}
2115 summary_info += {'Block whitelist (ro)': config_host['CONFIG_BDRV_RO_WHITELIST']}
2116 summary_info += {'VirtFS support':    config_host.has_key('CONFIG_VIRTFS')}
2117 summary_info += {'build virtiofs daemon': have_virtiofsd}
2118 summary_info += {'Multipath support': mpathpersist.found()}
2119 summary_info += {'VNC support':       vnc.found()}
2120 if vnc.found()
2121   summary_info += {'VNC SASL support':  sasl.found()}
2122   summary_info += {'VNC JPEG support':  jpeg.found()}
2123   summary_info += {'VNC PNG support':   png.found()}
2124 endif
2125 summary_info += {'xen support':       config_host.has_key('CONFIG_XEN_BACKEND')}
2126 if config_host.has_key('CONFIG_XEN_BACKEND')
2127   summary_info += {'xen ctrl version':  config_host['CONFIG_XEN_CTRL_INTERFACE_VERSION']}
2128 endif
2129 summary_info += {'brlapi support':    config_host.has_key('CONFIG_BRLAPI')}
2130 summary_info += {'Documentation':     build_docs}
2131 summary_info += {'PIE':               get_option('b_pie')}
2132 summary_info += {'vde support':       config_host.has_key('CONFIG_VDE')}
2133 summary_info += {'netmap support':    config_host.has_key('CONFIG_NETMAP')}
2134 summary_info += {'Linux AIO support': config_host.has_key('CONFIG_LINUX_AIO')}
2135 summary_info += {'Linux io_uring support': config_host.has_key('CONFIG_LINUX_IO_URING')}
2136 summary_info += {'ATTR/XATTR support': config_host.has_key('CONFIG_ATTR')}
2137 summary_info += {'Install blobs':     get_option('install_blobs')}
2138 summary_info += {'KVM support':       config_all.has_key('CONFIG_KVM')}
2139 summary_info += {'HAX support':       config_all.has_key('CONFIG_HAX')}
2140 summary_info += {'HVF support':       config_all.has_key('CONFIG_HVF')}
2141 summary_info += {'WHPX support':      config_all.has_key('CONFIG_WHPX')}
2142 summary_info += {'TCG support':       config_all.has_key('CONFIG_TCG')}
2143 if config_all.has_key('CONFIG_TCG')
2144   summary_info += {'TCG debug enabled': config_host.has_key('CONFIG_DEBUG_TCG')}
2145   summary_info += {'TCG interpreter':   config_host.has_key('CONFIG_TCG_INTERPRETER')}
2146 endif
2147 summary_info += {'malloc trim support': has_malloc_trim}
2148 summary_info += {'RDMA support':      config_host.has_key('CONFIG_RDMA')}
2149 summary_info += {'PVRDMA support':    config_host.has_key('CONFIG_PVRDMA')}
2150 summary_info += {'fdt support':       fdt_opt == 'disabled' ? false : fdt_opt}
2151 summary_info += {'membarrier':        config_host.has_key('CONFIG_MEMBARRIER')}
2152 summary_info += {'preadv support':    config_host.has_key('CONFIG_PREADV')}
2153 summary_info += {'fdatasync':         config_host.has_key('CONFIG_FDATASYNC')}
2154 summary_info += {'madvise':           config_host.has_key('CONFIG_MADVISE')}
2155 summary_info += {'posix_madvise':     config_host.has_key('CONFIG_POSIX_MADVISE')}
2156 summary_info += {'posix_memalign':    config_host.has_key('CONFIG_POSIX_MEMALIGN')}
2157 summary_info += {'libcap-ng support': config_host.has_key('CONFIG_LIBCAP_NG')}
2158 summary_info += {'vhost-kernel support': config_host.has_key('CONFIG_VHOST_KERNEL')}
2159 summary_info += {'vhost-net support': config_host.has_key('CONFIG_VHOST_NET')}
2160 summary_info += {'vhost-crypto support': config_host.has_key('CONFIG_VHOST_CRYPTO')}
2161 summary_info += {'vhost-scsi support': config_host.has_key('CONFIG_VHOST_SCSI')}
2162 summary_info += {'vhost-vsock support': config_host.has_key('CONFIG_VHOST_VSOCK')}
2163 summary_info += {'vhost-user support': config_host.has_key('CONFIG_VHOST_USER')}
2164 summary_info += {'vhost-user-blk server support': have_vhost_user_blk_server}
2165 summary_info += {'vhost-user-fs support': config_host.has_key('CONFIG_VHOST_USER_FS')}
2166 summary_info += {'vhost-vdpa support': config_host.has_key('CONFIG_VHOST_VDPA')}
2167 summary_info += {'Trace backends':    config_host['TRACE_BACKENDS']}
2168 if config_host['TRACE_BACKENDS'].split().contains('simple')
2169   summary_info += {'Trace output file': config_host['CONFIG_TRACE_FILE'] + '-<pid>'}
2170 endif
2171 # TODO: add back protocol and server version
2172 summary_info += {'spice support':     config_host.has_key('CONFIG_SPICE')}
2173 summary_info += {'rbd support':       config_host.has_key('CONFIG_RBD')}
2174 summary_info += {'xfsctl support':    config_host.has_key('CONFIG_XFS')}
2175 summary_info += {'smartcard support': config_host.has_key('CONFIG_SMARTCARD')}
2176 summary_info += {'U2F support':       u2f.found()}
2177 summary_info += {'libusb':            config_host.has_key('CONFIG_USB_LIBUSB')}
2178 summary_info += {'usb net redir':     config_host.has_key('CONFIG_USB_REDIR')}
2179 summary_info += {'OpenGL support':    config_host.has_key('CONFIG_OPENGL')}
2180 summary_info += {'OpenGL dmabufs':    config_host.has_key('CONFIG_OPENGL_DMABUF')}
2181 summary_info += {'libiscsi support':  config_host.has_key('CONFIG_LIBISCSI')}
2182 summary_info += {'libnfs support':    config_host.has_key('CONFIG_LIBNFS')}
2183 summary_info += {'build guest agent': config_host.has_key('CONFIG_GUEST_AGENT')}
2184 if targetos == 'windows'
2185   if 'WIN_SDK' in config_host
2186     summary_info += {'Windows SDK':       config_host['WIN_SDK']}
2187   endif
2188   summary_info += {'QGA VSS support':   config_host.has_key('CONFIG_QGA_VSS')}
2189   summary_info += {'QGA w32 disk info': config_host.has_key('CONFIG_QGA_NTDDSCSI')}
2190   summary_info += {'QGA MSI support':   config_host.has_key('CONFIG_QGA_MSI')}
2191 endif
2192 summary_info += {'seccomp support':   config_host.has_key('CONFIG_SECCOMP')}
2193 summary_info += {'coroutine backend': config_host['CONFIG_COROUTINE_BACKEND']}
2194 summary_info += {'coroutine pool':    config_host['CONFIG_COROUTINE_POOL'] == '1'}
2195 summary_info += {'debug stack usage': config_host.has_key('CONFIG_DEBUG_STACK_USAGE')}
2196 summary_info += {'mutex debugging':   config_host.has_key('CONFIG_DEBUG_MUTEX')}
2197 summary_info += {'crypto afalg':      config_host.has_key('CONFIG_AF_ALG')}
2198 summary_info += {'GlusterFS support': config_host.has_key('CONFIG_GLUSTERFS')}
2199 summary_info += {'gcov':              get_option('b_coverage')}
2200 summary_info += {'TPM support':       config_host.has_key('CONFIG_TPM')}
2201 summary_info += {'libssh support':    config_host.has_key('CONFIG_LIBSSH')}
2202 summary_info += {'QOM debugging':     config_host.has_key('CONFIG_QOM_CAST_DEBUG')}
2203 summary_info += {'Live block migration': config_host.has_key('CONFIG_LIVE_BLOCK_MIGRATION')}
2204 summary_info += {'lzo support':       config_host.has_key('CONFIG_LZO')}
2205 summary_info += {'snappy support':    config_host.has_key('CONFIG_SNAPPY')}
2206 summary_info += {'bzip2 support':     config_host.has_key('CONFIG_BZIP2')}
2207 summary_info += {'lzfse support':     config_host.has_key('CONFIG_LZFSE')}
2208 summary_info += {'zstd support':      config_host.has_key('CONFIG_ZSTD')}
2209 summary_info += {'NUMA host support': config_host.has_key('CONFIG_NUMA')}
2210 summary_info += {'libxml2':           config_host.has_key('CONFIG_LIBXML2')}
2211 summary_info += {'memory allocator':  get_option('malloc')}
2212 summary_info += {'avx2 optimization': config_host.has_key('CONFIG_AVX2_OPT')}
2213 summary_info += {'avx512f optimization': config_host.has_key('CONFIG_AVX512F_OPT')}
2214 summary_info += {'replication support': config_host.has_key('CONFIG_REPLICATION')}
2215 summary_info += {'bochs support':     config_host.has_key('CONFIG_BOCHS')}
2216 summary_info += {'cloop support':     config_host.has_key('CONFIG_CLOOP')}
2217 summary_info += {'dmg support':       config_host.has_key('CONFIG_DMG')}
2218 summary_info += {'qcow v1 support':   config_host.has_key('CONFIG_QCOW1')}
2219 summary_info += {'vdi support':       config_host.has_key('CONFIG_VDI')}
2220 summary_info += {'vvfat support':     config_host.has_key('CONFIG_VVFAT')}
2221 summary_info += {'qed support':       config_host.has_key('CONFIG_QED')}
2222 summary_info += {'parallels support': config_host.has_key('CONFIG_PARALLELS')}
2223 summary_info += {'sheepdog support':  config_host.has_key('CONFIG_SHEEPDOG')}
2224 summary_info += {'capstone':          capstone_opt == 'disabled' ? false : capstone_opt}
2225 summary_info += {'libpmem support':   config_host.has_key('CONFIG_LIBPMEM')}
2226 summary_info += {'libdaxctl support': config_host.has_key('CONFIG_LIBDAXCTL')}
2227 summary_info += {'libudev':           libudev.found()}
2228 summary_info += {'default devices':   config_host['CONFIG_MINIKCONF_MODE'] == '--defconfig'}
2229 summary_info += {'plugin support':    config_host.has_key('CONFIG_PLUGIN')}
2230 summary_info += {'fuzzing support':   config_host.has_key('CONFIG_FUZZ')}
2231 if config_host.has_key('HAVE_GDB_BIN')
2232   summary_info += {'gdb':             config_host['HAVE_GDB_BIN']}
2233 endif
2234 summary_info += {'thread sanitizer':  config_host.has_key('CONFIG_TSAN')}
2235 summary_info += {'rng-none':          config_host.has_key('CONFIG_RNG_NONE')}
2236 summary_info += {'Linux keyring':     config_host.has_key('CONFIG_SECRET_KEYRING')}
2237 summary_info += {'FUSE exports':      fuse.found()}
2238 summary_info += {'FUSE lseek':        fuse_lseek.found()}
2239 summary(summary_info, bool_yn: true)
2240
2241 if not supported_cpus.contains(cpu)
2242   message()
2243   warning('SUPPORT FOR THIS HOST CPU WILL GO AWAY IN FUTURE RELEASES!')
2244   message()
2245   message('CPU host architecture ' + cpu + ' support is not currently maintained.')
2246   message('The QEMU project intends to remove support for this host CPU in')
2247   message('a future release if nobody volunteers to maintain it and to')
2248   message('provide a build host for our continuous integration setup.')
2249   message('configure has succeeded and you can continue to build, but')
2250   message('if you care about QEMU on this platform you should contact')
2251   message('us upstream at qemu-devel@nongnu.org.')
2252 endif
2253
2254 if not supported_oses.contains(targetos)
2255   message()
2256   warning('WARNING: SUPPORT FOR THIS HOST OS WILL GO AWAY IN FUTURE RELEASES!')
2257   message()
2258   message('Host OS ' + targetos + 'support is not currently maintained.')
2259   message('The QEMU project intends to remove support for this host OS in')
2260   message('a future release if nobody volunteers to maintain it and to')
2261   message('provide a build host for our continuous integration setup.')
2262   message('configure has succeeded and you can continue to build, but')
2263   message('if you care about QEMU on this platform you should contact')
2264   message('us upstream at qemu-devel@nongnu.org.')
2265 endif