gcc/testsuite/gcc.target/mips/mips.exp

   1 # Copyright (C) 1997-2018 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with GCC; see the file COPYING3.  If not see
  15 # <http://www.gnu.org/licenses/>.
  16
  17 # A MIPS version of the GCC dg.exp driver.
  18 #
  19 # There are many MIPS features that we want to test, and many of those
  20 # features are specific to certain architectures, certain ABIs and so on.
  21 # There are therefore many cases in which we want to test something that
  22 # is incompatible with the user's chosen test options.
  23 #
  24 # In most dg testsuites, the options added by dg-options have a lower
  25 # priority than the options chosen by the user.  For example, if a test
  26 # specifies:
  27 #
  28 #    { dg-options "-mips1" }
  29 #
  30 # and the user passes the following option to runtest:
  31 #
  32 #    --target_board unix/-mips3
  33 #
  34 # the test would be compiled as MIPS III rather than MIPS I.  If the
  35 # test really wouldn't work with -mips3, normal practice would be to
  36 # have something like:
  37 #
  38 #    { dg-do compile { target can_force_mips1 } }
  39 #
  40 # so that the test is skipped when an option like -mips3 is passed.
  41 #
  42 # Sticking to the same approach here would cause us to skip many tests,
  43 # even though the toolchain can generate the required code.  For example,
  44 # there are 6 MIPS ABIs, plus variants.  Some configurations support
  45 # more than one ABI, so it is natural to use something like:
  46 #
  47 #    --target_board unix{-mabi=n32,-mabi=32,-mabi=64}
  48 #
  49 # when testing them.  But these -mabi=* options would normally prevent any
  50 # EABI and o64 tests from running.
  51 #
  52 # This testsuite therefore defines a local version of dg-options that
  53 # overrides any user options that are incompatible with the test options.
  54 # It tries to keep the other user options intact.
  55 #
  56 #
  57 # Most of the tests in this testsuite are scan-assembler tests, but
  58 # sometimes we need a link test instead.  In these cases, we must not
  59 # try to link code with options that are incompatible with the current
  60 # multilib, because xgcc is passed -L and -B options that are specific
  61 # to that multilib.
  62 #
  63 # Normal GCC practice would be to skip incompatible link tests as
  64 # unsupported, but in this particular case, it seems better to downgrade
  65 # them to an assemble test instead.  At least that way we get some
  66 # test-for-ICE and code-sanity coverage.
  67 #
  68 # The same problem applies to run tests.  If a test requires runtime
  69 # support for a particular feature, and if the current target does not
  70 # provide that support, normal practice would be to skip the test.
  71 # But in this case it seems better to downgrade it to a link test instead.
  72 # (We might then have to downgrade it to an assembler test according to
  73 # the constraints just mentioned.)
  74 #
  75 # The local dg-options therefore checks whether the new options are
  76 # link-compatiable with the user's options.  If not, it automatically
  77 # downgrades link tests to assemble tests.  It does the same for run
  78 # tests, but in addition, it downgrades run tests to link tests if the
  79 # target does not provide runtime support for a required feature or ASE.
  80 #
  81 #
  82 # Another problem is that many of the options we want to test require
  83 # certain other features.  For example, -mips3d requires both 64-bit
  84 # FPRs and a MIPS32 or MIPS64 target; -mfix-r10000 requires branch-
  85 # likely instructions; and so on.  We could handle this by specifying
  86 # a set of options that are guaranteed to give us what we want, such as:
  87 #
  88 #   dg-options "-mips3d -mpaired-single -mhard-float -mgp64 -mfp64 -mabi=n32 -march=mips64 -mips64"
  89 #
  90 # With the new dg-options semantics, this would override any troublesome
  91 # user options like -mips3, -march=vr4100, -mfp32, -mgp32, -msoft-float,
  92 # -mno-paired-single and so on.  But there are three major problems with
  93 # this:
  94 #
  95 #   - It is easy to forget options.
  96 #
  97 #   - If a new option is added, all tests that are incompatible with that
  98 #     option must be updated.
  99 #
 100 #   - We want to be able to test MIPS-3D with things like -march=mips32,
 101 #     -march=mips64r2, -march=sb1, and so on.
 102 #
 103 # The local version of dg-options therefore works out the requirements
 104 # of each test option.  As with the test options themselves, the local
 105 # dg-options overrides any user options that incompatible with these
 106 # requirements, but it keeps the other user options the same.
 107 #
 108 # For example, if the user passes -mips3, a MIPS-3D test will choose
 109 # a different architecture like -mips64 instead.  But if the user
 110 # passes -march=sb1, MIPS-3D tests will be run with that option.
 111 #
 112 #
 113 # Sometimes it is useful to say "I want an environment that is compatible
 114 # with option X, but I don't want to pass option X itself".  The main example
 115 # of this is -mips16: we want to be able to test __attribute__((mips16))
 116 # without requiring the test itself to be compiled as -mips16.  The local
 117 # version of dg-options lets you do this by putting X in parentheses.
 118 # For example:
 119 #
 120 #   { dg-options "(-mips16)" }
 121 #
 122 # selects a MIPS16-compatible target without passing -mips16 itself.
 123 #
 124 # It is also useful to say "any architecture within this ISA range is fine".
 125 # This can be done using special pseudo-options of the form:
 126 #
 127 #   PROP=VALUE PROP<=VALUE PROP>=VALUE
 128 #
 129 # where PROP can be:
 130 #
 131 #   isa:
 132 #       the value of the __mips macro.
 133 #
 134 #   isa_rev:
 135 #       the value of the __mips_isa_rev macro, or 0 if it isn't defined.
 136 #
 137 # For example, "isa_rev>=1" selects a MIPS32 or MIPS64 processor,
 138 # "isa=4" selects a MIPS IV processor, and so on.
 139 #
 140 # There are also the following special pseudo-options:
 141 #
 142 #   isa=loongson
 143 #       select a Loongson processor
 144 #
 145 #   isa=p5600
 146 #      select a P5600 processor
 147 #
 148 #   addressing=absolute
 149 #       force absolute addresses to be used
 150 #
 151 #   forbid_cpu=REGEXP
 152 #       forbid processors that match the given regexp; choose a
 153 #       generic ISA instead.
 154 #
 155 #
 156 # In summary:
 157 #
 158 #   (1) Try to avoid { target ... } requirements wherever possible.
 159 #       Specify the requirements as dg-options instead.
 160 #
 161 #   (2) Don't worry about the consequences of (1) for link and run tests.
 162 #       If the test uses { dg-do link } or { dg-do run }, and its
 163 #       dg-options are incompatible with the current target, the
 164 #       testsuite will downgrade them where necessary.
 165 #
 166 #   (3) Try to use the bare minimum of options and leave dg-options
 167 #       to work out the dependencies.  For example, if you want
 168 #       a MIPS-3D test, you should generally just specify -mips3d.
 169 #       Don't specify an architecture option like -mips64 unless
 170 #       the test really doesn't work with -mips32r2, -mips64r2,
 171 #       -march=sb1, etc.
 172 #
 173 #   (4) If you want something compatible with a particular option,
 174 #       but don't want to pass the option itself, wrap that option
 175 #       in parentheses.  In particular, pass '(-mips16)' if you
 176 #       want to use "mips16" attributes.
 177 #
 178 #   (5) When testing a feature of a generic ISA (as opposed to a
 179 #       processor-specific extension), try to use the "isa" and
 180 #       "isa_rev" pseudo-options instead of specific architecture
 181 #       options.  For example, if the feature is present on revision 2
 182 #       processors and above, try to use "isa_rev>=2" instead of
 183 #       "-mips32r2" or "-mips64r2".
 184 #
 185 #   (6) If you need to disable processor-specific extensions use
 186 #       forbid_cpu=REGEXP instead of forcing a generic ISA.
 187 #
 188 #
 189 # Terminology
 190 #
 191 #   Option group or just group:
 192 #      See comment before mips_option_groups.
 193 #
 194 #   Test options:
 195 #      The options specified in dg-options.
 196 #
 197 #   Explicit options:
 198 #      The options that were either passed to runtest as "multilib" options
 199 #      (e.g. -mips4 in --target_board=mips-sim-idt/-mips4) or specified as
 200 #      test options.  Note that options in parenthesis (i.e. (-mips16)) are
 201 #      not explicit and can be omitted depending on the base options.
 202 #
 203 #   Base options:
 204 #      Options that are on by default without being specified in dg-options,
 205 #      e.g. -march=mips64r2 for mipsisa64r2-elf or because they've been
 206 #      passed to runtest as "multilib" options.
 207 #
 208 #   Option array:
 209 #      Many functions in this file work with option arrays.  These are
 210 #      two-dimensional Tcl arrays where the first dimension can have three
 211 #      values: option, explicit_p or test_option_p.  The second dimension is
 212 #      the name of the option group.  "option" contains the name of the
 213 #      option that is in effect from this group.  If no option is active it
 214 #      contains the empty string.  The flags "explicit_p" and "test_option_p"
 215 #      are set for explicit and test options.
 216
 217 # Exit immediately if this isn't a MIPS target.
 218 if ![istarget mips*-*-*] {
 219     return
 220 }
 221
 222 # Load support procs.
 223 load_lib gcc-dg.exp
 224
 225 # A list of GROUP REGEXP pairs.  Each GROUP represents a logical group of
 226 # options from which only one option should be chosen.  REGEXP matches all
 227 # the options in that group; it is implicitly wrapped in "^(...)$".
 228 #
 229 # Note that -O* is deliberately omitted from this list.  Tests in this
 230 # directory are run at various optimisation levels and should use
 231 # dg-skip-if to skip any incompatible levels.
 232 set mips_option_groups {
 233     abi "-mabi=.*"
 234     addressing "addressing=.*"
 235     arch "-mips([1-5]|32.*|64.*)|-march=.*|isa(|_rev)(=|<=|>=).*"
 236     debug "-g.*"
 237     dump_pattern "-dp"
 238     endianness "-E(L|B)|-me(l|b)"
 239     float "-m(hard|soft)-float"
 240     fpu "-m(double|single)-float"
 241     forbid_cpu "forbid_cpu=.*"
 242     fp "-mfp(32|xx|64)"
 243     gp "-mgp(32|64)"
 244     long "-mlong(32|64)"
 245     micromips "-mmicromips|-mno-micromips"
 246     mips16 "-mips16|-mno-mips16|-mflip-mips16"
 247     mips3d "-mips3d|-mno-mips3d"
 248     pic "-f(no-|)(pic|PIC)"
 249     cb "-mcompact-branches=.*"
 250     profiling "-pg"
 251     small-data "-G[0-9]+"
 252     warnings "-w"
 253     dump "-fdump-.*"
 254     ins "HAS_INS"
 255     dmul "NOT_HAS_DMUL"
 256     ldc "HAS_LDC"
 257     movn "HAS_MOVN"
 258     madd "HAS_MADD"
 259     madd4_ghost "HAS_MADD4"
 260     maddps "HAS_MADDPS"
 261     lsa "(|!)HAS_LSA"
 262     lxc1 "HAS_LXC1"
 263     section_start "-Wl,--section-start=.*"
 264     frame-header "-mframe-header-opt|-mno-frame-header-opt"
 265     stack-protector "-fstack-protector"
 266     stdlib "REQUIRES_STDLIB"
 267 }
 268
 269 for { set option 0 } { $option < 32 } { incr option } {
 270     lappend mips_option_groups "fixed-f$option" "-ffixed-f$option"
 271 }
 272
 273 # Add -mfoo/-mno-foo options to mips_option_groups.
 274 foreach option {
 275     abicalls
 276     branch-likely
 277     dsp
 278     dspr2
 279     explicit-relocs
 280     extern-sdata
 281     fix-r4000
 282     fix-r10000
 283     fix-vr4130
 284     gpopt
 285     local-sdata
 286     long-calls
 287     lxc1-sxc1
 288     madd4
 289     paired-single
 290     plt
 291     shared
 292     smartmips
 293     sym32
 294     synci
 295     relax-pic-calls
 296     mcount-ra-address
 297     odd-spreg
 298     msa
 299 } {
 300     lappend mips_option_groups $option "-m(no-|)$option"
 301 }
 302
 303 # Add -mfoo= options to mips_option_groups.
 304 foreach option {
 305     abs
 306     branch-cost
 307     code-readable
 308     nan
 309     r10k-cache-barrier
 310     tune
 311 } {
 312     lappend mips_option_groups $option "-m$option=.*"
 313 }
 314
 315 # Add -ffoo/-fno-foo options to mips_option_groups.
 316 foreach option {
 317     common
 318     delayed-branch
 319     expensive-optimizations
 320     fast-math
 321     fat-lto-objects
 322     finite-math-only
 323     fixed-hi
 324     fixed-lo
 325     lax-vector-conversions
 326     omit-frame-pointer
 327     optimize-sibling-calls
 328     peephole2
 329     schedule-insns2
 330     split-wide-types
 331     tree-vectorize
 332     unroll-all-loops
 333     unroll-loops
 334     ipa-ra
 335 } {
 336     lappend mips_option_groups $option "-f(no-|)$option"
 337 }
 338
 339 # A list of option groups that have an impact on the ABI.
 340 set mips_abi_groups {
 341     abi
 342     abicalls
 343     arch
 344     endianness
 345     float
 346     fp
 347     gp
 348     gpopt
 349     long
 350     pic
 351     small-data
 352 }
 353
 354 # mips_option_tests(OPTION) is some assembly code that will run to completion
 355 # on a target that supports OPTION.
 356 set mips_option_tests(-mips16) {
 357     move $2,$31
 358     bal 1f
 359     .set mips16
 360     jr $31
 361     .set nomips16
 362     .align 2
 363 1:
 364     ori $3,$31,1
 365     jalr $3
 366     move $31,$2
 367 }
 368 set mips_option_tests(-mmicromips) {
 369     move $2,$31
 370     bal 1f
 371     .set push
 372     .set micromips
 373     jraddiusp 0
 374     .set pop
 375     .align 2
 376 1:
 377     ori $3,$31,1
 378     jalr $3
 379     move $31,$2
 380 }
 381 set mips_option_tests(-mpaired-single) {
 382     .set mips64
 383     lui $2,0x3f80
 384     mtc1 $2,$f0
 385     cvt.ps.s $f2,$f0,$f0
 386 }
 387 set mips_option_tests(-mips3d) {
 388     .set mips64
 389     .set mips3d
 390     lui $2,0x3f80
 391     mtc1 $2,$f0
 392     cvt.ps.s $f2,$f0,$f0
 393     mulr.ps $f2,$f2,$f2
 394     rsqrt1.s $f2,$f0
 395     mul.s $f4,$f2,$f0
 396     rsqrt2.s $f4,$f4,$f2
 397     madd.s $f4,$f2,$f2,$f4
 398 }
 399 set mips_option_tests(-mdsp) {
 400     .set mips64r2
 401     .set dsp
 402     addsc $2,$2,$2
 403 }
 404 set mips_option_tests(-mdspr2) {
 405     .set mips64r2
 406     .set dspr2
 407     prepend $2,$3,11
 408 }
 409 set mips_option_tests(-mcode-readable=yes) {
 410     move $2,$31
 411     bal 1f
 412     .set mips16
 413     la $3,0f
 414     lw $3,($3)
 415     jr $31
 416 0:
 417     .word 0xfacebead
 418     .set nomips16
 419     .align 2
 420 1:
 421     ori $3,$31,1
 422     jalr $3
 423     li $4,0xfacebead
 424     beq $3,$4,2f
 425     break
 426     b .
 427 2:
 428     move $31,$2
 429 }
 430
 431 # Canonicalize command-line option OPTION.
 432 proc mips_canonicalize_option { option } {
 433     regsub {^-mips([1-5]|32*|64*)$} $option {-march=mips\1} option
 434
 435     regsub {^-mel$} $option {-EL} option
 436     regsub {^-meb$} $option {-EB} option
 437
 438     regsub {^-O$} $option {-O1} option
 439
 440     # MIPS doesn't use -fpic and -fPIC to distinguish between code models.
 441     regsub {^-f(no-|)PIC} $option {-f\1pic} option
 442
 443     return $option
 444 }
 445
 446 # Return true if OPTION1 and OPTION2 represent the same command-line option.
 447 proc mips_same_option_p { option1 option2 } {
 448     return [string equal \
 449                 [mips_canonicalize_option $option1] \
 450                 [mips_canonicalize_option $option2]]
 451 }
 452
 453 # Preprocess CODE using target_compile options OPTIONS.  Return the
 454 # compiler output.
 455 proc mips_preprocess { options code ignore_output } {
 456     global tool
 457
 458     set src dummy[pid].c
 459     set f [open $src "w"]
 460     puts $f $code
 461     close $f
 462     if { $ignore_output } {
 463         set output [${tool}_target_compile $src dummy[pid].i preprocess $options]
 464         file delete dummy[pid].i
 465     } else {
 466         set output [${tool}_target_compile $src "" preprocess $options]
 467     }
 468     file delete $src
 469
 470     return $output
 471 }
 472
 473 # Set the target board's command-line options to NEW_OPTIONS, storing the
 474 # old values in UPVAR.
 475 proc mips_push_test_options { upvar new_options } {
 476     upvar $upvar var
 477     global board_info
 478
 479     array unset var
 480     set var(name) board_info([target_info name],multilib_flags)
 481     if { [info exists $var(name)] } {
 482         set var(old_options) [set $var(name)]
 483         set $var(name) [join $new_options " "]
 484     }
 485 }
 486
 487 # Undo the effects of [mips_push_test_options UPVAR ...]
 488 proc mips_pop_test_options { upvar } {
 489     upvar $upvar var
 490     global board_info
 491
 492     if { [info exists var(old_options)] } {
 493         set $var(name) $var(old_options)
 494     }
 495 }
 496
 497 # Return property PROP for architecture option ARCH (which belongs to
 498 # the "arch" group in mips_option_groups).  See the comment at the
 499 # top of the file for the valid property names.
 500 #
 501 # Cache the results in mips_arch_info (which can be reused between test
 502 # variants).
 503 proc mips_arch_info { arch prop } {
 504     global mips_arch_info
 505     global board_info
 506
 507     set arch [mips_canonicalize_option $arch]
 508     if { ![info exists mips_arch_info($arch,$prop)] } {
 509         mips_push_test_options saved_options {}
 510         set output [mips_preprocess [list "additional_flags=$arch -mabi=32"] {
 511             int isa = __mips;
 512             #ifdef __mips_isa_rev
 513             int isa_rev = __mips_isa_rev;
 514             #else
 515             int isa_rev = 0;
 516             #endif
 517         } 0]
 518         foreach lhs { isa isa_rev } {
 519             regsub ".*$lhs = (\[^;\]*).*" $output {\1} rhs
 520             verbose -log "Architecture $arch has $lhs $rhs"
 521             set mips_arch_info($arch,$lhs) $rhs
 522         }
 523         mips_pop_test_options saved_options
 524     }
 525     return $mips_arch_info($arch,$prop)
 526 }
 527
 528 # Return the option group associated with OPTION, or "" if none.
 529 proc mips_option_maybe_group { option } {
 530     global mips_option_groups
 531
 532     foreach { group regexp } $mips_option_groups {
 533         if { [regexp -- "^($regexp)\$" $option] } {
 534             return $group
 535         }
 536     }
 537     return ""
 538 }
 539
 540 # Return the option group associated with OPTION.  Raise an error if
 541 # there is none.
 542 proc mips_option_group { option } {
 543     set group [mips_option_maybe_group $option]
 544     if { [string equal $group ""] } {
 545         error "Unrecognised option: $option"
 546     }
 547     return $group
 548 }
 549
 550 # Return the option for option group GROUP, or "" if no option in that
 551 # group has been chosen.  UPSTATUS describes the option status.
 552 proc mips_option { upstatus group } {
 553     upvar $upstatus status
 554
 555     return $status(option,$group)
 556 }
 557
 558 # If the base options for this test run include an option in group GROUP,
 559 # return that option, otherwise return "".
 560 proc mips_original_option { group } {
 561     global mips_base_options
 562
 563     return [mips_option mips_base_options $group]
 564 }
 565
 566 # Return true if the test described by UPSTATUS requires a specific
 567 # option in group GROUP.  UPSTATUS describes the option status.
 568 proc mips_test_option_p { upstatus group } {
 569     upvar $upstatus status
 570
 571     return $status(test_option_p,$group)
 572 }
 573
 574 # If the test described by UPSTATUS requires a particular option in group
 575 # GROUP, return that option, otherwise return "".
 576 proc mips_test_option { upstatus group } {
 577     upvar $upstatus status
 578
 579     if { [mips_test_option_p status $group] } {
 580         return [mips_option status $group]
 581     } else {
 582         return ""
 583     }
 584 }
 585
 586 # Return true if the options described by UPSTATUS include OPTION.
 587 proc mips_have_option_p { upstatus option } {
 588     upvar $upstatus status
 589
 590     return [mips_same_option_p \
 591                 [mips_option status [mips_option_group $option]] \
 592                 $option]
 593 }
 594
 595 # Return true if the options described by UPSTATUS require MIPS16 support.
 596 proc mips_using_mips16_p { upstatus } {
 597     upvar $upstatus status
 598
 599     return [expr { [mips_have_option_p status "-mips16"]
 600                    || [mips_have_option_p status "-mflip-mips16"] }]
 601 }
 602
 603 # Return true if the test described by UPSTATUS requires option OPTION.
 604 proc mips_have_test_option_p { upstatus option } {
 605     upvar $upstatus status
 606
 607     set group [mips_option_group $option]
 608     return [mips_same_option_p [mips_test_option status $group] $option]
 609 }
 610
 611 # If the test described by UPSTATUS does not specify an option in
 612 # OPTION's group, act as though it had specified OPTION.
 613 #
 614 # The first optional argument indicates whether the option should be
 615 # treated as though it were wrapped in parentheses; see the comment at
 616 # the top of the file for details about this convention.  The default is 0.
 617 proc mips_make_test_option { upstatus option args } {
 618     upvar $upstatus status
 619
 620     set group [mips_option_group $option]
 621     if { ![mips_test_option_p status $group] } {
 622         set status(option,$group) $option
 623         set status(test_option_p,$group) 1
 624         if { [llength $args] == 0 || ![lindex $args 0] } {
 625             set status(explicit_p,$group) 1
 626         }
 627     }
 628 }
 629
 630 # If the test described by UPSTATUS requires option FROM, assume that
 631 # it implicitly requires option TO.
 632 proc mips_option_dependency { upstatus from to } {
 633     upvar $upstatus status
 634
 635     if { [mips_have_test_option_p status $from] } {
 636         mips_make_test_option status $to
 637     }
 638 }
 639
 640 # Return true if the given arch-group option specifies a 32-bit ISA.
 641 proc mips_32bit_arch_p { option } {
 642     set isa [mips_arch_info $option isa]
 643     return [expr { $isa < 3 || $isa == 32 }]
 644 }
 645
 646 # Return true if the given arch-group option specifies a 64-bit ISA.
 647 proc mips_64bit_arch_p { option } {
 648     return [expr { ![mips_32bit_arch_p $option] }]
 649 }
 650
 651 # Return true if the given abi-group option implicitly requires -mgp32.
 652 proc mips_32bit_abi_p { option } {
 653     switch -glob -- $option {
 654         -mabi=32 {
 655             return 1
 656         }
 657     }
 658     return 0
 659 }
 660
 661 # Return true if the given abi-group option implicitly requires -mgp64.
 662 proc mips_64bit_abi_p { option } {
 663     switch -glob -- $option {
 664         -mabi=o64 -
 665         -mabi=n32 -
 666         -mabi=64 {
 667             return 1
 668         }
 669     }
 670     return 0
 671 }
 672
 673 # Return true if the given abi-group option implicitly requires -mlong32.
 674 # o64 requires this for -mabicalls, but not otherwise; pick the conservative
 675 # case for simplicity.
 676 proc mips_long32_abi_p { option } {
 677     switch -glob -- $option {
 678         -mabi=o64 -
 679         -mabi=n32 -
 680         -mabi=32 {
 681             return 1
 682         }
 683     }
 684     return 0
 685 }
 686
 687 # Return true if the given abi-group option implicitly requires -mlong64.
 688 proc mips_long64_abi_p { option } {
 689     switch -glob -- $option {
 690         -mabi=64 {
 691             return 1
 692         }
 693     }
 694     return 0
 695 }
 696
 697 # Check whether the current target supports all the options that the
 698 # current test requires.  Return "" if so, otherwise return one of
 699 # the incompatible options.  UPSTATUS describes the option status.
 700 proc mips_first_unsupported_option { upstatus } {
 701     global mips_option_tests
 702     upvar $upstatus status
 703
 704     foreach { option code } [array get mips_option_tests] {
 705         if { [mips_have_test_option_p status $option] } {
 706             regsub -all "\n" $code "\\n\\\n" asm
 707             # Use check_runtime from target-supports.exp, which caches
 708             # the result for us.
 709             if { ![check_runtime mips_option_$option [subst {
 710                 __attribute__((nomips16)) int
 711                 main (void)
 712                 {
 713                     asm (".set push\
 714                     $asm\
 715                     .set pop");
 716                     return 0;
 717                 }
 718             }]] } {
 719                 return $option
 720             }
 721         }
 722     }
 723     return ""
 724 }
 725
 726 # Initialize this testsuite for a new test variant.
 727 proc mips-dg-init {} {
 728     # Invariant information.
 729     global mips_option_groups
 730
 731     # Internally-generated information about this run.
 732     global mips_base_options
 733     global mips_extra_options
 734
 735     # Override dg-options with our mips-dg-options routine.
 736     rename dg-options mips-old-dg-options
 737     rename mips-dg-options dg-options
 738
 739     # Start with a fresh option status.
 740     array unset mips_base_options
 741     foreach { group regexp } $mips_option_groups {
 742         set mips_base_options(option,$group) ""
 743         set mips_base_options(explicit_p,$group) 0
 744         set mips_base_options(test_option_p,$group) 0
 745     }
 746
 747     # Use preprocessor macros to work out as many implicit options as we can.
 748     set output [mips_preprocess "" {
 749         const char *options[] = {
 750             #if !defined _MIPS_SIM
 751             "-mabi=eabi",
 752             #elif _MIPS_SIM==_ABIO32
 753             "-mabi=32",
 754             #elif _MIPS_SIM==_ABIO64
 755             "-mabi=o64",
 756             #elif _MIPS_SIM==_ABIN32
 757             "-mabi=n32",
 758             #else
 759             "-mabi=64",
 760             #endif
 761
 762             "-march=" _MIPS_ARCH,
 763
 764             #ifdef _MIPSEB
 765             "-EB",
 766             #else
 767             "-EL",
 768             #endif
 769
 770             #ifdef __mips_hard_float
 771             "-mhard-float",
 772             #else
 773             "-msoft-float",
 774             #endif
 775
 776             #ifdef __mips_abs2008
 777             "-mabs=2008",
 778             #else
 779             "-mabs=legacy",
 780             #endif
 781
 782             #ifdef __mips_nan2008
 783             "-mnan=2008",
 784             #else
 785             "-mnan=legacy",
 786             #endif
 787
 788             #if __mips_fpr == 64
 789             "-mfp64",
 790             #else
 791             #if __mips_fpr == 0
 792             "-mfpxx",
 793             #else
 794             "-mfp32",
 795             #endif
 796             #endif
 797
 798             #ifdef __mips64
 799             "-mgp64",
 800             #else
 801             "-mgp32",
 802             #endif
 803
 804             #if _MIPS_SZLONG == 64
 805             "-mlong64",
 806             #else
 807             "-mlong32",
 808             #endif
 809
 810             #ifdef __mips16
 811             "-mips16",
 812             #else
 813             "-mno-mips16",
 814             #endif
 815
 816             #ifdef __mips3d
 817             "-mips3d",
 818             #else
 819             "-mno-mips3d",
 820             #endif
 821
 822             #ifdef __mips_paired_single_float
 823             "-mpaired-single",
 824             #else
 825             "-mno-paired-single",
 826             #endif
 827
 828             #if _MIPS_SPFPSET == 32
 829             "-modd-spreg",
 830             #else
 831             "-mno-odd-spreg",
 832             #endif
 833
 834             #if __mips_abicalls
 835             "-mabicalls",
 836             #else
 837             "-mno-abicalls",
 838             #endif
 839
 840             #if __mips_dsp_rev >= 2
 841             "-mdspr2",
 842             #else
 843             "-mno-dspr2",
 844             #endif
 845
 846             #if __mips_dsp_rev >= 1
 847             "-mdsp",
 848             #else
 849             "-mno-dsp",
 850             #endif
 851
 852             #ifndef __PIC__
 853             "addressing=absolute",
 854             #endif
 855
 856             #ifdef __mips_smartmips
 857             "-msmartmips",
 858             #else
 859             "-mno-smartmips",
 860             #endif
 861
 862             #ifdef __mips_no_lxc1_sxc1
 863             "-mno-lxc1-sxc1",
 864             #else
 865             "-mlxc1-sxc1"
 866             #endif
 867
 868             #ifdef __mips_no_madd4
 869             "-mno-madd4"
 870             #else
 871             "-mmadd4"
 872             #endif
 873
 874             #ifdef __mips_synci
 875             "-msynci",
 876             #else
 877             "-mno-synci",
 878             #endif
 879
 880             #ifdef __mips_msa
 881             "-mmsa"
 882             #else
 883             "-mno-msa"
 884             #endif
 885
 886             0
 887         };
 888     } 0]
 889     foreach line [split $output "\r\n"] {
 890         # Poor man's string concatenation.
 891         regsub -all {" "} $line "" line
 892         if { [regexp {"(.*)",} $line dummy option] } {
 893             set group [mips_option_group $option]
 894             set mips_base_options(option,$group) $option
 895         }
 896     }
 897
 898     # Process the target's multilib options, saving any unrecognized
 899     # ones in mips_extra_options.
 900     set mips_extra_options {}
 901     foreach option [split [board_info target multilib_flags]] {
 902         set group [mips_option_maybe_group $option]
 903         if { ![string equal $group ""] } {
 904             set mips_base_options(option,$group) $option
 905             set mips_base_options(explicit_p,$group) 1
 906         } else {
 907             lappend mips_extra_options $option
 908         }
 909     }
 910 }
 911
 912 # Finish a test run started by mips-dg-init.
 913 proc mips-dg-finish {} {
 914     rename dg-options mips-dg-options
 915     rename mips-old-dg-options dg-options
 916 }
 917
 918 # Override dg-options so that we can do some MIPS-specific processing.
 919 # All options used in this testsuite must appear in mips_option_groups.
 920 #
 921 # Test options override multilib options.  Certain test options can
 922 # also imply other test options, which also override multilib options.
 923 # These dependencies are ordered as follows:
 924 #
 925 #          START                        END
 926 #            |                           |
 927 #         -mips16/-mflip-mips16       -mno-mips16
 928 #            |                           |
 929 #         -micromips                  -mno-micromips
 930 #            |                           |
 931 #         -mips3d                     -mno-mips3d
 932 #            |                           |
 933 #         -mpaired-single             -mno-paired-single
 934 #            |                           |
 935 #         -mfp64                      -mfp32
 936 #            |                           |
 937 #         -modd-spreg                 -mno-odd-spreg
 938 #            |                           |
 939 #         -mdouble-float              -msingle-float
 940 #            |                           |
 941 #         -mabs=2008/-mabs=legacy     <no option>
 942 #            |                           |
 943 #         -mhard-float                -msoft-float
 944 #            |                           |
 945 #         -mno-sym32                  -msym32
 946 #            |                           |
 947 #         -mrelax-pic-calls           -mno-relax-pic-calls
 948 #            |                           |
 949 #         -fpic                       -fno-pic
 950 #            |                           |
 951 #         -mshared                    -mno-shared
 952 #            |                           |
 953 #         -mno-plt                    -mplt
 954 #            |                           |
 955 #         addressing=unknown          addressing=absolute
 956 #            |                           |
 957 #         -mabicalls                  -mno-abicalls
 958 #            |                           |
 959 #         -G0                         <other value>
 960 #            |                           |
 961 #         <other value>               -mr10k-cache-barrier=none
 962 #            |                           |
 963 #         -mfix-r10000                -mno-fix-r10000
 964 #            |                           |
 965 #         -mbranch-likely             -mno-branch-likely
 966 #            |                           |
 967 #         -msmartmips                 -mno-smartmips
 968 #            |                           |
 969 #         -mno-gpopt                  -mgpopt
 970 #            |                           |
 971 #         -mexplicit-relocs           -mno-explicit-relocs
 972 #            |                           |
 973 #         -mdspr2                     -mno-dspr2
 974 #            |                           |
 975 #         -mdsp                       -mno-dsp
 976 #            |                           |
 977 #         -msynci                     -mno-synci
 978 #            |                           |
 979 #            +-- gp, abi & arch ---------+
 980 #
 981 # For these purposes, the "gp", "abi" & "arch" option groups are treated
 982 # as a single node.
 983 proc mips-dg-options { args } {
 984     # dg.exp variables.
 985     upvar dg-extra-tool-flags extra_tool_flags
 986     upvar dg-do-what do_what
 987
 988     # Invariant information.
 989     global mips_option_groups
 990     global mips_abi_groups
 991
 992     # Information about this run.
 993     global mips_base_options
 994
 995     if { [llength $args] >= 3 } {
 996         switch { [dg-process-target [lindex $args 2]] } {
 997             "S" { }
 998             "N" { return }
 999             "F" { error "[lindex $args 0]: `xfail' not allowed here" }
1000             "P" { error "[lindex $args 0]: `xfail' not allowed here" }
1001         }
1002     }
1003
1004     # Start out with the default option state.
1005     array set options [array get mips_base_options]
1006
1007     # Record the options that this test explicitly needs.
1008     foreach option [lindex $args 1] {
1009         set all_but_p [regexp {^\((.*)\)$} $option dummy option]
1010         set group [mips_option_group $option]
1011         if { [mips_test_option_p options $group] } {
1012             set old [mips_option options $group]
1013             error "Inconsistent $group option: $old vs. $option"
1014         } else {
1015             mips_make_test_option options $option $all_but_p
1016         }
1017     }
1018
1019     # Handle dependencies between the test options and the optimization ones.
1020     mips_option_dependency options "-fno-unroll-loops" "-fno-unroll-all-loops"
1021     mips_option_dependency options "-pg" "-fno-omit-frame-pointer"
1022
1023     # Handle dependencies between options on the left of the
1024     # dependency diagram.
1025     mips_option_dependency options "-mips16" "-mno-micromips"
1026     mips_option_dependency options "-mmicromips" "-mno-mips16"
1027     mips_option_dependency options "-mips3d" "-mpaired-single"
1028     mips_option_dependency options "-mips3d" "-mno-micromips"
1029     mips_option_dependency options "-mpaired-single" "-mfp64"
1030     mips_option_dependency options "-mfp64" "-mhard-float"
1031     mips_option_dependency options "-mfp32" "-mhard-float"
1032     mips_option_dependency options "-mfpxx" "-mhard-float"
1033     mips_option_dependency options "-mfp64" "-modd-spreg"
1034     mips_option_dependency options "-mfp64" "-mdouble-float"
1035     mips_option_dependency options "-mfp32" "-mdouble-float"
1036     mips_option_dependency options "-mfpxx" "-mdouble-float"
1037     mips_option_dependency options "-mabs=2008" "-mhard-float"
1038     mips_option_dependency options "-mabs=legacy" "-mhard-float"
1039     mips_option_dependency options "-mrelax-pic-calls" "-mno-plt"
1040     mips_option_dependency options "-mrelax-pic-calls" "-mabicalls"
1041     mips_option_dependency options "-mrelax-pic-calls" "-mexplicit-relocs"
1042     mips_option_dependency options "-fpic" "-mshared"
1043     mips_option_dependency options "-mshared" "-mno-plt"
1044     mips_option_dependency options "-mshared" "-mabicalls"
1045     mips_option_dependency options "-mno-plt" "addressing=unknown"
1046     mips_option_dependency options "-mabicalls" "-G0"
1047     mips_option_dependency options "-mno-gpopt" "-mexplicit-relocs"
1048
1049     # Work out information about the current ABI.
1050     set abi_test_option_p [mips_test_option_p options abi]
1051     set abi [mips_option options abi]
1052     set eabi_p [mips_same_option_p $abi "-mabi=eabi"]
1053
1054     # If the test forces a particular ABI, set the register size
1055     # accordingly.
1056     if { $abi_test_option_p } {
1057         if { [mips_32bit_abi_p $abi] } {
1058             mips_make_test_option options "-mgp32"
1059         } elseif { [mips_64bit_abi_p $abi] } {
1060             mips_make_test_option options "-mgp64"
1061         }
1062     }
1063
1064     # See whether forbid_cpu forces us to choose a new architecture.
1065     set arch [mips_option mips_base_options arch]
1066     set force_generic_isa_p [expr {
1067         [regexp "forbid_cpu=(.*)" [mips_option options forbid_cpu] dummy spec]
1068         && [regexp -- "^-march=$spec\$" $arch]
1069     }]
1070
1071     # Interpret the special "isa" and "isa_rev" options.  If we have
1072     # a choice of a 32-bit or a 64-bit architecture, prefer to keep
1073     # the -mgp setting the same.
1074     set spec [mips_option options arch]
1075     if { [regexp {^[^-]} $spec] } {
1076         if { [string equal $spec "isa=loongson"] } {
1077             if { ![regexp {^-march=loongson} $arch] } {
1078                 set arch "-march=loongson2f"
1079             }
1080         } elseif { [string equal $spec "isa=p5600"] } {
1081             if { ![regexp {^-march=p5600} $arch] } {
1082                 set arch "-march=p5600"
1083             }
1084         } else {
1085             if { ![regexp {^(isa(?:|_rev))(=|<=|>=)([0-9]*)$} \
1086                        $spec dummy prop relation value nocpus] } {
1087                 error "Unrecognized isa specification: $spec"
1088             }
1089             set current [mips_arch_info $arch $prop]
1090             if { $force_generic_isa_p
1091                  || ($current < $value && ![string equal $relation "<="])
1092                  || ($current > $value && ![string equal $relation ">="])
1093                  || ([mips_have_test_option_p options "-mgp64"]
1094                      && [mips_32bit_arch_p $arch]) } {
1095                 # The current setting is out of range; it cannot
1096                 # possibly be used.  Find a replacement that can.
1097                 if { [string equal $prop "isa"] } {
1098                     set arch "-mips$value"
1099                 } elseif { $value == 0 } {
1100                     set arch "-mips4"
1101                 } else {
1102                     if { [mips_have_option_p options "-mgp32"] } {
1103                         set arch "-mips32"
1104                     } else {
1105                         set arch "-mips64"
1106                     }
1107                     if { $value > 1 } {
1108                         append arch "r$value"
1109                     }
1110                 }
1111             }
1112         }
1113         set options(option,arch) $arch
1114     }
1115
1116     # Work out information about the current architecture.
1117     set arch_test_option_p [mips_test_option_p options arch]
1118     set arch [mips_option options arch]
1119     set isa [mips_arch_info $arch isa]
1120     set isa_rev [mips_arch_info $arch isa_rev]
1121     set orig_isa_rev $isa_rev
1122
1123     # If the test forces a 32-bit architecture, force -mgp32.
1124     # Force the current -mgp setting otherwise; if we don't,
1125     # some configurations would make a 64-bit architecture
1126     # imply -mgp64.
1127     if { $arch_test_option_p } {
1128         if { [mips_32bit_arch_p $arch] } {
1129             mips_make_test_option options "-mgp32"
1130         } else {
1131             mips_make_test_option options [mips_option options gp]
1132         }
1133     }
1134
1135     # We've now fixed the GP register size.  Make it easily available.
1136     set gp_size [expr { [mips_have_option_p options "-mgp32"] ? 32 : 64 }]
1137
1138     # Handle dependencies between the pre-arch options and the arch option.
1139     # This should mirror the arch and post-arch code below.
1140     if { !$arch_test_option_p } {
1141         # We need a revision 6 or better ISA for:
1142         #
1143         #   - When the LSA instruction is required
1144         #   - When only using compact branches
1145         if { $isa_rev < 6
1146              && ([mips_have_test_option_p options "HAS_LSA"]
1147                  || [mips_have_test_option_p options "-mcompact-branches=always"]) } {
1148             if { $gp_size == 32 } {
1149                 mips_make_test_option options "-mips32r6"
1150             } else {
1151                 mips_make_test_option options "-mips64r6"
1152             }
1153         # We need a revision 2 or better ISA for:
1154         #
1155         #   - the combination of -mgp32 -mfp64
1156         #   - the DSP ASE
1157         } elseif { $isa_rev < 2
1158              && (($gp_size == 32 && [mips_have_test_option_p options "-mfp64"])
1159                  || [mips_have_test_option_p options "-msynci"]
1160                  || [mips_have_test_option_p options "-mdsp"]
1161                  || [mips_have_test_option_p options "HAS_INS"]
1162                  || [mips_have_test_option_p options "HAS_MADD"]
1163                  || [mips_have_test_option_p options "HAS_MADDPS"]
1164                  || [mips_have_test_option_p options "-mdspr2"]
1165                  || [mips_have_test_option_p options "-mnan=2008"]
1166                  || [mips_have_test_option_p options "-mabs=2008"]
1167                  || [mips_have_test_option_p options "-mmicromips"]) } {
1168             if { $gp_size == 32 } {
1169                 mips_make_test_option options "-mips32r2"
1170             } else {
1171                 mips_make_test_option options "-mips64r2"
1172             }
1173         # We need a MIPS32 or MIPS64 ISA for:
1174         #
1175         #   - paired-single instructions(*)
1176         #   - odd numbered single precision registers
1177         #
1178         # (*) Note that we don't support MIPS V at the moment.
1179         } elseif { $isa_rev < 1
1180                    && ([mips_have_test_option_p options "-mpaired-single"]
1181                        || ([mips_have_test_option_p options "-modd-spreg"]
1182                            && ![mips_have_test_option_p options "-mfp64"]))} {
1183             if { $gp_size == 32 } {
1184                 mips_make_test_option options "-mips32"
1185             } else {
1186                 mips_make_test_option options "-mips64"
1187             }
1188         # We need MIPS IV or higher for:
1189         #
1190         #
1191         } elseif { $isa < 4
1192                    && ([mips_have_test_option_p options "HAS_LXC1"]
1193                        || [mips_have_test_option_p options "HAS_MADD4"]
1194                        || [mips_have_test_option_p options "HAS_MOVN"]) } {
1195             mips_make_test_option options "-mips4"
1196         # We need MIPS III or higher for:
1197         #
1198         #   - the "cache" instruction
1199         } elseif { $isa < 3
1200                    && ([mips_have_test_option_p options \
1201                             "-mr10k-cache-barrier=load-store"]
1202                        || [mips_have_test_option_p options \
1203                                "-mr10k-cache-barrier=store"]) } {
1204             mips_make_test_option options "-mips3"
1205         # We need MIPS II or higher for:
1206         #
1207         #   - branch-likely instructions(*)
1208         #
1209         # (*) needed by both -mbranch-likely and -mfix-r10000
1210         } elseif { $isa < 2
1211                    && ([mips_have_test_option_p options "-mbranch-likely"]
1212                        || [mips_have_test_option_p options "-mfix-r10000"]
1213                        || ($gp_size == 32
1214                            && ([mips_have_test_option_p options "-mfpxx"]
1215                                || [mips_have_test_option_p options "HAS_LDC"]))) } {
1216             mips_make_test_option options "-mips2"
1217         # We need to use octeon's base ISA if a test must not run with an
1218         # architecture that supports dmul.
1219         } elseif { [regexp -- "^-march=octeon.*\$" $arch]
1220                    && [mips_have_test_option_p options "NOT_HAS_DMUL"] } {
1221             mips_make_test_option options "-mips${isa}r${isa_rev}"
1222         # Check whether we need to switch from mips*r6 down to mips*r5 due
1223         # to options that are incompatible with mips*r6.  If we do, use
1224         # -mnan=2008 because r6 is nan2008 by default and without this flag
1225         # tests that include stdlib.h will fail due to not finding
1226         # stubs-o32_hard.h  (r6 compilers only have stubs-o32_hard_2008.h)
1227         } elseif { $isa_rev > 5
1228                    && ([mips_have_test_option_p options "-mdsp"]
1229                        || [mips_have_test_option_p options "-mdspr2"]
1230                        || [mips_have_test_option_p options "-mips16"]
1231                        || [mips_have_test_option_p options "-mmicromips"]
1232                        || [mips_have_test_option_p options "-mfp32"]
1233                        || [mips_have_test_option_p options "-mfix-r10000"]
1234                        || [mips_have_test_option_p options "NOT_HAS_DMUL"]
1235                        || [mips_have_test_option_p options "HAS_LXC1"]
1236                        || [mips_have_test_option_p options "HAS_MADD"]
1237                        || [mips_have_test_option_p options "HAS_MADD4"]
1238                        || [mips_have_test_option_p options "HAS_MOVN"]
1239                        || [mips_have_test_option_p options "-mpaired-single"]
1240                        || [mips_have_test_option_p options "-mnan=legacy"]
1241                        || [mips_have_test_option_p options "-mabs=legacy"]
1242                        || [mips_have_test_option_p options "!HAS_LSA"]
1243                        || [mips_have_test_option_p options "-mbranch-likely"]) } {
1244             if { $gp_size == 32 } {
1245                 mips_make_test_option options "-mips32r5"
1246             } else {
1247                 mips_make_test_option options "-mips64r5"
1248             }
1249             mips_make_test_option options "-mnan=2008"
1250             if { [mips_have_option_p options "-mcompact-branches=always"] } {
1251                 mips_make_test_option options "-mcompact-branches=optimal"
1252             }
1253         # Check whether we need to switch from a 32-bit processor to the
1254         # "nearest" 64-bit processor.
1255         } elseif { $gp_size == 64 && [mips_32bit_arch_p $arch] } {
1256             if { $isa_rev == 0 } {
1257                 mips_make_test_option options "-mips3"
1258             } elseif { $isa_rev == 1 } {
1259                 mips_make_test_option options "-mips64"
1260             } else {
1261                 mips_make_test_option options "-mips64r$isa_rev"
1262             }
1263         # Otherwise, if the current choice of architecture is unacceptable,
1264         # choose the equivalent generic architecture.
1265         } elseif { $force_generic_isa_p } {
1266             set arch "-mips[mips_arch_info $arch isa]"
1267             if { $isa_rev > 1 } {
1268                 append arch "r$isa_rev"
1269             }
1270             mips_make_test_option options $arch
1271         }
1272         unset arch
1273         unset isa
1274         unset isa_rev
1275     }
1276
1277     # Re-calculate the isa_rev for use in the abi handling code below
1278     set arch [mips_option options arch]
1279     set isa [mips_arch_info $arch isa]
1280     set isa_rev [mips_arch_info $arch isa_rev]
1281
1282     # Set an appropriate ABI, handling dependencies between the pre-abi
1283     # options and the abi options.  This should mirror the abi and post-abi
1284     # code below.
1285     if { !$abi_test_option_p } {
1286         if { ($eabi_p
1287               && ([mips_have_option_p options "-mabicalls"]
1288                   || ($gp_size == 32
1289                       && [mips_have_option_p options "-mfp64"]))) } {
1290             # EABI doesn't support -mabicalls.
1291             # EABI doesn't support the combination -mgp32 -mfp64.
1292             set force_abi 1
1293         } elseif { [mips_using_mips16_p options]
1294                    && ![mips_same_option_p $abi "-mabi=32"]
1295                    && ![mips_same_option_p $abi "-mabi=o64"]
1296                    && (![mips_have_option_p options "addressing=absolute"]
1297                        || [mips_have_option_p options "-mhard-float"]) } {
1298             # -mips16 -mhard-float requires o32 or o64.
1299             # -mips16 PIC requires o32 or o64.
1300             set force_abi 1
1301         } elseif { [mips_have_test_option_p options "-mlong32"]
1302                    && [mips_long64_abi_p $abi] } {
1303             set force_abi 1
1304         } elseif { [mips_have_test_option_p options "-mlong64"]
1305                    && [mips_long32_abi_p $abi] } {
1306             set force_abi 1
1307         } elseif { [mips_have_test_option_p options "-mfpxx"]
1308                    && ![mips_same_option_p $abi "-mabi=32"] } {
1309             set force_abi 1
1310         } else {
1311             set force_abi 0
1312         }
1313         if { $gp_size == 32 } {
1314             if { $force_abi || [mips_64bit_abi_p $abi] } {
1315                 if { [mips_have_test_option_p options "-mlong64"] } {
1316                     mips_make_test_option options "-mabi=eabi"
1317                     mips_make_test_option options "-mgp32"
1318                 } else {
1319                     mips_make_test_option options "-mabi=32"
1320                 }
1321             }
1322         } else {
1323             if { $force_abi || [mips_32bit_abi_p $abi] } {
1324                 if { [mips_have_test_option_p options "-mlong64"] } {
1325                     mips_make_test_option options "-mabi=eabi"
1326                     mips_make_test_option options "-mgp64"
1327                 } else {
1328                     # All configurations should have an assembler that
1329                     # supports o64, since it requires the same BFD target
1330                     # vector as o32.  In contrast, many assembler
1331                     # configurations do not have n32 or n64 support.
1332                     mips_make_test_option options "-mabi=o64"
1333                 }
1334             }
1335         }
1336         set abi_test_option_p [mips_test_option_p options abi]
1337         set abi [mips_option options abi]
1338         set eabi_p [mips_same_option_p $abi "-mabi=eabi"]
1339     }
1340
1341     # Handle dependencies between the abi options and the post-abi options.
1342     # This should mirror the abi and pre-abi code above.
1343     if { $abi_test_option_p } {
1344         if { $eabi_p } {
1345             mips_make_test_option options "-mno-abicalls"
1346             if { $isa_rev < 6 && $gp_size == 32 } {
1347                     mips_make_test_option options "-mfp32"
1348             }
1349         }
1350         if { [mips_using_mips16_p options]
1351              && ![mips_same_option_p $abi "-mabi=32"]
1352              && ![mips_same_option_p $abi "-mabi=o64"]
1353              && ([mips_have_option_p options "-mabicalls"]
1354                  || [mips_have_option_p options "-mhard-float"]) } {
1355             if { [mips_test_option_p options mips16] } {
1356                 mips_make_test_option options "addressing=absolute"
1357                 mips_make_test_option options "-msoft-float"
1358             } else {
1359                 mips_make_test_option options "-mno-mips16"
1360             }
1361         }
1362         if { [mips_long32_abi_p $abi] } {
1363             mips_make_test_option options "-mlong32"
1364         } elseif { [mips_long64_abi_p $abi] } {
1365             mips_make_test_option options "-mlong64"
1366         }
1367     }
1368
1369     # Handle dependencies between the arch option and the post-arch options.
1370     # This should mirror the arch and pre-arch code above.  For pre-r6
1371     # architectures this only needs to be done when we've moved down
1372     # to a lower architecture and might need to turn features off,
1373     # but moving up from pre-r6 to r6 can remove features too.
1374     if { $arch_test_option_p || ($orig_isa_rev < 6 && $isa_rev >= 6) } {
1375         if { $isa < 2 } {
1376             mips_make_test_option options "-mno-branch-likely"
1377             mips_make_test_option options "-mno-fix-r10000"
1378         }
1379         if { $isa < 3 } {
1380             mips_make_test_option options "-mr10k-cache-barrier=none"
1381         }
1382         if { $isa_rev < 1 } {
1383             mips_make_test_option options "-mno-paired-single"
1384             if { ![mips_have_test_option_p options "-mgp64"] } {
1385                 mips_make_test_option options "-mno-odd-spreg"
1386             }
1387         }
1388         if { $isa_rev < 2 } {
1389             if { $gp_size == 32 } {
1390                 mips_make_test_option options "-mfp32"
1391             }
1392             mips_make_test_option options "-mno-dsp"
1393             mips_make_test_option options "-mno-synci"
1394             mips_make_test_option options "-mno-micromips"
1395             mips_make_test_option options "-mnan=legacy"
1396         }
1397         if { $isa_rev < 6 } {
1398             if { [mips_have_option_p options "-mcompact-branches=always"] } {
1399                 mips_make_test_option options "-mcompact-branches=optimal"
1400             }
1401         }
1402         if { $isa_rev > 5 } {
1403             mips_make_test_option options "-mno-dsp"
1404             mips_make_test_option options "-mno-mips16"
1405             if { [mips_have_test_option_p options "-mdsp"] } {
1406                 mips_make_test_option options "-mfp64"
1407             }
1408             mips_make_test_option options "-mno-fix-r10000"
1409             mips_make_test_option options "-mno-paired-single"
1410             mips_make_test_option options "-mnan=2008"
1411             mips_make_test_option options "-mabs=2008"
1412             mips_make_test_option options "-mno-branch-likely"
1413         }
1414         if { [regexp {^-march=(octeon|loongson)} $arch] } {
1415             mips_make_test_option options "-mno-micromips"
1416         }
1417
1418         unset arch
1419         unset isa
1420         unset isa_rev
1421     }
1422
1423     # Handle dependencies between options on the right of the diagram.
1424     mips_option_dependency options "-mno-dsp" "-mno-dspr2"
1425     mips_option_dependency options "-mno-explicit-relocs" "-mgpopt"
1426     switch -- [mips_test_option options small-data] {
1427         "" -
1428         -G0 {}
1429         default {
1430             mips_make_test_option options "-mno-abicalls"
1431         }
1432     }
1433     if { [mips_have_option_p options "-mabicalls"] } {
1434         mips_option_dependency options "addressing=absolute" "-mplt"
1435     }
1436     mips_option_dependency options "-mplt" "-msym32"
1437     mips_option_dependency options "-mplt" "-mno-shared"
1438     mips_option_dependency options "-mno-shared" "-fno-pic"
1439     mips_option_dependency options "-mfp32" "-mno-paired-single"
1440     mips_option_dependency options "-mfpxx" "-mno-paired-single"
1441     mips_option_dependency options "-msoft-float" "-mno-paired-single"
1442     mips_option_dependency options "-mno-paired-single" "-mno-mips3d"
1443     mips_option_dependency options "-mmsa" "-mno-mips16"
1444
1445     # If the test requires an unsupported option, change run tests
1446     # to link tests.
1447
1448     switch -- [lindex $do_what 0] {
1449         run {
1450             set option [mips_first_unsupported_option options]
1451             if { ![string equal $option ""] } {
1452                 set do_what [lreplace $do_what 0 0 link]
1453                 verbose -log "Downgraded to a 'link' test due to unsupported option '$option'"
1454             }
1455         }
1456     }
1457
1458     # If the test has overridden a option that changes the ABI,
1459     # downgrade a link or execution test to an assembler test.
1460     foreach group $mips_abi_groups {
1461         set old_option [mips_original_option $group]
1462         set new_option [mips_option options $group]
1463         if { ![mips_same_option_p $old_option $new_option]
1464              && ![mips_same_option_p $old_option "-mfpxx"]
1465              && ![mips_same_option_p $new_option "-mfpxx"] } {
1466             switch -- [lindex $do_what 0] {
1467                 link -
1468                 run {
1469                     set do_what [lreplace $do_what 0 0 assemble]
1470                     verbose -log "Downgraded to an 'assemble' test due to incompatible $group option ($old_option changed to $new_option)"
1471                 }
1472             }
1473             break
1474         }
1475     }
1476
1477     # Add all options to the dg variable.
1478     set options(explicit_p,addressing) 0
1479     set options(explicit_p,forbid_cpu) 0
1480     foreach { group regexp } $mips_option_groups {
1481         if { $options(explicit_p,$group) } {
1482             append extra_tool_flags " " $options(option,$group)
1483         }
1484     }
1485
1486     # If the test is marked as requiring standard libraries check
1487     # that the sysroot has support for the current set of test options.
1488     if { [mips_have_test_option_p options "REQUIRES_STDLIB"] } {
1489         mips_push_test_options saved_options $extra_tool_flags
1490         set output [mips_preprocess "" {
1491               #include <stdlib.h>
1492         } 1]
1493         mips_pop_test_options saved_options
1494
1495         # If the preprocessing of the stdlib.h file produced errors,
1496         # mark the test as unsupported by changing the second element of
1497         # do_what to "N".
1498         # The second element of do_what holds information about test selection
1499         # and it can have one of two values:
1500         # "S" - the test is selected and will be run
1501         # "N" - the test is not selected and will not be run
1502         # This mirrors the format of dg-do-what from lib/dg.exp in DejaGNU.
1503         if { ![string equal $output ""] } {
1504             set do_what [lreplace $do_what 1 1 "N"]
1505         }
1506     }
1507
1508     # If the test is MIPS16-compatible, provide a counterpart to the
1509     # NOMIPS16 convenience macro.
1510     if { [mips_have_test_option_p options "-mips16"] } {
1511         append extra_tool_flags " -DMIPS16=__attribute__((mips16))"
1512     }
1513
1514     if { [mips_have_test_option_p options "-mmicromips"] } {
1515         append extra_tool_flags " -DMICROMIPS=__attribute__((micromips))"
1516     }
1517
1518     # Use our version of gcc-dg-test for this test.
1519     if { ![string equal [info procs "mips-gcc-dg-test"] ""] } {
1520         rename gcc-dg-test mips-old-gcc-dg-test
1521         rename mips-gcc-dg-test gcc-dg-test
1522     }
1523 }
1524
1525 # A version of gcc-dg-test that is used by dg-options tests.
1526 proc mips-gcc-dg-test { prog do_what extra_tool_flags } {
1527     global board_info
1528     global mips_extra_options
1529
1530     # Override the user's chosen test options with the combined test/user
1531     # version.
1532     mips_push_test_options saved_options $mips_extra_options
1533     set result [gcc-dg-test-1 gcc_target_compile $prog \
1534                     $do_what $extra_tool_flags]
1535     mips_pop_test_options saved_options
1536
1537     # Restore the usual gcc-dg-test.
1538     rename gcc-dg-test mips-gcc-dg-test
1539     rename mips-old-gcc-dg-test gcc-dg-test
1540
1541     return $result
1542 }
1543
1544 dg-init
1545 mips-dg-init
1546 gcc-dg-runtest [lsort [glob -nocomplain $srcdir/$subdir/*.c]] \
1547     "" "-DNOMIPS16=__attribute__((nomips16)) -DNOMICROMIPS=__attribute__((nomicromips)) -DNOCOMPRESSION=__attribute__((nocompression))"
1548 mips-dg-finish
1549 dg-finish