gcc/configure.in

   1 # configure.in for GNU CC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 1997, 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   5
   6 #This file is part of GNU CC.
   7
   8 #GNU CC is free software; you can redistribute it and/or modify
   9 #it under the terms of the GNU General Public License as published by
  10 #the Free Software Foundation; either version 2, or (at your option)
  11 #any later version.
  12
  13 #GNU CC is distributed in the hope that it will be useful,
  14 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #GNU General Public License for more details.
  17
  18 #You should have received a copy of the GNU General Public License
  19 #along with GNU CC; see the file COPYING.  If not, write to
  20 #the Free Software Foundation, 59 Temple Place - Suite 330,
  21 #Boston, MA 02111-1307, USA.
  22
  23 # Initialization and defaults
  24 AC_PREREQ(2.13)
  25 AC_INIT(tree.c)
  26 AC_CONFIG_HEADER(auto-host.h:config.in)
  27
  28 remove=rm
  29 hard_link=ln
  30 symbolic_link='ln -s'
  31 copy=cp
  32
  33 # Check for bogus environment variables.
  34 # Test if LIBRARY_PATH contains the notation for the current directory
  35 # since this would lead to problems installing/building glibc.
  36 # LIBRARY_PATH contains the current directory if one of the following
  37 # is true:
  38 # - one of the terminals (":" and ";") is the first or last sign
  39 # - two terminals occur directly after each other
  40 # - the path contains an element with a dot in it
  41 AC_MSG_CHECKING(LIBRARY_PATH variable)
  42 changequote(,)dnl
  43 case ${LIBRARY_PATH} in
  44   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  45     library_path_setting="contains current directory"
  46     ;;
  47   *)
  48     library_path_setting="ok"
  49     ;;
  50 esac
  51 changequote([,])dnl
  52 AC_MSG_RESULT($library_path_setting)
  53 if test "$library_path_setting" != "ok"; then
  54 AC_MSG_ERROR([
  55 *** LIBRARY_PATH shouldn't contain the current directory when
  56 *** building gcc. Please change the environment variable
  57 *** and run configure again.])
  58 fi
  59
  60 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  61 # since this would lead to problems installing/building glibc.
  62 # GCC_EXEC_PREFIX contains the current directory if one of the following
  63 # is true:
  64 # - one of the terminals (":" and ";") is the first or last sign
  65 # - two terminals occur directly after each other
  66 # - the path contains an element with a dot in it
  67 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  68 changequote(,)dnl
  69 case ${GCC_EXEC_PREFIX} in
  70   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  71     gcc_exec_prefix_setting="contains current directory"
  72     ;;
  73   *)
  74     gcc_exec_prefix_setting="ok"
  75     ;;
  76 esac
  77 changequote([,])dnl
  78 AC_MSG_RESULT($gcc_exec_prefix_setting)
  79 if test "$gcc_exec_prefix_setting" != "ok"; then
  80 AC_MSG_ERROR([
  81 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  82 *** building gcc. Please change the environment variable
  83 *** and run configure again.])
  84 fi
  85
  86 # Check for additional parameters
  87
  88 # With GNU ld
  89 AC_ARG_WITH(gnu-ld,
  90 [  --with-gnu-ld           arrange to work with GNU ld.],
  91 gnu_ld_flag="$with_gnu_ld",
  92 gnu_ld_flag=no)
  93
  94 # With pre-defined ld
  95 AC_ARG_WITH(ld,
  96 [  --with-ld               arrange to use the specified ld (full pathname).],
  97 DEFAULT_LINKER="$with_ld")
  98 if test x"${DEFAULT_LINKER+set}" = x"set"; then
  99   if test ! -x "$DEFAULT_LINKER"; then
 100     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 101   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 102     gnu_ld_flag=yes
 103   fi
 104   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 105         [Define to enable the use of a default linker.])
 106 fi
 107
 108 # With GNU as
 109 AC_ARG_WITH(gnu-as,
 110 [  --with-gnu-as           arrange to work with GNU as.],
 111 gas_flag="$with_gnu_as",
 112 gas_flag=no)
 113
 114 AC_ARG_WITH(as,
 115 [  --with-as               arrange to use the specified as (full pathname).],
 116 DEFAULT_ASSEMBLER="$with_as")
 117 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 118   if test ! -x "$DEFAULT_ASSEMBLER"; then
 119     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 120   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 121     gas_flag=yes
 122   fi
 123   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 124         [Define to enable the use of a default assembler.])
 125 fi
 126
 127 # With stabs
 128 AC_ARG_WITH(stabs,
 129 [  --with-stabs            arrange to use stabs instead of host debug format.],
 130 stabs="$with_stabs",
 131 stabs=no)
 132
 133 # With ELF
 134 AC_ARG_WITH(elf,
 135 [  --with-elf              arrange to use ELF instead of host debug format.],
 136 elf="$with_elf",
 137 elf=no)
 138
 139 # Specify the local prefix
 140 local_prefix=
 141 AC_ARG_WITH(local-prefix,
 142 [  --with-local-prefix=DIR specifies directory to put local include.],
 143 [case "${withval}" in
 144 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 145 no)     ;;
 146 *)      local_prefix=$with_local_prefix ;;
 147 esac])
 148
 149 # Default local prefix if it is empty
 150 if test x$local_prefix = x; then
 151         local_prefix=/usr/local
 152 fi
 153
 154 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 155 # passed in by the toplevel make and thus we'd get different behavior
 156 # depending on where we built the sources.
 157 gcc_gxx_include_dir=
 158 # Specify the g++ header file directory
 159 AC_ARG_WITH(gxx-include-dir,
 160 [  --with-gxx-include-dir=DIR
 161                           specifies directory to put g++ header files.],
 162 [case "${withval}" in
 163 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 164 no)     ;;
 165 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 166 esac])
 167
 168 if test x${gcc_gxx_include_dir} = x; then
 169   if test x${enable_version_specific_runtime_libs} = xyes; then
 170     gcc_gxx_include_dir='${libsubdir}/include/g++'
 171   else
 172     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 173 changequote(<<, >>)dnl
 174     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 175 changequote([, ])dnl
 176   fi
 177 fi
 178
 179 # Determine whether or not multilibs are enabled.
 180 AC_ARG_ENABLE(multilib,
 181 [  --enable-multilib      enable library support for multiple ABIs],
 182 [], [enable_multilib=yes])
 183 AC_SUBST(enable_multilib)
 184
 185 # Enable expensive internal checks
 186 AC_ARG_ENABLE(checking,
 187 [  --enable-checking[=LIST]
 188                           enable expensive run-time checks.  With LIST,
 189                           enable only specific categories of checks.
 190                           Categories are: misc,tree,rtl,gc,gcac; default
 191                           is misc,tree,gc],
 192 [ac_checking=
 193 ac_tree_checking=
 194 ac_rtl_checking=
 195 ac_gc_checking=
 196 ac_gc_always_collect=
 197 case "${enableval}" in
 198 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;;
 199 no)     ;;
 200 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 201         set fnord $enableval; shift
 202         IFS="$ac_save_IFS"
 203         for check
 204         do
 205                 case $check in
 206                 misc)   ac_checking=1 ;;
 207                 tree)   ac_tree_checking=1 ;;
 208                 rtl)    ac_rtl_checking=1 ;;
 209                 gc)     ac_gc_checking=1 ;;
 210                 gcac)   ac_gc_always_collect=1 ;;
 211                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 212                 esac
 213         done
 214         ;;
 215 esac
 216 ],
 217 # Enable some checks by default for development versions of GCC
 218 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1;])
 219 if test x$ac_checking != x ; then
 220   AC_DEFINE(ENABLE_CHECKING, 1,
 221 [Define if you want more run-time sanity checks.  This one gets a grab
 222    bag of miscellaneous but relatively cheap checks.])
 223 fi
 224 if test x$ac_tree_checking != x ; then
 225   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 226 [Define if you want all operations on trees (the basic data
 227    structure of the front ends) to be checked for dynamic type safety
 228    at runtime.  This is moderately expensive.])
 229 fi
 230 if test x$ac_rtl_checking != x ; then
 231   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 232 [Define if you want all operations on RTL (the basic data structure
 233    of the optimizer and back end) to be checked for dynamic type safety
 234    at runtime.  This is quite expensive.])
 235 fi
 236 if test x$ac_gc_checking != x ; then
 237   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 238 [Define if you want the garbage collector to do object poisoning and
 239    other memory allocation checks.  This is quite expensive.])
 240 fi
 241 if test x$ac_gc_always_collect != x ; then
 242   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 243 [Define if you want the garbage collector to operate in maximally
 244    paranoid mode, validating the entire heap and collecting garbage at
 245    every opportunity.  This is extremely expensive.])
 246 fi
 247
 248
 249 AC_ARG_ENABLE(cpp,
 250 [  --disable-cpp           don't provide a user-visible C preprocessor.],
 251 [], [enable_cpp=yes])
 252
 253 AC_ARG_WITH(cpp_install_dir,
 254 [  --with-cpp-install-dir=DIR
 255                           install the user visible C preprocessor in DIR
 256                           (relative to PREFIX) as well as PREFIX/bin.],
 257 [if test x$withval = xyes; then
 258   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 259 elif test x$withval != xno; then
 260   cpp_install_dir=$withval
 261 fi])
 262
 263 # Enable Multibyte Characters for C/C++
 264 AC_ARG_ENABLE(c-mbchar,
 265 [  --enable-c-mbchar       Enable multibyte characters for C and C++.],
 266 if test x$enable_c_mbchar != xno; then
 267   AC_DEFINE(MULTIBYTE_CHARS, 1,
 268   [Define if you want the C and C++ compilers to support multibyte
 269    character sets for source code.])
 270 fi)
 271
 272 # Enable threads
 273 # Pass with no value to take the default
 274 # Pass with a value to specify a thread package
 275 AC_ARG_ENABLE(threads,
 276 [  --enable-threads        enable thread usage for target GCC.
 277   --enable-threads=LIB    use LIB thread package for target GCC.],,
 278 enable_threads='')
 279
 280 enable_threads_flag=$enable_threads
 281 # Check if a valid thread package
 282 case x${enable_threads_flag} in
 283         x | xno)
 284                 # No threads
 285                 target_thread_file='single'
 286                 ;;
 287         xyes)
 288                 # default
 289                 target_thread_file=''
 290                 ;;
 291         xdecosf1 | xirix | xmach | xos2 | xposix | xpthreads | xsingle | \
 292         xsolaris | xwin32 | xdce | xvxworks | xaix)
 293                 target_thread_file=$enable_threads_flag
 294                 ;;
 295         *)
 296                 echo "$enable_threads is an unknown thread package" 1>&2
 297                 exit 1
 298                 ;;
 299 esac
 300
 301 AC_ARG_ENABLE(objc-gc,
 302 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 303                           the GNU Objective-C runtime.],
 304 if test x$enable_objc_gc = xno; then
 305         objc_boehm_gc=''
 306 else
 307         objc_boehm_gc=1
 308 fi,
 309 objc_boehm_gc='')
 310
 311 AC_ARG_WITH(dwarf2,
 312 [  --with-dwarf2          force the default debug format to be DWARF2.],
 313 dwarf2="$with_dwarf2",
 314 dwarf2=no)
 315
 316 AC_ARG_ENABLE(shared,
 317 [  --disable-shared       don't provide a shared libgcc.],
 318 [], [enable_shared=yes])
 319 AC_SUBST(enable_shared)
 320
 321 # Determine the host, build, and target systems
 322 AC_CANONICAL_SYSTEM
 323
 324 # Find the native compiler
 325 AC_PROG_CC
 326 AC_PROG_CC_C_O
 327 # autoconf is lame and doesn't give us any substitution variable for this.
 328 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 329   NO_MINUS_C_MINUS_O=yes
 330 else
 331   OUTPUT_OPTION='-o $@'
 332 fi
 333 AC_SUBST(NO_MINUS_C_MINUS_O)
 334 AC_SUBST(OUTPUT_OPTION)
 335
 336 gcc_AC_C_LONG_DOUBLE
 337
 338 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
 339 ac_cv_prog_cc_no_long_long,
 340 [save_CFLAGS="$CFLAGS"
 341 CFLAGS="-Wno-long-long"
 342 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
 343                ac_cv_prog_cc_no_long_long=no)
 344 CFLAGS="$save_CFLAGS"])
 345 strict1_warn=
 346 if test $ac_cv_prog_cc_no_long_long = yes; then
 347   strict1_warn="-pedantic -Wno-long-long"
 348 fi
 349 AC_SUBST(strict1_warn)
 350
 351 # If the native compiler is GCC, we can enable warnings even in stage1.
 352 # That's useful for people building cross-compilers, or just running a
 353 # quick `make'.
 354 warn_cflags=
 355 if test "x$GCC" = "xyes"; then
 356   warn_cflags='$(GCC_WARN_CFLAGS)'
 357 fi
 358 AC_SUBST(warn_cflags)
 359
 360 # Stage specific cflags for build.
 361 stage1_cflags=
 362 case $build in
 363 vax-*-*)
 364   if test x$GCC = xyes
 365   then
 366     stage1_cflags="-Wa,-J"
 367   else
 368     stage1_cflags="-J"
 369   fi
 370   ;;
 371 esac
 372 AC_SUBST(stage1_cflags)
 373
 374 AC_PROG_MAKE_SET
 375
 376 AC_MSG_CHECKING([whether a default assembler was specified])
 377 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 378     if test x"$gas_flag" = x"no"; then
 379         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 380     else
 381         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 382     fi
 383 else
 384     AC_MSG_RESULT(no)
 385 fi
 386
 387 AC_MSG_CHECKING([whether a default linker was specified])
 388 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 389     if test x"$gnu_ld_flag" = x"no"; then
 390         AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 391     else
 392         AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 393     fi
 394 else
 395     AC_MSG_RESULT(no)
 396 fi
 397
 398 AC_MSG_CHECKING(for GNU C library)
 399 AC_CACHE_VAL(gcc_cv_glibc,
 400 [AC_TRY_COMPILE(
 401   [#include <features.h>],[
 402 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 403 #error Not a GNU C library system
 404 #endif],
 405   [gcc_cv_glibc=yes],
 406   gcc_cv_glibc=no)])
 407 AC_MSG_RESULT($gcc_cv_glibc)
 408 if test $gcc_cv_glibc = yes; then
 409   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 410 fi
 411
 412 AC_C_INLINE
 413
 414 # Find some useful tools
 415 AC_PROG_AWK
 416 gcc_AC_PROG_LN
 417 gcc_AC_PROG_LN_S
 418 gcc_AC_C_VOLATILE
 419 AC_PROG_RANLIB
 420 gcc_AC_PROG_INSTALL
 421
 422 AC_HEADER_STDC
 423 AC_HEADER_TIME
 424 gcc_AC_HEADER_STRING
 425 AC_HEADER_SYS_WAIT
 426 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 427                  fcntl.h unistd.h stab.h sys/file.h sys/time.h \
 428                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 429                  direct.h malloc.h langinfo.h iconv.h stdbool.h)
 430
 431 # Check for thread headers.
 432 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 433 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 434
 435 # See if GNAT has been installed
 436 AC_CHECK_PROG(have_gnat, gnatbind, yes, no)
 437
 438 # See if we have the mktemp command.
 439 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 440
 441 # Do we have a single-tree copy of texinfo?
 442 if test -f $srcdir/../texinfo/Makefile.in; then
 443   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 444   gcc_cv_prog_makeinfo_modern=yes
 445   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 446 else
 447   # See if makeinfo has been installed and is modern enough
 448   # that we can use it.
 449   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 450   [GNU texinfo.* \([0-9][0-9.]*\)],
 451   [4.*])
 452 fi
 453
 454 if test $gcc_cv_prog_makeinfo_modern = no; then
 455   AC_MSG_WARN([
 456 *** Makeinfo is missing or too old.
 457 *** Info documentation will not be built.])
 458   BUILD_INFO=
 459 else
 460   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 461 fi
 462
 463 # Is pod2man recent enough to regenerate manpages?
 464 AC_MSG_CHECKING([for recent Pod::Man])
 465 if perl -e 'use 1.10 Pod::Man' >/dev/null 2>&1; then
 466   AC_MSG_RESULT(yes)
 467   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 468 else
 469   AC_MSG_RESULT(no)
 470   GENERATED_MANPAGES=
 471 fi
 472
 473 # How about lex?
 474 dnl Don't use AC_PROG_LEX; we insist on flex.
 475 dnl LEXLIB is not useful in gcc.
 476 if test -f $srcdir/../flex/skel.c; then
 477   FLEX='$(objdir)/../flex/flex'
 478 else
 479   AC_CHECK_PROG(FLEX, flex, flex, false)
 480 fi
 481
 482 # Bison?
 483 # The -L switch is so bison can find its skeleton file.
 484 if test -f $srcdir/../bison/bison.simple; then
 485   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 486 else
 487   AC_CHECK_PROG(BISON, bison, bison, false)
 488 fi
 489
 490 # See if the stage1 system preprocessor understands the ANSI C
 491 # preprocessor stringification operator.
 492 AC_C_STRINGIZE
 493
 494 # Use <inttypes.h> only if it exists,
 495 # doesn't clash with <sys/types.h>, and declares intmax_t.
 496 AC_MSG_CHECKING(for inttypes.h)
 497 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 498 [AC_TRY_COMPILE(
 499   [#include <sys/types.h>
 500 #include <inttypes.h>],
 501   [intmax_t i = -1;],
 502   [gcc_cv_header_inttypes_h=yes],
 503   gcc_cv_header_inttypes_h=no)])
 504 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 505 if test $gcc_cv_header_inttypes_h = yes; then
 506   AC_DEFINE(HAVE_INTTYPES_H, 1,
 507         [Define if you have a working <inttypes.h> header file.])
 508 fi
 509
 510 #
 511 # Determine if enumerated bitfields are unsigned.   ISO C says they can
 512 # be either signed or unsigned.
 513 #
 514 AC_CACHE_CHECK(for unsigned enumerated bitfields, gcc_cv_enum_bf_unsigned,
 515 [AC_TRY_RUN(#include <stdlib.h>
 516 enum t { BLAH = 128 } ;
 517 struct s_t { enum t member : 8; } s ;
 518 int main(void)
 519 {
 520         s.member = BLAH;
 521         if (s.member < 0) exit(1);
 522         exit(0);
 523
 524 }, gcc_cv_enum_bf_unsigned=yes, gcc_cv_enum_bf_unsigned=no, gcc_cv_enum_bf_unsigned=yes)])
 525 if test $gcc_cv_enum_bf_unsigned = yes; then
 526   AC_DEFINE(ENUM_BITFIELDS_ARE_UNSIGNED, 1,
 527     [Define if enumerated bitfields are treated as unsigned values.])
 528 fi
 529
 530 AC_CHECK_FUNCS(strtoul bsearch putenv popen bcopy \
 531         strchr strrchr kill getrlimit setrlimit atoll atoq \
 532         sysconf isascii gettimeofday strsignal putc_unlocked fputc_unlocked \
 533         fputs_unlocked getrusage iconv nl_langinfo)
 534
 535 AC_CHECK_TYPE(ssize_t, int)
 536
 537 # Try to determine the array type of the second argument of getgroups
 538 # for the target system (int or gid_t).
 539 AC_TYPE_GETGROUPS
 540 if test "${target}" = "${build}"; then
 541   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 542 else
 543   case "${target}" in
 544         # This condition may need some tweaking.  It should include all
 545         # targets where the array type of the second argument of getgroups
 546         # is int and the type of gid_t is not equivalent to int.
 547         *-*-sunos* | *-*-ultrix*)
 548                 TARGET_GETGROUPS_T=int
 549                 ;;
 550         *)
 551                 TARGET_GETGROUPS_T=gid_t
 552                 ;;
 553   esac
 554 fi
 555 AC_SUBST(TARGET_GETGROUPS_T)
 556
 557 gcc_AC_FUNC_VFPRINTF_DOPRNT
 558 gcc_AC_FUNC_STRSTR
 559 gcc_AC_FUNC_PRINTF_PTR
 560
 561 case "${host}" in
 562 *-*-uwin*)
 563   AC_MSG_ERROR([
 564 *** UWIN may not be used as a host platform because
 565 *** linking with posix.dll is not allowed by the GNU GPL])
 566   ;;
 567 esac
 568 AC_FUNC_VFORK
 569 AC_FUNC_MMAP_ANYWHERE
 570 AC_FUNC_MMAP_FILE
 571
 572 # We will need to find libiberty.h and ansidecl.h
 573 saved_CFLAGS="$CFLAGS"
 574 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 575 gcc_AC_CHECK_DECLS(bcopy \
 576         getenv atol sbrk abort atof getcwd getwd \
 577         strsignal putc_unlocked fputs_unlocked strstr environ \
 578         malloc realloc calloc free basename getopt, , ,[
 579 #include "gansidecl.h"
 580 #include "system.h"])
 581
 582 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 583 #include "gansidecl.h"
 584 #include "system.h"
 585 #ifdef HAVE_SYS_RESOURCE_H
 586 #include <sys/resource.h>
 587 #endif
 588 ])
 589
 590 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 591 CFLAGS="$saved_CFLAGS"
 592
 593 # mkdir takes a single argument on some systems.
 594 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 595
 596 # File extensions
 597 manext='.1'
 598 objext='.o'
 599 AC_SUBST(manext)
 600 AC_SUBST(objext)
 601
 602 build_xm_file=
 603 build_xm_defines=
 604 build_install_headers_dir=install-headers-tar
 605 build_exeext=
 606 host_xm_file=
 607 host_xm_defines=
 608 host_xmake_file=
 609 host_truncate_target=
 610 host_exeext=
 611
 612 # Decode the host machine, then the target machine.
 613 # For the host machine, we save the xm_file variable as host_xm_file;
 614 # then we decode the target machine and forget everything else
 615 # that came from the host machine.
 616 for machine in $build $host $target; do
 617         . ${srcdir}/config.gcc
 618 done
 619
 620 extra_objs="${host_extra_objs} ${extra_objs}"
 621
 622 # Default the target-machine variables that were not explicitly set.
 623 if test x"$tm_file" = x
 624 then tm_file=$cpu_type/$cpu_type.h; fi
 625
 626 if test x"$extra_headers" = x
 627 then extra_headers=; fi
 628
 629 if test x"$xm_file" = x
 630 then xm_file=$cpu_type/xm-$cpu_type.h; fi
 631
 632 if test x$md_file = x
 633 then md_file=$cpu_type/$cpu_type.md; fi
 634
 635 if test x$out_file = x
 636 then out_file=$cpu_type/$cpu_type.c; fi
 637
 638 if test x"$tmake_file" = x
 639 then tmake_file=$cpu_type/t-$cpu_type
 640 fi
 641
 642 if test x"$dwarf2" = xyes
 643 then tm_file="$tm_file tm-dwarf2.h"
 644 fi
 645
 646 if test x$float_format = x
 647 then float_format=i64
 648 fi
 649
 650 if test $float_format = none
 651 then float_h_file=Makefile.in
 652 else float_h_file=float-$float_format.h
 653 fi
 654
 655 # Handle cpp installation.
 656 if test x$enable_cpp != xno
 657 then
 658   tmake_file="$tmake_file t-install-cpp"
 659 fi
 660
 661 # Say what files are being used for the output code and MD file.
 662 echo "Using \`$srcdir/config/$out_file' to output insns."
 663 echo "Using \`$srcdir/config/$md_file' as machine description file."
 664
 665 count=a
 666 for f in $tm_file; do
 667         count=${count}x
 668 done
 669 if test $count = ax; then
 670         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
 671 else
 672         echo "Using the following target machine macro files:"
 673         for f in $tm_file; do
 674                 echo "  $srcdir/config/$f"
 675         done
 676 fi
 677
 678 count=a
 679 for f in $host_xm_file; do
 680         count=${count}x
 681 done
 682 if test $count = ax; then
 683         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
 684 else
 685         echo "Using the following host machine macro files:"
 686         for f in $host_xm_file; do
 687                 echo "  $srcdir/config/$f"
 688         done
 689 fi
 690
 691 if test "$host_xm_file" != "$build_xm_file"; then
 692         count=a
 693         for f in $build_xm_file; do
 694                 count=${count}x
 695         done
 696         if test $count = ax; then
 697                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
 698         else
 699                 echo "Using the following build machine macro files:"
 700                 for f in $build_xm_file; do
 701                         echo "  $srcdir/config/$f"
 702                 done
 703         fi
 704 fi
 705
 706 if test x$thread_file = x; then
 707         if test x$target_thread_file != x; then
 708                 thread_file=$target_thread_file
 709         else
 710                 thread_file='single'
 711         fi
 712 fi
 713
 714 # Set up the header files.
 715 # $links is the list of header files to create.
 716 # $vars is the list of shell variables with file names to include.
 717 # auto-host.h is the file containing items generated by autoconf and is
 718 # the first file included by config.h.
 719 null_defines=
 720 host_xm_file="auto-host.h gansidecl.h ${host_xm_file} defaults.h hwint.h"
 721
 722 # If host=build, it is correct to have hconfig include auto-host.h
 723 # as well.  If host!=build, we are in error and need to do more
 724 # work to find out the build config parameters.
 725 if test x$host = x$build
 726 then
 727         build_xm_file="auto-host.h gansidecl.h ${build_xm_file} defaults.h hwint.h"
 728 else
 729         # We create a subdir, then run autoconf in the subdir.
 730         # To prevent recursion we set host and build for the new
 731         # invocation of configure to the build for this invocation
 732         # of configure.
 733         tempdir=build.$$
 734         rm -rf $tempdir
 735         mkdir $tempdir
 736         cd $tempdir
 737         case ${srcdir} in
 738         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
 739         *) realsrcdir=../${srcdir};;
 740         esac
 741         CC=${CC_FOR_BUILD} ${realsrcdir}/configure \
 742                 --target=$target --host=$build --build=$build
 743
 744         # We just finished tests for the build machine, so rename
 745         # the file auto-build.h in the gcc directory.
 746         mv auto-host.h ../auto-build.h
 747         cd ..
 748         rm -rf $tempdir
 749         build_xm_file="auto-build.h gansidecl.h ${build_xm_file} defaults.h hwint.h"
 750 fi
 751
 752 xm_file="gansidecl.h ${xm_file} defaults.h"
 753 tm_file="gansidecl.h ${tm_file} defaults.h"
 754
 755 vars="host_xm_file tm_file tm_p_file xm_file build_xm_file"
 756 links="config.h tm.h tm_p.h tconfig.h hconfig.h"
 757 defines="host_xm_defines null_defines null_defines xm_defines build_xm_defines"
 758
 759 rm -f config.bak
 760 if test -f config.status; then mv -f config.status config.bak; fi
 761
 762 # Make the links.
 763 while test -n "$vars"
 764 do
 765         set $vars; var=$1; shift; vars=$*
 766         set $links; link=$1; shift; links=$*
 767         set $defines; define=$1; shift; defines=$*
 768
 769         rm -f $link
 770         # Make sure the file is created, even if it is empty.
 771         echo >$link
 772
 773         # Define TARGET_CPU_DEFAULT if the system wants one.
 774         # This substitutes for lots of *.h files.
 775         if test "$target_cpu_default" != "" -a $link = tm.h
 776         then
 777                 echo "#define TARGET_CPU_DEFAULT ($target_cpu_default)" >>$link
 778         fi
 779
 780         for file in `eval echo '$'$var`; do
 781                 case $file in
 782                 auto-host.h | auto-build.h )
 783                         ;;
 784                 *)
 785                         echo '#ifdef IN_GCC' >>$link
 786                         ;;
 787                 esac
 788                 echo "#include \"$file\"" >>$link
 789                 case $file in
 790                 auto-host.h | auto-build.h )
 791                         ;;
 792                 *)
 793                         echo '#endif' >>$link
 794                         ;;
 795                 esac
 796         done
 797
 798         for def in `eval echo '$'$define`; do
 799                 echo "#ifndef $def" >>$link
 800                 echo "#define $def" >>$link
 801                 echo "#endif" >>$link
 802         done
 803
 804         if test $link = tm.h
 805         then
 806                 # Include insn-codes.h last, because it includes machmode.h,
 807                 # and we want EXTRA_CC_MODES to be taken into account.
 808                 echo "#ifndef GENERATOR_FILE" >>$link
 809                 echo "#include \"insn-codes.h\"" >>$link
 810                 echo "#endif" >>$link
 811         fi
 812 done
 813
 814 # Truncate the target if necessary
 815 if test x$host_truncate_target != x; then
 816         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
 817 fi
 818
 819 # Get the version trigger filename from the toplevel
 820 if test "${with_gcc_version_trigger+set}" = set; then
 821         gcc_version_trigger=$with_gcc_version_trigger
 822 else
 823         gcc_version_trigger=${srcdir}/version.c
 824 fi
 825 changequote(,)dnl
 826 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
 827 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 828
 829 # Compile in configure arguments.
 830 if test -f configargs.h ; then
 831         # Being re-configured.
 832         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
 833         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
 834 else
 835         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
 836 fi
 837 cat > configargs.h <<EOF
 838 /* Generated automatically. */
 839 static const char configuration_arguments[] = "$gcc_config_arguments";
 840 EOF
 841 changequote([,])dnl
 842
 843 # Internationalization
 844 PACKAGE=gcc
 845 VERSION="$gcc_version"
 846 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",
 847         [Define to the name of the distribution.])
 848 AC_DEFINE_UNQUOTED(VERSION, "$VERSION",
 849         [Define to the version of the distribution.])
 850 AC_SUBST(PACKAGE)
 851 AC_SUBST(VERSION)
 852
 853 ALL_LINGUAS="sv"
 854
 855 # Enable NLS support by default
 856 AC_ARG_ENABLE(nls,
 857   [  --enable-nls            use Native Language Support (default)],
 858   , enable_nls=yes)
 859
 860 # if cross compiling, disable NLS support.
 861 # It's not worth the trouble, at least for now.
 862
 863 if test "${build}" != "${host}" && test "x$enable_nls" = "xyes"; then
 864   AC_MSG_WARN(Disabling NLS support for canadian cross compiler.)
 865   enable_nls=no
 866 fi
 867
 868 # if NLS is enabled, also enable check in po subdir
 869 if test $enable_nls = yes; then
 870   CHECK_PO=check-po
 871 else
 872   CHECK_PO=""
 873 fi
 874
 875 AC_SUBST(CHECK_PO)
 876
 877 AM_GNU_GETTEXT
 878 XGETTEXT="AWK='$AWK' \$(SHELL) \$(top_srcdir)/exgettext $XGETTEXT"
 879
 880 # Windows32 Registry support for specifying GCC installation paths.
 881 AC_ARG_ENABLE(win32-registry,
 882 [  --disable-win32-registry
 883                           Disable lookup of installation paths in the
 884                          Registry on Windows hosts.
 885   --enable-win32-registry Enable registry lookup (default).
 886   --enable-win32-registry=KEY
 887                           Use KEY instead of GCC version as the last portion
 888                          of the registry key.],,)
 889
 890 AC_MSG_CHECKING(whether windows registry support is requested)
 891 if test x$enable_win32_registry != xno; then
 892   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
 893 [Define to 1 if installation paths should be looked up in Windows32
 894    Registry. Ignored on non windows32 hosts.])
 895   AC_MSG_RESULT(yes)
 896 else
 897   AC_MSG_RESULT(no)
 898 fi
 899
 900 # Check if user specified a different registry key.
 901 case x${enable_win32_registry} in
 902 x | xyes)
 903   # default.
 904   gcc_cv_win32_registry_key="$VERSION"
 905   ;;
 906 xno)
 907   # no registry lookup.
 908   gcc_cv_win32_registry_key=''
 909   ;;
 910 *)
 911   # user-specified key.
 912   gcc_cv_win32_registry_key="$enable_win32_registry"
 913   ;;
 914 esac
 915
 916 if test x$enable_win32_registry != xno; then
 917   AC_MSG_CHECKING(registry key on windows hosts)
 918   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
 919         [Define to be the last portion of registry key on windows hosts.])
 920   AC_MSG_RESULT($gcc_cv_win32_registry_key)
 921 fi
 922
 923 # Get an absolute path to the GCC top-level source directory
 924 holddir=`pwd`
 925 cd $srcdir
 926 topdir=`pwd`
 927 cd $holddir
 928
 929 # Conditionalize the makefile for this host machine.
 930 # Make-host contains the concatenation of all host makefile fragments
 931 # [there can be more than one].  This file is built by configure.frag.
 932 host_overrides=Make-host
 933 dep_host_xmake_file=
 934 for f in .. ${host_xmake_file}
 935 do
 936         if test -f ${srcdir}/config/$f
 937         then
 938                 dep_host_xmake_file="${dep_host_xmake_file} ${srcdir}/config/$f"
 939         fi
 940 done
 941
 942 # Conditionalize the makefile for this target machine.
 943 # Make-target contains the concatenation of all host makefile fragments
 944 # [there can be more than one].  This file is built by configure.frag.
 945 target_overrides=Make-target
 946 dep_tmake_file=
 947 for f in .. ${tmake_file}
 948 do
 949         if test -f ${srcdir}/config/$f
 950         then
 951                 dep_tmake_file="${dep_tmake_file} ${srcdir}/config/$f"
 952         fi
 953 done
 954
 955 # If the host doesn't support symlinks, modify CC in
 956 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
 957 # Otherwise, we can use "CC=$(CC)".
 958 rm -f symtest.tem
 959 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
 960 then
 961         cc_set_by_configure="\$(CC)"
 962         quoted_cc_set_by_configure="\$(CC)"
 963         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
 964 else
 965         rm -f symtest.tem
 966         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
 967         then
 968                 symbolic_link="cp -p"
 969         else
 970                 symbolic_link="cp"
 971         fi
 972         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
 973         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
 974         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
 975 fi
 976 rm -f symtest.tem
 977
 978 out_object_file=`basename $out_file .c`.o
 979
 980 tm_file_list=
 981 for f in $tm_file; do
 982   case $f in
 983     gansidecl.h | defaults.h )
 984        tm_file_list="${tm_file_list} $f" ;;
 985     *) tm_file_list="${tm_file_list} \$(srcdir)/config/$f" ;;
 986   esac
 987 done
 988
 989 host_xm_file_list=
 990 for f in $host_xm_file; do
 991   case $f in
 992     auto-host.h | gansidecl.h | defaults.h | hwint.h )
 993        host_xm_file_list="${host_xm_file_list} $f" ;;
 994     *) host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f" ;;
 995   esac
 996 done
 997
 998 build_xm_file_list=
 999 for f in $build_xm_file; do
