configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-liboffloadmic \
 154                 target-libhsail-rt \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libmpx \
 161                 target-libssp \
 162                 target-libquadmath \
 163                 target-libgfortran \
 164                 target-libffi \
 165                 target-libobjc \
 166                 target-libada \
 167                 target-libgo"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 AC_ARG_WITH(system-zlib,
 243 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 244 # Make sure we don't let ZLIB be added if we didn't want it.
 245 if test x$with_system_zlib = xyes ; then
 246   use_included_zlib=no
 247   noconfigdirs="$noconfigdirs zlib"
 248 fi
 249
 250 # some tools are so dependent upon X11 that if we're not building with X,
 251 # it's not even worth trying to configure, much less build, that tool.
 252
 253 case ${with_x} in
 254   yes | "") ;; # the default value for this tree is that X11 is available
 255   no)
 256     skipdirs="${skipdirs} tk itcl libgui"
 257     # We won't be able to build gdbtk without X.
 258     enable_gdbtk=no
 259     ;;
 260   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 261 esac
 262
 263 # Some are only suitable for cross toolchains.
 264 # Remove these if host=target.
 265 cross_only="target-libgloss target-newlib target-opcodes"
 266
 267 case $is_cross_compiler in
 268   no) skipdirs="${skipdirs} ${cross_only}" ;;
 269 esac
 270
 271 # If both --with-headers and --with-libs are specified, default to
 272 # --without-newlib.
 273 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 274    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 275   if test x"${with_newlib}" = x ; then
 276     with_newlib=no
 277   fi
 278 fi
 279
 280 # Recognize --with-newlib/--without-newlib.
 281 case ${with_newlib} in
 282   no) skipdirs="${skipdirs} target-newlib" ;;
 283   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 284 esac
 285
 286 AC_ARG_ENABLE(as-accelerator-for,
 287 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 288                 [build as offload target compiler.
 289                 Specify offload host triple by ARG])])
 290
 291 AC_ARG_ENABLE(offload-targets,
 292 [AS_HELP_STRING([--enable-offload-targets=LIST],
 293                 [enable offloading to devices from comma-separated LIST of
 294                 TARGET[=DIR]. Use optional path to find offload target compiler
 295                 during the build])],
 296 [
 297   if test x"$enable_offload_targets" = x; then
 298     AC_MSG_ERROR([no offload targets specified])
 299   fi
 300 ], [enable_offload_targets=])
 301
 302 # Handle --enable-gold, --enable-ld.
 303 # --disable-gold [--enable-ld]
 304 #     Build only ld.  Default option.
 305 # --enable-gold [--enable-ld]
 306 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 307 #     as "ld.bfd" and "ld".
 308 # --enable-gold=default [--enable-ld]
 309 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 310 #     install ld as "ld.bfd".
 311 # --enable-gold[=default] --disable-ld
 312 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 313 # --enable-gold --enable-ld=default
 314 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 315 #     and ld.bfd).
 316 #     In other words, ld is default
 317 # --enable-gold=default --enable-ld=default
 318 #     Error.
 319
 320 default_ld=
 321 AC_ARG_ENABLE(gold,
 322 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 323                 [build gold @<:@ARG={default,yes,no}@:>@])],
 324 ENABLE_GOLD=$enableval,
 325 ENABLE_GOLD=no)
 326 case "${ENABLE_GOLD}" in
 327   yes|default)
 328     # Check for ELF target.
 329     is_elf=no
 330     case "${target}" in
 331       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 332       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 333       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 334       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 335         case "${target}" in
 336           *-*-linux*aout* | *-*-linux*oldld*)
 337             ;;
 338           *)
 339             is_elf=yes
 340             ;;
 341         esac
 342     esac
 343
 344     if test "$is_elf" = "yes"; then
 345       # Check for target supported by gold.
 346       case "${target}" in
 347         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 348         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 349           configdirs="$configdirs gold"
 350           if test x${ENABLE_GOLD} = xdefault; then
 351             default_ld=gold
 352           fi
 353           ENABLE_GOLD=yes
 354           ;;
 355       esac
 356     fi
 357     ;;
 358   no)
 359     ;;
 360   *)
 361     AC_MSG_ERROR([invalid --enable-gold argument])
 362     ;;
 363 esac
 364
 365 AC_ARG_ENABLE(ld,
 366 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 367                 [build ld @<:@ARG={default,yes,no}@:>@])],
 368 ENABLE_LD=$enableval,
 369 ENABLE_LD=yes)
 370
 371 case "${ENABLE_LD}" in
 372   default)
 373     if test x${default_ld} != x; then
 374       AC_MSG_ERROR([either gold or ld can be the default ld])
 375     fi
 376     ;;
 377   yes)
 378     ;;
 379   no)
 380     if test x${ENABLE_GOLD} != xyes; then
 381       AC_MSG_WARN([neither ld nor gold are enabled])
 382     fi
 383     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 384     ;;
 385   *)
 386     AC_MSG_ERROR([invalid --enable-ld argument])
 387     ;;
 388 esac
 389
 390 # PR gas/19109
 391 # Decide the default method for compressing debug sections.
 392 # Provide a configure time option to override our default.
 393 AC_ARG_ENABLE(compressed_debug_sections,
 394 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 395                 [Enable compressed debug sections for gas, gold or ld by
 396                  default])],
 397 [
 398   if test x"$enable_compressed_debug_sections" = xyes; then
 399     AC_MSG_ERROR([no program with compressed debug sections specified])
 400   fi
 401 ], [enable_compressed_debug_sections=])
 402
 403 # Configure extra directories which are host specific
 404
 405 case "${host}" in
 406   *-cygwin*)
 407     configdirs="$configdirs libtermcap" ;;
 408 esac
 409
 410 # A target can indicate whether a language isn't supported for some reason.
 411 # Only spaces may be used in this macro; not newlines or tabs.
 412 unsupported_languages=
 413
 414 # Remove more programs from consideration, based on the host or
 415 # target this usually means that a port of the program doesn't
 416 # exist yet.
 417
 418 case "${host}" in
 419   i[[3456789]]86-*-msdosdjgpp*)
 420     noconfigdirs="$noconfigdirs tcl tk itcl"
 421     ;;
 422 esac
 423
 424
 425 AC_ARG_ENABLE(libquadmath,
 426 AS_HELP_STRING([--disable-libquadmath],
 427   [do not build libquadmath directory]),
 428 ENABLE_LIBQUADMATH=$enableval,
 429 ENABLE_LIBQUADMATH=yes)
 430 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 431   noconfigdirs="$noconfigdirs target-libquadmath"
 432 fi
 433
 434
 435 AC_ARG_ENABLE(libquadmath-support,
 436 AS_HELP_STRING([--disable-libquadmath-support],
 437   [disable libquadmath support for Fortran]),
 438 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 439 ENABLE_LIBQUADMATH_SUPPORT=yes)
 440 enable_libquadmath_support=
 441 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 442   enable_libquadmath_support=no
 443 fi
 444
 445
 446 AC_ARG_ENABLE(libada,
 447 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 448 ENABLE_LIBADA=$enableval,
 449 ENABLE_LIBADA=yes)
 450 if test "${ENABLE_LIBADA}" != "yes" ; then
 451   noconfigdirs="$noconfigdirs gnattools"
 452 fi
 453
 454 AC_ARG_ENABLE(libssp,
 455 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 456 ENABLE_LIBSSP=$enableval,
 457 ENABLE_LIBSSP=yes)
 458
 459 AC_ARG_ENABLE(libstdcxx,
 460 AS_HELP_STRING([--disable-libstdcxx],
 461   [do not build libstdc++-v3 directory]),
 462 ENABLE_LIBSTDCXX=$enableval,
 463 ENABLE_LIBSTDCXX=default)
 464 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 465   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 466 fi]
 467
 468 # If this is accelerator compiler and its target is intelmic we enable
 469 # target liboffloadmic by default.  If this is compiler with offloading
 470 # for intelmic we enable host liboffloadmic by default.  Otherwise
 471 # liboffloadmic is disabled by default.
 472 AC_ARG_ENABLE([liboffloadmic],
 473 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 474                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 475 [case "$enableval" in
 476   no | host | target)
 477     enable_liboffloadmic=$enableval ;;
 478   *)
 479     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 480 esac],
 481 [if test x"$enable_as_accelerator_for" != x; then
 482   case "${target}" in
 483     *-intelmic-* | *-intelmicemul-*)
 484       enable_liboffloadmic=target
 485       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 486       ;;
 487     *)
 488       enable_liboffloadmic=no
 489       ;;
 490   esac
 491 else
 492   case "${enable_offload_targets}" in
 493     *-intelmic-* | *-intelmicemul-*)
 494       enable_liboffloadmic=host
 495       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 496       ;;
 497     *)
 498       enable_liboffloadmic=no
 499       ;;
 500     esac
 501 fi])
 502 AC_SUBST(extra_liboffloadmic_configure_flags)
 503
 504 # Enable libgomp by default on hosted POSIX systems, and a few others.
 505 if test x$enable_libgomp = x ; then
 506     case "${target}" in
 507     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 508         ;;
 509     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 510         ;;
 511     *-*-solaris2* | *-*-hpux11*)
 512         ;;
 513     *-*-darwin* | *-*-aix*)
 514         ;;
 515     nvptx*-*-*)
 516         ;;
 517     *)
 518         noconfigdirs="$noconfigdirs target-libgomp"
 519         ;;
 520     esac
 521 fi
 522
 523 # Disable libatomic on unsupported systems.
 524 if test -d ${srcdir}/libatomic; then
 525     if test x$enable_libatomic = x; then
 526         AC_MSG_CHECKING([for libatomic support])
 527         if (srcdir=${srcdir}/libatomic; \
 528                 . ${srcdir}/configure.tgt; \
 529                 test -n "$UNSUPPORTED")
 530         then
 531             AC_MSG_RESULT([no])
 532             noconfigdirs="$noconfigdirs target-libatomic"
 533         else
 534             AC_MSG_RESULT([yes])
 535         fi
 536     fi
 537 fi
 538
 539 # Disable liboffloadmic on unsupported systems.
 540 if test -d ${srcdir}/liboffloadmic; then
 541     if test x$enable_liboffloadmic != xno; then
 542         AC_MSG_CHECKING([for liboffloadmic support])
 543         if (srcdir=${srcdir}/liboffloadmic; \
 544                 . ${srcdir}/configure.tgt; \
 545                 test -n "$UNSUPPORTED")
 546         then
 547             AC_MSG_RESULT([no])
 548             noconfigdirs="$noconfigdirs target-liboffloadmic"
 549         else
 550             AC_MSG_RESULT([yes])
 551         fi
 552     fi
 553 fi
 554
 555 # Disable libitm on unsupported systems.
 556 if test -d ${srcdir}/libitm; then
 557     if test x$enable_libitm = x; then
 558         AC_MSG_CHECKING([for libitm support])
 559         if (srcdir=${srcdir}/libitm; \
 560                 . ${srcdir}/configure.tgt; \
 561                 test -n "$UNSUPPORTED")
 562         then
 563             AC_MSG_RESULT([no])
 564             noconfigdirs="$noconfigdirs target-libitm"
 565         else
 566             AC_MSG_RESULT([yes])
 567         fi
 568     fi
 569 fi
 570
 571 # Disable libsanitizer on unsupported systems.
 572 if test -d ${srcdir}/libsanitizer; then
 573     if test x$enable_libsanitizer = x; then
 574         AC_MSG_CHECKING([for libsanitizer support])
 575         if (srcdir=${srcdir}/libsanitizer; \
 576                 . ${srcdir}/configure.tgt; \
 577                 test -n "$UNSUPPORTED")
 578         then
 579             AC_MSG_RESULT([no])
 580             noconfigdirs="$noconfigdirs target-libsanitizer"
 581         else
 582             AC_MSG_RESULT([yes])
 583         fi
 584     fi
 585 fi
 586
 587 # Disable libvtv on unsupported systems.
 588 if test -d ${srcdir}/libvtv; then
 589     if test x$enable_libvtv = x; then
 590         AC_MSG_CHECKING([for libvtv support])
 591         if (srcdir=${srcdir}/libvtv; \
 592                 . ${srcdir}/configure.tgt; \
 593                 test "$VTV_SUPPORTED" != "yes")
 594         then
 595             AC_MSG_RESULT([no])
 596             noconfigdirs="$noconfigdirs target-libvtv"
 597         else
 598             AC_MSG_RESULT([yes])
 599         fi
 600     fi
 601 fi
 602
 603
 604 # Enable libmpx on supported systems by request.
 605 if test -d ${srcdir}/libmpx; then
 606     if test x$enable_libmpx = x; then
 607        AC_MSG_CHECKING([for libmpx support])
 608        if (srcdir=${srcdir}/libmpx; \
 609                . ${srcdir}/configure.tgt; \
 610                test "$LIBMPX_SUPPORTED" != "yes")
 611        then
 612            AC_MSG_RESULT([no])
 613            noconfigdirs="$noconfigdirs target-libmpx"
 614        else
 615            AC_MSG_RESULT([yes])
 616        fi
 617     fi
 618 fi
 619
 620 # Disable libhsail-rt on unsupported systems.
 621 if test -d ${srcdir}/libhsail-rt; then
 622     if test x$enable_libhsail_rt = x; then
 623         AC_MSG_CHECKING([for libhsail-rt support])
 624         if (srcdir=${srcdir}/libhsail-rt; \
 625                 . ${srcdir}/configure.tgt; \
 626                 test -n "$UNSUPPORTED")
 627         then
 628             AC_MSG_RESULT([no])
 629             unsupported_languages="$unsupported_languages brig"
 630             # This implicitly disables also target-libhsail-rt as it won't
 631             # get added to the build without BRIG FE.
 632         else
 633             AC_MSG_RESULT([yes])
 634         fi
 635     fi
 636 fi
 637
 638
 639 # Disable libquadmath for some systems.
 640 case "${target}" in
 641   avr-*-*)
 642     noconfigdirs="$noconfigdirs target-libquadmath"
 643     ;;
 644   # libquadmath is unused on AIX and libquadmath build process use of
 645   # LD_LIBRARY_PATH can break AIX bootstrap.
 646   powerpc-*-aix* | rs6000-*-aix*)
 647     noconfigdirs="$noconfigdirs target-libquadmath"
 648     ;;
 649 esac
 650
 651 # Disable libssp for some systems.
 652 case "${target}" in
 653   avr-*-*)
 654     # No hosted I/O support.
 655     noconfigdirs="$noconfigdirs target-libssp"
 656     ;;
 657   powerpc-*-aix* | rs6000-*-aix*)
 658     noconfigdirs="$noconfigdirs target-libssp"
 659     ;;
 660   rl78-*-*)
 661     # libssp uses a misaligned load to trigger a fault, but the RL78
 662     # doesn't fault for those - instead, it gives a build-time error
 663     # for explicit misaligned loads.
 664     noconfigdirs="$noconfigdirs target-libssp"
 665     ;;
 666   visium-*-*)
 667     # No hosted I/O support.
 668     noconfigdirs="$noconfigdirs target-libssp"
 669     ;;
 670 esac
 671
 672 # Disable libstdc++-v3 for some systems.
 673 # Allow user to override this if they pass --enable-libstdc++-v3
 674 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 675   case "${target}" in
 676     *-*-vxworks*)
 677       # VxWorks uses the Dinkumware C++ library.
 678       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 679       ;;
 680     arm*-wince-pe*)
 681       # the C++ libraries don't build on top of CE's C libraries
 682       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 683       ;;
 684     avr-*-*)
 685       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 686       ;;
 687     ft32-*-*)
 688       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 689       ;;
 690   esac
 691 fi
 692
 693 # Disable Fortran for some systems.
 694 case "${target}" in
 695   mmix-*-*)
 696     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 697     unsupported_languages="$unsupported_languages fortran"
 698     ;;
 699 esac
 700
 701 # Disable libffi for some systems.
 702 case "${target}" in
 703   powerpc-*-darwin*)
 704     ;;
 705   i[[3456789]]86-*-darwin*)
 706     ;;
 707   x86_64-*-darwin[[912]]*)
 708     ;;
 709   *-*-darwin*)
 710     noconfigdirs="$noconfigdirs target-libffi"
 711     ;;
 712   *-*-netware*)
 713     noconfigdirs="$noconfigdirs target-libffi"
 714     ;;
 715   *-*-phoenix*)
 716     noconfigdirs="$noconfigdirs target-libffi"
 717     ;;
 718   *-*-rtems*)
 719     noconfigdirs="$noconfigdirs target-libffi"
 720     ;;
 721   *-*-tpf*)
 722     noconfigdirs="$noconfigdirs target-libffi"
 723     ;;
 724   *-*-uclinux*)
 725     noconfigdirs="$noconfigdirs target-libffi"
 726     ;;
 727   *-*-vxworks*)
 728     noconfigdirs="$noconfigdirs target-libffi"
 729     ;;
 730   aarch64*-*-freebsd*)
 731     noconfigdirs="$noconfigdirs target-libffi"
 732     ;;
 733   alpha*-*-*vms*)
 734     noconfigdirs="$noconfigdirs target-libffi"
 735     ;;
 736   arm*-*-freebsd*)
 737     noconfigdirs="$noconfigdirs target-libffi"
 738     ;;
 739   arm-wince-pe)
 740     noconfigdirs="$noconfigdirs target-libffi"
 741     ;;
 742   arm*-*-symbianelf*)
 743     noconfigdirs="$noconfigdirs target-libffi"
 744     ;;
 745   cris-*-* | crisv32-*-*)
 746     case "${target}" in
 747       *-*-linux*)
 748         ;;
 749       *) # See PR46792 regarding target-libffi.
 750         noconfigdirs="$noconfigdirs target-libffi";;
 751     esac
 752     ;;
 753   hppa*64*-*-hpux*)
 754     noconfigdirs="$noconfigdirs target-libffi"
 755     ;;
 756   hppa*-hp-hpux11*)
 757     ;;
 758   hppa*-*-hpux*)
 759     noconfigdirs="$noconfigdirs target-libffi"
 760     ;;
 761   ia64*-*-*vms*)
 762     noconfigdirs="$noconfigdirs target-libffi"
 763     ;;
 764   i[[3456789]]86-w64-mingw*)
 765     noconfigdirs="$noconfigdirs target-libffi"
 766     ;;
 767   i[[3456789]]86-*-mingw*)
 768     noconfigdirs="$noconfigdirs target-libffi"
 769     ;;
 770   x86_64-*-mingw*)
 771     noconfigdirs="$noconfigdirs target-libffi"
 772     ;;
 773   mmix-*-*)
 774     noconfigdirs="$noconfigdirs target-libffi"
 775     ;;
 776   powerpc-*-aix*)
 777     ;;
 778   rs6000-*-aix*)
 779     ;;
 780   ft32-*-*)
 781     noconfigdirs="$noconfigdirs target-libffi"
 782     ;;
 783   *-*-lynxos*)
 784     noconfigdirs="$noconfigdirs target-libffi"
 785     ;;
 786 esac
 787
 788 # Disable the go frontend on systems where it is known to not work. Please keep
 789 # this in sync with contrib/config-list.mk.
 790 case "${target}" in
 791 *-*-darwin* | *-*-cygwin* | *-*-mingw*)
 792     unsupported_languages="$unsupported_languages go"
 793     ;;
 794 esac
 795
 796 # Disable libgo for some systems where it is known to not work.
 797 # For testing, you can easily override this with --enable-libgo.
 798 if test x$enable_libgo = x; then
 799     case "${target}" in
 800     *-*-darwin*)
 801         # PR 46986
 802         noconfigdirs="$noconfigdirs target-libgo"
 803         ;;
 804     *-*-cygwin* | *-*-mingw*)
 805         noconfigdirs="$noconfigdirs target-libgo"
 806         ;;
 807     esac
 808 fi
 809
 810 # Default libgloss CPU subdirectory.
 811 libgloss_dir="$target_cpu"
 812
 813 case "${target}" in
 814   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 815     libgloss_dir=wince
 816     ;;
 817   aarch64*-*-* )
 818     libgloss_dir=aarch64
 819     ;;
 820   arm*-*-*)
 821     libgloss_dir=arm
 822     ;;
 823   cris-*-* | crisv32-*-*)
 824     libgloss_dir=cris
 825     ;;
 826   hppa*-*-*)
 827     libgloss_dir=pa
 828     ;;
 829   i[[3456789]]86-*-*)
 830     libgloss_dir=i386
 831     ;;
 832   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 833     libgloss_dir=m68hc11
 834     ;;
 835   m68*-*-* | fido-*-*)
 836     libgloss_dir=m68k
 837     ;;
 838   mips*-*-*)
 839     libgloss_dir=mips
 840     ;;
 841   powerpc*-*-*)
 842     libgloss_dir=rs6000
 843     ;;
 844   sparc*-*-*)
 845     libgloss_dir=sparc
 846     ;;
 847 esac
 848
 849 # Disable newlib and libgloss for various target OSes.
 850 case "${target}" in
 851   alpha*-dec-osf*)
 852     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 853     ;;
 854   i[[3456789]]86-*-linux*)
 855     # This section makes it possible to build newlib natively on linux.
 856     # If we are using a cross compiler then don't configure newlib.
 857     if test x${is_cross_compiler} != xno ; then
 858       noconfigdirs="$noconfigdirs target-newlib"
 859     fi
 860     noconfigdirs="$noconfigdirs target-libgloss"
 861     # If we are not using a cross compiler, do configure newlib.
 862     # Note however, that newlib will only be configured in this situation
 863     # if the --with-newlib option has been given, because otherwise
 864     # 'target-newlib' will appear in skipdirs.
 865     ;;
 866   i[[3456789]]86-*-rdos*)
 867     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 868     ;;
 869   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 870     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 871     ;;
 872   sparc-*-sunos4*)
 873     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 874     ;;
 875   *-*-aix*)
 876     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 877     ;;
 878   *-*-beos*)
 879     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 880     ;;
 881   *-*-chorusos)
 882     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 883     ;;
 884   *-*-dragonfly*)
 885     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 886     ;;
 887   *-*-freebsd*)
 888     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 889     ;;
 890   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 891     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 892     ;;
 893   *-*-lynxos*)
 894     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 895     ;;
 896   *-*-mingw*)
 897     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 898     ;;
 899   *-*-netbsd*)
 900     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 901     ;;
 902   *-*-netware*)
 903     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 904     ;;
 905   *-*-tpf*)
 906     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 907     ;;
 908   *-*-uclinux*)
 909     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 910     ;;
 911   *-*-vxworks*)
 912     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 913     ;;
 914 esac
 915
 916 case "${target}" in
 917   *-*-chorusos)
 918     ;;
 919   aarch64-*-darwin*)
 920     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 921     noconfigdirs="$noconfigdirs sim target-rda"
 922     ;;
 923   arm-*-darwin*)
 924     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 925     noconfigdirs="$noconfigdirs sim target-rda"
 926     ;;
 927   powerpc-*-darwin*)
 928     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 929     noconfigdirs="$noconfigdirs sim target-rda"
 930     ;;
 931   i[[3456789]]86-*-darwin*)
 932     noconfigdirs="$noconfigdirs ld gprof"
 933     noconfigdirs="$noconfigdirs sim target-rda"
 934     ;;
 935   x86_64-*-darwin[[912]]*)
 936     noconfigdirs="$noconfigdirs ld gas gprof"
 937     noconfigdirs="$noconfigdirs sim target-rda"
 938     ;;
 939   *-*-darwin*)
 940     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 941     noconfigdirs="$noconfigdirs sim target-rda"
 942     ;;
 943   *-*-dragonfly*)
 944     ;;
 945   *-*-freebsd*)
 946     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 947         && test -f /usr/local/include/gmp.h; then
 948       with_gmp=/usr/local
 949     fi
 950     ;;
 951   *-*-kaos*)
 952     # Remove unsupported stuff on all kaOS configurations.
 953     noconfigdirs="$noconfigdirs target-libgloss"
 954     ;;
 955   *-*-netbsd*)
 956     ;;
 957   *-*-netware*)
 958     ;;
 959   *-*-phoenix*)
 960     noconfigdirs="$noconfigdirs target-libgloss"
 961     ;;
 962   *-*-rtems*)
 963     noconfigdirs="$noconfigdirs target-libgloss"
 964     # this is not caught below because this stanza matches earlier
 965     case $target in
 966       or1k*-*-*) noconfigdirs="$noconfigdirs gdb" ;;
 967     esac
 968     ;;
 969     # The tpf target doesn't support gdb yet.
 970   *-*-tpf*)
 971     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 972     ;;
 973   *-*-uclinux*)
 974     noconfigdirs="$noconfigdirs target-rda"
 975     ;;
 976   *-*-vxworks*)
 977     ;;
 978   alpha*-dec-osf*)
 979     # ld works, but does not support shared libraries.
 980     # gas doesn't generate exception information.
 981     noconfigdirs="$noconfigdirs gas ld"
 982     ;;
 983   alpha*-*-*vms*)
 984     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 985     ;;
 986   alpha*-*-*)
 987     # newlib is not 64 bit ready
 988     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 989     ;;
 990   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 991     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 992     ;;
 993   arc*-*-*)
 994     noconfigdirs="$noconfigdirs sim"
 995     ;;
 996   arm-*-pe*)
 997     noconfigdirs="$noconfigdirs target-libgloss"
 998     ;;
 999   arm-*-riscix*)
