lisp/muse-project.el

   1 ;;; muse-project.el --- handle Muse projects
   2
   3 ;; Copyright (C) 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5 ;; This file is part of Emacs Muse.  It is not part of GNU Emacs.
   6
   7 ;; Emacs Muse is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published
   9 ;; by the Free Software Foundation; either version 2, or (at your
  10 ;; option) any later version.
  11
  12 ;; Emacs Muse is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Emacs Muse; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  20 ;; Boston, MA 02110-1301, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Contributors:
  25
  26 ;;; Code:
  27
  28 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  29 ;;
  30 ;; Muse Project Maintainance
  31 ;;
  32 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  33
  34 (require 'muse)
  35 (require 'muse-publish)
  36 (require 'cus-edit)
  37
  38 (defgroup muse-project nil
  39   "Options controlling the behavior of Muse project handling."
  40   :group 'muse)
  41
  42 (defcustom muse-before-project-publish-hook nil
  43   "A hook run before a project is published.
  44 Each function is passed the project object, a cons with the format
  45   (PROJNAME . SETTINGS)"
  46   :type 'hook
  47   :group 'muse-project)
  48
  49 (defcustom muse-after-project-publish-hook nil
  50   "A hook run after a project is published.
  51 Each function is passed the project object, a cons with the format
  52   (PROJNAME . SETTINGS)"
  53   :type 'hook
  54   :group 'muse-project)
  55
  56 (defvar muse-project-alist-using-customize nil
  57   "Used internally by Muse to indicate whether `muse-project-alist'
  58 has been modified via the customize interface.")
  59 (make-variable-buffer-local 'muse-project-alist-using-customize)
  60
  61 (defmacro with-muse-project (project &rest body)
  62   `(progn
  63      (unless (muse-project ,project)
  64        (error "Can't find project %s" ,project))
  65      (with-temp-buffer
  66        (muse-mode)
  67        (setq muse-current-project (muse-project ,project))
  68        (muse-project-set-variables)
  69        ,@body)))
  70
  71 (put 'with-muse-project 'lisp-indent-function 0)
  72 (put 'with-muse-project 'edebug-form-spec '(sexp body))
  73
  74 (defun muse-project-alist-get (sym)
  75   "Turn `muse-project-alist' into something we can customize easily."
  76   (when (boundp sym)
  77     (setq muse-project-alist-using-customize t)
  78     (let* ((val (copy-alist (symbol-value sym)))
  79            (head val))
  80       (while val
  81         (let ((head (car (cdar val)))
  82               res)
  83           ;; Turn settings of first part into cons cells, symbol->string
  84           (while head
  85             (cond ((stringp (car head))
  86                    (add-to-list 'res (car head) t)
  87                    (setq head (cdr head)))
  88                   ((symbolp (car head))
  89                    (add-to-list 'res (list (symbol-name (car head))
  90                                            (cadr head)) t)
  91                    (setq head (cddr head)))
  92                   (t
  93                    (setq head (cdr head)))))
  94           (setcdr (car val) (cons res (cdr (cdar val)))))
  95         (let ((styles (cdar val)))
  96           ;; Symbol->string in every style
  97           (while (cdr styles)
  98             (let ((head (cadr styles))
  99                   res)
 100               (while (consp head)
 101                 (setq res (plist-put res (symbol-name (car head))
 102                                      (cadr head)))
 103                 (setq head (cddr head)))
 104               (setcdr styles (cons res (cddr styles))))
 105             (setq styles (cdr styles))))
 106         (setq val (cdr val)))
 107       head)))
 108
 109 (defun muse-project-alist-set (sym val)
 110   "Turn customized version of `muse-project-alist' into something
 111 Muse can make use of."
 112   (set sym val)
 113   (when muse-project-alist-using-customize
 114     ;; Make sure the unescaped version is written to .emacs
 115     (put sym 'saved-value (list (custom-quote val)))
 116     ;; Perform unescaping
 117     (while val
 118       (let ((head (car (cdar val)))
 119             res)
 120         ;; Turn cons cells into flat list, string->symbol
 121         (while head
 122           (cond ((stringp (car head))
 123                  (add-to-list 'res (car head) t))
 124                 ((consp (car head))
 125                  (add-to-list 'res (intern (caar head)) t)
 126                  (add-to-list 'res (car (cdar head)) t)))
 127           (setq head (cdr head)))
 128         (setcdr (car val) (cons res (cdr (cdar val)))))
 129       (let ((styles (cdar val)))
 130         ;; String->symbol in every style
 131         (while (cdr styles)
 132           (let ((head (cadr styles))
 133                 res)
 134             (while (consp head)
 135               (setq res (plist-put res (intern (car head))
 136                                    (cadr head)))
 137               (setq head (cddr head)))
 138             (setcdr styles (cons res (cddr styles))))
 139           (setq styles (cdr styles))))
 140       (setq val (cdr val)))))
 141
 142 (define-widget 'muse-project 'default
 143   "A widget that defines a Muse project."
 144   :format "\n%v"
 145   :value-create 'muse-widget-type-value-create
 146   :value-get 'muse-widget-child-value-get
 147   :value-delete 'ignore
 148   :match 'muse-widget-type-match
 149   :type '(cons :format "    %v"
 150                (repeat :tag "Settings" :format "%{%t%}:\n%v%i\n\n"
 151                        (choice
 152                         (string :tag "Directory")
 153                         (list :tag "Book function"
 154                               (const :tag ":book-funcall" ":book-funcall")
 155                               (choice (function)
 156                                       (sexp :tag "Unknown")))
 157                         (list :tag "Book part"
 158                               (const :tag ":book-part" ":book-part")
 159                               (string :tag "Name"))
 160                         (list :tag "Book style"
 161                               (const :tag ":book-style" ":book-style")
 162                               (string :tag "Style"))
 163                         (list :tag "Default file"
 164                               (const :tag ":default" ":default")
 165                               (string :tag "File"))
 166                         (list :tag "End of book"
 167                               (const :tag ":book-end" ":book-end")
 168                               (const t))
 169                         (list :tag "Force publishing"
 170                               (const :tag ":force-publish" ":force-publish")
 171                               (repeat (string :tag "File")))
 172                         (list :tag "Major mode"
 173                               (const :tag ":major-mode" ":major-mode")
 174                               (choice (function :tag "Mode")
 175                                       (sexp :tag "Unknown")))
 176                         (list :tag "New chapter"
 177                               (const :tag ":book-chapter" ":book-chapter")
 178                               (string :tag "Name"))
 179                         (list :tag "No chapters"
 180                               (const :tag ":nochapters" ":nochapters")
 181                               (const t))
 182                         (list :tag "Set variables"
 183                               (const :tag ":set" ":set")
 184                               (repeat (list :inline t
 185                                             (symbol :tag "Variable")
 186                                             (sexp :tag "Setting"))))
 187                         (list :tag "Visit links using"
 188                               (const :tag ":visit-link" ":visit-link")
 189                               (choice (function)
 190                                       (sexp :tag "Unknown")))))
 191                (repeat :tag "Styles" :format "%{%t%}:\n%v%i\n\n"
 192                        (set :tag "Style"
 193                             (list :inline t
 194                                   :tag "Publishing style"
 195                                   (const :tag ":base" ":base")
 196                                   (string :tag "Style"))
 197                             (list :inline t
 198                                   :tag "Base URL"
 199                                   (const :tag ":base-url" ":base-url")
 200                                   (string :tag "URL"))
 201                             (list :inline t
 202                                   :tag "Exclude matching"
 203                                   (const :tag ":exclude" ":exclude")
 204                                   (regexp))
 205                             (list :inline t
 206                                   :tag "Include matching"
 207                                   (const :tag ":include" ":include")
 208                                   (regexp))
 209                             (list :inline t
 210                                   :tag "Timestamps file"
 211                                   (const :tag ":timestamps" ":timestamps")
 212                                   (file))
 213                             (list :inline t
 214                                   :tag "Path"
 215                                   (const :tag ":path" ":path")
 216                                   (string :tag "Path"))))))
 217
 218 (defcustom muse-project-alist nil
 219   "An alist of Muse projects.
 220 A project defines a fileset, and a list of custom attributes for use
 221 when publishing files in that project."
 222   :type '(choice (const :tag "No projects defined." nil)
 223                  (repeat (cons :format "%{%t%}:\n\n%v"
 224                                :tag "Project" :indent 4
 225                                (string :tag "Project name")
 226                                muse-project))
 227                  (sexp :tag "Cannot parse expression"))
 228   :get 'muse-project-alist-get
 229   :set 'muse-project-alist-set
 230   :group 'muse-project)
 231
 232 ;; Make it easier to specify a muse-project-alist entry
 233
 234 (defcustom muse-project-ignore-regexp
 235   (concat "\\`\\(#.*#\\|.*,v\\|.*~\\|\\.\\.?\\|\\.#.*\\|,.*\\)\\'\\|"
 236           "/\\(CVS\\|RCS\\|\\.arch-ids\\|{arch}\\|,.*\\|\\.svn\\|"
 237           "_darcs\\)\\(/\\|\\'\\)")
 238   "A regexp matching files to be ignored in Wiki directories.
 239
 240 You should set case-fold-search to nil before using this regexp
 241 in code."
 242   :type 'regexp
 243   :group 'muse-regexp)
 244
 245 (defun muse-project-recurse-directory (base)
 246   "Recusively retrieve all of the directories underneath BASE.
 247 A list of these directories is returned.
 248 Directories starting with \".\" will be ignored, as well as those
 249 which match `muse-project-ignore-regexp'."
 250   (let ((case-fold-search nil)
 251         list dir)
 252     (when (and (file-directory-p base)
 253                (not (string-match muse-project-ignore-regexp base)))
 254       (dolist (file (directory-files base t "^[^.]"))
 255         (when (and (file-directory-p file)
 256                    (not (string-match muse-project-ignore-regexp file)))
 257           (setq dir (file-name-nondirectory file))
 258           (push dir list)
 259           (nconc list (mapcar #'(lambda (item)
 260                                   (concat dir "/" item))
 261                               (muse-project-recurse-directory file)))))
 262       list)))
 263
 264 (defun muse-project-alist-styles (entry-dir output-dir style)
 265   "Return a list of styles to use in a `muse-project-alist' entry.
 266 ENTRY-DIR is the top-level directory of the project.
 267 OUTPUT-DIR is where Muse files are published, keeping directory structure.
 268 STYLE is the publishing style to use.
 269
 270 For an example of the use of this function, see
 271 `examples/mwolson/muse-init.el' from the Muse distribution."
 272   (cons `(:base ,style :path ,(expand-file-name output-dir)
 273                 :include ,(concat "/" (file-name-nondirectory entry-dir)
 274                                   "/[^/]+$"))
 275         (mapcar (lambda (dir)
 276                   `(:base ,style
 277                           :path ,(expand-file-name dir output-dir)
 278                           :include ,(concat "/" dir "/[^/]+$")))
 279                 (muse-project-recurse-directory entry-dir))))
 280
 281 (defun muse-project-alist-dirs (entry-dir)
 282   "Return a list of directories to use in a `muse-project-alist' entry.
 283 ENTRY-DIR is the top-level directory of the project.
 284
 285 For an example of the use of this function, see
 286 `examples/mwolson/muse-init.el' from the Muse distribution."
 287   (cons (expand-file-name entry-dir)
 288         (mapcar (lambda (dir) (expand-file-name dir entry-dir))
 289                 (muse-project-recurse-directory entry-dir))))
 290
 291 ;; Constructing the file-alist
 292
 293 (defvar muse-project-file-alist nil
 294   "This variable is automagically constructed as needed.")
 295
 296 (defvar muse-project-file-alist-hook nil
 297   "Functions that are to be exectuted immediately after updating
 298 `muse-project-file-alist'.")
 299
 300 (defvar muse-current-project nil
 301   "Project we are currently visiting.")
 302 (make-variable-buffer-local 'muse-current-project)
 303
 304 (defsubst muse-project (&optional project)
 305   "Resolve the given PROJECT into a full Muse project, if it is a string."
 306   (if (null project)
 307       (or muse-current-project
 308           (muse-project-of-file))
 309     (if (stringp project)
 310         (assoc project muse-project-alist)
 311       (muse-assert (consp project))
 312       project)))
 313
 314 (defun muse-project-page-file (page project &optional no-check-p)
 315   "Return a filename if PAGE exists within the given Muse PROJECT."
 316   (setq project (muse-project project))
 317   (let ((dir (file-name-directory page)))
 318     (when dir (setq page (file-name-nondirectory page)))
 319     (let ((files (muse-collect-alist
 320                   (muse-project-file-alist project no-check-p)
 321                   page))
 322           (matches nil))
 323       (if dir
 324           (save-match-data
 325             (dolist (file files)
 326               (setq matches (cons (cons (string-match
 327                                          (concat (regexp-quote dir) "\\'")
 328                                          (file-name-directory (cdr file)))
 329                                         (cdr file))
 330                                   matches)))
 331             (car (muse-sort-by-rating files)))
 332         (dolist (file files)
 333           (setq matches (cons (cons (length (cdr file)) (cdr file))
 334                               matches)))
 335         (car (muse-sort-by-rating matches '<))))))
 336
 337 (defun muse-project-private-p (file)
 338   "Return non-nil if NAME is a private page with PROJECT."
 339   (unless muse-under-windows-p
 340     (setq file (file-truename file))
 341     (if (file-attributes file)  ; don't publish if no attributes exist
 342         (or (when (eq ?- (aref (nth 8 (file-attributes
 343                                        (file-name-directory file))) 7))
 344               (message (concat
 345                         "The " (file-name-directory file)
 346                         " directory must be readable by others"
 347                         " in order for its contents to be published.")))
 348             (eq ?- (aref (nth 8 (file-attributes file)) 7)))
 349       t)))
 350
 351 (defun muse-project-file-entries (path)
 352   (let* ((names (list t))
 353          (lnames names)
 354          (case-fold-search nil))
 355     (cond
 356      ((file-directory-p path)
 357       (dolist (file (directory-files
 358                      path t (when (and muse-file-extension
 359                                        (not (string= muse-file-extension "")))
 360                               (concat "." muse-file-extension "\\'"))))
 361         (unless (or (string-match muse-project-ignore-regexp file)
 362                     (file-directory-p file))
 363           (setcdr lnames
 364                   (cons (cons (muse-page-name file) file) nil))
 365           (setq lnames (cdr lnames)))))
 366      ((file-readable-p path)
 367       (setcdr lnames
 368               (cons (cons (muse-page-name path) path) nil))
 369       (setq lnames (cdr lnames)))
 370      (t                                 ; regexp
 371       (muse-assert (file-name-directory path))
 372       (dolist (file (directory-files
 373                      (file-name-directory path) t
 374                      (file-name-nondirectory path)))
 375         (unless (string-match muse-project-ignore-regexp file)
 376           (setcdr lnames
 377                   (cons (cons (muse-page-name file) file) nil))
 378           (setq lnames (cdr lnames))))))
 379     (cdr names)))
 380
 381 (defvar muse-updating-file-alist-p nil
 382   "Make sure that recursive calls to `muse-project-file-alist' are bounded.")
 383
 384 (defun muse-project-file-alist (&optional project no-check-p)
 385   "Return member filenames for the given Muse PROJECT.
 386 On UNIX, this list is only updated if one of the directories'
 387 contents have changed.  On Windows, it is always reread from
 388 disk."
 389   (setq project (muse-project project))
 390   (let* ((file-alist (assoc (car project) muse-project-file-alist))
 391          (last-mod (cdr (cdr file-alist))))
 392     ;; Determine the last modified of any directory mentioned in the
 393     ;; project's pattern list
 394     (unless (or muse-under-windows-p no-check-p)
 395       (let ((pats (cadr project)))
 396         (while pats
 397           (if (symbolp (car pats))
 398               (setq pats (cddr pats))
 399             (let* ((fnd (file-name-directory (car pats)))
 400                    (dir (cond ((file-directory-p (car pats))
 401                                (car pats))
 402                               ((and (not (file-readable-p (car pats)))
 403                                     fnd
 404                                     (file-directory-p fnd))
 405                                fnd))))
 406               (when dir
 407                 (let ((mod-time (nth 5 (file-attributes dir))))
 408                   (when (or (null last-mod)
 409                             (and mod-time
 410                                  (muse-time-less-p last-mod mod-time)))
 411                     (setq last-mod mod-time)))))
 412             (setq pats (cdr pats))))))
 413     ;; Either return the currently known list, or read it again from
 414     ;; disk
 415     (if (or (and no-check-p (cadr file-alist))
 416             muse-updating-file-alist-p
 417             (not (or muse-under-windows-p
 418                      (null (cddr file-alist))
 419                      (null last-mod)
 420                      (muse-time-less-p (cddr file-alist) last-mod))))
 421         (cadr file-alist)
 422       (if file-alist
 423           (setcdr (cdr file-alist) last-mod)
 424         (setq file-alist (cons (car project) (cons nil last-mod))
 425               muse-project-file-alist
 426               (cons file-alist muse-project-file-alist)))
 427       ;; Read in all of the file entries
 428       (let ((muse-updating-file-alist-p t))
 429         (prog1
 430             (save-match-data
 431               (setcar
 432                (cdr file-alist)
 433                (let* ((names (list t))
 434                       (pats (cadr project)))
 435                  (while pats
 436                    (if (symbolp (car pats))
 437                        (setq pats (cddr pats))
 438                      (nconc names (muse-project-file-entries (car pats)))
 439                      (setq pats (cdr pats))))
 440                  (cdr names))))
 441           (run-hooks 'muse-project-file-alist-hook))))))
 442
 443 (defun muse-project-of-file (&optional pathname)
 444   "Determine which project the given PATHNAME relates to.
 445 If PATHNAME is nil, the current buffer's filename is used."
 446   (if (and (null pathname) muse-current-project)
 447       muse-current-project
 448     (unless pathname (setq pathname (muse-current-file)))
 449     (save-match-data
 450       (when (and (stringp pathname)
 451                  (not (string= pathname ""))
 452                  (not (let ((case-fold-search nil))
 453                         (string-match muse-project-ignore-regexp pathname))))
 454         (let* ((file (file-truename pathname))
 455                (dir  (file-name-directory file))
 456                (project-entry muse-project-alist)
 457                found)
 458           (while (and project-entry (not found))
 459             (let ((pats (car (cdar project-entry))))
 460               (while (and pats (not found))
 461                 (if (symbolp (car pats))
 462                     (setq pats (cddr pats))
 463                   (let ((truename (file-truename (car pats))))
 464                     (if (or (string= truename file)
 465                             (string= truename dir)
 466                             (string-match (regexp-quote truename) file))
 467                         (setq found (car project-entry))))
 468                   (setq pats (cdr pats))))
 469               (setq project-entry (cdr project-entry))))
 470           found)))))
 471
 472 (defun muse-project-after-save-hook ()
 473   "Update Muse's file-alist if we are saving a Muse file."
 474   (let ((project (muse-project-of-file)))
 475     (when project
 476       (muse-project-file-alist project))))
 477
 478 (add-hook 'after-save-hook 'muse-project-after-save-hook)
 479
 480 (defun muse-read-project (prompt &optional no-check-p no-assume)
 481   "Read a project name from the minibuffer, if it can't be figured
 482   out."
 483   (if (null muse-project-alist)
 484       (error "There are no Muse projects defined; see `muse-project-alist'.")
 485     (or (unless no-check-p
 486           (muse-project-of-file))
 487         (if (and (not no-assume)
 488                  (= 1 (length muse-project-alist)))
 489             (car muse-project-alist)
 490           (assoc (completing-read prompt muse-project-alist)
 491                  muse-project-alist)))))
 492
 493 (defvar muse-project-page-history nil)
 494
 495 (defun muse-read-project-file (project prompt &optional default)
 496   (let ((name (completing-read prompt (muse-project-file-alist project)
 497                                nil nil nil 'muse-project-page-history
 498                                default)))
 499     (cons name (muse-project-page-file name project))))
 500
 501 ;;;###autoload
 502 (defun muse-project-find-file (name project &optional command directory)
 503   "Open the Muse page given by NAME in PROJECT.
 504 If COMMAND is non-nil, it is the function used to visit the file.
 505 If DIRECTORY is non-nil, it is the directory in which the page
 506 will be created if it does not already exist.  Otherwise, the
 507 first directory within the project's fileset is used."
 508   (interactive
 509    (let* ((project (muse-read-project "Find in project: "
 510                                       current-prefix-arg))
 511           (default (muse-get-keyword :default (cadr project)))
 512           (entry (muse-read-project-file
 513                   project (if default
 514                               (format "Find page: (default: %s) "
 515                                       default)
 516                             "Find page: ")
 517                   default)))
 518      (list entry project)))
 519   (setq project (muse-project project))
 520   (let ((project-name (car project)))
 521     (unless (interactive-p)
 522       (setq project (muse-project project)
 523             name (cons name (muse-project-page-file name project))))
 524     ;; If we're given a relative or absolute filename, open it as-is
 525     (if (and (car name)
 526              (save-match-data
 527                (or (string-match muse-file-regexp (car name))
 528                    (string-match muse-image-regexp (car name)))))
 529         (setcdr name (car name))
 530       ;; At this point, name is (PAGE . FILE).
 531       (unless (cdr name)
 532         (let ((pats (cadr project)))
 533           (while (and pats (null directory))
 534             (if (symbolp (car pats))
 535                 (setq pats (cddr pats))
 536               (if (file-directory-p (car pats))
 537                   (setq directory (car pats) pats nil)
 538                 (setq pats (cdr pats))))))
 539         (when directory
 540           (let ((filename (expand-file-name
 541                            (if (and muse-file-extension
 542                                     (not (string= muse-file-extension "")))
 543                                (concat (car name) "." muse-file-extension)
 544                              (car name))
 545                            directory)))
 546             (unless (file-exists-p directory)
 547               (make-directory directory t))
 548             (setcdr name filename)))))
 549     ;; Open the file
 550     (if (cdr name)
 551         (funcall (or command 'find-file) (cdr name))
 552       (error "There is no page %s in project %s."
 553              (car name) project-name))))
 554
 555 (defun muse-project-choose-style (closure test styles)
 556   "Run TEST on STYLES and return first style where TEST yields non-nil.
 557 TEST should take two arguments.  The first is CLOSURE, which is
 558 passed verbatim.  The second if the current style to consider.
 559
 560 If no style passes TEST, return the first style."
 561   (or (catch 'winner
 562         (dolist (style styles)
 563           (when (funcall test closure style)
 564             (throw 'winner style))))
 565       (car styles)))
 566
 567 (defun muse-project-choose-style-by-link-suffix (given-suffix style)
 568   "If the given STYLE has a link-suffix that equals GIVEN-SUFFIX,
 569 return non-nil."
 570   (let ((link-suffix (muse-style-element :link-suffix style)))
 571     (and (stringp link-suffix)
 572          (string= given-suffix link-suffix))))
 573
 574 (defun muse-project-applicable-styles (file styles &optional ignore-regexp)
 575   "Given STYLES, return a list of the ones that are considered for FILE.
 576 The name of a project may be used for STYLES."
 577   (when (stringp styles)
 578     (setq styles (cddr (muse-project styles))))
 579   (when (and file styles)
 580     (let ((used-styles nil))
 581       (dolist (style styles)
 582         (let ((include-regexp (muse-style-element :include style))
 583               (exclude-regexp (muse-style-element :exclude style))
 584               (rating nil))
 585           (when (and (or ignore-regexp
 586                          (and (null include-regexp)
 587                               (null exclude-regexp))
 588                          (if include-regexp
 589                              (setq rating (string-match include-regexp file))
 590                            (not (string-match exclude-regexp file))))
 591                      (or (not (file-exists-p file))
 592                          (not (muse-project-private-p file))))
 593             (setq used-styles (cons (cons rating style) used-styles)))))
 594       (muse-sort-by-rating (nreverse used-styles)))))
 595
 596 (defun muse-project-resolve-link (page local-style remote-styles)
 597   "Return a published relative link from the output path of one file
 598 to another file.
 599
 600 The best match for PAGE is determined by comparing the link
 601 suffix of the given potential local style and that of the remote
 602 styles.
 603
 604 The remote styles are usually populated by
 605 `muse-project-applicable-styles'."
 606   (let ((link-suffix (muse-style-element :link-suffix local-style))
 607         remote-style)
 608     (if (not (stringp link-suffix))
 609         (setq remote-style (car remote-styles))
 610       (setq remote-style (muse-project-choose-style
 611                           link-suffix
 612                           #'muse-project-choose-style-by-link-suffix
 613                           remote-styles)))
 614     (muse-publish-link-file
 615      (if (null remote-style)
 616          page
 617        (let ((prefix (muse-style-element :base-url remote-style)))
 618          (if prefix
 619              (concat prefix page)
 620            (file-relative-name (expand-file-name
 621                                 (file-name-nondirectory page)
 622                                 (muse-style-element :path remote-style))
 623                                (expand-file-name
 624                                 (muse-style-element :path local-style))))))
 625      nil remote-style)))
 626
 627 (defun muse-project-link-page (page)
 628   (let ((project (muse-project-of-file)))
 629     (muse-project-resolve-link page (muse-style)
 630                                (muse-project-applicable-styles
 631                                 (muse-project-page-file page project)
 632                                 (cddr project)))))
 633
 634 (defun muse-project-publish-file (file styles &optional force ignore-regexp)
 635   (setq styles (muse-project-applicable-styles file styles ignore-regexp))
 636   (let (published)
 637     (dolist (style styles)
 638       (let ((output-dir (muse-style-element :path style)))
 639         ;; ensure the publishing location is available
 640         (unless (file-exists-p output-dir)
 641           (message "Creating publishing directory %s" output-dir)
 642           (make-directory output-dir t))
 643         ;; publish the member file!
 644         (if (muse-publish-file file style output-dir force)
 645             (setq published t))))
 646     published))
 647
 648 (defun muse-project-save-buffers (&optional project)
 649   (setq project (muse-project project))
 650   (map-y-or-n-p
 651    (function
 652     (lambda (buffer)
 653       (and (buffer-modified-p buffer)
 654            (not (buffer-base-buffer buffer))
 655            (or (buffer-file-name buffer)
 656                (progn
 657                  (set-buffer buffer)
 658                  (and buffer-offer-save
 659                       (> (buffer-size) 0))))
 660            (with-current-buffer buffer
 661              (let ((proj (muse-project-of-file)))
 662                (and proj (string= (car proj)
 663                                   (car project)))))
 664            (if (buffer-file-name buffer)
 665                (format "Save file %s? "
 666                        (buffer-file-name buffer))
 667              (format "Save buffer %s? "
 668                      (buffer-name buffer))))))
 669    (function
 670     (lambda (buffer)
 671       (set-buffer buffer)
 672       (save-buffer)))
 673    (buffer-list)
 674    '("buffer" "buffers" "save")
 675    (if (boundp 'save-some-buffers-action-alist)
 676        save-some-buffers-action-alist)))
 677
 678 ;;;###autoload
 679 (defun muse-project-publish (project &optional force)
 680   "Publish the pages of PROJECT that need publishing."
 681   (interactive (list (muse-read-project "Publish project: " nil t)
 682                      current-prefix-arg))
 683   (setq project (muse-project project))
 684   (let ((styles (cddr project))
 685         (muse-current-project project)
 686         published)
 687     ;; determine the style from the project, or else ask
 688     (unless styles
 689       (setq styles (list (muse-publish-get-style))))
 690     (unless project
 691       (error "Cannot find a project to publish"))
 692     ;; prompt to save any buffers related to this project
 693     (muse-project-save-buffers project)
 694     ;; run hook before publishing begins
 695     (run-hook-with-args 'muse-before-project-publish-hook project)
 696     ;; publish all files in the project, for each style; the actual
 697     ;; publishing will only happen if the files are newer than the
 698     ;; last published output, or if the file is listed in
 699     ;; :force-publish.  Files in :force-publish will not trigger the
 700     ;; "All pages need to be published" message.
 701     (let ((forced-files (muse-get-keyword :force-publish (cadr project)))
 702           (file-alist (muse-project-file-alist project)))
 703       (dolist (pair file-alist)
 704         (when (muse-project-publish-file (cdr pair) styles force)
 705           (setq forced-files (delete (car pair) forced-files))
 706           (setq published t)))
 707       (dolist (file forced-files)
 708         (muse-project-publish-file (cdr (assoc file file-alist)) styles t)))
 709     ;; run hook after publishing ends
 710     (run-hook-with-args 'muse-after-project-publish-hook project)
 711     ;; notify the user that everything is now done
 712     (if published
 713         (message "All pages in %s have been published." (car project))
 714       (message "No pages in %s need publishing at this time."
 715                (car project)))))
 716
 717 (defun muse-project-batch-publish ()
 718   "Publish Muse files in batch mode."
 719   (let ((muse-batch-publishing-p t)
 720         force)
 721     (if (string= "--force" (or (car command-line-args-left) ""))
 722         (setq force t
 723               command-line-args-left (cdr command-line-args-left)))
 724     (if command-line-args-left
 725         (dolist (project command-line-args-left)
 726           (message "Publishing project %s ..." project)
 727           (muse-project-publish project force))
 728       (message "No projects specified."))))
 729
 730 (eval-when-compile
 731   (put 'make-local-hook 'byte-compile nil))
 732
 733 (defun muse-project-set-variables ()
 734   "Load project-specific variables."
 735   (let ((vars (muse-get-keyword :set (cadr muse-current-project)))
 736         sym custom-set var)
 737     (while vars
 738       (setq sym (car vars))
 739       (setq custom-set (or (get sym 'custom-set) 'set))
 740       (setq var (if (eq (get sym 'custom-type) 'hook)
 741                     (make-local-hook sym)
 742                   (make-local-variable sym)))
 743       (funcall custom-set var (car (cdr vars)))
 744       (setq vars (cdr (cdr vars))))))
 745
 746 (defun muse-project-delete-output-files (project)
 747   (interactive
 748    (list (muse-read-project "Remove all output files for project: " nil t)))
 749   (setq project (muse-project project))
 750   (let ((file-alist (muse-project-file-alist project))
 751         (styles (cddr project))
 752         output-file path)
 753     (dolist (entry file-alist)
 754       (dolist (style styles)
 755         (setq output-file
 756               (and (setq path (muse-style-element :path style))
 757                    (expand-file-name
 758                     (concat (muse-style-element :prefix style)
 759                             (car entry)
 760                             (or (muse-style-element :osuffix style)
 761                                 (muse-style-element :suffix style)))
 762                     path)))
 763         (if output-file
 764             (muse-delete-file-if-exists output-file))))))
 765
 766 (provide 'muse-project)
 767
 768 ;;; muse-project.el ends here