cmake/PollyConfig.cmake.in

   1 # This file allows users to call find_package(Polly) and pick up our targets.
   2
   3 find_package(LLVM REQUIRED CONFIG
   4              HINTS "@POLLY_CONFIG_LLVM_CMAKE_DIR@")
   5
   6 set(Polly_CMAKE_DIR ${CMAKE_CURRENT_LIST_DIR})
   7 set(Polly_BUNDLED_ISL @POLLY_BUNDLED_ISL@)
   8 set(Polly_BUNDLED_JSONCPP @POLLY_BUNDLED_JSONCPP@)
   9 set(Polly_ENABLE_GPGPU_CODEGEN @POLLY_ENABLE_GPGPU_CODEGEN@)
  10
  11 set(Polly_DEFINITIONS ${LLVM_DEFINITIONS})
  12 set(Polly_INCLUDE_DIRS @POLLY_CONFIG_INCLUDE_DIRS@ ${LLVM_INCLUDE_DIRS})
  13 set(Polly_LIBRARY_DIRS @POLLY_CONFIG_LIBRARY_DIRS@)
  14 set(Polly_EXPORTED_TARGETS @POLLY_CONFIG_EXPORTED_TARGETS@)
  15 set(Polly_LIBRARIES ${LLVM_LIBRARIES} ${Polly_EXPORTED_TARGETS})
  16
  17 # Imported Targets:
  18 @ISL_CONFIG_CODE@
  19
  20 if (Polly_ENABLE_GPGPU_CODEGEN AND NOT TARGET PollyPPCG)
  21   add_library(PollyPPCG @POLLY_CONFIG_TARGET_PollyPPCG_TYPE@ IMPORTED)
  22   set_property(TARGET PollyPPCG PROPERTY INTERFACE_LINK_LIBRARIES @ISL_TARGET@)
  23 endif()
  24
  25 if (NOT TARGET Polly)
  26   add_library(Polly @POLLY_CONFIG_TARGET_Polly_TYPE@ IMPORTED)
  27   set_property(TARGET Polly PROPERTY INTERFACE_LINK_LIBRARIES @ISL_TARGET@)
  28   if (Polly_ENABLE_GPGPU_CODEGEN)
  29     set_property(TARGET Polly APPEND PROPERTY INTERFACE_LINK_LIBRARIES PollyPPCG)
  30   endif()
  31   set_property(TARGET Polly APPEND PROPERTY INTERFACE_LINK_LIBRARIES @JSONCPP_LIBRARIES@)
  32 endif()
  33
  34 if (NOT TARGET LLVMPolly)
  35   add_library(LLVMPolly @POLLY_CONFIG_TARGET_LLVMPolly_TYPE@ IMPORTED)
  36   set_property(TARGET LLVMPolly PROPERTY INTERFACE_LINK_LIBRARIES Polly)
  37 endif()
  38
  39 # Exported locations:
  40 file(GLOB CONFIG_FILES "${Polly_CMAKE_DIR}/PollyExports-*.cmake")
  41 foreach(f ${CONFIG_FILES})
  42   include(${f})
  43 endforeach()