1000     noconfigdirs="$noconfigdirs ld target-libgloss"
1001     ;;
1002   avr-*-*)
1003     if test x${with_avrlibc} != xno; then
1004       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1005     fi
1006     ;;
1007   c4x-*-* | tic4x-*-*)
1008     noconfigdirs="$noconfigdirs target-libgloss"
1009     ;;
1010   tic54x-*-*)
1011     noconfigdirs="$noconfigdirs target-libgloss gdb"
1012     ;;
1013   d10v-*-*)
1014     noconfigdirs="$noconfigdirs target-libgloss"
1015     ;;
1016   d30v-*-*)
1017     noconfigdirs="$noconfigdirs gdb"
1018     ;;
1019   fr30-*-elf*)
1020     noconfigdirs="$noconfigdirs gdb"
1021     ;;
1022   ft32-*-*)
1023     noconfigdirs="$noconfigdirs target-rda gprof"
1024     ;;
1025   moxie-*-*)
1026     noconfigdirs="$noconfigdirs"
1027     ;;
1028   h8300*-*-*)
1029     noconfigdirs="$noconfigdirs target-libgloss"
1030     ;;
1031   h8500-*-*)
1032     noconfigdirs="$noconfigdirs target-libgloss"
1033     ;;
1034   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1035     ;;
1036   hppa*64*-*-hpux*)
1037     noconfigdirs="$noconfigdirs gdb"
1038     ;;
1039   hppa*-*-hpux11*)
1040     noconfigdirs="$noconfigdirs gdb ld"
1041     ;;
1042   hppa*64*-*-linux*)
1043     ;;
1044   hppa*-*-linux*)
1045     ;;
1046   hppa*-*-*elf* | \
1047   hppa*-*-lites* | \
1048   hppa*-*-openbsd* | \
1049   hppa*64*-*-*)
1050     ;;
1051   hppa*-*-pro*)
1052     ;;
1053   hppa*-*-*)
1054     noconfigdirs="$noconfigdirs ld"
1055     ;;
1056   i960-*-*)
1057     noconfigdirs="$noconfigdirs gdb"
1058     ;;
1059   ia64*-*-elf*)
1060     # No gdb support yet.
1061     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1062     ;;
1063   ia64*-**-hpux*)
1064     # No ld support yet.
1065     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1066     ;;
1067   ia64*-*-*vms*)
1068     # No ld support yet.
1069     noconfigdirs="$noconfigdirs libgui itcl ld"
1070     ;;
1071   i[[3456789]]86-w64-mingw*)
1072     ;;
1073   i[[3456789]]86-*-mingw*)
1074     target_configdirs="$target_configdirs target-winsup"
1075     ;;
1076   *-*-cygwin*)
1077     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1078     noconfigdirs="$noconfigdirs target-libgloss"
1079     # always build newlib if winsup directory is present.
1080     if test -d "$srcdir/winsup/cygwin"; then
1081       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1082     elif test -d "$srcdir/newlib"; then
1083       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1084     fi
1085     ;;
1086   i[[3456789]]86-*-pe)
1087     noconfigdirs="$noconfigdirs target-libgloss"
1088     ;;
1089   i[[3456789]]86-*-sco3.2v5*)
1090     # The linker does not yet know about weak symbols in COFF,
1091     # and is not configured to handle mixed ELF and COFF.
1092     noconfigdirs="$noconfigdirs ld target-libgloss"
1093     ;;
1094   i[[3456789]]86-*-sco*)
1095     noconfigdirs="$noconfigdirs gprof target-libgloss"
1096     ;;
1097   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1098     noconfigdirs="$noconfigdirs target-libgloss"
1099     ;;
1100   i[[3456789]]86-*-sysv4*)
1101     noconfigdirs="$noconfigdirs target-libgloss"
1102     ;;
1103   i[[3456789]]86-*-beos*)
1104     noconfigdirs="$noconfigdirs gdb"
1105     ;;
1106   i[[3456789]]86-*-rdos*)
1107     noconfigdirs="$noconfigdirs gdb"
1108     ;;
1109   mmix-*-*)
1110     noconfigdirs="$noconfigdirs gdb"
1111     ;;
1112   mt-*-*)
1113     noconfigdirs="$noconfigdirs sim"
1114     ;;
1115   powerpc-*-aix*)
1116     # copied from rs6000-*-* entry
1117     noconfigdirs="$noconfigdirs gprof"
1118     ;;
1119   powerpc*-*-winnt* | powerpc*-*-pe*)
1120     target_configdirs="$target_configdirs target-winsup"
1121     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1122     # always build newlib.
1123     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1124     ;;
1125     # This is temporary until we can link against shared libraries
1126   powerpcle-*-solaris*)
1127     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1128     ;;
1129   powerpc-*-beos*)
1130     noconfigdirs="$noconfigdirs gdb"
1131     ;;
1132   rs6000-*-lynxos*)
1133     noconfigdirs="$noconfigdirs gprof"
1134     ;;
1135   rs6000-*-aix*)
1136     noconfigdirs="$noconfigdirs gprof"
1137     ;;
1138   rs6000-*-*)
1139     noconfigdirs="$noconfigdirs gprof"
1140     ;;
1141   m68k-apollo-*)
1142     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1143     ;;
1144   microblaze*)
1145     noconfigdirs="$noconfigdirs gprof"
1146     ;;
1147   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1148     if test x$with_newlib = xyes; then
1149       noconfigdirs="$noconfigdirs gprof"
1150     fi
1151     ;;
1152   mips*-*-irix5*)
1153     noconfigdirs="$noconfigdirs gprof target-libgloss"
1154     ;;
1155   mips*-*-irix6*)
1156     noconfigdirs="$noconfigdirs gprof target-libgloss"
1157     ;;
1158   mips*-*-bsd*)
1159     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1160     ;;
1161   mips*-*-linux*)
1162     ;;
1163   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1164   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1165     noconfigdirs="$noconfigdirs ld gas gprof"
1166     ;;
1167   mips*-*-*)
1168     noconfigdirs="$noconfigdirs gprof"
1169     ;;
1170   nvptx*-*-*)
1171     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1172     ;;
1173   or1k*-*-*)
1174     noconfigdirs="$noconfigdirs gdb"
1175     ;;
1176   sh-*-*)
1177     case "${target}" in
1178       sh*-*-elf)
1179          ;;
1180       *)
1181          noconfigdirs="$noconfigdirs target-libgloss" ;;
1182     esac
1183     ;;
1184   sparc-*-sunos4*)
1185     if test x${is_cross_compiler} = xno ; then
1186            use_gnu_ld=no
1187     fi
1188     ;;
1189   tic6x-*-*)
1190     noconfigdirs="$noconfigdirs sim"
1191     ;;
1192   tilepro*-*-* | tilegx*-*-*)
1193     noconfigdirs="$noconfigdirs sim"
1194     ;;
1195   v810-*-*)
1196     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1197     ;;
1198   vax-*-*)
1199     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1200     ;;
1201 esac
1202
1203 # If we aren't building newlib, then don't build libgloss, since libgloss
1204 # depends upon some newlib header files.
1205 case "${noconfigdirs}" in
1206   *target-libgloss*) ;;
1207   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1208 esac
1209
1210 # Work in distributions that contain no compiler tools, like Autoconf.
1211 host_makefile_frag=/dev/null
1212 if test -d ${srcdir}/config ; then
1213 case "${host}" in
1214   i[[3456789]]86-*-msdosdjgpp*)
1215     host_makefile_frag="config/mh-djgpp"
1216     ;;
1217   *-cygwin*)
1218     ACX_CHECK_CYGWIN_CAT_WORKS
1219     host_makefile_frag="config/mh-cygwin"
1220     ;;
1221   *-mingw*)
1222     host_makefile_frag="config/mh-mingw"
1223     ;;
1224   alpha*-linux*)
1225     host_makefile_frag="config/mh-alpha-linux"
1226     ;;
1227   hppa*-hp-hpux10*)
1228     host_makefile_frag="config/mh-pa-hpux10"
1229     ;;
1230   hppa*-hp-hpux*)
1231     host_makefile_frag="config/mh-pa"
1232     ;;
1233   hppa*-*)
1234     host_makefile_frag="config/mh-pa"
1235     ;;
1236   *-*-darwin*)
1237     host_makefile_frag="config/mh-darwin"
1238     ;;
1239   powerpc-*-aix*)
1240     host_makefile_frag="config/mh-ppc-aix"
1241     ;;
1242   rs6000-*-aix*)
1243     host_makefile_frag="config/mh-ppc-aix"
1244     ;;
1245 esac
1246 fi
1247
1248 if test "${build}" != "${host}" ; then
1249   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1250   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1251   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1252   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1253   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1254   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1255   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1256   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1257   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1258   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1259   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1260   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1261 else
1262   AR_FOR_BUILD="\$(AR)"
1263   AS_FOR_BUILD="\$(AS)"
1264   CC_FOR_BUILD="\$(CC)"
1265   CXX_FOR_BUILD="\$(CXX)"
1266   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1267   GOC_FOR_BUILD="\$(GOC)"
1268   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1269   LD_FOR_BUILD="\$(LD)"
1270   NM_FOR_BUILD="\$(NM)"
1271   RANLIB_FOR_BUILD="\$(RANLIB)"
1272   WINDRES_FOR_BUILD="\$(WINDRES)"
1273   WINDMC_FOR_BUILD="\$(WINDMC)"
1274 fi
1275
1276 AC_PROG_CC
1277 AC_PROG_CXX
1278
1279 # We must set the default linker to the linker used by gcc for the correct
1280 # operation of libtool.  If LD is not defined and we are using gcc, try to
1281 # set the LD default to the ld used by gcc.
1282 if test -z "$LD"; then
1283   if test "$GCC" = yes; then
1284     case $build in
1285     *-*-mingw*)
1286       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1287     *)
1288       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1289     esac
1290     case $gcc_prog_ld in
1291     # Accept absolute paths.
1292     [[\\/]* | [A-Za-z]:[\\/]*)]
1293       LD="$gcc_prog_ld" ;;
1294     esac
1295   fi
1296 fi
1297
1298 # Check whether -static-libstdc++ -static-libgcc is supported.
1299 have_static_libs=no
1300 if test "$GCC" = yes; then
1301   saved_LDFLAGS="$LDFLAGS"
1302
1303   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1304   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1305   AC_LANG_PUSH(C++)
1306   AC_LINK_IFELSE([
1307 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1308 #error -static-libstdc++ not implemented
1309 #endif
1310 int main() {}],
1311     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1312     [AC_MSG_RESULT([no])])
1313   AC_LANG_POP(C++)
1314
1315   LDFLAGS="$saved_LDFLAGS"
1316 fi
1317
1318 ACX_PROG_GNAT
1319 ACX_PROG_CMP_IGNORE_INITIAL
1320
1321 AC_ARG_ENABLE([bootstrap],
1322 [AS_HELP_STRING([--enable-bootstrap],
1323                 [enable bootstrapping @<:@yes if native build@:>@])],,
1324 enable_bootstrap=default)
1325
1326 # Issue errors and warnings for invalid/strange bootstrap combinations.
1327 if test -r $srcdir/gcc/configure; then
1328   have_compiler=yes
1329 else
1330   have_compiler=no
1331 fi
1332
1333 case "$have_compiler:$host:$target:$enable_bootstrap" in
1334   *:*:*:no) ;;
1335
1336   # Default behavior.  Enable bootstrap if we have a compiler
1337   # and we are in a native configuration.
1338   yes:$build:$build:default)
1339     enable_bootstrap=yes ;;
1340
1341   *:*:*:default)
1342     enable_bootstrap=no ;;
1343
1344   # We have a compiler and we are in a native configuration, bootstrap is ok
1345   yes:$build:$build:yes)
1346     ;;
1347
1348   # Other configurations, but we have a compiler.  Assume the user knows
1349   # what he's doing.
1350   yes:*:*:yes)
1351     AC_MSG_WARN([trying to bootstrap a cross compiler])
1352     ;;
1353
1354   # No compiler: if they passed --enable-bootstrap explicitly, fail
1355   no:*:*:yes)
1356     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1357
1358   # Fail if wrong command line
1359   *)
1360     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1361     ;;
1362 esac
1363
1364 # When bootstrapping with GCC, build stage 1 in C++98 mode to ensure that a
1365 # C++98 compiler can still start the bootstrap.
1366 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1367   CXX="$CXX -std=gnu++98"
1368 fi
1369
1370 # Used for setting $lt_cv_objdir
1371 _LT_CHECK_OBJDIR
1372
1373 # Check for GMP, MPFR and MPC
1374 gmplibs="-lmpc -lmpfr -lgmp"
1375 gmpinc=
1376 have_gmp=no
1377
1378 # Specify a location for mpc
1379 # check for this first so it ends up on the link line before mpfr.
1380 AC_ARG_WITH(mpc,
1381 [AS_HELP_STRING([--with-mpc=PATH],
1382                 [specify prefix directory for installed MPC package.
1383                  Equivalent to --with-mpc-include=PATH/include
1384                  plus --with-mpc-lib=PATH/lib])])
1385 AC_ARG_WITH(mpc-include,
1386 [AS_HELP_STRING([--with-mpc-include=PATH],
1387                 [specify directory for installed MPC include files])])
1388 AC_ARG_WITH(mpc-lib,
1389 [AS_HELP_STRING([--with-mpc-lib=PATH],
1390                 [specify directory for the installed MPC library])])
1391
1392 if test "x$with_mpc" != x; then
1393   gmplibs="-L$with_mpc/lib $gmplibs"
1394   gmpinc="-I$with_mpc/include $gmpinc"
1395 fi
1396 if test "x$with_mpc_include" != x; then
1397   gmpinc="-I$with_mpc_include $gmpinc"
1398 fi
1399 if test "x$with_mpc_lib" != x; then
1400   gmplibs="-L$with_mpc_lib $gmplibs"
1401 fi
1402 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1403   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1404   gmpinc='-I$$s/mpc/src '"$gmpinc"
1405   # Do not test the mpc version.  Assume that it is sufficient, since
1406   # it is in the source tree, and the library has not been built yet
1407   # but it would be included on the link line in the version check below
1408   # hence making the test fail.
1409   have_gmp=yes
1410 fi
1411
1412 # Specify a location for mpfr
1413 # check for this first so it ends up on the link line before gmp.
1414 AC_ARG_WITH(mpfr-dir,
1415 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1416 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1417 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1418
1419 AC_ARG_WITH(mpfr,
1420 [AS_HELP_STRING([--with-mpfr=PATH],
1421                 [specify prefix directory for installed MPFR package.
1422                  Equivalent to --with-mpfr-include=PATH/include
1423                  plus --with-mpfr-lib=PATH/lib])])
1424 AC_ARG_WITH(mpfr-include,
1425 [AS_HELP_STRING([--with-mpfr-include=PATH],
1426                 [specify directory for installed MPFR include files])])
1427 AC_ARG_WITH(mpfr-lib,
1428 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1429                 [specify directory for the installed MPFR library])])
1430
1431 if test "x$with_mpfr" != x; then
1432   gmplibs="-L$with_mpfr/lib $gmplibs"
1433   gmpinc="-I$with_mpfr/include $gmpinc"
1434 fi
1435 if test "x$with_mpfr_include" != x; then
1436   gmpinc="-I$with_mpfr_include $gmpinc"
1437 fi
1438 if test "x$with_mpfr_lib" != x; then
1439   gmplibs="-L$with_mpfr_lib $gmplibs"
1440 fi
1441 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1442   # MPFR v3.1.0 moved the sources into a src sub-directory.
1443   if ! test -d ${srcdir}/mpfr/src; then
1444     AC_MSG_ERROR([dnl
1445 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1446   fi
1447   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1448   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1449   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1450   # Do not test the mpfr version.  Assume that it is sufficient, since
1451   # it is in the source tree, and the library has not been built yet
1452   # but it would be included on the link line in the version check below
1453   # hence making the test fail.
1454   have_gmp=yes
1455 fi
1456
1457 # Specify a location for gmp
1458 AC_ARG_WITH(gmp-dir,
1459 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1460 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1461 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1462
1463 AC_ARG_WITH(gmp,
1464 [AS_HELP_STRING([--with-gmp=PATH],
1465                 [specify prefix directory for the installed GMP package.
1466                  Equivalent to --with-gmp-include=PATH/include
1467                  plus --with-gmp-lib=PATH/lib])])
1468 AC_ARG_WITH(gmp-include,
1469 [AS_HELP_STRING([--with-gmp-include=PATH],
1470                 [specify directory for installed GMP include files])])
1471 AC_ARG_WITH(gmp-lib,
1472 [AS_HELP_STRING([--with-gmp-lib=PATH],
1473                 [specify directory for the installed GMP library])])
1474
1475
1476 if test "x$with_gmp" != x; then
1477   gmplibs="-L$with_gmp/lib $gmplibs"
1478   gmpinc="-I$with_gmp/include $gmpinc"
1479 fi
1480 if test "x$with_gmp_include" != x; then
1481   gmpinc="-I$with_gmp_include $gmpinc"
1482 fi
1483 if test "x$with_gmp_lib" != x; then
1484   gmplibs="-L$with_gmp_lib $gmplibs"
1485 fi
1486 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1487   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1488   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1489   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1490   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1491   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1492   # Do not test the gmp version.  Assume that it is sufficient, since
1493   # it is in the source tree, and the library has not been built yet
1494   # but it would be included on the link line in the version check below
1495   # hence making the test fail.
1496   have_gmp=yes
1497 fi
1498
1499 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1500   have_gmp=yes
1501   saved_CFLAGS="$CFLAGS"
1502   CFLAGS="$CFLAGS $gmpinc"
1503   # Check for the recommended and required versions of GMP.
1504   AC_MSG_CHECKING([for the correct version of gmp.h])
1505   AC_TRY_COMPILE([#include "gmp.h"],[
1506   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1507   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1508   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1509   choke me
1510   #endif
1511   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1512   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1513   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1514   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1515   choke me
1516   #endif
1517   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1518    [AC_MSG_RESULT([no]); have_gmp=no])
1519
1520   # If we have GMP, check the MPFR version.
1521   if test x"$have_gmp" = xyes; then
1522     # Check for the recommended and required versions of MPFR.
1523     AC_MSG_CHECKING([for the correct version of mpfr.h])
1524     AC_TRY_COMPILE([#include <gmp.h>
1525     #include <mpfr.h>],[
1526     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1527     choke me
1528     #endif
1529     ], [AC_TRY_COMPILE([#include <gmp.h>
1530     #include <mpfr.h>],[
1531     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1532     choke me
1533     #endif
1534     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1535      [AC_MSG_RESULT([no]); have_gmp=no])
1536   fi
1537
1538   # Check for the MPC header version.
1539   if test x"$have_gmp" = xyes ; then
1540     # Check for the recommended and required versions of MPC.
1541     AC_MSG_CHECKING([for the correct version of mpc.h])
1542     AC_TRY_COMPILE([#include <mpc.h>],[
1543     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1544     choke me
1545     #endif
1546     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1547     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1548     choke me
1549     #endif
1550     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1551      [AC_MSG_RESULT([no]); have_gmp=no])
1552   fi
1553
1554   # Now check the MPFR library.
1555   if test x"$have_gmp" = xyes; then
1556     saved_LIBS="$LIBS"
1557     LIBS="$LIBS $gmplibs"
1558     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1559     AC_TRY_LINK([#include <mpc.h>],[
1560     mpfr_t n;
1561     mpfr_t x;
1562     mpc_t c;
1563     int t;
1564     mpfr_init (n);
1565     mpfr_init (x);
1566     mpfr_atan2 (n, n, x, GMP_RNDN);
1567     mpfr_erfc (n, x, GMP_RNDN);
1568     mpfr_subnormalize (x, t, GMP_RNDN);
1569     mpfr_clear(n);
1570     mpfr_clear(x);
1571     mpc_init2 (c, 53);
1572     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1573     mpc_cosh (c, c, MPC_RNDNN);
1574     mpc_pow (c, c, c, MPC_RNDNN);
1575     mpc_acosh (c, c, MPC_RNDNN);
1576     mpc_clear (c);
1577     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1578     LIBS="$saved_LIBS"
1579   fi
1580
1581   CFLAGS="$saved_CFLAGS"
1582
1583 # The library versions listed in the error message below should match
1584 # the HARD-minimums enforced above.
1585   if test x$have_gmp != xyes; then
1586     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1587 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1588 their locations.  Source code for these libraries can be found at
1589 their respective hosting sites as well as at
1590 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1591 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1592 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1593 make sure that you have installed both the libraries and the header
1594 files.  They may be located in separate packages.])
1595   fi
1596 fi
1597
1598 # Flags needed for both GMP, MPFR and/or MPC.
1599 AC_SUBST(gmplibs)
1600 AC_SUBST(gmpinc)
1601 AC_SUBST(extra_mpfr_configure_flags)
1602 AC_SUBST(extra_mpc_gmp_configure_flags)
1603 AC_SUBST(extra_mpc_mpfr_configure_flags)
1604 AC_SUBST(extra_isl_gmp_configure_flags)
1605
1606 # Libraries to use for stage1 or when not bootstrapping.
1607 AC_ARG_WITH(stage1-libs,
1608 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1609 [if test "$withval" = "no" -o "$withval" = "yes"; then
1610    stage1_libs=
1611  else
1612    stage1_libs=$withval
1613  fi],
1614 [stage1_libs=])
1615 AC_SUBST(stage1_libs)
1616
1617 # Linker flags to use for stage1 or when not bootstrapping.
1618 AC_ARG_WITH(stage1-ldflags,
1619 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1620 [if test "$withval" = "no" -o "$withval" = "yes"; then
1621    stage1_ldflags=
1622  else
1623    stage1_ldflags=$withval
1624  fi],
1625 [stage1_ldflags=
1626  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1627  # if supported.  But if the user explicitly specified the libraries to use,
1628  # trust that they are doing what they want.
1629  if test "$stage1_libs" = "" -a "$have_static_libs" = yes; then
1630    stage1_ldflags="-static-libstdc++ -static-libgcc"
1631  fi])
1632 AC_SUBST(stage1_ldflags)
1633
1634 # Libraries to use for stage2 and later builds.
1635 AC_ARG_WITH(boot-libs,
1636 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1637 [if test "$withval" = "no" -o "$withval" = "yes"; then
1638    poststage1_libs=
1639  else
1640    poststage1_libs=$withval
1641  fi],
1642 [poststage1_libs=])
1643 AC_SUBST(poststage1_libs)
1644
1645 # Linker flags to use for stage2 and later builds.
1646 AC_ARG_WITH(boot-ldflags,
1647 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1648                 [linker flags for stage2 and later])],
1649 [if test "$withval" = "no" -o "$withval" = "yes"; then
1650    poststage1_ldflags=
1651  else
1652    poststage1_ldflags=$withval
1653  fi],
1654 [poststage1_ldflags=
1655  # In stages 2 and 3, default to linking libstdc++ and libgcc
1656  # statically.  But if the user explicitly specified the libraries to
1657  # use, trust that they are doing what they want.
1658  if test "$poststage1_libs" = ""; then
1659    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1660  fi])
1661 AC_SUBST(poststage1_ldflags)
1662
1663 # GCC GRAPHITE dependency isl.
1664 # Basic setup is inlined here, actual checks are in config/isl.m4
1665
1666 AC_ARG_WITH(isl,
1667   [AS_HELP_STRING(
1668    [--with-isl=PATH],
1669    [Specify prefix directory for the installed isl package.
1670     Equivalent to --with-isl-include=PATH/include
1671     plus --with-isl-lib=PATH/lib])])
1672
1673 # Treat --without-isl as a request to disable
1674 # GRAPHITE support and skip all following checks.
1675 if test "x$with_isl" != "xno"; then
1676   # Check for isl
1677   dnl Provide configure switches and initialize islinc & isllibs
1678   dnl with user input.
1679   ISL_INIT_FLAGS
1680   dnl The versions of isl that work for Graphite
1681   ISL_CHECK_VERSION()
1682   dnl Only execute fail-action, if isl has been requested.
1683   ISL_IF_FAILED([
1684     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1685 fi
1686
1687 # If the isl check failed, disable builds of in-tree variant of isl
1688 if test "x$with_isl" = xno ||
1689    test "x$gcc_cv_isl" = xno; then
1690   noconfigdirs="$noconfigdirs isl"
1691   islinc=
1692 fi
1693
1694 AC_SUBST(isllibs)
1695 AC_SUBST(islinc)
1696
1697 # Check for LTO support.
1698 AC_ARG_ENABLE(lto,
1699 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1700 enable_lto=$enableval,
1701 enable_lto=yes; default_enable_lto=yes)
1702
1703 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1704   build_lto_plugin=yes
1705 ],[if test x"$default_enable_lto" = x"yes" ; then
1706     case $target in
1707       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1708       # On other non-ELF platforms, LTO has yet to be validated.
1709       *) enable_lto=no ;;
1710     esac
1711   else
1712   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1713   # It would also be nice to check the binutils support, but we don't
1714   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1715   # warn during gcc/ subconfigure; unless you're bootstrapping with
1716   # -flto it won't be needed until after installation anyway.
1717     case $target in
1718       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1719       *) if test x"$enable_lto" = x"yes"; then
1720         AC_MSG_ERROR([LTO support is not enabled for this target.])
1721         fi
1722       ;;
1723     esac
1724   fi
1725   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1726   # Build it unless LTO was explicitly disabled.
1727   case $target in
1728     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1729     *) ;;
1730   esac
1731 ])
1732
1733 AC_ARG_ENABLE(linker-plugin-configure-flags,
1734   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1735     [additional flags for configuring linker plugins @<:@none@:>@])],
1736   extra_linker_plugin_configure_flags=$enableval,
1737   extra_linker_plugin_configure_flags=)
1738 AC_SUBST(extra_linker_plugin_configure_flags)
1739 AC_ARG_ENABLE(linker-plugin-flags,
1740   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1741     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1742   extra_linker_plugin_flags=$enableval,
1743   extra_linker_plugin_flags=)
1744 AC_SUBST(extra_linker_plugin_flags)
1745
1746 # Enable --enable-host-shared.
1747 # Checked early to determine whether jit is an 'all' language
1748 AC_ARG_ENABLE(host-shared,
1749 [AS_HELP_STRING([--enable-host-shared],
1750                 [build host code as shared libraries])],
1751 [host_shared=$enableval], [host_shared=no])
1752 AC_SUBST(host_shared)
1753
1754 # By default, C and C++ are the only stage 1 languages.
1755 stage1_languages=,c,
1756
1757 # Target libraries that we bootstrap.
1758 bootstrap_target_libs=,target-libgcc,
1759
1760 # Figure out what language subdirectories are present.
1761 # Look if the user specified --enable-languages="..."; if not, use
1762 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1763 # go away some day.
1764 # NB:  embedded tabs in this IF block -- do not untabify
1765 if test -d ${srcdir}/gcc; then
1766   if test x"${enable_languages+set}" != xset; then
1767     if test x"${LANGUAGES+set}" = xset; then
1768       enable_languages="${LANGUAGES}"
1769         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1770     else
1771       enable_languages=default
1772     fi
1773   else
1774     if test x"${enable_languages}" = x ||
1775        test x"${enable_languages}" = xyes;
1776        then
1777       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1778       exit 1
1779     fi
1780   fi
1781   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1782
1783   # 'f95' is the old name for the 'fortran' language. We issue a warning
1784   # and make the substitution.
1785   case ,${enable_languages}, in
1786     *,f95,*)
1787       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1788       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1789       ;;
1790   esac
1791
1792   # If bootstrapping, C++ must be enabled.
1793   case ",$enable_languages,:$enable_bootstrap" in
1794     *,c++,*:*) ;;
1795     *:yes)
1796       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1797         enable_languages="${enable_languages},c++"
1798       else
1799         AC_MSG_ERROR([bootstrapping requires c++ sources])
1800       fi
1801       ;;
1802   esac
1803
1804   # First scan to see if an enabled language requires some other language.
1805   # We assume that a given config-lang.in will list all the language
1806   # front ends it requires, even if some are required indirectly.
1807   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1808     case ${lang_frag} in
1809       ..) ;;
1810       # The odd quoting in the next line works around
1811       # an apparent bug in bash 1.12 on linux.
1812       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1813       *)
1814         # From the config-lang.in, get $language, $lang_requires, and
1815         # $lang_requires_boot_languages.
1816         language=
1817         lang_requires=
1818         lang_requires_boot_languages=
1819         # set srcdir during sourcing lang_frag to the gcc dir.
1820         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1821         # polutes this shell
1822         saved_srcdir=${srcdir}
1823         srcdir=${srcdir}/gcc . ${lang_frag}
1824         srcdir=${saved_srcdir}
1825         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1826           case ,${enable_languages}, in
1827             *,$other,*) ;;
1828             *,default,*) ;;
1829             *,all,*) ;;
1830             *,$language,*)
1831               echo " \`$other' language required by \`$language'; enabling" 1>&2
1832               enable_languages="${enable_languages},${other}"
1833               ;;
1834           esac
1835         done
1836         for other in ${lang_requires_boot_languages} ; do
1837           if test "$other" != "c"; then
1838             case ,${enable_stage1_languages}, in
1839               *,$other,*) ;;
1840               *,default,*) ;;
1841               *,all,*) ;;
1842               *)
1843                 case ,${enable_languages}, in
1844                   *,$language,*)
1845                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1846                     enable_stage1_languages="$enable_stage1_languages,${other}"
1847                     ;;
1848                 esac
1849                 ;;
1850             esac
1851           fi
1852         done
1853         ;;
1854     esac
1855   done
1856
1857   new_enable_languages=,c,
1858
1859   # If LTO is enabled, add the LTO front end.
1860   if test "$enable_lto" = "yes" ; then
1861     case ,${enable_languages}, in
1862       *,lto,*) ;;
1863       *) enable_languages="${enable_languages},lto" ;;
1864     esac
1865     if test "${build_lto_plugin}" = "yes" ; then
1866       configdirs="$configdirs lto-plugin"
1867     fi
1868   fi
1869
1870   # If we're building an offloading compiler, add the LTO front end.
1871   if test x"$enable_as_accelerator_for" != x ; then
1872     case ,${enable_languages}, in
1873       *,lto,*) ;;
1874       *) enable_languages="${enable_languages},lto" ;;
1875     esac
1876   fi
1877
1878   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
1879   potential_languages=,c,
1880
1881   enabled_target_libs=
1882   disabled_target_libs=
1883
1884   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1885     case ${lang_frag} in
1886       ..) ;;
1887       # The odd quoting in the next line works around
1888       # an apparent bug in bash 1.12 on linux.
1889       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1890       *)
1891         # From the config-lang.in, get $language, $target_libs,
1892         # $lang_dirs, $boot_language, and $build_by_default
1893         language=
1894         target_libs=
1895         lang_dirs=
1896         subdir_requires=
1897         boot_language=no
1898         build_by_default=yes
1899         # set srcdir during sourcing.  See above about save & restore
1900         saved_srcdir=${srcdir}
1901         srcdir=${srcdir}/gcc . ${lang_frag}
1902         srcdir=${saved_srcdir}
1903         if test x${language} = x; then
1904           echo "${lang_frag} doesn't set \$language." 1>&2
1905           exit 1
1906         fi
1907
1908         if test "$language" = "c++"; then
1909           boot_language=yes
1910         fi
1911
1912         add_this_lang=no
1913         # C is always enabled, so no need to add it again
1914         if test "$language" != "c"; then
1915           case ,${enable_languages}, in
1916             *,${language},*)
1917               # Language was explicitly selected; include it
1918               add_this_lang=yes
1919               ;;
1920             *,all,*)
1921               # All languages are enabled
1922               add_this_lang=all
1923               ;;
1924             *,default,*)
1925               # 'default' was selected, select it if it is a default language
1926               add_this_lang=${build_by_default}
1927               ;;
1928           esac
1929         fi
1930
1931         # Disable languages that need other directories if these aren't available.
1932         for i in $subdir_requires; do
1933           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1934           case ${add_this_lang} in
1935             yes)
1936               # Specifically requested language; tell them.
1937               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1938               ;;
1939             all)
1940               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
1941               add_this_lang=unsupported
1942               ;;
1943             *)
1944               # Silently disable.
1945               add_this_lang=unsupported
1946               ;;
1947           esac
1948         done
1949
1950         # Disable Ada if no preexisting GNAT is available.
1951         case ${add_this_lang}:${language}:${have_gnat} in
1952           yes:ada:no)
1953             # Specifically requested language; tell them.
1954             AC_MSG_ERROR([GNAT is required to build $language])
1955             ;;
1956           all:ada:no)
1957             AC_MSG_WARN([GNAT is required to build $language])
1958             add_this_lang=unsupported
1959             ;;
1960           *:ada:no)
1961             # Silently disable.
1962             add_this_lang=unsupported
1963             ;;
1964         esac
1965
1966         # Disable jit if -enable-host-shared not specified
1967         case ${add_this_lang}:${language}:${host_shared} in
1968           yes:jit:no)
1969             # PR jit/64780: explicitly specify --enable-host-shared
1970             AC_MSG_ERROR([
1971 Enabling language "jit" requires --enable-host-shared.
1972
1973 --enable-host-shared typically slows the rest of the compiler down by
1974 a few %, so you must explicitly enable it.
1975
1976 If you want to build both the jit and the regular compiler, it is often
1977 best to do this via two separate configure/builds, in separate
1978 directories, to avoid imposing the performance cost of
1979 --enable-host-shared on the regular compiler.])
1980             ;;
1981           all:jit:no)
1982             AC_MSG_WARN([--enable-host-shared required to build $language])
1983             add_this_lang=unsupported
1984             ;;
1985           *:jit:no)
1986             # Silently disable.
1987             add_this_lang=unsupported
1988             ;;
1989         esac
1990
1991         # Disable a language that is unsupported by the target.
1992         case "${add_this_lang}: $unsupported_languages " in
1993           no:*) ;;
1994           unsupported:*) ;;
1995           *:*" $language "*)
1996             AC_MSG_WARN([${language} not supported for this target])
1997             add_this_lang=unsupported
1998             ;;
1999         esac
2000
2001         case $add_this_lang in
2002           unsupported)
2003             # Remove language-dependent dirs.
2004             disabled_target_libs="$disabled_target_libs $target_libs"
2005             noconfigdirs="$noconfigdirs $lang_dirs"
2006             ;;
2007           no)
2008             # Remove language-dependent dirs; still show language as supported.
2009             disabled_target_libs="$disabled_target_libs $target_libs"
2010             noconfigdirs="$noconfigdirs $lang_dirs"
2011             potential_languages="${potential_languages}${language},"
2012             ;;
2013           all|yes)
2014             new_enable_languages="${new_enable_languages}${language},"
2015             potential_languages="${potential_languages}${language},"
2016             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2017             enabled_target_libs="$enabled_target_libs $target_libs"
2018             case "${boot_language}:,$enable_stage1_languages," in
2019               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2020                 # Add to (comma-separated) list of stage 1 languages.
2021                 case ",$stage1_languages," in
2022                   *,$language,* | ,yes, | ,all,) ;;
2023                   *) stage1_languages="${stage1_languages}${language}," ;;
2024                 esac
2025                 # We need to bootstrap any supporting libraries.
2026                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2027                 ;;
2028             esac
2029             ;;
2030         esac
2031         ;;
2032     esac
2033   done
2034
2035   # Add target libraries which are only needed for disabled languages
2036   # to noconfigdirs.
2037   if test -n "$disabled_target_libs"; then
2038     for dir in $disabled_target_libs; do
2039       case " $enabled_target_libs " in
2040       *" ${dir} "*) ;;
2041       *) noconfigdirs="$noconfigdirs $dir" ;;
2042       esac
2043     done
2044   fi
2045
2046   AC_ARG_ENABLE(stage1-languages,
2047   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2048                   [choose additional languages to build during
2049                   stage1.  Mostly useful for compiler development])],
2050   [case ,${enable_stage1_languages}, in
2051     ,no,|,,)
2052       # Set it to something that will have no effect in the loop below
2053       enable_stage1_languages=c ;;
2054     ,yes,)
2055       enable_stage1_languages=`echo $new_enable_languages | \
2056         sed -e "s/^,//" -e "s/,$//" ` ;;
2057     *,all,*)
2058       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2059         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2060   esac
2061
2062   # Add "good" languages from enable_stage1_languages to stage1_languages,
2063   # while "bad" languages go in missing_languages.  Leave no duplicates.
2064   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2065     case $potential_languages in
2066       *,$i,*)
2067         case $stage1_languages in
2068           *,$i,*) ;;
2069           *) stage1_languages="$stage1_languages$i," ;;
2070         esac ;;
2071       *)
2072         case $missing_languages in
2073           *,$i,*) ;;
2074           *) missing_languages="$missing_languages$i," ;;
2075         esac ;;
2076      esac
2077   done])
2078
2079   # Remove leading/trailing commas that were added for simplicity
2080   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2081   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2082   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2083   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2084
2085   if test "x$missing_languages" != x; then
2086     AC_MSG_ERROR([
2087 The following requested languages could not be built: ${missing_languages}
2088 Supported languages are: ${potential_languages}])
2089   fi
2090   if test "x$new_enable_languages" != "x$enable_languages"; then
2091     echo The following languages will be built: ${new_enable_languages}
2092     enable_languages="$new_enable_languages"
2093   fi
2094
2095   AC_SUBST(stage1_languages)
2096   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2097 fi
2098
2099 # Handle --disable-<component> generically.
2100 for dir in $configdirs $build_configdirs $target_configdirs ; do
2101   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2102   varname=`echo $dirname | sed -e s/+/_/g`
2103   if eval test x\${enable_${varname}} "=" xno ; then
2104     noconfigdirs="$noconfigdirs $dir"
2105   fi
2106 done
2107
2108 # Check for Boehm's garbage collector
2109 AC_ARG_ENABLE(objc-gc,
2110 [AS_HELP_STRING([--enable-objc-gc],
2111                 [enable use of Boehm's garbage collector with the
2112                  GNU Objective-C runtime])])
2113 AC_ARG_WITH([target-bdw-gc],
2114 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2115                 [specify prefix directory for installed bdw-gc package.
2116                  Equivalent to --with-target-bdw-gc-include=PATH/include
2117                  plus --with-target-bdw-gc-lib=PATH/lib])])
2118 AC_ARG_WITH([target-bdw-gc-include],
2119 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2120                 [specify directories for installed bdw-gc include files])])
2121 AC_ARG_WITH([target-bdw-gc-lib],
2122 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2123                 [specify directories for installed bdw-gc library])])
2124
2125 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2126   AC_MSG_CHECKING([for bdw garbage collector])
2127   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2128     dnl no bdw-gw options, assume default locations
2129     AC_MSG_RESULT([using bdw-gc in default locations])
2130   else
2131     dnl bdw-gw options, first error checking, complete checking in libobjc
2132     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2133       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2134     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2135       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2136     else
2137       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2138     fi
2139   fi
2140 esac
2141
2142 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2143 case ,${enable_languages}, in
2144   *,c++,*)
2145     # Disable libitm, libsanitizer if we're not building libstdc++
2146     case "${noconfigdirs}" in
2147       *target-libstdc++-v3*)
2148         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2149         ;;
2150       *) ;;
2151     esac
2152     ;;
2153   *)
2154     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2155     ;;
2156 esac
2157
2158 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2159 # $build_configdirs and $target_configdirs.
2160 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2161
2162 notsupp=""
2163 for dir in . $skipdirs $noconfigdirs ; do
2164   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2165   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2166     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2167     if test -r $srcdir/$dirname/configure ; then
2168       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2169         true
2170       else
2171         notsupp="$notsupp $dir"
2172       fi
2173     fi
2174   fi
2175   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2176     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2177     if test -r $srcdir/$dirname/configure ; then
2178       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2179         true
2180       else
2181         notsupp="$notsupp $dir"
2182       fi
2183     fi
2184   fi
2185   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2186     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2187     if test -r $srcdir/$dirname/configure ; then
2188       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2189         true
2190       else
2191         notsupp="$notsupp $dir"
2192       fi
2193     fi
2194   fi
2195 done
2196
2197 # Quietly strip out all directories which aren't configurable in this tree.
2198 # This relies on all configurable subdirectories being autoconfiscated, which
2199 # is now the case.
2200 build_configdirs_all="$build_configdirs"
2201 build_configdirs=
2202 for i in ${build_configdirs_all} ; do
2203   j=`echo $i | sed -e s/build-//g`
2204   if test -f ${srcdir}/$j/configure ; then
2205     build_configdirs="${build_configdirs} $i"
2206   fi
2207 done
2208
2209 configdirs_all="$configdirs"
2210 configdirs=
2211 for i in ${configdirs_all} ; do
2212   if test -f ${srcdir}/$i/configure ; then
2213     configdirs="${configdirs} $i"
2214   fi
2215 done
2216
2217 target_configdirs_all="$target_configdirs"
2218 target_configdirs=
2219 for i in ${target_configdirs_all} ; do
2220   j=`echo $i | sed -e s/target-//g`
2221   if test -f ${srcdir}/$j/configure ; then
2222     target_configdirs="${target_configdirs} $i"
2223   fi
2224 done
2225
2226 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2227 # so we have to add it after the preceding checks.
2228 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2229 then
2230   case " $configdirs " in
2231     *" libiberty "*)
2232       # If we can build libiberty, we can also build libiberty-linker-plugin.
2233       configdirs="$configdirs libiberty-linker-plugin"
2234       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2235         --with-libiberty=../libiberty-linker-plugin";;
2236     *)
2237       AC_MSG_ERROR([libiberty missing]);;
2238   esac
2239 fi
2240
2241 # Sometimes we have special requirements for the host libiberty.
2242 extra_host_libiberty_configure_flags=
2243 extra_host_zlib_configure_flags=
2244 case " $configdirs " in
2245   *" lto-plugin "* | *" libcc1 "*)
2246     # When these are to be built as shared libraries, the same applies to
2247     # libiberty.
2248     extra_host_libiberty_configure_flags=--enable-shared
2249     ;;
2250   *" bfd "*)
2251     # When bfd is to be built as a shared library, the same applies to
2252     # zlib.
2253     if test "$enable_shared" = "yes"; then
2254       extra_host_zlib_configure_flags=--enable-host-shared
2255     fi
2256     ;;
2257 esac
2258 AC_SUBST(extra_host_libiberty_configure_flags)
2259 AC_SUBST(extra_host_zlib_configure_flags)
2260
2261 # Produce a warning message for the subdirs we can't configure.
2262 # This isn't especially interesting in the Cygnus tree, but in the individual
2263 # FSF releases, it's important to let people know when their machine isn't
2264 # supported by the one or two programs in a package.
2265
2266 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2267   # If $appdirs is non-empty, at least one of those directories must still
2268   # be configured, or we error out.  (E.g., if the gas release supports a
2269   # specified target in some subdirs but not the gas subdir, we shouldn't
2270   # pretend that all is well.)
2271   if test -n "$appdirs" ; then
2272     for dir in $appdirs ; do
2273       if test -r $dir/Makefile.in ; then
2274         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2275           appdirs=""
2276           break
2277         fi
2278         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2279           appdirs=""
2280           break
2281         fi
2282       fi
2283     done
2284     if test -n "$appdirs" ; then
2285       echo "*** This configuration is not supported by this package." 1>&2
2286       exit 1
2287     fi
2288   fi
2289   # Okay, some application will build, or we don't care to check.  Still
2290   # notify of subdirs not getting built.
2291   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2292   echo "    ${notsupp}" 1>&2
2293   echo "    (Any other directories should still work fine.)" 1>&2
2294 fi
2295
2296 case "$host" in
2297   *msdosdjgpp*)
2298     enable_gdbtk=no ;;
2299 esac
2300
2301 # To find our prefix, in gcc_cv_tool_prefix.
2302 ACX_TOOL_DIRS
2303
2304 copy_dirs=
2305
2306 AC_ARG_WITH([build-sysroot],
2307   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2308                   [use sysroot as the system root during the build])],
2309   [if test x"$withval" != x ; then
2310      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2311    fi],
2312   [SYSROOT_CFLAGS_FOR_TARGET=])
2313 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2314
2315 AC_ARG_WITH([debug-prefix-map],
2316   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2317                   [map A to B, C to D ... in debug information])],
2318   [if test x"$withval" != x; then
2319      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2320      for debug_map in $withval; do
2321        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2322      done
2323    fi],
2324   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2325 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2326
2327 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2328 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2329 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2330 # We want to ensure that TARGET libraries (which we know are built with
2331 # gcc) are built with "-O2 -g", so include those options when setting
2332 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2333 if test "x$CFLAGS_FOR_TARGET" = x; then
2334   if test "x${is_cross_compiler}" = xyes; then
2335     CFLAGS_FOR_TARGET="-g -O2"
2336   else
2337     CFLAGS_FOR_TARGET=$CFLAGS
2338     case " $CFLAGS " in
2339       *" -O2 "*) ;;
2340       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2341     esac
2342     case " $CFLAGS " in
2343       *" -g "* | *" -g3 "*) ;;
2344       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2345     esac
2346   fi
2347 fi
2348 AC_SUBST(CFLAGS_FOR_TARGET)
2349
2350 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2351   if test "x${is_cross_compiler}" = xyes; then
2352     CXXFLAGS_FOR_TARGET="-g -O2"
2353   else
2354     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2355     case " $CXXFLAGS " in
2356       *" -O2 "*) ;;
2357       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2358     esac
2359     case " $CXXFLAGS " in
2360       *" -g "* | *" -g3 "*) ;;
2361       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2362     esac
2363   fi
2364 fi
2365 AC_SUBST(CXXFLAGS_FOR_TARGET)
2366
2367 AC_SUBST(LDFLAGS_FOR_TARGET)
2368
2369 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2370 # the named directory are copied to $(tooldir)/sys-include.
2371 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2372   if test x${is_cross_compiler} = xno ; then
2373     echo 1>&2 '***' --with-headers is only supported when cross compiling
2374     exit 1
2375   fi
2376   if test x"${with_headers}" != xyes ; then
2377     x=${gcc_cv_tool_prefix}
2378     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2379   fi
2380 fi
2381
2382 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2383 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2384 # are permitted.
2385 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2386   if test x${is_cross_compiler} = xno ; then
2387     echo 1>&2 '***' --with-libs is only supported when cross compiling
2388     exit 1
2389   fi
2390   if test x"${with_libs}" != xyes ; then
2391     # Copy the libraries in reverse order, so that files in the first named
2392     # library override files in subsequent libraries.
2393     x=${gcc_cv_tool_prefix}
2394     for l in ${with_libs}; do
2395       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2396     done
2397   fi
2398 fi
2399
2400 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2401 #
2402 # This is done by determining whether or not the appropriate directory
2403 # is available, and by checking whether or not specific configurations
2404 # have requested that this magic not happen.
2405 #
2406 # The command line options always override the explicit settings in
2407 # configure.ac, and the settings in configure.ac override this magic.
2408 #
2409 # If the default for a toolchain is to use GNU as and ld, and you don't
2410 # want to do that, then you should use the --without-gnu-as and
2411 # --without-gnu-ld options for the configure script.  Similarly, if
2412 # the default is to use the included zlib and you don't want to do that,
2413 # you should use the --with-system-zlib option for the configure script.
2414
2415 if test x${use_gnu_as} = x &&
2416    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2417   with_gnu_as=yes
2418   extra_host_args="$extra_host_args --with-gnu-as"
2419 fi
2420
2421 if test x${use_gnu_ld} = x &&
2422    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2423   with_gnu_ld=yes
2424   extra_host_args="$extra_host_args --with-gnu-ld"
2425 fi
2426
2427 if test x${use_included_zlib} = x &&
2428    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2429   :
2430 else
2431   with_system_zlib=yes
2432   extra_host_args="$extra_host_args --with-system-zlib"
2433 fi
2434
2435 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2436 # can detect this case.
2437
2438 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2439   with_newlib=yes
2440   extra_host_args="$extra_host_args --with-newlib"
2441 fi
2442
2443 # Handle ${copy_dirs}
2444 set fnord ${copy_dirs}
2445 shift
2446 while test $# != 0 ; do
2447   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2448     :
2449   else
2450     echo Copying $1 to $2
2451
2452     # Use the install script to create the directory and all required
2453     # parent directories.
2454     if test -d $2 ; then
2455       :
2456     else
2457       echo >config.temp
2458       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2459     fi
2460
2461     # Copy the directory, assuming we have tar.
2462     # FIXME: Should we use B in the second tar?  Not all systems support it.
2463     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2464
2465     # It is the responsibility of the user to correctly adjust all
2466     # symlinks.  If somebody can figure out how to handle them correctly
2467     # here, feel free to add the code.
2468
2469     echo $1 > $2/COPIED
2470   fi
2471   shift; shift
2472 done
2473
2474 # Determine a target-dependent exec_prefix that the installed
2475 # gcc will search in.  Keep this list sorted by triplet, with
2476 # the *-*-osname triplets last.
2477 md_exec_prefix=
2478 case "${target}" in
2479   i[[34567]]86-pc-msdosdjgpp*)
2480     md_exec_prefix=/dev/env/DJDIR/bin
2481     ;;
2482   *-*-hpux* | \
2483   *-*-nto-qnx* | \
2484   *-*-solaris2*)
2485     md_exec_prefix=/usr/ccs/bin
2486     ;;
2487 esac
2488
2489 extra_arflags_for_target=
2490 extra_nmflags_for_target=
2491 extra_ranlibflags_for_target=
2492 target_makefile_frag=/dev/null
2493 case "${target}" in
2494   spu-*-*)
2495     target_makefile_frag="config/mt-spu"
2496     ;;
2497   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2498     target_makefile_frag="config/mt-sde"
2499     ;;
2500   mipsisa*-*-elfoabi*)
2501     target_makefile_frag="config/mt-mips-elfoabi"
2502     ;;
2503   mips*-*-*linux* | mips*-*-gnu*)
2504     target_makefile_frag="config/mt-mips-gnu"
2505     ;;
2506   nios2-*-elf*)
2507     target_makefile_frag="config/mt-nios2-elf"
2508     ;;
2509   *-*-linux-android*)
2510     target_makefile_frag="config/mt-android"
2511     ;;
2512   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2513     target_makefile_frag="config/mt-gnu"
2514     ;;
2515   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2516     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2517     # commands to handle both 32-bit and 64-bit objects.  These flags are
2518     # harmless if we're using GNU nm or ar.
2519     extra_arflags_for_target=" -X32_64"
2520     extra_nmflags_for_target=" -B -X32_64"
2521     ;;
2522 esac
2523
2524 alphaieee_frag=/dev/null
2525 case $target in
2526   alpha*-*-*)
2527     # This just makes sure to use the -mieee option to build target libs.
2528     # This should probably be set individually by each library.
2529     alphaieee_frag="config/mt-alphaieee"
2530     ;;
2531 esac
2532
2533 # If --enable-target-optspace always use -Os instead of -O2 to build
2534 # the target libraries, similarly if it is not specified, use -Os
2535 # on selected platforms.
2536 ospace_frag=/dev/null
2537 case "${enable_target_optspace}:${target}" in
2538   yes:*)
2539     ospace_frag="config/mt-ospace"
2540     ;;
2541   :d30v-*)
2542     ospace_frag="config/mt-d30v"
2543     ;;
2544   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2545     ospace_frag="config/mt-ospace"
2546     ;;
2547   no:* | :*)
2548     ;;
2549   *)
2550     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2551     ;;
2552 esac
2553
2554 # Some systems (e.g., one of the i386-aix systems the gas testers are
2555 # using) don't handle "\$" correctly, so don't use it here.
2556 tooldir='${exec_prefix}'/${target_noncanonical}
2557 build_tooldir=${tooldir}
2558
2559 # Create a .gdbinit file which runs the one in srcdir
2560 # and tells GDB to look there for source files.
2561
2562 if test -r ${srcdir}/.gdbinit ; then
2563   case ${srcdir} in
2564     .) ;;
2565     *) cat > ./.gdbinit <<EOF
2566 # ${NO_EDIT}
2567 dir ${srcdir}
2568 dir .
2569 source ${srcdir}/.gdbinit
2570 EOF
2571     ;;
2572   esac
2573 fi
2574
2575 # Make sure that the compiler is able to generate an executable.  If it
2576 # can't, we are probably in trouble.  We don't care whether we can run the
2577 # executable--we might be using a cross compiler--we only care whether it
2578 # can be created.  At this point the main configure script has set CC.
2579 we_are_ok=no
2580 echo "int main () { return 0; }" > conftest.c
2581 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2582 if test $? = 0 ; then
2583   if test -s conftest || test -s conftest.exe ; then
2584     we_are_ok=yes
2585   fi
2586 fi
2587 case $we_are_ok in
2588   no)
2589     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2590     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2591     rm -f conftest*
2592     exit 1
2593     ;;
2594 esac
2595 rm -f conftest*
2596
2597 # Decide which environment variable is used to find dynamic libraries.
2598 case "${host}" in
2599   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2600   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2601   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2602   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2603 esac
2604
2605 # On systems where the dynamic library environment variable is PATH,
2606 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2607 # built executables to PATH.
2608 if test "$RPATH_ENVVAR" = PATH; then
2609   GCC_SHLIB_SUBDIR=/shlib
2610 else
2611   GCC_SHLIB_SUBDIR=
2612 fi
2613
2614 # Adjust the toplevel makefile according to whether bootstrap was selected.
2615 case $enable_bootstrap in
2616   yes)
2617     bootstrap_suffix=bootstrap
2618     BUILD_CONFIG=bootstrap-debug
2619     ;;
2620   no)
2621     bootstrap_suffix=no-bootstrap
2622     BUILD_CONFIG=
2623     ;;
2624 esac
2625
2626 AC_MSG_CHECKING(for default BUILD_CONFIG)
2627
2628 AC_ARG_WITH([build-config],
2629   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2630                   [use config/NAME.mk build configuration])],
2631   [case $with_build_config in
2632    yes) with_build_config= ;;
2633    no) with_build_config= BUILD_CONFIG= ;;
2634    esac])
2635
2636 if test "x${with_build_config}" != x; then
2637   BUILD_CONFIG=$with_build_config
2638 else
2639   case $BUILD_CONFIG in
2640   bootstrap-debug)
2641     if echo "int f (void) { return 0; }" > conftest.c &&
2642        ${CC} -c conftest.c &&
2643        mv conftest.o conftest.o.g0 &&
2644        ${CC} -c -g conftest.c &&
2645        mv conftest.o conftest.o.g &&
2646        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2647       :
2648     else
2649       BUILD_CONFIG=
2650     fi
2651     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2652     ;;
2653   esac
2654 fi
2655 AC_MSG_RESULT($BUILD_CONFIG)
2656 AC_SUBST(BUILD_CONFIG)
2657
2658 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2659 AC_MSG_CHECKING([for --enable-vtable-verify])
2660 AC_ARG_ENABLE(vtable-verify,
2661 [AS_HELP_STRING([--enable-vtable-verify],
2662                 [Enable vtable verification feature])],
2663 [case "$enableval" in
2664  yes) enable_vtable_verify=yes ;;
2665  no)  enable_vtable_verify=no ;;
2666  *)   enable_vtable_verify=no;;
2667  esac],
2668 [enable_vtable_verify=no])
2669 AC_MSG_RESULT($enable_vtable_verify)
2670
2671 # Record target_configdirs and the configure arguments for target and
2672 # build configuration in Makefile.
2673 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2674 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2675 bootstrap_fixincludes=no
2676
2677 # If we are building libgomp, bootstrap it.
2678 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2679   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2680 fi
2681
2682 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2683 # or bootstrap-ubsan, bootstrap it.
2684 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2685   case "$BUILD_CONFIG" in
2686     *bootstrap-asan* | *bootstrap-ubsan* )
2687       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2688       bootstrap_fixincludes=yes
2689       ;;
2690   esac
2691 fi
2692
2693 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2694 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2695    test "$enable_vtable_verify" != no; then
2696   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2697 fi
2698
2699 # If we are building libmpx and $BUILD_CONFIG contains bootstrap-mpx,
2700 # bootstrap it.
2701 if echo " ${target_configdirs} " | grep " libmpx " > /dev/null 2>&1; then
2702   case "$BUILD_CONFIG" in
2703     *bootstrap-mpx* )
2704       bootstrap_target_libs=${bootstrap_target_libs}target-libmpx,
2705       ;;
2706   esac
2707 fi
2708
2709 # Determine whether gdb needs tk/tcl or not.
2710 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2711 # and in that case we want gdb to be built without tk.  Ugh!
2712 # In fact I believe gdb is the *only* package directly dependent on tk,
2713 # so we should be able to put the 'maybe's in unconditionally and
2714 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2715 # 100% sure that that's safe though.
2716
2717 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2718 case "$enable_gdbtk" in
2719   no)
2720     GDB_TK="" ;;
2721   yes)
2722     GDB_TK="${gdb_tk}" ;;
2723   *)
2724     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2725     # distro.  Eventually someone will fix this and move Insight, nee
2726     # gdbtk to a separate directory.
2727     if test -d ${srcdir}/gdb/gdbtk ; then
2728       GDB_TK="${gdb_tk}"
2729     else
2730       GDB_TK=""
2731     fi
2732     ;;
2733 esac
2734 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2735 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2736
2737 # Strip out unwanted targets.
2738
2739 # While at that, we remove Makefiles if we were started for recursive
2740 # configuration, so that the top-level Makefile reconfigures them,
2741 # like we used to do when configure itself was recursive.
2742
2743 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2744 # but now we're fixing up the Makefile ourselves with the additional
2745 # commands passed to AC_CONFIG_FILES.  Use separate variables
2746 # extrasub-{build,host,target} not because there is any reason to split
2747 # the substitutions up that way, but only to remain below the limit of
2748 # 99 commands in a script, for HP-UX sed.
2749 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2750
2751 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2752   yes:yes:*\ gold\ *:*,c++,*) ;;
2753   yes:yes:*\ gold\ *:*)
2754     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2755     ;;
2756 esac
2757
2758 extrasub_build=
2759 for module in ${build_configdirs} ; do
2760   if test -z "${no_recursion}" \
2761      && test -f ${build_subdir}/${module}/Makefile; then
2762     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2763     rm -f ${build_subdir}/${module}/Makefile
2764   fi
2765   extrasub_build="$extrasub_build
2766 /^@if build-$module\$/d
2767 /^@endif build-$module\$/d
2768 /^@if build-$module-$bootstrap_suffix\$/d
2769 /^@endif build-$module-$bootstrap_suffix\$/d"
2770 done
2771 extrasub_host=
2772 for module in ${configdirs} ; do
2773   if test -z "${no_recursion}"; then
2774     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2775       if test -f ${file}; then
2776         echo 1>&2 "*** removing ${file} to force reconfigure"
2777         rm -f ${file}
2778       fi
2779     done
2780   fi
2781   case ${module},${bootstrap_fixincludes} in
2782     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2783     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2784   esac
2785   extrasub_host="$extrasub_host
2786 /^@if $module\$/d
2787 /^@endif $module\$/d
2788 /^@if $module-$host_bootstrap_suffix\$/d
2789 /^@endif $module-$host_bootstrap_suffix\$/d"
2790 done
2791 extrasub_target=
2792 for module in ${target_configdirs} ; do
2793   if test -z "${no_recursion}" \
2794      && test -f ${target_subdir}/${module}/Makefile; then
2795     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2796     rm -f ${target_subdir}/${module}/Makefile
2797   fi
2798
2799   # We only bootstrap target libraries listed in bootstrap_target_libs.
2800   case $bootstrap_target_libs in
2801     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2802     *) target_bootstrap_suffix=no-bootstrap ;;
2803   esac
2804
2805   extrasub_target="$extrasub_target
2806 /^@if target-$module\$/d
2807 /^@endif target-$module\$/d
2808 /^@if target-$module-$target_bootstrap_suffix\$/d
2809 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2810 done
2811
2812 # Do the final fixup along with target modules.
2813 extrasub_target="$extrasub_target
2814 /^@if /,/^@endif /d"
2815
2816 # Create the serialization dependencies.  This uses a temporary file.
2817
2818 AC_ARG_ENABLE([serial-configure],
2819 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2820                 [force sequential configuration of
2821                  sub-packages for the host, target or build
2822                  machine, or all sub-packages])])
2823
2824 case ${enable_serial_configure} in
2825   yes)
2826     enable_serial_build_configure=yes
2827     enable_serial_host_configure=yes
2828     enable_serial_target_configure=yes
2829     ;;
2830 esac
2831
2832 # These force 'configure's to be done one at a time, to avoid problems
2833 # with contention over a shared config.cache.
2834 rm -f serdep.tmp
2835 echo '# serdep.tmp' > serdep.tmp
2836 olditem=
2837 test "x${enable_serial_build_configure}" = xyes &&
2838 for item in ${build_configdirs} ; do
2839   case ${olditem} in
2840     "") ;;
2841     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2842   esac
2843   olditem=${item}
2844 done
2845 olditem=
2846 test "x${enable_serial_host_configure}" = xyes &&
2847 for item in ${configdirs} ; do
2848   case ${olditem} in
2849     "") ;;
2850     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2851   esac
2852   olditem=${item}
2853 done
2854 olditem=
2855 test "x${enable_serial_target_configure}" = xyes &&
2856 for item in ${target_configdirs} ; do
2857   case ${olditem} in
2858     "") ;;
2859     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2860   esac
2861   olditem=${item}
2862 done
2863 serialization_dependencies=serdep.tmp
2864 AC_SUBST_FILE(serialization_dependencies)
2865
2866 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2867 # target, nonopt, and variable assignments.  These are the ones we
2868 # might not want to pass down to subconfigures.  The exception being
2869 # --cache-file=/dev/null, which is used to turn off the use of cache
2870 # files altogether, and which should be passed on to subconfigures.
2871 # Also strip program-prefix, program-suffix, and program-transform-name,
2872 # so that we can pass down a consistent program-transform-name.
2873 baseargs=
2874 tbaseargs=
2875 keep_next=no
2876 skip_next=no
2877 eval "set -- $ac_configure_args"
2878 for ac_arg
2879 do
2880   if test X"$skip_next" = X"yes"; then
2881     skip_next=no
2882     continue
2883   fi
2884   if test X"$keep_next" = X"yes"; then
2885     case $ac_arg in
2886       *\'*)
2887         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2888     esac
2889     baseargs="$baseargs '$ac_arg'"
2890     tbaseargs="$tbaseargs '$ac_arg'"
2891     keep_next=no
2892     continue
2893   fi
2894
2895   # Handle separated arguments.  Based on the logic generated by
2896   # autoconf 2.59.
2897   case $ac_arg in
2898     *=* | --config-cache | -C | -disable-* | --disable-* \
2899       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2900       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2901       | -with-* | --with-* | -without-* | --without-* | --x)
2902       separate_arg=no
2903       ;;
2904     -*)
2905       separate_arg=yes
2906       ;;
2907     *)
2908       separate_arg=no
2909       ;;
2910   esac
2911
2912   skip_targ=no
2913   case $ac_arg in
2914 changequote(,)
2915   --with-* | --without-*)
2916     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2917
2918     case $libopt in
2919     *[-_]include)
2920       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2921       ;;
2922     *[-_]lib)
2923       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2924       ;;
2925     *)
2926       lib=$libopt
2927       ;;
2928     esac
2929 changequote([,])
2930
2931     case $lib in
2932     mpc | mpfr | gmp | isl)
2933       # If we're processing --with-$lib, --with-$lib-include or
2934       # --with-$lib-lib, for one of the libs above, and target is
2935       # different from host, don't pass the current argument to any
2936       # target library's configure.
2937       if test x$is_cross_compiler = xyes; then
2938         skip_targ=yes
2939       fi
2940       ;;
2941     esac
2942     ;;
2943   esac
2944
2945   case "$ac_arg" in
2946     --cache-file=/dev/null | \
2947     -cache-file=/dev/null )
2948       # Handled here to avoid the test to skip args below.
2949       baseargs="$baseargs '$ac_arg'"
2950       tbaseargs="$tbaseargs '$ac_arg'"
2951       # Assert: $separate_arg should always be no.
2952       keep_next=$separate_arg
2953       ;;
2954     --no*)
2955       continue
2956       ;;
2957     --c* | \
2958     --sr* | \
2959     --ho* | \
2960     --bu* | \
2961     --t* | \
2962     --program-* | \
2963     -cache_file* | \
2964     -srcdir* | \
2965     -host* | \
2966     -build* | \
2967     -target* | \
2968     -program-prefix* | \
2969     -program-suffix* | \
2970     -program-transform-name* )
2971       skip_next=$separate_arg
2972       continue
2973       ;;
2974     -*)
2975       # An option.  Add it.
2976       case $ac_arg in
2977         *\'*)
2978           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2979       esac
2980       baseargs="$baseargs '$ac_arg'"
2981       if test X"$skip_targ" = Xno; then
2982         tbaseargs="$tbaseargs '$ac_arg'"
2983       fi
2984       keep_next=$separate_arg
2985       ;;
2986     *)
2987       # Either a variable assignment, or a nonopt (triplet).  Don't
2988       # pass it down; let the Makefile handle this.
2989       continue
2990       ;;
2991   esac
2992 done
2993 # Remove the initial space we just introduced and, as these will be
2994 # expanded by make, quote '$'.
2995 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2996
2997 # Add in --program-transform-name, after --program-prefix and
2998 # --program-suffix have been applied to it.  Autoconf has already
2999 # doubled dollar signs and backslashes in program_transform_name; we want
3000 # the backslashes un-doubled, and then the entire thing wrapped in single
3001 # quotes, because this will be expanded first by make and then by the shell.
3002 # Also, because we want to override the logic in subdir configure scripts to
3003 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3004 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3005 ${program_transform_name}
3006 EOF_SED
3007 gcc_transform_name=`cat conftestsed.out`
3008 rm -f conftestsed.out
3009 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3010 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3011 if test "$silent" = yes; then
3012   baseargs="$baseargs --silent"
3013   tbaseargs="$tbaseargs --silent"
3014 fi
3015 baseargs="$baseargs --disable-option-checking"
3016 tbaseargs="$tbaseargs --disable-option-checking"
3017
3018 # Record and document user additions to sub configure arguments.
3019 AC_ARG_VAR([build_configargs],
3020            [additional configure arguments for build directories])
3021 AC_ARG_VAR([host_configargs],
3022            [additional configure arguments for host directories])
3023 AC_ARG_VAR([target_configargs],
3024            [additional configure arguments for target directories])
3025
3026 # For the build-side libraries, we just need to pretend we're native,
3027 # and not use the same cache file.  Multilibs are neither needed nor
3028 # desired.  We can't even use the same cache file for all build-side
3029 # libraries, as they're compiled differently; some with C, some with
3030 # C++ or with different feature-enabling options.
3031 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3032
3033 # For host modules, accept cache file option, or specification as blank.
3034 case "${cache_file}" in
3035 "") # empty
3036   cache_file_option="" ;;
3037 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3038   cache_file_option="--cache-file=${cache_file}" ;;
3039 *) # relative path
3040   cache_file_option="--cache-file=../${cache_file}" ;;
3041 esac
3042
3043 # Host dirs don't like to share a cache file either, horribly enough.
3044 # This seems to be due to autoconf 2.5x stupidity.
3045 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3046
3047 target_configargs="$target_configargs ${tbaseargs}"
3048
3049 # Passing a --with-cross-host argument lets the target libraries know
3050 # whether they are being built with a cross-compiler or being built
3051 # native.  However, it would be better to use other mechanisms to make the
3052 # sorts of decisions they want to make on this basis.  Please consider
3053 # this option to be deprecated.  FIXME.
3054 if test x${is_cross_compiler} = xyes ; then
3055   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3056 fi
3057
3058 # Special user-friendly check for native x86_64-linux build, if
3059 # multilib is not explicitly enabled.
3060 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3061   x86_64-*linux*:yes:$build:$build:)
3062     # Make sure we have a development environment that handles 32-bit
3063     dev64=no
3064     echo "int main () { return 0; }" > conftest.c
3065     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3066     if test $? = 0 ; then
3067       if test -s conftest || test -s conftest.exe ; then
3068         dev64=yes
3069       fi
3070     fi
3071     rm -f conftest*
3072     if test x${dev64} != xyes ; then
3073       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3074     fi
3075     ;;
3076 esac
3077
3078 # Default to --enable-multilib.
3079 if test x${enable_multilib} = x ; then
3080   target_configargs="--enable-multilib ${target_configargs}"
3081 fi
3082
3083 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3084 # changed from the earlier setting of with_newlib.
3085 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3086   target_configargs="--with-newlib ${target_configargs}"
3087 fi
3088
3089 # Different target subdirs use different values of certain variables
3090 # (notably CXX).  Worse, multilibs use *lots* of different values.
3091 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3092 # it doesn't automatically accept command-line overrides of them.
3093 # This means it's not safe for target subdirs to share a cache file,
3094 # which is disgusting, but there you have it.  Hopefully this can be
3095 # fixed in future.  It's still worthwhile to use a cache file for each
3096 # directory.  I think.
3097
3098 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3099 # We need to pass --target, as newer autoconf's requires consistency
3100 # for target_alias and gcc doesn't manage it consistently.
3101 target_configargs="--cache-file=./config.cache ${target_configargs}"
3102
3103 FLAGS_FOR_TARGET=
3104 case " $target_configdirs " in
3105  *" newlib "*)
3106   case " $target_configargs " in
3107   *" --with-newlib "*)
3108    case "$target" in
3109     *-cygwin*)
3110       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3111       ;;
3112    esac
3113
3114    # If we're not building GCC, don't discard standard headers.
3115    if test -d ${srcdir}/gcc; then
3116      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3117
3118      if test "${build}" != "${host}"; then
3119        # On Canadian crosses, CC_FOR_TARGET will have already been set
3120        # by `configure', so we won't have an opportunity to add -Bgcc/
3121        # to it.  This is right: we don't want to search that directory
3122        # for binaries, but we want the header files in there, so add
3123        # them explicitly.
3124        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3125
3126        # Someone might think of using the pre-installed headers on
3127        # Canadian crosses, in case the installed compiler is not fully
3128        # compatible with the compiler being built.  In this case, it
3129        # would be better to flag an error than risking having
3130        # incompatible object files being constructed.  We can't
3131        # guarantee that an error will be flagged, but let's hope the
3132        # compiler will do it, when presented with incompatible header
3133        # files.
3134      fi
3135    fi
3136
3137    case "${target}-${is_cross_compiler}" in
3138    i[[3456789]]86-*-linux*-no)
3139       # Here host == target, so we don't need to build gcc,
3140       # so we don't want to discard standard headers.
3141       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3142       ;;
3143    *)
3144       # If we're building newlib, use its generic headers last, but search
3145       # for any libc-related directories first (so make it the last -B
3146       # switch).
3147       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3148
3149       # If we're building libgloss, find the startup file, simulator library
3150       # and linker script.
3151       case " $target_configdirs " in
3152         *" libgloss "*)
3153         # Look for startup file, simulator library and maybe linker script.
3154         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3155         # Look for libnosys.a in case the target needs it.
3156         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3157         # Most targets have the linker script in the source directory.
3158         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3159         ;;
3160       esac
3161       ;;
3162    esac
3163    ;;
3164   esac
3165   ;;
3166 esac
3167
3168 case "$target" in
3169   x86_64-*mingw* | *-w64-mingw*)
3170   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3171   # however, use a symlink named 'mingw' in ${prefix} .
3172     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3173     ;;
3174   *-mingw*)
3175   # MinGW can't be handled as Cygwin above since it does not use newlib.
3176     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3177     ;;
3178 esac
3179
3180 # Allow the user to override the flags for
3181 # our build compiler if desired.
3182 if test x"${build}" = x"${host}" ; then
3183   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3184   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3185   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3186 fi
3187
3188 # On Canadian crosses, we'll be searching the right directories for
3189 # the previously-installed cross compiler, so don't bother to add
3190 # flags for directories within the install tree of the compiler
3191 # being built; programs in there won't even run.
3192 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3193   # Search for pre-installed headers if nothing else fits.
3194   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3195 fi
3196
3197 if test "x${use_gnu_ld}" = x &&
3198    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3199   # Arrange for us to find uninstalled linker scripts.
3200   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3201 fi
3202
3203 # Search for other target-specific linker scripts and such.
3204 case "${target}" in
3205   mep*)
3206     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3207     ;;
3208 esac
3209
3210 # Makefile fragments.
3211 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3212 do
3213   eval fragval=\$$frag
3214   if test $fragval != /dev/null; then
3215     eval $frag=${srcdir}/$fragval
3216   fi
3217 done
3218 AC_SUBST_FILE(host_makefile_frag)
3219 AC_SUBST_FILE(target_makefile_frag)
3220 AC_SUBST_FILE(alphaieee_frag)
3221 AC_SUBST_FILE(ospace_frag)
3222
3223 # Miscellanea: directories, flags, etc.
3224 AC_SUBST(RPATH_ENVVAR)
3225 AC_SUBST(GCC_SHLIB_SUBDIR)
3226 AC_SUBST(tooldir)
3227 AC_SUBST(build_tooldir)
3228 AC_SUBST(CONFIGURE_GDB_TK)
3229 AC_SUBST(GDB_TK)
3230 AC_SUBST(INSTALL_GDB_TK)
3231
3232 # Build module lists & subconfigure args.
3233 AC_SUBST(build_configargs)
3234 AC_SUBST(build_configdirs)
3235
3236 # Host module lists & subconfigure args.
3237 AC_SUBST(host_configargs)
3238 AC_SUBST(configdirs)
3239 AC_SUBST(target_configdirs)
3240
3241 # Target module lists & subconfigure args.
3242 AC_SUBST(target_configargs)
3243
3244
3245 # Build tools.
3246 AC_SUBST(AR_FOR_BUILD)
3247 AC_SUBST(AS_FOR_BUILD)
3248 AC_SUBST(CC_FOR_BUILD)
3249 AC_SUBST(CFLAGS_FOR_BUILD)
3250 AC_SUBST(CXXFLAGS_FOR_BUILD)
3251 AC_SUBST(CXX_FOR_BUILD)
3252 AC_SUBST(DLLTOOL_FOR_BUILD)
3253 AC_SUBST(GFORTRAN_FOR_BUILD)
3254 AC_SUBST(GOC_FOR_BUILD)
3255 AC_SUBST(LDFLAGS_FOR_BUILD)
3256 AC_SUBST(LD_FOR_BUILD)
3257 AC_SUBST(NM_FOR_BUILD)
3258 AC_SUBST(RANLIB_FOR_BUILD)
3259 AC_SUBST(WINDMC_FOR_BUILD)
3260 AC_SUBST(WINDRES_FOR_BUILD)
3261
3262 # Generate default definitions for YACC, M4, LEX and other programs that run
3263 # on the build machine.  These are used if the Makefile can't locate these
3264 # programs in objdir.
3265 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3266
3267 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3268 case " $build_configdirs " in
3269   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3270 esac
3271
3272 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3273 case " $build_configdirs " in
3274   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3275 esac
3276
3277 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3278 case " $build_configdirs " in
3279   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3280 esac
3281
3282 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3283 case " $build_configdirs " in
3284   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3285   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3286 esac
3287
3288 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3289 case " $build_configdirs " in
3290   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3291 esac
3292
3293 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3294 case " $build_configdirs " in
3295   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3296   *)
3297 changequote(,)
3298     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3299     # higher, else we use the "missing" dummy.
3300     if ${MAKEINFO} --version \
3301        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3302       :
3303     else
3304       MAKEINFO="$MISSING makeinfo"
3305     fi
3306     ;;
3307 changequote([,])
3308 esac
3309
3310 # FIXME: expect and dejagnu may become build tools?
3311
3312 AC_CHECK_PROGS(EXPECT, expect, expect)
3313 case " $configdirs " in
3314   *" expect "*)
3315     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3316     ;;
3317 esac
3318
3319 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3320 case " $configdirs " in
3321   *" dejagnu "*)
3322     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3323     ;;
3324 esac
3325
3326
3327 # Host tools.
3328 NCN_STRICT_CHECK_TOOLS(AR, ar)
3329 NCN_STRICT_CHECK_TOOLS(AS, as)
3330 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3331 NCN_STRICT_CHECK_TOOLS(LD, ld)
3332 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3333 NCN_STRICT_CHECK_TOOLS(NM, nm)
3334 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3335 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3336 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3337 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3338 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3339 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3340 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3341 AC_SUBST(CC)
3342 AC_SUBST(CXX)
3343 AC_SUBST(CFLAGS)
3344 AC_SUBST(CXXFLAGS)
3345
3346 # Target tools.
3347 AC_ARG_WITH([build-time-tools],
3348   [AS_HELP_STRING([--with-build-time-tools=PATH],
3349                   [use given path to find target tools during the build])],
3350   [case x"$withval" in
3351      x/*) ;;
3352      *)
3353        with_build_time_tools=
3354        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3355        ;;
3356    esac],
3357   [with_build_time_tools=])
3358
3359 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3360 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3361 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3362 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3363 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3364
3365 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3366 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3367 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3368 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3369 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3370 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3371 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3372 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3373 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3374 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3375 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3376 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3377 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3378
3379 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3380
3381 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3382 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3383 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3384 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3385 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3386                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3387                 c++)
3388 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3389                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3390                 c++)
3391 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3392 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3393 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3394                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3395 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3396                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3397 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3398 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3399 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3400 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3401 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3402 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3403 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3404 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3405 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3406 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3407
3408 AC_SUBST(FLAGS_FOR_TARGET)
3409 AC_SUBST(RAW_CXX_FOR_TARGET)
3410
3411 # Certain tools may need extra flags.
3412 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3413 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3414 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3415
3416 # When building target libraries, except in a Canadian cross, we use
3417 # the same toolchain as the compiler we just built.
3418 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3419 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3420 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3421 if test $host = $build; then
3422   case " $configdirs " in
3423     *" gcc "*)
3424       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3425       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3426       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3427       ;;
3428   esac
3429 fi
3430
3431 AC_SUBST(COMPILER_AS_FOR_TARGET)
3432 AC_SUBST(COMPILER_LD_FOR_TARGET)
3433 AC_SUBST(COMPILER_NM_FOR_TARGET)
3434
3435 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3436 AC_ARG_ENABLE(maintainer-mode,
3437 [AS_HELP_STRING([--enable-maintainer-mode],
3438                 [enable make rules and dependencies not useful
3439                  (and sometimes confusing) to the casual installer])],
3440       USE_MAINTAINER_MODE=$enableval,
3441       USE_MAINTAINER_MODE=no)
3442 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3443 AC_SUBST(MAINTAINER_MODE_TRUE)
3444 AC_SUBST(MAINTAINER_MODE_FALSE)
3445 if test "$USE_MAINTAINER_MODE" = yes; then
3446   MAINTAINER_MODE_TRUE=
3447   MAINTAINER_MODE_FALSE='#'
3448 else
3449   MAINTAINER_MODE_TRUE='#'
3450   MAINTAINER_MODE_FALSE=
3451 fi
3452 MAINT=$MAINTAINER_MODE_TRUE
3453 AC_SUBST(MAINT)dnl
3454
3455 # ---------------------
3456 # GCC bootstrap support
3457 # ---------------------
3458
3459 # Stage specific cflags for build.
3460 stage1_cflags="-g"
3461 case $build in
3462   vax-*-*)
3463     case ${GCC} in
3464       yes) stage1_cflags="-g -Wa,-J" ;;
3465       *) stage1_cflags="-g -J" ;;
3466     esac ;;
3467 esac
3468
3469 AC_SUBST(stage1_cflags)
3470
3471 # Enable --enable-checking in stage1 of the compiler.
3472 AC_ARG_ENABLE(stage1-checking,
3473 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3474                 [choose additional checking for stage1 of the compiler])],
3475 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3476 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3477   # For --disable-checking or implicit --enable-checking=release, avoid
3478   # setting --enable-checking=gc in the default stage1 checking for LTO
3479   # bootstraps.  See PR62077.
3480   case $BUILD_CONFIG in
3481     *lto*)
3482       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3483     *)
3484       stage1_checking=--enable-checking=yes,types;;
3485   esac
3486   if test "x$enable_checking" = x && \
3487      test -d ${srcdir}/gcc && \
3488      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3489     stage1_checking=--enable-checking=yes,types,extra
3490   fi
3491 else
3492   stage1_checking=--enable-checking=$enable_checking,types
3493 fi])
3494 AC_SUBST(stage1_checking)
3495
3496 # Enable -Werror in bootstrap stage2 and later.
3497 AC_ARG_ENABLE(werror,
3498 [AS_HELP_STRING([--enable-werror],
3499                 [enable -Werror in bootstrap stage2 and later])],
3500 [
3501 case ${enable_werror} in
3502   yes) stage2_werror_flag="--enable-werror-always" ;;
3503   *) stage2_werror_flag="" ;;
3504 esac
3505 ],
3506 [
3507 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3508   case $BUILD_CONFIG in
3509   bootstrap-debug)
3510       stage2_werror_flag="--enable-werror-always" ;;
3511   "")
3512       stage2_werror_flag="--enable-werror-always" ;;
3513   esac
3514 fi
3515 ])
3516
3517 AC_SUBST(stage2_werror_flag)
3518
3519 # Specify what files to not compare during bootstrap.
3520
3521 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3522 case "$target" in
3523   hppa*64*-*-hpux*) ;;
3524   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/* | gcc/function-tests.o" ;;
3525   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3526 esac
3527 AC_SUBST(compare_exclusions)
3528
3529 AC_CONFIG_FILES([Makefile],
3530   [sed "$extrasub_build" Makefile |
3531    sed "$extrasub_host" |
3532    sed "$extrasub_target" > mf$$
3533    mv -f mf$$ Makefile],
3534   [extrasub_build="$extrasub_build"
3535    extrasub_host="$extrasub_host"
3536    extrasub_target="$extrasub_target"])
3537 AC_OUTPUT