1000   case $f in
1001     auto-build.h | auto-host.h | gansidecl.h | defaults.h | hwint.h )
1002        build_xm_file_list="${build_xm_file_list} $f" ;;
1003     *) build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f" ;;
1004   esac
1005 done
1006
1007 # Define macro CROSS_COMPILE in compilation
1008 # if this is a cross-compiler.
1009 # Also use all.cross instead of all.internal
1010 # and add cross-make to Makefile.
1011 cross_overrides="/dev/null"
1012 if test x$host != x$target
1013 then
1014         cross_defines="CROSS=-DCROSS_COMPILE"
1015         cross_overrides="${topdir}/cross-make"
1016 fi
1017
1018 # If this is a cross-compiler that does not
1019 # have its own set of headers then define
1020 # inhibit_libc
1021
1022 # If this is using newlib, then define inhibit_libc in
1023 # LIBGCC2_CFLAGS.  This will cause __eprintf to be left out of
1024 # libgcc.a, but that's OK because newlib should have its own version of
1025 # assert.h.
1026 inhibit_libc=
1027 if [test x$host != x$target] && [test x$with_headers = x]; then
1028        inhibit_libc=-Dinhibit_libc
1029 else
1030        if [test x$with_newlib = xyes]; then
1031                inhibit_libc=-Dinhibit_libc
1032        fi
1033 fi
1034 AC_SUBST(inhibit_libc)
1035
1036 # When building gcc with a cross-compiler, we need to fix a few things.
1037 # This must come after cross-make as we want all.build to override
1038 # all.cross.
1039 build_overrides="/dev/null"
1040 if test x$build != x$host
1041 then
1042         build_overrides="${topdir}/build-make"
1043 fi
1044
1045 # Expand extra_headers to include complete path.
1046 # This substitutes for lots of t-* files.
1047 extra_headers_list=
1048 if test "x$extra_headers" = x
1049 then true
1050 else
1051         # Prepend ${srcdir}/ginclude/ to every entry in extra_headers.
1052         for file in $extra_headers;
1053         do
1054                 extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/${file}"
1055         done
1056 fi
1057
1058 if test x$use_collect2 = xno; then
1059         use_collect2=
1060 fi
1061
1062 # Add a definition of USE_COLLECT2 if system wants one.
1063 # Also tell toplev.c what to do.
1064 # This substitutes for lots of t-* files.
1065 if test x$use_collect2 = x
1066 then
1067         will_use_collect2=
1068         maybe_use_collect2=
1069 else
1070         will_use_collect2="collect2"
1071         maybe_use_collect2="-DUSE_COLLECT2"
1072 fi
1073
1074 # If we have gas in the build tree, make a link to it.
1075 if test -f ../gas/Makefile; then
1076         rm -f as; $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1077 fi
1078
1079 # If we have nm in the build tree, make a link to it.
1080 if test -f ../binutils/Makefile; then
1081         rm -f nm; $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1082 fi
1083
1084 # If we have ld in the build tree, make a link to it.
1085 if test -f ../ld/Makefile; then
1086 #       if test x$use_collect2 = x; then
1087 #               rm -f ld; $symbolic_link ../ld/ld-new$host_exeext ld$host_exeext 2>/dev/null
1088 #       else
1089                 rm -f collect-ld; $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext 2>/dev/null
1090 #       fi
1091 fi
1092
1093 # Figure out what assembler we will be using.
1094 AC_MSG_CHECKING(what assembler to use)
1095 gcc_cv_as=
1096 gcc_cv_gas_major_version=
1097 gcc_cv_gas_minor_version=
1098 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1099 if test -x "$DEFAULT_ASSEMBLER"; then
1100         gcc_cv_as="$DEFAULT_ASSEMBLER"
1101 elif test -x "$AS"; then
1102         gcc_cv_as="$AS"
1103 elif test -x as$host_exeext; then
1104         # Build using assembler in the current directory.
1105         gcc_cv_as=./as$host_exeext
1106 elif test -f $gcc_cv_as_gas_srcdir/configure.in -a -f ../gas/Makefile; then
1107         # Single tree build which includes gas.
1108         for f in $gcc_cv_as_gas_srcdir/configure $gcc_cv_as_gas_srcdir/configure.in $gcc_cv_as_gas_srcdir/Makefile.in
1109         do
1110 changequote(,)dnl
1111                 gcc_cv_gas_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1112 changequote([,])dnl
1113                 if test x$gcc_cv_gas_version != x; then
1114                         break
1115                 fi
1116         done
1117 changequote(,)dnl
1118         gcc_cv_gas_major_version=`expr "$gcc_cv_gas_version" : "VERSION=\([0-9]*\)"`
1119         gcc_cv_gas_minor_version=`expr "$gcc_cv_gas_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1120 changequote([,])dnl
1121 fi
1122
1123 if test "x$gcc_cv_as" = x -a x$host = x$target; then
1124         # Native build.
1125         # Search the same directories that the installed compiler will
1126         # search.  Else we may find the wrong assembler and lose.  If we
1127         # do not find a suitable assembler binary, then try the user's
1128         # path.
1129         #
1130         # Also note we have to check MD_EXEC_PREFIX before checking the
1131         # user's path.  Unfortunately, there is no good way to get at the
1132         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1133         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1134         # to be fixed as part of the make/configure rewrite too.
1135
1136         if test "x$exec_prefix" = xNONE; then
1137                 if test "x$prefix" = xNONE; then
1138                         test_prefix=/usr/local
1139                 else
1140                         test_prefix=$prefix
1141                 fi
1142         else
1143                 test_prefix=$exec_prefix
1144         fi
1145
1146         # If the loop below does not find an assembler, then use whatever
1147         # one we can find in the users's path.
1148         # user's path.
1149         as=as$host_exeext
1150
1151         test_dirs="$test_prefix/lib/gcc-lib/$target/$gcc_version \
1152                    $test_prefix/lib/gcc-lib/$target \
1153                    /usr/lib/gcc/$target/$gcc_version \
1154                    /usr/lib/gcc/$target \
1155                    $test_prefix/$target/bin/$target/$gcc_version \
1156                    $test_prefix/$target/bin \
1157                    /usr/libexec \
1158                    /usr/ccs/gcc \
1159                    /usr/ccs/bin \
1160                    /udk/usr/ccs/bin \
1161                    /bsd43/usr/lib/cmplrs/cc \
1162                    /usr/cross64/usr/bin \
1163                    /usr/lib/cmplrs/cc \
1164                    /sysv/usr/lib/cmplrs/cc \
1165                    /svr4/usr/lib/cmplrs/cc \
1166                    /usr/bin"
1167
1168         for dir in $test_dirs; do
1169                 if test -f $dir/as$host_exeext; then
1170                         gcc_cv_as=$dir/as$host_exeext
1171                         break;
1172                 fi
1173         done
1174 fi
1175 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1176   AC_MSG_RESULT("newly built gas")
1177 else
1178   AC_MSG_RESULT($gcc_cv_as)
1179 fi
1180
1181 # Figure out what nm we will be using.
1182 AC_MSG_CHECKING(what nm to use)
1183 if test -x nm$host_exeext; then
1184         gcc_cv_nm=./nm$host_exeext
1185 elif test x$host = x$target; then
1186         # Native build.
1187         gcc_cv_nm=nm$host_exeext
1188 fi
1189 AC_MSG_RESULT($gcc_cv_nm)
1190
1191 # Figure out what assembler alignment features are present.
1192 AC_MSG_CHECKING(assembler alignment features)
1193 gcc_cv_as_alignment_features=none
1194 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1195         # Gas version 2.6 and later support for .balign and .p2align.
1196         # bytes to skip when using .p2align.
1197         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 6 -o "$gcc_cv_gas_major_version" -gt 2; then
1198                 gcc_cv_as_alignment_features=".balign and .p2align"
1199                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1200         fi
1201         # Gas version 2.8 and later support specifying the maximum
1202         # bytes to skip when using .p2align.
1203         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 8 -o "$gcc_cv_gas_major_version" -gt 2; then
1204                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1205                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1206         fi
1207 elif test x$gcc_cv_as != x; then
1208         # Check if we have .balign and .p2align
1209         echo ".balign  4" > conftest.s
1210         echo ".p2align  2" >> conftest.s
1211         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1212                 gcc_cv_as_alignment_features=".balign and .p2align"
1213                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1214         fi
1215         rm -f conftest.s conftest.o
1216         # Check if specifying the maximum bytes to skip when
1217         # using .p2align is supported.
1218         echo ".p2align 4,,7" > conftest.s
1219         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1220                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1221                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1222         fi
1223         rm -f conftest.s conftest.o
1224 fi
1225 AC_MSG_RESULT($gcc_cv_as_alignment_features)
1226
1227 AC_MSG_CHECKING(assembler subsection support)
1228 gcc_cv_as_subsections=no
1229 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1230   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1231     gcc_cv_as_subsections="working .subsection -1"
1232   fi
1233 elif test x$gcc_cv_as != x; then
1234         # Check if we have .subsection
1235         echo ".subsection 1" > conftest.s
1236         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1237                 gcc_cv_as_subsections=".subsection"
1238                 if test x$gcc_cv_nm != x; then
1239                         cat > conftest.s <<EOF
1240 conftest_label1: .word 0
1241 .subsection -1
1242 conftest_label2: .word 0
1243 .previous
1244 EOF
1245                         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1246                                 $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1247                                 $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1248                                 if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1; then
1249                                         :
1250                                 else
1251                                         gcc_cv_as_subsections="working .subsection -1"
1252                                 fi
1253                         fi
1254                 fi
1255         fi
1256         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1257 fi
1258 if test x"$gcc_cv_as_subsections" = x"working .subsection -1"; then
1259         AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1260 [Define if your assembler supports .subsection and .subsection -1 starts
1261    emitting at the beginning of your section.])
1262 fi
1263 AC_MSG_RESULT($gcc_cv_as_subsections)
1264
1265 AC_MSG_CHECKING(assembler weak support)
1266 gcc_cv_as_weak=no
1267 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1268   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 2 -o "$gcc_cv_gas_major_version" -gt 2; then
1269     gcc_cv_as_weak="yes"
1270   fi
1271 elif test x$gcc_cv_as != x; then
1272         # Check if we have .weak
1273         echo "  .weak foobar" > conftest.s
1274         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1275                 gcc_cv_as_weak="yes"
1276         fi
1277         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1278 fi
1279 if test x"$gcc_cv_as_weak" = xyes; then
1280         AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])
1281 fi
1282 AC_MSG_RESULT($gcc_cv_as_weak)
1283
1284 AC_MSG_CHECKING(assembler hidden support)
1285 gcc_cv_as_hidden=no
1286 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1287   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 10 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1288     gcc_cv_as_hidden="yes"
1289   fi
1290 elif test x$gcc_cv_as != x; then
1291         # Check if we have .hidden
1292         echo "  .hidden foobar" > conftest.s
1293         echo "foobar:" >> conftest.s
1294         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1295                 gcc_cv_as_hidden="yes"
1296         fi
1297         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1298 fi
1299 if test x"$gcc_cv_as_hidden" = xyes; then
1300         AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1301                 [Define if your assembler supports .hidden.])
1302 fi
1303 AC_MSG_RESULT($gcc_cv_as_hidden)
1304
1305 case "$target" in
1306   sparc*-*-*)
1307     AC_CACHE_CHECK([assembler .register pseudo-op support],
1308         gcc_cv_as_register_pseudo_op, [
1309         gcc_cv_as_register_pseudo_op=unknown
1310         if test x$gcc_cv_as != x; then
1311             # Check if we have .register
1312             echo ".register %g2, #scratch" > conftest.s
1313             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1314                 gcc_cv_as_register_pseudo_op=yes
1315             else
1316                 gcc_cv_as_register_pseudo_op=no
1317             fi
1318             rm -f conftest.s conftest.o
1319         fi
1320     ])
1321     if test "x$gcc_cv_as_register_pseudo_op" = xyes; then
1322         AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
1323                 [Define if your assembler supports .register.])
1324     fi
1325
1326     AC_CACHE_CHECK([assembler supports -relax],
1327         gcc_cv_as_relax_opt, [
1328         gcc_cv_as_relax_opt=unknown
1329         if test x$gcc_cv_as != x; then
1330             # Check if gas supports -relax
1331             echo ".text" > conftest.s
1332             if $gcc_cv_as -relax -o conftest.o conftest.s > /dev/null 2>&1; then
1333                 gcc_cv_as_relax_opt=yes
1334             else
1335                 gcc_cv_as_relax_opt=no
1336             fi
1337             rm -f conftest.s conftest.o
1338         fi
1339     ])
1340     if test "x$gcc_cv_as_relax_opt" = xyes; then
1341         AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
1342                 [Define if your assembler supports -relax option.])
1343     fi
1344
1345     case "$tm_file" in
1346     *64*)
1347         AC_CACHE_CHECK([for 64 bit support in assembler ($gcc_cv_as)],
1348             gcc_cv_as_flags64, [
1349                 if test -n "$gcc_cv_as"; then
1350                     echo ".xword foo" > conftest.s
1351                     gcc_cv_as_flags64=no
1352                     for flag in "-xarch=v9" "-64 -Av9"; do
1353                         if $gcc_cv_as $flag -o conftest.o conftest.s \
1354                             > /dev/null 2>&1; then
1355                             gcc_cv_as_flags64=$flag
1356                             break
1357                         fi
1358                     done
1359                     rm -f conftest.s conftest.o
1360                 else
1361                     if test "$gas" = yes; then
1362                         gcc_cv_as_flags64="-64 -Av9"
1363                     else
1364                         gcc_cv_as_flags64="-xarch=v9"
1365                     fi
1366                 fi
1367         ])
1368         if test "x$gcc_cv_as_flags64" = xno; then
1369 changequote(, )
1370             tmake_file=`echo " $tmake_file " | sed -e 's, sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1371             dep_tmake_file=`echo " $dep_tmake_file " | sed -e 's, [^ ]*/config/sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1372 changequote([, ])
1373         else
1374             AC_DEFINE_UNQUOTED(AS_SPARC64_FLAG, "$gcc_cv_as_flags64",
1375                         [Define if the assembler supports 64bit sparc.])
1376         fi
1377         ;;
1378     *) gcc_cv_as_flags64=${gcc_cv_as_flags64-no}
1379         ;;
1380     esac
1381
1382     if test "x$gcc_cv_as_flags64" != xno; then
1383         AC_CACHE_CHECK([for assembler offsetable %lo() support],
1384             gcc_cv_as_offsetable_lo10, [
1385             gcc_cv_as_offsetable_lo10=unknown
1386             if test "x$gcc_cv_as" != x; then
1387                 # Check if assembler has offsetable %lo()
1388                 echo "or %g1, %lo(ab) + 12, %g1" > conftest.s
1389                 echo "or %g1, %lo(ab + 12), %g1" > conftest1.s
1390                 if $gcc_cv_as $gcc_cv_as_flags64 -o conftest.o conftest.s \
1391                         > /dev/null 2>&1 &&
1392                    $gcc_cv_as $gcc_cv_as_flags64 -o conftest1.o conftest1.s \
1393                         > /dev/null 2>&1; then
1394                     if cmp conftest.o conftest1.o > /dev/null 2>&1; then
1395                         gcc_cv_as_offsetable_lo10=no
1396                     else
1397                         gcc_cv_as_offsetable_lo10=yes
1398                     fi
1399                 else
1400                     gcc_cv_as_offsetable_lo10=no
1401                 fi
1402                 rm -f conftest.s conftest.o conftest1.s conftest1.o
1403             fi
1404         ])
1405         if test "x$gcc_cv_as_offsetable_lo10" = xyes; then
1406             AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
1407                 [Define if your assembler supports offsetable %lo().])
1408         fi
1409     fi
1410     ;;
1411
1412 changequote(,)dnl
1413   i[34567]86-*-*)
1414 changequote([,])dnl
1415     AC_MSG_CHECKING(assembler instructions)
1416     gcc_cv_as_instructions=
1417     if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1418       if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2; then
1419         gcc_cv_as_instructions="filds fists"
1420       fi
1421     elif test x$gcc_cv_as != x; then
1422         set "filds fists" "filds mem; fists mem"
1423         while test $# -gt 0
1424         do
1425                 echo "$2" > conftest.s
1426                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1427                         gcc_cv_as_instructions=${gcc_cv_as_instructions}$1" "
1428                 fi
1429                 shift 2
1430         done
1431         rm -f conftest.s conftest.o
1432     fi
1433     if test x"$gcc_cv_as_instructions" != x; then
1434         AC_DEFINE_UNQUOTED(HAVE_GAS_`echo "$gcc_cv_as_instructions" | sed -e 's/ $//' | tr '[a-z ]' '[A-Z_]'`)
1435     fi
1436     AC_MSG_RESULT($gcc_cv_as_instructions)
1437     ;;
1438 esac
1439
1440 AC_MSG_CHECKING(assembler dwarf2 debug_line support)
1441 gcc_cv_as_dwarf2_debug_line=no
1442 # ??? Not all targets support dwarf2 debug_line, even within a version
1443 # of gas.  Moreover, we need to emit a valid instruction to trigger any
1444 # info to the output file.  So, as supported targets are added to gas 2.11,
1445 # add some instruction here to (also) show we expect this might work.
1446 # ??? Once 2.11 is released, probably need to add first known working
1447 # version to the per-target configury.
1448 case "$target" in
1449   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-*)
1450     insn="nop"
1451     ;;
1452   ia64*-*-*)
1453     insn="nop 0"
1454     ;;
1455   esac
1456 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x;
1457 then
1458   if test "$gcc_cv_gas_major_version" -eq 2 \
1459         -a "$gcc_cv_gas_minor_version" -ge 11 \
1460         -o "$gcc_cv_gas_major_version" -gt 2 \
1461      && grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1462      && test x"$insn" != x ; then
1463     gcc_cv_as_dwarf2_debug_line="yes"
1464   fi
1465 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
1466         echo '  .file 0 "conftest.s"' > conftest.s
1467         echo '  .loc 0 3 0' >> conftest.s
1468         echo "  $insn" >> conftest.s
1469         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1470            && grep debug_line conftest.o > /dev/null 2>&1 ; then
1471                 gcc_cv_as_dwarf2_debug_line="yes"
1472         fi
1473         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1474 fi
1475 if test x"$gcc_cv_as_dwarf2_debug_line" = xyes; then
1476         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
1477           [Define if your assembler supports dwarf2 .file/.loc directives.])
1478 fi
1479 AC_MSG_RESULT($gcc_cv_as_dwarf2_debug_line)
1480
1481 # Figure out what language subdirectories are present.
1482 # Look if the user specified --enable-languages="..."; if not, use
1483 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1484 # go away some day.
1485 if test x"${enable_languages+set}" != xset; then
1486         if test x"${LANGUAGES+set}" = xset; then
1487                 enable_languages="`echo ${LANGUAGES} | tr ' ' ','`"
1488         else
1489                 enable_languages=all
1490         fi
1491 else
1492         if test x"${enable_languages}" = x; then
1493                 AC_MSG_ERROR([--enable-languages needs at least one argument])
1494         fi
1495 fi
1496 subdirs=
1497 for lang in ${srcdir}/*/config-lang.in ..
1498 do
1499         case $lang in
1500         ..) ;;
1501         # The odd quoting in the next line works around
1502         # an apparent bug in bash 1.12 on linux.
1503 changequote(,)dnl
1504         ${srcdir}/[*]/config-lang.in) ;;
1505         *)
1506           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
1507           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
1508           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
1509           if test "x$lang_alias" = x
1510           then
1511                 echo "$lang doesn't set \$language." 1>&2
1512                 exit 1
1513           fi
1514           case ${build_by_default},${enable_languages}, in
1515           *,$lang_alias,*) add_this_lang=yes ;;
1516           no,*) add_this_lang=no ;;
1517           *,all,*) add_this_lang=yes ;;
1518           *) add_this_lang=no ;;
1519           esac
1520           if test x"${add_this_lang}" = xyes; then
1521                 case $lang in
1522                     ${srcdir}/ada/config-lang.in)
1523                         if test x$have_gnat = xyes ; then
1524                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
1525                         fi
1526                         ;;
1527                     *)
1528                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
1529                         ;;
1530                 esac
1531           fi
1532           ;;
1533 changequote([,])dnl
1534         esac
1535 done
1536
1537 # Make gthr-default.h if we have a thread file.
1538 gthread_flags=
1539 if test $thread_file != single; then
1540     rm -f gthr-default.h
1541     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1542     gthread_flags=-DHAVE_GTHR_DEFAULT
1543 fi
1544 AC_SUBST(gthread_flags)
1545
1546 # Find out what GC implementation we want, or may, use.
1547 AC_ARG_WITH(gc,
1548 [  --with-gc={simple,page} Choose the garbage collection mechanism to use
1549                            with the compiler.],
1550 [case "$withval" in
1551   simple | page)
1552     GGC=ggc-$withval
1553     ;;
1554   *)
1555     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
1556     ;;
1557 esac],
1558 [GGC=ggc-page])
1559 AC_SUBST(GGC)
1560 echo "Using $GGC for garbage collection."
1561
1562 # Use the system's zlib library.
1563 zlibdir=-L../zlib
1564 zlibinc="-I\$(srcdir)/../zlib"
1565 AC_ARG_WITH(system-zlib,
1566 [  --with-system-zlib      use installed libz],
1567 zlibdir=
1568 zlibinc=
1569 )
1570 AC_SUBST(zlibdir)
1571 AC_SUBST(zlibinc)
1572
1573 AC_DEFINE_UNQUOTED(ENABLE_STD_NAMESPACE, 1,
1574   [Define to 1 if you want to enable namespaces (-fhonor-std) by default.])
1575
1576 dnl Very limited version of automake's enable-maintainer-mode
1577
1578 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
1579   dnl maintainer-mode is disabled by default
1580   AC_ARG_ENABLE(maintainer-mode,
1581 [  --enable-maintainer-mode enable make rules and dependencies not useful
1582                           (and sometimes confusing) to the casual installer],
1583       maintainer_mode=$enableval,
1584       maintainer_mode=no)
1585
1586 AC_MSG_RESULT($maintainer_mode)
1587
1588 if test "$maintainer_mode" = "yes"; then
1589   MAINT=''
1590 else
1591   MAINT='#'
1592 fi
1593 AC_SUBST(MAINT)dnl
1594
1595 # Make empty files to contain the specs and options for each language.
1596 # Then add #include lines to for a compiler that has specs and/or options.
1597
1598 lang_specs_files=
1599 lang_options_files=
1600 lang_tree_files=
1601 rm -f specs.h options.h gencheck.h
1602 touch specs.h options.h gencheck.h
1603 for subdir in . $subdirs
1604 do
1605         if test -f $srcdir/$subdir/lang-specs.h; then
1606                 echo "#include \"$subdir/lang-specs.h\"" >>specs.h
1607                 lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
1608         fi
1609         if test -f $srcdir/$subdir/lang-options.h; then
1610                 echo "#include \"$subdir/lang-options.h\"" >>options.h
1611                 lang_options_files="$lang_options_files $srcdir/$subdir/lang-options.h"
1612         fi
1613         if test -f $srcdir/$subdir/$subdir-tree.def; then
1614                 echo "#include \"$subdir/$subdir-tree.def\"" >>gencheck.h
1615                 lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
1616         fi
1617 done
1618
1619 # These (without "all_") are set in each config-lang.in.
1620 # `language' must be a single word so is spelled singularly.
1621 all_languages=
1622 all_boot_languages=
1623 all_compilers=
1624 all_stagestuff=
1625 all_diff_excludes=
1626 all_outputs='Makefile intl/Makefile po/Makefile.in fixinc/Makefile gccbug mklibgcc'
1627 # List of language makefile fragments.
1628 all_lang_makefiles=
1629 all_headers=
1630 all_lib2funcs=
1631
1632 # Add the language fragments.
1633 # Languages are added via two mechanisms.  Some information must be
1634 # recorded in makefile variables, these are defined in config-lang.in.
1635 # We accumulate them and plug them into the main Makefile.
1636 # The other mechanism is a set of hooks for each of the main targets
1637 # like `clean', `install', etc.
1638
1639 language_fragments="Make-lang"
1640 language_hooks="Make-hooks"
1641
1642 for s in .. $subdirs
1643 do
1644         if test $s != ".."
1645         then
1646                 language=
1647                 boot_language=
1648                 compilers=
1649                 stagestuff=
1650                 diff_excludes=
1651                 headers=
1652                 outputs=
1653                 lib2funcs=
1654                 . ${srcdir}/$s/config-lang.in
1655                 if test "x$language" = x
1656                 then
1657                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
1658                         exit 1
1659                 fi
1660                 all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Make-lang.in"
1661                 if test -f ${srcdir}/$s/Makefile.in
1662                 then all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Makefile.in"
1663                 fi
1664                 all_languages="$all_languages $language"
1665                 if test "x$boot_language" = xyes
1666                 then
1667                         all_boot_languages="$all_boot_languages $language"
1668                 fi
1669                 all_compilers="$all_compilers $compilers"
1670                 all_stagestuff="$all_stagestuff $stagestuff"
1671                 all_diff_excludes="$all_diff_excludes $diff_excludes"
1672                 all_headers="$all_headers $headers"
1673                 all_outputs="$all_outputs $outputs"
1674                 all_lib2funcs="$all_lib2funcs $lib2funcs"
1675         fi
1676 done
1677
1678 check_languages=
1679 for language in .. $all_languages
1680 do
1681         if test $language != ".."
1682         then
1683                 check_languages="$check_languages check-$language"
1684         fi
1685 done
1686
1687 # Since we can't use `::' targets, we link each language in
1688 # with a set of hooks, reached indirectly via lang.${target}.
1689
1690 rm -f Make-hooks
1691 touch Make-hooks
1692 target_list="all.build all.cross start.encap rest.encap \
1693         info dvi \
1694         install-normal install-common install-info install-man \
1695         uninstall \
1696         mostlyclean clean distclean extraclean maintainer-clean \
1697         stage1 stage2 stage3 stage4"
1698 for t in $target_list
1699 do
1700         x=
1701         for lang in .. $all_languages
1702         do
1703                 if test $lang != ".."; then
1704                         x="$x $lang.$t"
1705                 fi
1706         done
1707         echo "lang.$t: $x" >> Make-hooks
1708 done
1709
1710 # Create .gdbinit.
1711
1712 echo "dir ." > .gdbinit
1713 echo "dir ${srcdir}" >> .gdbinit
1714 if test x$gdb_needs_out_file_path = xyes
1715 then
1716         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
1717 fi
1718 if test "x$subdirs" != x; then
1719         for s in $subdirs
1720         do
1721                 echo "dir ${srcdir}/$s" >> .gdbinit
1722         done
1723 fi
1724 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
1725
1726 # Define variables host_canonical and build_canonical
1727 # because some Cygnus local changes in the Makefile depend on them.
1728 build_canonical=${build}
1729 host_canonical=${host}
1730 target_subdir=
1731 if test "${host}" != "${target}" ; then
1732     target_subdir=${target}/
1733 fi
1734 AC_SUBST(build_canonical)
1735 AC_SUBST(host_canonical)
1736 AC_SUBST(target_subdir)
1737
1738 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
1739 # absolute path for gcc_tooldir based on inserting the number of up-directory
1740 # movements required to get from $(exec_prefix) to $(prefix) into the basic
1741 # $(libsubdir)/@(unlibsubdir) based path.
1742 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
1743 # make and thus we'd get different behavior depending on where we built the
1744 # sources.
1745 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
1746     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_alias)'
1747 else
1748 changequote(<<, >>)dnl
1749 # An explanation of the sed strings:
1750 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
1751 #  -e 's|/$||'            match a trailing forward slash and eliminates it
1752 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
1753 #  -e 's|/[^/]*|../|g'    replaces each occurance of /<directory> with ../
1754 #
1755 # (*) Note this pattern overwrites the first character of the string
1756 # with a forward slash if one is not already present.  This is not a
1757 # problem because the exact names of the sub-directories concerned is
1758 # unimportant, just the number of them matters.
1759 #
1760 # The practical upshot of these patterns is like this:
1761 #
1762 #  prefix     exec_prefix        result
1763 #  ------     -----------        ------
1764 #   /foo        /foo/bar          ../
1765 #   /foo/       /foo/bar          ../
1766 #   /foo        /foo/bar/         ../
1767 #   /foo/       /foo/bar/         ../
1768 #   /foo        /foo/bar/ugg      ../../
1769 #
1770     dollar='$$'
1771     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_alias)"
1772 changequote([, ])dnl
1773 fi
1774 AC_SUBST(gcc_tooldir)
1775 AC_SUBST(dollar)
1776
1777 # Find a directory in which to install a shared libgcc.
1778
1779 AC_ARG_ENABLE(version-specific-runtime-libs,
1780 [  --enable-version-specific-runtime-libs    Specify that runtime libraries shou
1781 ld be installed in a compiler-specific directory ])
1782
1783 AC_ARG_WITH(slibdir,
1784 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
1785 slibdir="$with_slibdir",
1786 if test "${enable_version_specific_runtime_libs+set}" = set; then
1787   slibdir='$(libsubdir)'
1788 elif test "$host" != "$target"; then
1789   slibdir='$(build_tooldir)/lib'
1790 else
1791   slibdir='$(libdir)'
1792 fi)
1793 AC_SUBST(slibdir)
1794
1795 # Nothing to do for FLOAT_H, float_format already handled.
1796 objdir=`pwd`
1797 AC_SUBST(objdir)
1798
1799 # Process the language and host/target makefile fragments.
1800 ${CONFIG_SHELL-/bin/sh} $srcdir/configure.frag $srcdir "$subdirs" "$dep_host_xmake_file" "$dep_tmake_file"
1801
1802 # Substitute configuration variables
1803 AC_SUBST(subdirs)
1804 AC_SUBST(all_boot_languages)
1805 AC_SUBST(all_compilers)
1806 AC_SUBST(all_diff_excludes)
1807 AC_SUBST(all_headers)
1808 AC_SUBST(all_lang_makefiles)
1809 AC_SUBST(all_languages)
1810 AC_SUBST(all_lib2funcs)
1811 AC_SUBST(all_stagestuff)
1812 AC_SUBST(build_exeext)
1813 AC_SUBST(build_install_headers_dir)
1814 AC_SUBST(build_xm_file_list)
1815 AC_SUBST(check_languages)
1816 AC_SUBST(cc_set_by_configure)
1817 AC_SUBST(quoted_cc_set_by_configure)
1818 AC_SUBST(cpp_install_dir)
1819 AC_SUBST(dep_host_xmake_file)
1820 AC_SUBST(dep_tmake_file)
1821 AC_SUBST(extra_c_flags)
1822 AC_SUBST(extra_headers_list)
1823 AC_SUBST(extra_objs)
1824 AC_SUBST(extra_parts)
1825 AC_SUBST(extra_passes)
1826 AC_SUBST(extra_programs)
1827 AC_SUBST(float_h_file)
1828 AC_SUBST(gcc_config_arguments)
1829 AC_SUBST(gcc_gxx_include_dir)
1830 AC_SUBST(libstdcxx_incdir)
1831 AC_SUBST(gcc_version)
1832 AC_SUBST(gcc_version_full)
1833 AC_SUBST(gcc_version_trigger)
1834 AC_SUBST(host_exeext)
1835 AC_SUBST(host_extra_gcc_objs)
1836 AC_SUBST(host_xm_file_list)
1837 AC_SUBST(install)
1838 AC_SUBST(lang_options_files)
1839 AC_SUBST(lang_specs_files)
1840 AC_SUBST(lang_tree_files)
1841 AC_SUBST(local_prefix)
1842 AC_SUBST(maybe_use_collect2)
1843 AC_SUBST(md_file)
1844 AC_SUBST(objc_boehm_gc)
1845 AC_SUBST(out_file)
1846 AC_SUBST(out_object_file)
1847 AC_SUBST(stage_prefix_set_by_configure)
1848 AC_SUBST(symbolic_link)
1849 AC_SUBST(thread_file)
1850 AC_SUBST(tm_file_list)
1851 AC_SUBST(will_use_collect2)
1852 AC_SUBST(c_target_objs)
1853 AC_SUBST(cxx_target_objs)
1854
1855
1856 AC_SUBST_FILE(target_overrides)
1857 AC_SUBST_FILE(host_overrides)
1858 AC_SUBST(cross_defines)
1859 AC_SUBST_FILE(cross_overrides)
1860 AC_SUBST_FILE(build_overrides)
1861 AC_SUBST_FILE(language_fragments)
1862 AC_SUBST_FILE(language_hooks)
1863
1864 # Echo that links are built
1865 if test x$host = x$target
1866 then
1867         str1="native "
1868 else
1869         str1="cross-"
1870         str2=" from $host"
1871 fi
1872
1873 if test x$host != x$build
1874 then
1875         str3=" on a $build system"
1876 fi
1877
1878 if test "x$str2" != x || test "x$str3" != x
1879 then
1880         str4=
1881 fi
1882
1883 echo "Links are now set up to build a ${str1}compiler for ${target}$str4" 1>&2
1884
1885 if test "x$str2" != x || test "x$str3" != x
1886 then
1887         echo " ${str2}${str3}." 1>&2
1888 fi
1889
1890 # Truncate the target if necessary
1891 if test x$host_truncate_target != x; then
1892         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
1893 fi
1894
1895 # Configure the subdirectories
1896 # AC_CONFIG_SUBDIRS($subdirs)
1897
1898 # Create the Makefile
1899 # and configure language subdirectories
1900 AC_OUTPUT($all_outputs,
1901 [
1902 case x$CONFIG_HEADERS in
1903 xauto-host.h:config.in)
1904 echo > cstamp-h ;;
1905 esac
1906 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
1907 # bootstrapping and the installation procedure can still use
1908 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
1909 # FLAGS_TO_PASS has been modified to solve the problem there.
1910 # This is virtually a duplicate of what happens in configure.lang; we do
1911 # an extra check to make sure this only happens if ln -s can be used.
1912 if test "$symbolic_link" = "ln -s"; then
1913  for d in .. ${subdirs} ; do
1914    if test $d != ..; then
1915         STARTDIR=`pwd`
1916         cd $d
1917         for t in stage1 stage2 stage3 stage4 include
1918         do
1919                 rm -f $t
1920                 $symbolic_link ../$t $t 2>/dev/null
1921         done
1922         cd $STARTDIR
1923    fi
1924  done
1925 else true ; fi
1926 # Avoid having to add intl to our include paths.
1927 if test -f intl/libintl.h; then
1928   echo creating libintl.h
1929   echo '#include "intl/libintl.h"' >libintl.h
1930 fi
1931 ],
1932 [
1933 host='${host}'
1934 build='${build}'
1935 target='${target}'
1936 target_alias='${target_alias}'
1937 srcdir='${srcdir}'
1938 subdirs='${subdirs}'
1939 symbolic_link='${symbolic_link}'
1940 program_transform_set='${program_transform_set}'
1941 program_transform_name='${program_transform_name}'
1942 dep_host_xmake_file='${dep_host_xmake_file}'
1943 host_xmake_file='${host_xmake_file}'
1944 dep_tmake_file='${dep_tmake_file}'
1945 tmake_file='${tmake_file}'
1946 thread_file='${thread_file}'
1947 gcc_config_arguments='${gcc_config_arguments}'
1948 gcc_version='${gcc_version}'
1949 gcc_version_full='${gcc_version_full}'
1950 gcc_version_trigger='${gcc_version_trigger}'
1951 local_prefix='${local_prefix}'
1952 build_install_headers_dir='${build_install_headers_dir}'
1953 build_exeext='${build_exeext}'
1954 host_exeext='${host_exeext}'
1955 out_file='${out_file}'
1956 gdb_needs_out_file_path='${gdb_needs_out_file_path}'
1957 SET_MAKE='${SET_MAKE}'
1958 target_list='${target_list}'
1959 target_overrides='${target_overrides}'
1960 host_overrides='${host_overrides}'
1961 cross_defines='${cross_defines}'
1962 cross_overrides='${cross_overrides}'
1963 build_overrides='${build_overrides}'
1964 cpp_install_dir='${cpp_install_dir}'
1965 ])