conf/bitbake.conf

   1 ##################################################################
   2 # Recipe Parsing
   3 ##################################################################
   4 BBMASK = "/(nonworking|obsolete)/"
   5 BBMASK[type] = "regex"
   6
   7 ##################################################################
   8 # Standard target filesystem layout.
   9 ##################################################################
  10
  11 # Path prefixes
  12 layout_prefix = "${prefix}"
  13 layout_exec_prefix = "${exec_prefix}"
  14 layout_base_prefix = "${base_prefix}"
  15
  16 # Base paths
  17 layout_base_bindir = "${base_bindir}"
  18 layout_base_sbindir = "${base_sbindir}"
  19 layout_base_libdir = "${base_libdir}"
  20
  21 # Architecture independent paths
  22 layout_sysconfdir = "${sysconfdir}"
  23 layout_localstatedir = "${localstatedir}"
  24 layout_servicedir = "${servicedir}"
  25 layout_sharedstatedir = "${sharedstatedir}"
  26 layout_datadir = "${datadir}"
  27 layout_infodir = "${infodir}"
  28 layout_mandir = "${mandir}"
  29 layout_docdir = "${docdir}"
  30
  31 # Architecture dependent paths
  32 layout_bindir = "${bindir}"
  33 layout_sbindir = "${sbindir}"
  34 layout_libdir = "${libdir}"
  35 layout_includedir = "${includedir}"
  36 layout_libexecdir = "${libexecdir}"
  37
  38 ##################################################################
  39 # Standard target filesystem paths.
  40 ##################################################################
  41
  42 # Path prefixes
  43 export base_prefix = ""
  44 export prefix = "/usr"
  45 export exec_prefix = "/usr"
  46
  47 # Base paths
  48 export base_bindir = "${base_prefix}/bin"
  49 export base_sbindir = "${base_prefix}/sbin"
  50 export base_libdir = "${base_prefix}/lib"
  51
  52 # Architecture independent paths
  53 export datadir = "${prefix}/share"
  54 export sysconfdir = "${base_prefix}/etc"
  55 export servicedir = "${base_prefix}/srv"
  56 export sharedstatedir = "${base_prefix}/com"
  57 export localstatedir = "${base_prefix}/var"
  58 export infodir = "${datadir}/info"
  59 export mandir = "${datadir}/man"
  60 export docdir = "${datadir}/doc"
  61
  62 # Architecture dependent paths
  63 export bindir = "${exec_prefix}/bin"
  64 export sbindir = "${exec_prefix}/sbin"
  65 export libexecdir = "${exec_prefix}/libexec"
  66 export libdir = "${exec_prefix}/lib"
  67 export includedir = "${exec_prefix}/include"
  68 export oldincludedir = "${exec_prefix}/include"
  69
  70 #
  71 # These must match the various bbclass layout definitions
  72 #
  73 base_bindir_native = "/bin"
  74 base_sbindir_native = "/sbin"
  75 sysconfdir_native = "/etc"
  76 base_libdir_native = "/lib"
  77 prefix_native = "/usr"
  78 bindir_native = "${prefix_native}/bin"
  79 sbindir_native = "${prefix_native}/sbin"
  80 includedir_native = "${prefix_native}/include"
  81 libdir_native = "${prefix_native}/lib"
  82 datadir_native = "${prefix_native}/share"
  83 bindir_cross = "/bin"
  84
  85 #
  86 # Cross recipes need to know about the target layout
  87 # := is used carefully here
  88 #
  89 target_datadir := "${datadir}"
  90
  91 ##################################################################
  92 # Architecture-dependent build variables.
  93 ##################################################################
  94
  95 BUILD_ARCH := "${@os.uname()[4]}"
  96 BUILD_OS := "${@os.uname()[0].lower()}"
  97 BUILD_VENDOR = ""
  98 BUILD_SYS = "${BUILD_ARCH}${BUILD_VENDOR}-${BUILD_OS}"
  99 BUILD_PREFIX = ""
 100 BUILD_CC_ARCH = ""
 101 BUILD_EXEEXT = ""
 102
 103 HOST_ARCH = "${TARGET_ARCH}"
 104 HOST_OS = "${TARGET_OS}"
 105 HOST_VENDOR = "${TARGET_VENDOR}"
 106 HOST_SYS = "${HOST_ARCH}${HOST_VENDOR}-${HOST_OS}"
 107 HOST_PREFIX = "${TARGET_PREFIX}"
 108 HOST_CC_ARCH = "${TARGET_CC_ARCH}"
 109 HOST_EXEEXT = ""
 110
 111 TARGET_ARCH ?= "INVALID"
 112 TARGET_OS = "INVALID"
 113 TARGET_VENDOR = "${BUILD_VENDOR}"
 114 TARGET_SYS = "${TARGET_ARCH}${TARGET_VENDOR}${@['-' + bb.data.getVar('TARGET_OS', d, 1), ''][bb.data.getVar('TARGET_OS', d, 1) in ('', 'custom')]}"
 115 TARGET_PREFIX = "${TARGET_SYS}-"
 116 TARGET_CC_ARCH = ""
 117 TARGET_EXEEXT = ""
 118
 119 SDK_ARCH ?= "${BUILD_ARCH}"
 120 SDK_OS ?= "${BUILD_OS}"
 121 SDK_VENDOR ?= "${BUILD_VENDOR}"
 122 SDK_SYS = "${SDK_ARCH}${SDK_VENDOR}${@['-' + bb.data.getVar('SDK_OS', d, 1), ''][bb.data.getVar('SDK_OS', d, 1) in ('', 'custom')]}"
 123 SDK_PREFIX = "${SDK_SYS}-"
 124 SDK_CC_ARCH ?= "${BUILD_CC_ARCH}"
 125 SDK_EXEEXT = ""
 126
 127 # A shortcut for the commonly used value
 128 EXEEXT = "${HOST_EXEEXT}"
 129
 130 BASE_PACKAGE_ARCH = "${HOST_ARCH}"
 131 PACKAGE_ARCH = "${BASE_PACKAGE_ARCH}"
 132 PACKAGE_EXTRA_ARCHS ?= ""
 133 MACHINE_ARCH = "${@oe.utils.ifelse(bool(d.getVar('MACHINE', True)), '${MACHINE}', \
 134                                    'BASE_PACKAGE_ARCH')}"
 135 PACKAGE_ARCHS = "all any noarch ${TARGET_ARCH} ${PACKAGE_EXTRA_ARCHS} ${MACHINE}"
 136
 137 MULTIMACH_ARCH = "${PACKAGE_ARCH}"
 138 MULTIMACH_TARGET_SYS = "${MULTIMACH_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
 139 MULTIMACH_HOST_SYS = "${MULTIMACH_ARCH}${HOST_VENDOR}-${HOST_OS}"
 140 BASEPKG_HOST_SYS = "${BASE_PACKAGE_ARCH}${HOST_VENDOR}-${HOST_OS}"
 141 BASEPKG_TARGET_SYS = "${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
 142
 143 # select proper CPU to get binary locales generated
 144 QEMU_OPTIONS = ""
 145 QEMU_OPTIONS_iwmmxt  = "-cpu pxa270-c5"
 146 QEMU_OPTIONS_armv6   = "-cpu arm1136"
 147 QEMU_OPTIONS_armv6-novfp = "-cpu arm1136"
 148 QEMU_OPTIONS_armv7a   = "-cpu cortex-a8"
 149
 150 # default compression levels
 151 XZ_COMPRESSION_LEVEL ?= "-e -9"
 152
 153 ##################################################################
 154 # Date/time variables.
 155 ##################################################################
 156
 157 DATE := "${@time.strftime('%Y%m%d',time.gmtime())}"
 158 TIME := "${@time.strftime('%H%M%S',time.gmtime())}"
 159 DATETIME = "${DATE}${TIME}"
 160
 161 ##################################################################
 162 # Openembedded Software Prerequisites.
 163 ##################################################################
 164
 165 # python-native should be here but python relies on building
 166 # its own in staging
 167 ASSUME_PROVIDED = "\
 168     bc-native \
 169     bzip2-native \
 170     cvs-native \
 171     diffstat-native \
 172     patch-native \
 173     python-native-runtime \
 174     svn-native \
 175     texinfo-native \
 176     util-linux-native \
 177     "
 178 ASSUME_PROVIDED[type] = "list"
 179
 180 ##################################################################
 181 # Package default variables.
 182 ##################################################################
 183 PN = "${@bb.parse.BBHandler.vars_from_file('${FILE}', d)[0] or 'defaultpkgname'}"
 184 PV = "${@bb.parse.BBHandler.vars_from_file('${FILE}', d)[1] or '1.0'}"
 185 PR = "${@bb.parse.BBHandler.vars_from_file('${FILE}', d)[2] or 'r0'}"
 186 PF = "${PN}-${EXTENDPE}${PV}-${PR}"
 187 PE ?= "0"
 188 EXTENDPE = "${@int('${PE}') and '${PE}_' or ''}"
 189 EXTENDPEVER = "${@int('${PE}') and '${PE}:' or ''}"
 190 EXTENDPV = "${EXTENDPEVER}${PV}-${PR}${DISTRO_PR}"
 191 P = "${PN}-${PV}"
 192
 193 # Define a PR for kernels that machines can override so things like
 194 # modules get rebuilt
 195 MACHINE_KERNEL_PR = ""
 196
 197 # Base package name
 198 # Automatically derives "foo" from "foo-native", "foo-cross" or "foo-initial"
 199 # otherwise it is the same as PN and P
 200 SPECIAL_PKGSUFFIX = "-native -cross -initial -intermediate -nativesdk -crosssdk -cross-canadian -sdk"
 201 BPN = "${@base_prune_suffix('${PN}', '${SPECIAL_PKGSUFFIX}'.split(), d)}"
 202 BP = "${BPN}-${PV}"
 203
 204 # Package info.
 205
 206 SECTION = "base"
 207 PRIORITY = "optional"
 208 DESCRIPTION = "Version ${PV}-${PR} of package ${PN}"
 209 LICENSE = "unknown"
 210 MAINTAINER = "OpenEmbedded Team <openembedded-devel@lists.openembedded.org>"
 211 HOMEPAGE = "unknown"
 212
 213 # Package dependencies and provides.
 214
 215 # Ensure that -dev packages recommend the corresponding -dev packages of their
 216 # deps, and the same for -dbg.
 217 DEPCHAIN_PRE  = ""
 218 DEPCHAIN_PRE[type] = "list"
 219 DEPCHAIN_POST = "-dev -dbg"
 220 DEPCHAIN_POST[type] = "list"
 221
 222 DEPENDS = ""
 223 RDEPENDS = ""
 224 PROVIDES = ""
 225 PROVIDES_prepend = "${P} ${PF} ${PN} "
 226 RPROVIDES = ""
 227
 228 MULTI_PROVIDER_WHITELIST = "virtual/libintl"
 229
 230 SOLIBS = ".so.*"
 231 SOLIBS_darwin = ".*.dylib"
 232 SOLIBS_darwin8 = ".*.dylib"
 233 SOLIBS_darwin9 = ".*.dylib"
 234
 235 SOLIBSDEV = ".so"
 236 SOLIBSDEV_darwin = ".dylib"
 237 SOLIBSDEV_darwin8 = ".dylib"
 238 SOLIBSDEV_darwin9 = ".dylib"
 239
 240 PACKAGES = "${PN}-dbg ${PN} ${PN}-doc ${PN}-dev ${PN}-static ${PN}-locale"
 241 PACKAGES[type] = "list"
 242 #enable this when bitbake is upgraded to cope with ++ values in the field
 243 PACKAGES_DYNAMIC = "${PN}-locale-*"
 244 PACKAGES_DYNAMIC[type] = "list"
 245 FILES = ""
 246
 247 FILES_${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*${SOLIBS} \
 248             ${sysconfdir} ${sharedstatedir} ${localstatedir} \
 249             ${base_bindir}/* ${base_sbindir}/* \
 250             ${base_libdir}/*${SOLIBS} \
 251             ${datadir}/${PN} ${libdir}/${PN}/* \
 252             ${datadir}/pixmaps ${datadir}/applications \
 253             ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
 254             ${libdir}/bonobo/servers"
 255
 256 FILES_${PN}-doc = "${docdir} ${mandir} ${infodir} ${datadir}/gtk-doc \
 257             ${datadir}/gnome/help"
 258 SECTION_${PN}-doc = "doc"
 259
 260 FILES_${PN}-static = "${libdir}/*.a ${base_libdir}/*.a"
 261
 262 FILES_${PN}-dev = "${includedir} ${libdir}/lib*${SOLIBSDEV} ${libdir}/*.la \
 263                 ${libdir}/*.o ${libdir}/pkgconfig \
 264                 ${base_libdir}/*.o ${datadir}/aclocal ${datadir}/pkgconfig"
 265 SECTION_${PN}-dev = "devel"
 266 ALLOW_EMPTY_${PN}-dev = "1"
 267 RDEPENDS_${PN}-dev = "${PN} (= ${EXTENDPV})"
 268
 269 FILES_${PN}-dbg = "${bindir}/.debug ${sbindir}/.debug ${libexecdir}/.debug ${libdir}/.debug \
 270             ${base_bindir}/.debug ${base_sbindir}/.debug ${base_libdir}/.debug ${libdir}/${PN}/.debug \
 271             ${libdir}/matchbox-panel/.debug ${datadir}/gdb/autoload"
 272 SECTION_${PN}-dbg = "devel"
 273 ALLOW_EMPTY_${PN}-dbg = "1"
 274 RRECOMMENDS_${PN}-dbg = "${PN} (= ${EXTENDPV})"
 275
 276 FILES_${PN}-locale = "${datadir}/locale"
 277
 278 # file:// search paths
 279 FILE_DIRNAME = "${@os.path.dirname(bb.data.getVar('FILE', d))}"
 280 FILESPATHBASE = "${FILE_DIRNAME}"
 281 FILESPATHBASE[type] = "list"
 282 FILESPATHBASE[separator] = ":"
 283 FILESPATHPKG = "${PF}:${P}:${PN}:${BP}:${BPN}:files:."
 284 FILESPATHPKG[type] = "list"
 285 FILESPATHPKG[separator] = ":"
 286 FILESPATH = "${@':'.join(uniq(os.path.normpath(os.path.join(fp, p, o)) for fp in '${FILESPATHBASE}'.split(':') for p in '${FILESPATHPKG}'.split(':') for o in reversed([''] + filter(None, '${OVERRIDES}'.split(':')))))}"
 287 FILESPATH[type] = "list"
 288 FILESPATH[separator] = ":"
 289 FILESDIR = "${@bb.which(d.getVar('FILESPATH', 1), '.')}"
 290
 291 ##################################################################
 292 # General work and output directories for the build system.
 293 ##################################################################
 294
 295 TMPDIR = "${TOPDIR}/tmp"
 296 CACHE = "${TMPDIR}/cache${@['', '/' + str(bb.data.getVar('MACHINE', d, 1))][bool(bb.data.getVar('MACHINE', d, 1))]}"
 297 CO_DIR = "${DL_DIR}"
 298 CVSDIR = "${CO_DIR}/cvs"
 299 SVNDIR = "${CO_DIR}/svn"
 300 GITDIR = "${CO_DIR}/git"
 301 BZRDIR = "${CO_DIR}/bzr"
 302 HGDIR = "${CO_DIR}/hg"
 303
 304 STAMP = "${TMPDIR}/stamps/${MULTIMACH_TARGET_SYS}/${PF}"
 305 WORKDIR = "${TMPDIR}/work/${MULTIMACH_TARGET_SYS}/${PF}"
 306 T = "${WORKDIR}/temp"
 307 D = "${WORKDIR}/image"
 308 S = "${WORKDIR}/${BP}"
 309 B = "${S}"
 310
 311 STAGING_DIR = "${TMPDIR}/sysroots"
 312
 313 STAGING_DIR_NATIVE = "${STAGING_DIR}/${BUILD_SYS}"
 314 STAGING_BINDIR_NATIVE = "${STAGING_DIR_NATIVE}${bindir_native}"
 315 STAGING_SBINDIR_NATIVE = "${STAGING_DIR_NATIVE}${sbindir_native}"
 316 STAGING_BINDIR_CROSS  = "${STAGING_DIR_NATIVE}${prefix_native}/${BASE_PACKAGE_ARCH}${base_bindir_native}"
 317 STAGING_LIBDIR_NATIVE = "${STAGING_DIR_NATIVE}${libdir_native}"
 318 STAGING_INCDIR_NATIVE = "${STAGING_DIR_NATIVE}${includedir_native}"
 319 STAGING_ETCDIR_NATIVE = "${STAGING_DIR_NATIVE}${sysconfdir_native}"
 320 STAGING_DATADIR_NATIVE = "${STAGING_DIR_NATIVE}${datadir_native}"
 321
 322 # This should really be MULTIMACH_HOST_SYS but that breaks "all" and machine
 323 # specific packages - hack around it for now.
 324 STAGING_DIR_HOST = "${STAGING_DIR}/${BASEPKG_HOST_SYS}"
 325 STAGING_BINDIR = "${STAGING_DIR_HOST}${bindir}"
 326 STAGING_LIBDIR = "${STAGING_DIR_HOST}${libdir}"
 327 STAGING_INCDIR = "${STAGING_DIR_HOST}${includedir}"
 328 STAGING_ETCDIR = "${STAGING_DIR_HOST}${sysconfdir}"
 329 STAGING_DATADIR = "${STAGING_DIR_HOST}${datadir}"
 330 STAGING_EXECPREFIXDIR = "${STAGING_DIR_HOST}${exec_prefix}"
 331 STAGING_LOADER_DIR = "${STAGING_DIR_HOST}/loader"
 332 STAGING_FIRMWARE_DIR = "${STAGING_DIR_HOST}/firmware"
 333 STAGING_PYDIR = "${STAGING_DIR}/lib/python2.4"
 334
 335 # This should really be MULTIMACH_TARGET_SYS but that breaks "all" and machine
 336 # specific packages - hack around it for now.
 337 STAGING_DIR_TARGET = "${STAGING_DIR}/${BASEPKG_TARGET_SYS}"
 338 STAGING_DIR_JAVA = "${STAGING_DATADIR}/java"
 339
 340 STAGING_DIR_SDK = "${STAGING_DIR}/${SDK_SYS}"
 341
 342 # Setting DEPLOY_DIR outside of TMPDIR is helpful, when you are using
 343 # packaged staging and/or multimachine.
 344 DEPLOY_DIR ?= "${TMPDIR}/deploy"
 345 DEPLOY_DIR_TAR = "${DEPLOY_DIR}/tar"
 346 DEPLOY_DIR_IPK = "${DEPLOY_DIR}/ipk"
 347 DEPLOY_DIR_RPM = "${DEPLOY_DIR}/rpm"
 348 DEPLOY_DIR_DEB = "${DEPLOY_DIR}/deb"
 349 DEPLOY_DIR_IMAGE = "${DEPLOY_DIR}/images"
 350 DEPLOY_DIR_TOOLS = "${DEPLOY_DIR}/tools"
 351
 352 PKGDATA_DIR = "${TMPDIR}/pkgdata/${MULTIMACH_TARGET_SYS}"
 353
 354 SDK_NAME = "${DISTRO}/${TARGET_ARCH}"
 355 SDK_PATH = "/usr/local/${SDK_NAME}"
 356 SDKPATH = "${SDK_PATH}"
 357
 358 ##################################################################
 359 # Kernel info.
 360 ##################################################################
 361
 362 STAGING_KERNEL_DIR = "${STAGING_DIR}/${MULTIMACH_TARGET_SYS}/kernel"
 363
 364 ##################################################################
 365 # Specific image creation and rootfs population info.
 366 ##################################################################
 367
 368 IMAGE_ROOTFS = "${TMPDIR}/rootfs/${PN}"
 369 IMAGE_BASENAME = "${PN}"
 370 IMAGE_NAME = "${IMAGE_BASENAME}-${MACHINE}-${DATETIME}"
 371 IMAGE_LINK_NAME = "${IMAGE_BASENAME}-${MACHINE}"
 372 IMAGE_EXTRA_SPACE = 10240
 373
 374 UBI_VOLNAME ?= "${MACHINE}-rootfs"
 375
 376 IMAGE_CMD = ""
 377 IMAGE_CMD_jffs2 = "mkfs.jffs2 -x lzo --root=${IMAGE_ROOTFS} --faketime --output=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.jffs2 ${EXTRA_IMAGECMD}"
 378 IMAGE_CMD_yaffs2 = "mkyaffs2image ${EXTRA_IMAGECMD} ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.yaffs2"
 379 IMAGE_CMD_cramfs = "mkcramfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cramfs ${EXTRA_IMAGECMD}"
 380 IMAGE_CMD_ext2 = "genext2fs -i 4096 -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}"
 381 IMAGE_CMD_ext2.gz = "install -d ${DEPLOY_DIR_IMAGE}/tmp.gz ; genext2fs -i 4096 -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}; gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2; mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2.gz"
 382 IMAGE_CMD_ext2.bz2 = "install -d ${DEPLOY_DIR_IMAGE}/tmp.bz2 ; genext2fs -i 4096 -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}; bzip2 -f -9 ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext2; mv ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext2.bz2 ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2.bz2"
 383 IMAGE_CMD_ext3 = "genext2fs -i 4096 -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3"
 384 IMAGE_CMD_ext3.gz = "install -d ${DEPLOY_DIR_IMAGE}/tmp.gz ; genext2fs -i 4096 -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3; gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3; mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3.gz"
 385 IMAGE_CMD_ext3.bz2 = "install -d ${DEPLOY_DIR_IMAGE}/tmp.bz2 ; genext2fs -i 4096 -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext3; bzip2 -f -9 ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext3; mv ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext3.bz2 ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3.bz2"
 386 IMAGE_CMD_ext4 = "genext2fs -i 4096 -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext4 ${EXTRA_IMAGECMD}; tune2fs -O extents,uninit_bg,dir_index,has_journal ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext4; set +e; e2fsck -yfDC0 ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext4;chk=$?; set -e; case $chk in 0|1|2);;*)exit $chk;;esac;"
 387 IMAGE_CMD_ext4.gz = "install -d ${DEPLOY_DIR_IMAGE}/tmp.gz ; genext2fs -i 4096 -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext4 ${EXTRA_IMAGECMD}; tune2fs -O extents,uninit_bg,dir_index,has_journal ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext4; set +e;e2fsck -yfDC0 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext4;chk=$?; set -e; case $chk in 0|1|2);;*)exit $chk;;esac; gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext4; mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext4.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext4.gz"
 388 IMAGE_CMD_ext4.bz2 = "install -d ${DEPLOY_DIR_IMAGE}/tmp.bz2 ; genext2fs -i 4096 -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext4 ${EXTRA_IMAGECMD}; tune2fs -O extents,uninit_bg,dir_index,has_journal ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext4; set +e; e2fsck -yfDC0 ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext4;chk=$?; set -e; case $chk in 0|1|2);;*)exit $chk;;esac; bzip2 -f -9 ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext4; mv ${DEPLOY_DIR_IMAGE}/tmp.bz2/${IMAGE_NAME}.rootfs.ext4.bz2 ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext4.bz2"
 389 IMAGE_CMD_ext4.xz = "install -d ${DEPLOY_DIR_IMAGE}/tmp.xz; genext2fs -i 4096 -b ${ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.xz/${IMAGE_NAME}.rootfs.ext4 ${EXTRA_IMAGECMD}; tune2fs -O extents,uninit_bg,dir_index,has_journal ${DEPLOY_DIR_IMAGE}/tmp.xz/${IMAGE_NAME}.rootfs.ext4; set +e; e2fsck -yfDC0 ${DEPLOY_DIR_IMAGE}/tmp.xz/${IMAGE_NAME}.rootfs.ext4;chk=$?; set -e; case $chk in 0|1|2);;*)exit $chk;;esac; xz -c ${XZ_COMPRESSION_LEVEL} ${DEPLOY_DIR_IMAGE}/tmp.xz/${IMAGE_NAME}.rootfs.ext4 > ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext4.xz ; rm -f ${DEPLOY_DIR_IMAGE}/tmp.xz/${IMAGE_NAME}.rootfs.ext4 ; rmdir ${DEPLOY_DIR_IMAGE}/tmp.xz"
 390
 391 IMAGE_CMD_squashfs = "mksquashfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs ${EXTRA_IMAGECMD} -noappend"
 392 IMAGE_CMD_squashfs-lzma = "mksquashfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs-lzma ${EXTRA_IMAGECMD} -noappend -comp lzma"
 393 IMAGE_CMD_tar = "cd ${IMAGE_ROOTFS} && tar -cvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar ."
 394 IMAGE_CMD_tar.gz = "cd ${IMAGE_ROOTFS} && tar -zcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.gz ."
 395 IMAGE_CMD_tar.bz2 = "cd ${IMAGE_ROOTFS} && tar -jcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.bz2 ."
 396 IMAGE_CMD_cpio = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio) ${EXTRA_IMAGECMD}"
 397 IMAGE_CMD_cpio.gz = "type cpio >/dev/null; cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | gzip -c -9 >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz) ${EXTRA_IMAGECMD}"
 398 IMAGE_CMD_cpio.xz = "type cpio >/dev/null; cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | xz -c ${XZ_COMPRESSION_LEVEL} > ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.xz) ${EXTRA_IMAGECMD}"
 399 IMAGE_CMD_cpio.gz.u-boot = "type cpio >/dev/null; cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | gzip -c -9 >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz) ${EXTRA_IMAGECMD}; mkimage -A ${UBOOT_ARCH} -O linux -T ramdisk -C gzip -n ${IMAGE_NAME} -d ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz.u-boot"
 400 IMAGE_CMD_cpio.lzma = "type cpio >/dev/null; cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | lzma -c -9 >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.lzma) ${EXTRA_IMAGECMD}"
 401 IMAGE_CMD_ubi = "echo \[ubifs\] > ubinize.cfg ; echo mode=ubi >> ubinize.cfg ; echo image=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubifs >> ubinize.cfg ; echo vol_id=0 >> ubinize.cfg ; echo vol_type=dynamic >> ubinize.cfg ; echo vol_name=${UBI_VOLNAME} >> ubinize.cfg ; echo vol_flags=autoresize >> ubinize.cfg;mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubifs ${MKUBIFS_ARGS} && ubinize -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubi ${UBINIZE_ARGS} ubinize.cfg"
 402 IMAGE_CMD_ubifs = "mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.ubifs.img ${MKUBIFS_ARGS}"
 403
 404 EXTRA_IMAGECMD = ""
 405 EXTRA_IMAGECMD_jffs2 = ""
 406 EXTRA_IMAGECMD_yaffs2 = "1"
 407 EXTRA_IMAGECMD_squashfs = ""
 408 EXTRA_IMAGECMD_squashfs-lzma = ""
 409 EXTRA_IMAGECMD_cpio = ""
 410 EXTRA_IMAGECMD_cpio.gz = ""
 411 EXTRA_IMAGECMD_cpio.lzma = ""
 412 EXTRA_IMAGECMD_ubi = ""
 413 EXTRA_IMAGECMD_ubifs = ""
 414
 415 IMAGE_DEPENDS = ""
 416 IMAGE_DEPENDS_jffs2 = "mtd-utils-native"
 417 IMAGE_DEPENDS_yaffs2 = "yaffs2-utils-native"
 418 IMAGE_DEPENDS_cramfs = "cramfs-native"
 419 IMAGE_DEPENDS_ext2 = "genext2fs-native"
 420 IMAGE_DEPENDS_ext2.gz = "genext2fs-native"
 421 IMAGE_DEPENDS_ext2.bz2 = "genext2fs-native"
 422 IMAGE_DEPENDS_ext3 = "genext2fs-native e2fsprogs-native"
 423 IMAGE_DEPENDS_ext3.gz = "genext2fs-native e2fsprogs-native"
 424 IMAGE_DEPENDS_ext3.bz2 = "genext2fs-native e2fsprogs-native"
 425 IMAGE_DEPENDS_ext4 = "genext2fs-native e2fsprogs-native"
 426 IMAGE_DEPENDS_ext4.gz = "genext2fs-native e2fsprogs-native"
 427 IMAGE_DEPENDS_ext4.bz2 = "genext2fs-native e2fsprogs-native"
 428 IMAGE_DEPENDS_ext4.xz = "genext2fs-native e2fsprogs-native xz-native"
 429 IMAGE_DEPENDS_cpio.gz.u-boot = "u-boot-mkimage-native"
 430 IMAGE_DEPENDS_cpio.lzma = "lzma-native"
 431 IMAGE_DEPENDS_cpio.xz = "xz-native"
 432 IMAGE_DEPENDS_squashfs = "squashfs-tools-native"
 433 IMAGE_DEPENDS_squashfs-lzma = "squashfs-tools-native"
 434 IMAGE_DEPENDS_ubi = "mtd-utils-native"
 435 IMAGE_DEPENDS_ubifs = "mtd-utils-native"
 436
 437 EXTRA_IMAGEDEPENDS = ""
 438
 439 ##################################################################
 440 # Toolchain info.
 441 ##################################################################
 442
 443 # This variable is needed to set to 'yes' in conjuction with
 444 # PREFERRED_VERSION for libtool when choosing libtool >= 2.4
 445 # by default this is unset and should be so for libtools < 2.4
 446
 447 LIBTOOL_HAS_SYSROOT ?= "no"
 448 LIBTOOL_HAS_SYSROOT[type] = "boolean"
 449
 450 BBPATH_BIN = "${@':'.join('%s/bin' % path for path in '${BBPATH}'.split(':'))}"
 451 PATH_prepend = "${BBPATH_BIN}:${STAGING_BINDIR_CROSS}:${STAGING_DIR_NATIVE}${sbindir_native}:${STAGING_BINDIR_NATIVE}:${STAGING_DIR_NATIVE}${base_sbindir_native}:${STAGING_DIR_NATIVE}/${base_bindir_native}:"
 452 PATH[type] = "list"
 453 PATH[separator] = ":"
 454 export PATH
 455
 456 ##################################################################
 457 # Build utility info.
 458 ##################################################################
 459
 460 CCACHE ?= ""
 461 TOOLCHAIN_OPTIONS = ""
 462 TOOLCHAIN_PATH ?= "${STAGING_DIR_NATIVE}${prefix_native}/${BASE_PACKAGE_ARCH}"
 463 TOOLCHAIN_SYSPATH ?= "${TOOLCHAIN_PATH}/${TARGET_SYS}"
 464
 465 export CC = "${CCACHE}${HOST_PREFIX}gcc ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 466 export CXX = "${CCACHE}${HOST_PREFIX}g++ ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 467 export F77 = "${CCACHE}${HOST_PREFIX}g77 ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 468 export CPP = "${HOST_PREFIX}gcc -E${TOOLCHAIN_OPTIONS}"
 469 export LD = "${HOST_PREFIX}ld${TOOLCHAIN_OPTIONS}"
 470 export CCLD = "${CC}"
 471 export AR = "${HOST_PREFIX}ar"
 472 export AS = "${HOST_PREFIX}as"
 473 export RANLIB = "${HOST_PREFIX}ranlib"
 474 export STRIP = "${HOST_PREFIX}strip"
 475 export OBJCOPY = "${HOST_PREFIX}objcopy"
 476 export OBJDUMP = "${HOST_PREFIX}objdump"
 477 export NM = "${HOST_PREFIX}nm"
 478 PYTHON = "${@sys.executable}"
 479
 480 export BUILD_CC = "${CCACHE}${BUILD_PREFIX}gcc ${BUILD_CC_ARCH}"
 481 export BUILD_CXX = "${CCACHE}${BUILD_PREFIX}g++ ${BUILD_CC_ARCH}"
 482 export BUILD_F77 = "${CCACHE}${BUILD_PREFIX}g77 ${BUILD_CC_ARCH}"
 483 export BUILD_CPP = "${BUILD_PREFIX}cpp"
 484 export BUILD_LD = "${BUILD_PREFIX}ld"
 485 export BUILD_CCLD = "${BUILD_PREFIX}gcc"
 486 export BUILD_AR = "${BUILD_PREFIX}ar"
 487 export BUILD_RANLIB = "${BUILD_PREFIX}ranlib"
 488 export BUILD_STRIP = "${BUILD_PREFIX}strip"
 489
 490 export MAKE = "make"
 491 EXTRA_OEMAKE = "-e MAKEFLAGS="
 492
 493 ##################################################################
 494 # Patch handling.
 495 ##################################################################
 496 PATCHTOOL = 'quilt'
 497 PATCHRESOLVE = 'noop'
 498
 499 ##################################################################
 500 # Build flags and options.
 501 ##################################################################
 502
 503 export BUILD_CPPFLAGS = "-isystem${STAGING_INCDIR_NATIVE}"
 504 export CPPFLAGS = "${TARGET_CPPFLAGS}"
 505 export TARGET_CPPFLAGS = "-isystem${STAGING_DIR_TARGET}${includedir}"
 506 export SDK_CPPFLAGS = "-isystem${STAGING_DIR_SDK}${includedir} -isystem${STAGING_DIR_HOST}${includedir}"
 507
 508 export BUILD_CFLAGS = "${BUILD_CPPFLAGS} ${BUILD_OPTIMIZATION}"
 509 export CFLAGS = "${TARGET_CFLAGS}"
 510 export TARGET_CFLAGS = "${TARGET_CPPFLAGS} ${SELECTED_OPTIMIZATION}"
 511 export SDK_CFLAGS = "${SDK_CPPFLAGS} ${SELECTED_OPTIMIZATION}"
 512
 513 export BUILD_CXXFLAGS = "${BUILD_CFLAGS} -fpermissive"
 514 export CXXFLAGS = "${TARGET_CXXFLAGS}"
 515 export TARGET_CXXFLAGS = "${TARGET_CFLAGS} -fpermissive"
 516 export SDK_CXXFLAGS = "${SDK_CFLAGS} -fpermissive"
 517
 518 export BUILD_LDFLAGS = "-L${STAGING_LIBDIR_NATIVE} \
 519                         -Wl,-rpath-link,${STAGING_LIBDIR_NATIVE} \
 520                         -Wl,-rpath,${STAGING_LIBDIR_NATIVE} -Wl,-O1"
 521
 522 export LDFLAGS = "${TARGET_LDFLAGS}"
 523 export TARGET_LDFLAGS = '${@["-L${STAGING_DIR_TARGET}${libdir} -Wl,-rpath-link,${STAGING_DIR_TARGET}${libdir} -Wl,-O1 ${TARGET_LINK_HASH_STYLE}", "-Wl,-O1 ${TARGET_LINK_HASH_STYLE}"][bb.data.getVar('LIBTOOL_HAS_SYSROOT', d, 1) == "yes"]}'
 524
 525 export SDK_LDFLAGS = "-L${STAGING_DIR_SDK}${libdir} \
 526                          -Wl,-rpath-link,${STAGING_DIR_SDK}${libdir} \
 527                          -Wl,-O1"
 528
 529 # Which flags to leave by strip-flags() in bin/build/oebuild.sh ?
 530 ALLOWED_FLAGS = "-O -mcpu -march -pipe"
 531
 532 # Pass parallel make options to the compile task only
 533 EXTRA_OEMAKE_prepend_task_do_compile = "${PARALLEL_MAKE} "
 534 EXTRA_OEMAKE_prepend_task-compile = "${PARALLEL_MAKE} "
 535
 536 ##################################################################
 537 # Optimization flags.
 538 ##################################################################
 539
 540 FULL_OPTIMIZATION = "-fexpensive-optimizations -fomit-frame-pointer -frename-registers -O2"
 541 DEBUG_OPTIMIZATION = "-O -fno-omit-frame-pointer -g"
 542 SELECTED_OPTIMIZATION = "${@bb.data.getVar(['FULL_OPTIMIZATION', 'DEBUG_OPTIMIZATION'][bb.data.getVar('DEBUG_BUILD', d, 1) == '1'], d, 1)}"
 543 BUILD_OPTIMIZATION = "-O2 -g"
 544
 545 ##################################################################
 546 # Bootstrap stuff.
 547 ##################################################################
 548
 549 BOOTSTRAP_EXTRA_RDEPENDS = ""
 550 BOOTSTRAP_EXTRA_RRECOMMENDS = ""
 551
 552 ##################################################################
 553 # Palmtop stuff.
 554 ##################################################################
 555
 556 export QTDIR = "${STAGING_DIR_HOST}/qt2"
 557 export QPEDIR = "${STAGING_DIR_HOST}"
 558 export OPIEDIR = "${STAGING_DIR_HOST}"
 559 export palmtopdir = "${libdir}/opie"
 560 export palmqtdir = "${palmtopdir}"
 561
 562 ##################################################################
 563 # Download locations and utilities.
 564 ##################################################################
 565
 566 OE_STRICT_CHECKSUMS ?= "1"
 567
 568 ADOBE_MIRROR = "http://fpdownload.macromedia.com/get/flashplayer/current/"
 569 APACHE_MIRROR = "http://archive.apache.org/dist"
 570 DEBIAN_MIRROR = "ftp://ftp.debian.org/debian/pool"
 571 E_MIRROR = "http://download.enlightenment.org/releases"
 572 E_SVN = "svn://svn.enlightenment.org/svn/e"
 573 FREEBSD_MIRROR = "ftp://ftp.freebsd.org/pub/FreeBSD/"
 574 FREEDESKTOP_CVS = "cvs://anoncvs:anoncvs@anoncvs.freedesktop.org/cvs"
 575 FREESMARTPHONE_GIT = "git://git.freesmartphone.org"
 576 GENTOO_MIRROR = "http://distfiles.gentoo.org/distfiles"
 577 GNOME_GIT = "git://git.gnome.org"
 578 GNOME_MIRROR = "http://ftp.gnome.org/pub/GNOME/sources"
 579 GNU_MIRROR = "ftp://ftp.gnu.org/gnu"
 580 GPE_MIRROR = "http://gpe.linuxtogo.org/download/source"
 581 GPE_EXTRA_SVN = "svn://projects.linuxtogo.org/svn/gpe/trunk/extra;module=${PN}"
 582 GPE_SVN = "svn://projects.linuxtogo.org/svn/gpe/trunk/base;module=${PN}"
 583 GPEPHONE_MIRROR = "http://gpephone.linuxtogo.org/download/gpephone"
 584 GPEPHONE_SVN = "svn://projects.linuxtogo.org/svn/gpephone/trunk/source;module=${PN}"
 585 HANDHELDS_CVS = "cvs://anoncvs:anoncvs@anoncvs.handhelds.org/cvs"
 586 KERNELORG_MIRROR = "http://kernel.org"
 587 OPIE_GIT = "git://gitorious.org/opie/opie.git"
 588 SAVANNAH_MIRROR = "http://download.savannah.gnu.org/"
 589 SOURCEFORGE_MIRROR = "http://downloads.sourceforge.net"
 590 XLIBS_MIRROR = "http://xlibs.freedesktop.org/release"
 591 XORG_MIRROR = "http://xorg.freedesktop.org/releases"
 592
 593 # You can use the mirror of your country to get faster downloads by putting
 594 #  export DEBIAN_MIRROR = "ftp://ftp.de.debian.org/debian/pool"
 595 #     into your local.conf
 596
 597 FETCHCMD_svn = "/usr/bin/env svn --non-interactive"
 598 FETCHCMD_cvs = "/usr/bin/env cvs"
 599 FETCHCMD_wget = "/usr/bin/env wget -t 5 --no-check-certificate"
 600 FETCHCMD_bzr = "/usr/bin/env bzr"
 601 FETCHCMD_hg = "/usr/bin/env hg"
 602
 603 FETCHCOMMAND = "ERROR, this must be a BitBake bug"
 604 FETCHCOMMAND_wget = "/usr/bin/env 'PATH=${PATH}' wget -t 5 --passive-ftp --no-check-certificate -P ${DL_DIR} '${URI}'"
 605 FETCHCOMMAND_cvs = "/usr/bin/env 'PATH=${PATH}' cvs '-d${CVSROOT}' co ${CVSCOOPTS} ${CVSMODULE}"
 606 FETCHCOMMAND_svn = "/usr/bin/env svn co --non-interactive ${SVNCOOPTS} ${SVNROOT} ${SVNMODULE}"
 607 RESUMECOMMAND = "ERROR, this must be a BitBake bug"
 608 RESUMECOMMAND_wget = "/usr/bin/env 'PATH=${PATH}' wget -c -t 5 --passive-ftp --no-check-certificate -P ${DL_DIR} '${URI}'"
 609 UPDATECOMMAND = "ERROR, this must be a BitBake bug"
 610 UPDATECOMMAND_cvs = "/usr/bin/env 'PATH=${PATH}' cvs -d${CVSROOT} update -d -P ${CVSCOOPTS}"
 611 UPDATECOMMAND_svn = "/usr/bin/env svn update --non-interactive --force --accept theirs-full ${SVNCOOPTS}"
 612 SRCDATE = "${DATE}"
 613 SRCREV = "1"
 614 SRCPV = "${@bb.fetch.get_srcrev(d)}"
 615 AUTOREV = "${SRCPV}"
 616
 617 # For now disable autoincrement of revision counter in SRCPV, whoever wants it, should enable it in local.conf or distro config
 618 # Revision counter is incremented only locally (bad for multiple builders filling shared feeds), LOCALCOUNT can be used to maintain
 619 # counter globally in OE metadata (LOCALCOUNT value set in recipe).
 620 # Make sure you disable it, if you want always upgradable paths for git recipes without bumping LOCALCOUNT with every SRCREV change
 621 # or if you're using AUTOREV feature.
 622 BB_LOCALCOUNT_OVERRIDE = "1"
 623
 624 # Value for revision counter in GIT recipes (NNNN in PV="1.0+gitrNNNN+a7401084a72285c8d3485bacf4eed593f303b1b7-r4.4")
 625 LOCALCOUNT = "0"
 626 LOCALCOUNT[type] = "integer"
 627
 628 SRC_URI = "file://${FILE}"
 629 SRC_URI[type] = "list"
 630
 631 ##################################################################
 632 # UI/Interaction Configuration
 633 ##################################################################
 634
 635 SHELLRCCMD = "bash --rcfile $TERMRCFILE"
 636 export SHELLCMDS = "${SHELLRCCMD}"
 637 # Some common terminal programs to choose from
 638 GNOME_TERMCMD = 'gnome-terminal --disable-factory -t "$TERMWINDOWTITLE"'
 639 GNOME_TERMCMDRUN = '${GNOME_TERMCMD} -x $SHELLCMDS'
 640 SCREEN_TERMCMD = 'screen -D -m -t "$TERMWINDOWTITLE"'
 641 SCREEN_TERMCMDRUN = '${SCREEN_TERMCMD} $SHELLCMDS'
 642 XTERM_TERMCMD = 'xterm -T "$TERMWINDOWTITLE"'
 643 XTERM_TERMCMDRUN = '${XTERM_TERMCMD} -e $SHELLCMDS'
 644 KONSOLE_TERMCMD = 'konsole -T "$TERMWINDOWTITLE"'
 645 KONSOLE_TERMCMDRUN = '${KONSOLE_TERMCMD} -e $SHELLCMDS'
 646
 647 # Set a default
 648 TERMCMD ?= "${GNOME_TERMCMD}"
 649 TERMCMDRUN ?= "${GNOME_TERMCMDRUN}"
 650
 651 ##################################################################
 652 # Miscellaneous utilities.
 653 ##################################################################
 654
 655 MKTEMPDIRCMD = "mktemp -d -q ${TMPBASE}"
 656 MKTEMPCMD = "mktemp -q ${TMPBASE}"
 657
 658 # GNU patch tries to be intellgent about checking out read-only files from
 659 # a RCS, which freaks out those special folks with active Perforce clients
 660 # the following makes patch ignore RCS:
 661
 662 export PATCH_GET="0"
 663
 664 # Program to be used to build ipkg packages
 665
 666 OPKGBUILDCMD = "opkg-build -o 0 -g 0"
 667
 668 ##################################################################
 669 # Not sure about the rest of this yet.
 670 ##################################################################
 671
 672 # slot - currently unused by OE. portage remnants
 673 SLOT = "0"
 674
 675 # Other
 676 export HOSTNAME := "${@os.uname()[1]}"
 677
 678 PKG_CONFIG_DIR = "${STAGING_LIBDIR}/pkgconfig"
 679 export PKG_CONFIG_PATH = "${STAGING_LIBDIR}/pkgconfig:${STAGING_DATADIR}/pkgconfig"
 680 PKG_CONFIG_PATH .= ":${STAGING_LIBDIR_NATIVE}/pkgconfig:${STAGING_DATADIR_NATIVE}/pkgconfig"
 681 PKG_CONFIG_PATH[type] = "list"
 682 PKG_CONFIG_PATH[separator] = ":"
 683
 684 export PKG_CONFIG_SYSROOT_DIR = "${STAGING_DIR}/${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
 685 export PKG_CONFIG_DISABLE_UNINSTALLED = "yes"
 686
 687 export XDG_DATA_DIRS = "${STAGING_DATADIR}"
 688
 689 export QMAKE_MKSPEC_PATH = "${STAGING_DATADIR_NATIVE}/qmake"
 690 export STAGING_SIPDIR = "${STAGING_DATADIR_NATIVE}/sip"
 691 export STAGING_IDLDIR = "${STAGING_DATADIR}/idl"
 692
 693 # library package naming
 694 AUTO_LIBNAME_PKGS = "${PACKAGES}"
 695
 696 # Globally toggle certain dependencies
 697 ENTERPRISE_DISTRO ?= "0"
 698
 699 # Pre-build configuration output
 700
 701 BUILDCFG_HEADER = "Build Configuration:"
 702 BUILDCFG_VARS ?= "BB_VERSION METADATA_BRANCH METADATA_REVISION TARGET_ARCH TARGET_OS MACHINE DISTRO DISTRO_VERSION"
 703 BUILDCFG_VARS[type] = "list"
 704 BUILDCFG_VARS_append_arm = " TARGET_FPU"
 705 BUILDCFG_VARS_append_armeb = " TARGET_FPU"
 706 BUILDCFG_NEEDEDVARS ?= "TARGET_ARCH TARGET_OS"
 707 BUILDCFG_NEEDEDVARS[type] = "list"
 708
 709 ###
 710 ### Config file processing
 711 ###
 712
 713 # Overrides are processed left to right, so the ones that are named later take precedence.
 714 # You generally want them to go from least to most specific.
 715 MACHINE_OVERRIDES ?= ""
 716 OVERRIDES = "pn-${PN}:fail-fast:build-${BUILD_OS}:${TARGET_ARCH}:${TARGET_OS}:${DISTRO}:\
 717 ${@[':'.join(d.getVar('MACHINE_OVERRIDES', True).split())+':',''][d.getVar('MACHINE_OVERRIDES', True).strip() == '']}\
 718 ${MACHINE}:local"
 719 OVERRIDES[type] = "list"
 720 OVERRIDES[separator] = ":"
 721
 722 ##################################################################
 723 # Include the rest of the config files.
 724 ##################################################################
 725
 726 include conf/site.conf
 727 include conf/auto.conf
 728 include conf/local.conf
 729 # USERDISTRO should always contain original DISTRO value as set by user
 730 # If a distro config overrides DISTRO for whatever reason (e.g. to get
 731 # overrides like it wants), USERDISTRO must be reassigned with := first
 732 USERDISTRO = "${DISTRO}"
 733 include conf/build/${BUILD_SYS}.conf
 734 include conf/target/${TARGET_SYS}.conf
 735 include conf/machine/${MACHINE}.conf
 736 include conf/distro/${DISTRO}.conf
 737 include conf/documentation.conf
 738 require conf/sanity.conf
 739 require conf/abi_version.conf
 740 require conf/enterprise.conf
 741 require conf/compatibility-providers.conf
 742
 743 ##################################################################
 744 # Weak variables (usually to retain backwards compatibility)
 745 ##################################################################
 746
 747 DL_DIR ?= "${TMPDIR}/downloads"
 748 PSTAGE_DIR ?= "${TMPDIR}/pstage"
 749 IMAGE_FSTYPES ?= "tar.gz"
 750 PCMCIA_MANAGER ?= "pcmcia-cs"
 751 DEFAULT_TASK_PROVIDER ?= "task-base"
 752 MACHINE_TASK_PROVIDER ?= "${DEFAULT_TASK_PROVIDER}"
 753 IMAGE_ROOTFS_SIZE ?= "65536"
 754 IMAGE_ROOTFS_SIZE[type] = "integer"
 755 IMAGE_ROOTFS_SIZE_ext2 ?= "65536"
 756 IMAGE_ROOTFS_SIZE_ext2.gz ?= "65536"
 757 IMAGE_ROOTFS_SIZE_ext3 ?= "65536"
 758 IMAGE_ROOTFS_SIZE_ext3.gz ?= "65536"
 759 DISTRO_PR ?= ""
 760
 761 # Forcefully set CACHE now so future changes to things like
 762 # MACHINE don't change the path to the cache
 763 CACHE := "${CACHE}"
 764
 765 # Default to disabling packaged staging code
 766 export PSTAGING_ACTIVE = "0"
 767 PSTAGING_ACTIVE[type] = "boolean"
 768
 769 ##################################################################
 770 # Magic Cookie for SANITY CHECK
 771 ##################################################################
 772 OES_BITBAKE_CONF = "1"
 773
 774 ##################################################################
 775 # Machine properties and task-base stuff
 776 ##################################################################
 777
 778 MACHINE_FEATURES ?= "kernel26"
 779 DISTRO_FEATURES ?= ""
 780 # Add thumb-interwork to feature list if selected machine supports it.
 781 DISTRO_FEATURES += ' ${@["", "thumb-interwork"][bb.data.getVar('THUMB_INTERWORK', d, 1) == "yes"]}'
 782
 783 # This is used to limit what packages goes into images built, so set big by default
 784 ROOT_FLASH_SIZE ?= "256"
 785 ROOT_FLASH_SIZE[type] = "integer"
 786
 787 MACHINE_GUI_CLASS ?= "smallscreen"
 788 MACHINE_GUI_CLASS[type] = "choice"
 789 MACHINE_GUI_CLASS[choices] = "bigscreen smallscreen"
 790 # GUI_MACHINE_CLASS is deprecated, please use MACHINE_GUI_CLASS instead
 791 GUI_MACHINE_CLASS ?= "${MACHINE_GUI_CLASS}"
 792 MACHINE_DISPLAY_WIDTH_PIXELS ?= "240"
 793 MACHINE_DISPLAY_WIDTH_PIXELS[type] = "integer"
 794 MACHINE_DISPLAY_HEIGHT_PIXELS ?= "320"
 795 MACHINE_DISPLAY_HEIGHT_PIXELS[type] = "integer"
 796 MACHINE_DISPLAY_ORIENTATION ?= "0"
 797 MACHINE_DISPLAY_ORIENTATION[type] = "boolean"
 798 MACHINE_DISPLAY_BPP ?= "16"
 799 MACHINE_DISPLAY_BPP[type] = "integer"
 800
 801 DISTRO_EXTRA_RDEPENDS ?= ""
 802 DISTRO_EXTRA_RRECOMMENDS ?= ""
 803 MACHINE_EXTRA_RDEPENDS ?= ""
 804 MACHINE_EXTRA_RRECOMMENDS ?= ""
 805 MACHINE_ESSENTIAL_EXTRA_RDEPENDS ?= ""
 806 MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS ?= ""
 807
 808 DISTRO_FEATURES[type] = "list"
 809 MACHINE_FEATURES[type] = "list"
 810
 811 COMBINED_FEATURES = "\
 812     ${@base_both_contain('DISTRO_FEATURES', 'MACHINE_FEATURES', 'alsa', d)} \
 813     ${@base_both_contain('DISTRO_FEATURES', 'MACHINE_FEATURES', 'bluetooth', d)} \
 814     ${@base_both_contain('DISTRO_FEATURES', 'MACHINE_FEATURES', 'ext2', d)} \
 815     ${@base_both_contain('DISTRO_FEATURES', 'MACHINE_FEATURES', 'vfat', d)} \
 816     ${@base_both_contain('DISTRO_FEATURES', 'MACHINE_FEATURES', 'irda', d)} \
 817     ${@base_both_contain('DISTRO_FEATURES', 'MACHINE_FEATURES', 'pcmcia', d)} \
 818     ${@base_both_contain('DISTRO_FEATURES', 'MACHINE_FEATURES', 'pci', d)} \
 819     ${@base_both_contain('DISTRO_FEATURES', 'MACHINE_FEATURES', 'usbgadget', d)} \
 820     ${@base_both_contain('DISTRO_FEATURES', 'MACHINE_FEATURES', 'usbhost', d)} \
 821     ${@base_both_contain('DISTRO_FEATURES', 'MACHINE_FEATURES', 'wifi', d)}"
 822
 823 # We want madwifi if all of the following are true:
 824 # - distro has pci, wifi, and madwifi in its features
 825 # - machine has pci in its features
 826 COMBINED_FEATURES += "${@base_ifelse( \
 827     base_contains('DISTRO_FEATURES', ('pci', 'wifi', 'madwifi'), True, False, d) and \
 828     base_contains('MACHINE_FEATURES', 'pci', True, False, d), \
 829     'madwifi', '')}"
 830
 831 # We want hostap if all of the following are true:
 832 # - 'wifi' and 'hostap' are in distro features
 833 # - either 'pci' or 'pcmcia' are in both distro and machine features
 834 COMBINED_FEATURES += "${@base_ifelse( \
 835     base_contains('DISTRO_FEATURES', ('wifi', 'hostap'), True, False, d) and \
 836     ((base_contains('MACHINE_FEATURES', 'pci', True, False, d) and \
 837       base_contains('DISTRO_FEATURES', 'pci', True, False, d)) or \
 838      (base_contains('MACHINE_FEATURES', 'pcmcia', True, False, d) and \
 839       base_contains('DISTRO_FEATURES', 'pcmcia', True, False, d))), \
 840     'hostap', '')}"
 841 COMBINED_FEATURES[type] = "list"
 842
 843 # Make sure MACHINE isn't exported
 844 # (breaks binutils at least)
 845 MACHINE[unexport] = "1"
 846
 847 # Make sure TARGET_ARCH isn't exported
 848 # (breaks Makefiles using implicit rules, e.g. quilt, as GNU make has this
 849 # in them, undocumented)
 850 TARGET_ARCH[unexport] = "1"
 851
 852 # Make sure DISTRO isn't exported
 853 # (breaks sysvinit at least)
 854 DISTRO[unexport] = "1"
 855
 856 # Make sure that LIBC isn't exported
 857 # (breaks perl at least)
 858 LIBC[unexport] = "1"