CMakeLists.txt

   1 # Check if this is a in tree build.
   2 if (NOT DEFINED LLVM_MAIN_SRC_DIR)
   3   project(Polly)
   4   cmake_minimum_required(VERSION 2.8)
   5
   6   # Where is LLVM installed?
   7   set(LLVM_INSTALL_ROOT "" CACHE PATH "Root of LLVM install.")
   8   # Check if the LLVM_INSTALL_ROOT valid.
   9   if( NOT EXISTS ${LLVM_INSTALL_ROOT}/include/llvm )
  10     message(FATAL_ERROR "LLVM_INSTALL_ROOT (${LLVM_INSTALL_ROOT}) is not a valid LLVM installation.")
  11   endif(NOT EXISTS ${LLVM_INSTALL_ROOT}/include/llvm)
  12   # FileCheck, not and llvm-lit are not install by default, warn the user to copy them.
  13   if( NOT EXISTS ${LLVM_INSTALL_ROOT}/bin/FileCheck
  14       OR NOT EXISTS ${LLVM_INSTALL_ROOT}/bin/not
  15       OR NOT EXISTS ${LLVM_INSTALL_ROOT}/bin/llvm-lit )
  16     message(WARNING "'FileCheck', 'not' and 'llvm-lit' are required by running regress tests, "
  17                     "but they are not installed! Please copy them to "
  18                     "${LLVM_INSTALL_ROOT}/bin.")
  19   endif()
  20   # Add the llvm header path.
  21   include_directories(${LLVM_INSTALL_ROOT}/include/)
  22
  23   # Get the system librarys that will link into LLVM.
  24   function(get_system_libs return_var)
  25     # Returns in `return_var' a list of system libraries used by LLVM.
  26     if( NOT MSVC )
  27       if( MINGW )
  28         set(system_libs ${system_libs} imagehlp psapi)
  29       elseif( CMAKE_HOST_UNIX )
  30         if( HAVE_LIBDL )
  31           set(system_libs ${system_libs} ${CMAKE_DL_LIBS})
  32         endif()
  33         if( LLVM_ENABLE_THREADS AND HAVE_LIBPTHREAD )
  34           set(system_libs ${system_libs} pthread)
  35         endif()
  36       endif( MINGW )
  37     endif( NOT MSVC )
  38     set(${return_var} ${system_libs} PARENT_SCOPE)
  39   endfunction(get_system_libs)
  40
  41   # Determine where LLVM stores its libraries.
  42   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --libdir
  43                   OUTPUT_VARIABLE LLVM_LIBRARY_DIR
  44                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  45   link_directories("${LLVM_LIBRARY_DIR}")
  46
  47   # Now set the header paths.
  48   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --includedir
  49                   OUTPUT_VARIABLE LLVM_INCLUDE_DIR
  50                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  51   include_directories( ${LLVM_INCLUDE_DIR} )
  52
  53   # Get the TARGET_TRIPLE
  54   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --host-target
  55                   OUTPUT_VARIABLE TARGET_TRIPLE
  56                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  57
  58   # And then set the cxx flags.
  59   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --cxxflags
  60                   OUTPUT_VARIABLE LLVM_CXX_FLAGS
  61                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  62   set(CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS} ${LLVM_CXX_FLAGS})
  63
  64   # Check LLVM_ENABLE_ASSERTIONS
  65   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --assertion-mode
  66                   OUTPUT_VARIABLE LLVM_ENABLE_ASSERTIONS
  67                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  68   # Copied from LLVM's HandleLLVMOptions.cmake
  69   if( LLVM_ENABLE_ASSERTIONS )
  70     # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  71     if( NOT MSVC )
  72       add_definitions( -D_DEBUG )
  73     endif()
  74     # On non-Debug builds cmake automatically defines NDEBUG, so we
  75     # explicitly undefine it:
  76     if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  77       add_definitions( -UNDEBUG )
  78       # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
  79       foreach (flags_var_to_scrub
  80           CMAKE_CXX_FLAGS_RELEASE
  81           CMAKE_CXX_FLAGS_RELWITHDEBINFO
  82           CMAKE_CXX_FLAGS_MINSIZEREL
  83           CMAKE_C_FLAGS_RELEASE
  84           CMAKE_C_FLAGS_RELWITHDEBINFO
  85           CMAKE_C_FLAGS_MINSIZEREL)
  86         string (REGEX REPLACE "(^| )[/-]D *NDEBUG($| )" " "
  87           "${flags_var_to_scrub}" "${${flags_var_to_scrub}}")
  88       endforeach()
  89     endif()
  90   endif()
  91
  92   # Sources available, too?
  93   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --src-root
  94                   OUTPUT_VARIABLE MAIN_SRC_DIR
  95                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  96   set(LLVM_SOURCE_ROOT ${MAIN_SRC_DIR} CACHE PATH "Path to LLVM source tree")
  97
  98   # Enable unit tests if available.
  99   set(UNITTEST_DIR ${LLVM_SOURCE_ROOT}/utils/unittest)
 100   if(EXISTS ${UNITTEST_DIR}/googletest/include/gtest/gtest.h)
 101     add_library(gtest ${UNITTEST_DIR}/googletest/src/gtest-all.cc)
 102     target_include_directories(gtest PUBLIC "${UNITTEST_DIR}/googletest/include" PRIVATE "${UNITTEST_DIR}/googletest")
 103     if( NOT MSVC )
 104       target_link_libraries(gtest pthread tinfo dl)
 105     endif ()
 106
 107     add_library(gtest_main ${UNITTEST_DIR}/UnitTestMain/TestMain.cpp)
 108     target_link_libraries(gtest_main gtest)
 109
 110     set(POLLY_GTEST_AVAIL 1)
 111   endif()
 112
 113   # Make sure the isl c files are built as fPIC
 114   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
 115 else ()
 116   set(LLVM_SOURCE_ROOT "${LLVM_MAIN_SRC_DIR}")
 117   set(POLLY_GTEST_AVAIL 1)
 118 endif ()
 119
 120 set(POLLY_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 121 set(POLLY_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 122
 123 # Add path for custom modules
 124 set(CMAKE_MODULE_PATH
 125   ${CMAKE_MODULE_PATH}
 126   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 127   )
 128
 129 include("polly_macros")
 130
 131 # Add appropriate flags for GCC
 132 if (CMAKE_COMPILER_IS_GNUCXX)
 133   # FIXME: Turn off exceptions, RTTI:
 134   # -fno-exceptions -fno-rtti
 135   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-common -Woverloaded-virtual -Wno-long-long -Wall -W -Wno-unused-parameter -Wwrite-strings -fno-exceptions -fno-rtti")
 136 elseif (MSVC)
 137   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /EHs-c-")
 138   add_definitions("-D_HAS_EXCEPTIONS=0")
 139 else ()
 140   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
 141 endif ()
 142
 143 # Add path for custom modules
 144 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${POLLY_SOURCE_DIR}/cmake")
 145
 146 SET(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 147
 148 option(POLLY_ENABLE_GPGPU_CODEGEN "Enable GPGPU code generation feature" OFF)
 149 if (POLLY_ENABLE_GPGPU_CODEGEN)
 150   # Do not require CUDA, as GPU code generation test cases can be run without
 151   # a cuda library.
 152   FIND_PACKAGE(CUDA)
 153   set(GPU_CODEGEN TRUE)
 154 else(POLLY_ENABLE_GPGPU_CODEGEN)
 155   set(GPU_CODEGEN FALSE)
 156 endif(POLLY_ENABLE_GPGPU_CODEGEN)
 157
 158
 159 # Support GPGPU code generation if the library is available.
 160 if (CUDALIB_FOUND)
 161   INCLUDE_DIRECTORIES( ${CUDALIB_INCLUDE_DIR} )
 162 endif(CUDALIB_FOUND)
 163
 164 include_directories(
 165   BEFORE
 166   ${CMAKE_CURRENT_SOURCE_DIR}/include
 167   ${CMAKE_CURRENT_SOURCE_DIR}/lib/JSON/include
 168   ${CMAKE_CURRENT_BINARY_DIR}/lib/External/isl/include
 169   ${CMAKE_CURRENT_SOURCE_DIR}/lib/External/isl/include
 170   ${CMAKE_CURRENT_SOURCE_DIR}/lib/External/pet/include
 171   ${CMAKE_CURRENT_SOURCE_DIR}/lib/External
 172   ${CMAKE_CURRENT_BINARY_DIR}/include
 173   )
 174
 175 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 176   install(DIRECTORY include/
 177     DESTINATION include
 178     FILES_MATCHING
 179     PATTERN "*.h"
 180     PATTERN ".svn" EXCLUDE
 181     )
 182
 183   install(DIRECTORY ${POLLY_BINARY_DIR}/include/
 184     DESTINATION include
 185     FILES_MATCHING
 186     PATTERN "*.h"
 187     PATTERN "CMakeFiles" EXCLUDE
 188     PATTERN ".svn" EXCLUDE
 189     )
 190 endif()
 191
 192 add_definitions( -D_GNU_SOURCE )
 193
 194 add_subdirectory(docs)
 195 add_subdirectory(lib)
 196 add_subdirectory(test)
 197 if (POLLY_GTEST_AVAIL)
 198   add_subdirectory(unittests)
 199 endif ()
 200 add_subdirectory(tools)
 201 # TODO: docs.
 202
 203
 204 configure_file( ${CMAKE_CURRENT_SOURCE_DIR}/include/polly/Config/config.h.cmake
 205                 ${POLLY_BINARY_DIR}/include/polly/Config/config.h )
 206
 207 # Add target to check formatting of polly files
 208 file( GLOB_RECURSE files *.h lib/*.cpp lib/*.c tools/*.cpp tools/*.c tools/*.h unittests/*.cpp)
 209 file( GLOB_RECURSE jsonfiles lib/JSON/*.h lib/JSON/*.cpp)
 210 file( GLOB_RECURSE external lib/External/*.h lib/External/*.c)
 211 list( REMOVE_ITEM files ${jsonfiles} ${external})
 212
 213 set(check_format_depends)
 214 set(update_format_depends)
 215 set(i 0)
 216 foreach (file IN LISTS files)
 217   add_custom_command(OUTPUT polly-check-format${i}
 218     COMMAND clang-format -sort-includes -style=llvm ${file} | diff -u ${file} -
 219     VERBATIM
 220     COMMENT "Checking format of ${file}..."
 221   )
 222   list(APPEND check_format_depends "polly-check-format${i}")
 223
 224   add_custom_command(OUTPUT polly-update-format${i}
 225     COMMAND clang-format -sort-includes -i -style=llvm ${file}
 226     VERBATIM
 227     COMMENT "Updating format of ${file}..."
 228   )
 229   list(APPEND update_format_depends "polly-update-format${i}")
 230
 231   math(EXPR i ${i}+1)
 232 endforeach ()
 233
 234 add_custom_target(polly-check-format DEPENDS ${check_format_depends})
 235 set_target_properties(polly-check-format PROPERTIES FOLDER "Polly")
 236
 237 add_custom_target(polly-update-format DEPENDS ${update_format_depends})
 238 set_target_properties(polly-update-format PROPERTIES FOLDER "Polly")
 239
 240 # Set the variable POLLY_LINK_LIBS in the llvm/tools/ dir.
 241 set(POLLY_LINK_LIBS ${POLLY_LINK_LIBS} PARENT_SCOPE)