recipes/vim/vim_7.2.bb

   1 VIMVER = "72"
   2
   3 # vim-tiny sets that too
   4 VIMFEATURES ?= "big"
   5
   6 # GUI type - gvim recipe sets "gtk2"
   7 VIMGUI ?= "no"
   8
   9 # gvim recipes uses "--with-x"
  10 VIMX ?= "--without-x"
  11
  12 require vim.inc
  13
  14 PR = "${INC_PR}.3"
  15
  16 # 001-411.diff contains 411 patches fetched from upstream
  17 SRC_URI += "file://001-411.diff;apply=no"
  18 SRC_URI += "file://configure.in_remove_CC_quotes.patch;apply=no"
  19 SRC_URI += "file://vimrc"
  20
  21 # we need to apply patches in other dir then ${S}
  22 do_applypatch() {
  23         cd ${WORKDIR}/vim${VIMVER}
  24         patch -p1 <${WORKDIR}/001-411.diff
  25         patch -p1 <${WORKDIR}/configure.in_remove_CC_quotes.patch
  26 }
  27
  28 addtask applypatch after do_unpack before do_patch
  29
  30 do_install_append() {
  31     install -m 0644 ${WORKDIR}/vimrc ${D}/${datadir}/vim
  32 }
  33
  34 RCONFLICTS_${PN} = "gvim vim-tiny"
  35 PACKAGES =+ "${PN}-vimrc"
  36
  37 FILES_${PN}-vimrc = "${datadir}/vim/vimrc"
  38