target/mips: Move MUL opcode check from decode_mxu() to decode_legacy()
[qemu/ar7.git] / docs / meson.build
blobf84306ba7e0cf7d230392d4a587e09a802de9b81
1 if get_option('sphinx_build') == ''
2   sphinx_build = find_program(['sphinx-build-3', 'sphinx-build'],
3                               required: get_option('docs'))
4 else
5   sphinx_build = find_program(get_option('sphinx_build'),
6                               required: get_option('docs'))
7 endif
9 # Check if tools are available to build documentation.
10 build_docs = false
11 if sphinx_build.found()
12   SPHINX_ARGS = ['env', 'CONFDIR=' + qemu_confdir, sphinx_build]
13   # If we're making warnings fatal, apply this to Sphinx runs as well
14   if get_option('werror')
15     SPHINX_ARGS += [ '-W' ]
16   endif
18   # This is a bit awkward but works: create a trivial document and
19   # try to run it with our configuration file (which enforces a
20   # version requirement). This will fail if sphinx-build is too old.
21   run_command('mkdir', ['-p', tmpdir / 'sphinx'])
22   run_command('touch', [tmpdir / 'sphinx/index.rst'])
23   sphinx_build_test_out = run_command(SPHINX_ARGS + [
24     '-c', meson.current_source_dir(),
25     '-b', 'html', tmpdir / 'sphinx',
26     tmpdir / 'sphinx/out'])
27   build_docs = (sphinx_build_test_out.returncode() == 0)
29   if not build_docs
30     warning('@0@ is either too old or uses too old a Python version'
31             .format(sphinx_build.full_path()))
32     if get_option('docs').enabled()
33       error('Install a Python 3 version of python-sphinx')
34     endif
35   endif
36 endif
38 if build_docs
39   SPHINX_ARGS += ['-Dversion=' + meson.project_version(), '-Drelease=' + config_host['PKGVERSION']]
41   sphinx_extn_depends = [ meson.source_root() / 'docs/sphinx/depfile.py',
42                           meson.source_root() / 'docs/sphinx/hxtool.py',
43                           meson.source_root() / 'docs/sphinx/kerneldoc.py',
44                           meson.source_root() / 'docs/sphinx/kernellog.py',
45                           meson.source_root() / 'docs/sphinx/qapidoc.py',
46                           meson.source_root() / 'docs/sphinx/qmp_lexer.py',
47                           qapi_gen_depends ]
49   have_ga = have_tools and config_host.has_key('CONFIG_GUEST_AGENT')
51   man_pages = {
52         'qemu-ga.8': (have_ga ? 'man8' : ''),
53         'qemu-ga-ref.7': (have_ga ? 'man7' : ''),
54         'qemu-qmp-ref.7': 'man7',
55         'qemu-storage-daemon-qmp-ref.7': (have_tools ? 'man7' : ''),
56         'qemu-img.1': (have_tools ? 'man1' : ''),
57         'qemu-nbd.8': (have_tools ? 'man8' : ''),
58         'qemu-pr-helper.8': (have_tools ? 'man8' : ''),
59         'qemu-storage-daemon.1': (have_tools ? 'man1' : ''),
60         'qemu-trace-stap.1': (config_host.has_key('CONFIG_TRACE_SYSTEMTAP') ? 'man1' : ''),
61         'virtfs-proxy-helper.1': (have_virtfs_proxy_helper ? 'man1' : ''),
62         'virtiofsd.1': (have_virtiofsd ? 'man1' : ''),
63         'qemu.1': 'man1',
64         'qemu-block-drivers.7': 'man7',
65         'qemu-cpu-models.7': 'man7'
66   }
68   sphinxdocs = []
69   sphinxmans = []
71   private_dir = meson.current_build_dir() / 'manual.p'
72   output_dir = meson.current_build_dir() / 'manual'
73   input_dir = meson.current_source_dir()
75   this_manual = custom_target('QEMU manual',
76                 build_by_default: build_docs,
77                 output: 'docs.stamp',
78                 input: files('conf.py'),
79                 depfile: 'docs.d',
80                 depend_files: sphinx_extn_depends,
81                 command: [SPHINX_ARGS, '-Ddepfile=@DEPFILE@',
82                           '-Ddepfile_stamp=@OUTPUT0@',
83                           '-b', 'html', '-d', private_dir,
84                           input_dir, output_dir])
85   sphinxdocs += this_manual
86   install_subdir(output_dir, install_dir: qemu_docdir, strip_directory: true)
88   these_man_pages = []
89   install_dirs = []
90   foreach page, section : man_pages
91     these_man_pages += page
92     install_dirs += section == '' ? false : get_option('mandir') / section
93   endforeach
95   sphinxmans += custom_target('QEMU man pages',
96                               build_by_default: build_docs,
97                               output: these_man_pages,
98                               input: this_manual,
99                               install: build_docs,
100                               install_dir: install_dirs,
101                               command: [SPHINX_ARGS, '-b', 'man', '-d', private_dir,
102                                         input_dir, meson.current_build_dir()])
104   alias_target('sphinxdocs', sphinxdocs)
105   alias_target('html', sphinxdocs)
106   alias_target('man', sphinxmans)
107 endif