Installer: Early check whether the installation directory is writable
[msysgit.git] / bin / prove
blob470ac0e953e6871223f606cb803ed79eb2d3749c
1 #!/usr/bin/perl
2 eval 'exec /usr/bin/perl -S $0 ${1+"$@"}'
3 if $running_under_some_shell;
4 #!/usr/bin/perl -w
6 use strict;
8 use Test::Harness;
9 use Getopt::Long;
10 use Pod::Usage 1.12;
11 use File::Spec;
13 use vars qw( $VERSION );
14 $VERSION = "1.04";
16 my @ext = ();
17 my $shuffle = 0;
18 my $dry = 0;
19 my $blib = 0;
20 my $lib = 0;
21 my $recurse = 0;
22 my @includes = ();
23 my @switches = ();
25 # Allow cuddling the paths with the -I
26 @ARGV = map { /^(-I)(.+)/ ? ($1,$2) : $_ } @ARGV;
28 # Stick any default switches at the beginning, so they can be overridden
29 # by the command line switches.
30 unshift @ARGV, split( " ", $ENV{PROVE_SWITCHES} ) if defined $ENV{PROVE_SWITCHES};
32 Getopt::Long::Configure( "no_ignore_case" );
33 Getopt::Long::Configure( "bundling" );
34 GetOptions(
35 'b|blib' => \$blib,
36 'd|debug' => \$Test::Harness::debug,
37 'D|dry' => \$dry,
38 'h|help|?' => sub {pod2usage({-verbose => 1}); exit},
39 'H|man' => sub {pod2usage({-verbose => 2}); exit},
40 'I=s@' => \@includes,
41 'l|lib' => \$lib,
42 'r|recurse' => \$recurse,
43 's|shuffle' => \$shuffle,
44 't' => sub { unshift @switches, "-t" }, # Always want -t up front
45 'T' => sub { unshift @switches, "-T" }, # Always want -T up front
46 'timer' => \$Test::Harness::Timer,
47 'v|verbose' => \$Test::Harness::verbose,
48 'V|version' => sub { print_version(); exit; },
49 'ext=s@' => \@ext,
50 ) or exit 1;
52 $ENV{TEST_VERBOSE} = 1 if $Test::Harness::verbose;
54 # Build up extensions regex
55 @ext = map { split /,/ } @ext;
56 s/^\.// foreach @ext;
57 @ext = ("t") unless @ext;
58 my $ext_regex = join( "|", map { quotemeta } @ext );
59 $ext_regex = qr/\.($ext_regex)$/;
61 # Handle blib includes
62 if ( $blib ) {
63 my @blibdirs = blibdirs();
64 if ( @blibdirs ) {
65 unshift @includes, @blibdirs;
66 } else {
67 warn "No blib directories found.\n";
71 # Handle lib includes
72 if ( $lib ) {
73 unshift @includes, "lib";
76 # Build up TH switches
77 push( @switches, map { /\s/ && !/^".*"$/ ? qq["-I$_"] : "-I$_" } @includes );
78 $Test::Harness::Switches = join( " ", @switches );
79 print "# \$Test::Harness::Switches: $Test::Harness::Switches\n" if $Test::Harness::debug;
81 my @tests;
82 @ARGV = File::Spec->curdir unless @ARGV;
83 push( @tests, -d $_ ? all_in( $_ ) : $_ ) for map { glob } @ARGV;
85 if ( @tests ) {
86 shuffle(@tests) if $shuffle;
87 if ( $dry ) {
88 print join( "\n", @tests, "" );
89 } else {
90 print "# ", scalar @tests, " tests to run\n" if $Test::Harness::debug;
91 runtests(@tests);
95 sub all_in {
96 my $start = shift;
98 my @hits = ();
100 local *DH;
101 if ( opendir( DH, $start ) ) {
102 my @files = sort readdir DH;
103 closedir DH;
104 for my $file ( @files ) {
105 next if $file eq File::Spec->updir || $file eq File::Spec->curdir;
106 next if $file eq ".svn";
107 next if $file eq "CVS";
109 my $currfile = File::Spec->catfile( $start, $file );
110 if ( -d $currfile ) {
111 push( @hits, all_in( $currfile ) ) if $recurse;
112 } else {
113 push( @hits, $currfile ) if $currfile =~ $ext_regex;
116 } else {
117 warn "$start: $!\n";
120 return @hits;
123 sub shuffle {
124 # Fisher-Yates shuffle
125 my $i = @_;
126 while ($i) {
127 my $j = rand $i--;
128 @_[$i, $j] = @_[$j, $i];
132 sub print_version {
133 printf( "prove v%s, using Test::Harness v%s and Perl v%vd\n",
134 $VERSION, $Test::Harness::VERSION, $^V );
137 # Stolen directly from blib.pm
138 sub blibdirs {
139 my $dir = File::Spec->curdir;
140 if ($^O eq 'VMS') {
141 ($dir = VMS::Filespec::unixify($dir)) =~ s-/\z--;
143 my $archdir = "arch";
144 if ( $^O eq "MacOS" ) {
145 # Double up the MP::A so that it's not used only once.
146 $archdir = $MacPerl::Architecture = $MacPerl::Architecture;
149 my $i = 5;
150 while ($i--) {
151 my $blib = File::Spec->catdir( $dir, "blib" );
152 my $blib_lib = File::Spec->catdir( $blib, "lib" );
153 my $blib_arch = File::Spec->catdir( $blib, $archdir );
155 if ( -d $blib && -d $blib_arch && -d $blib_lib ) {
156 return ($blib_arch,$blib_lib);
158 $dir = File::Spec->catdir($dir, File::Spec->updir);
160 warn "$0: Cannot find blib\n";
161 return;
164 __END__
166 =head1 NAME
168 prove -- A command-line tool for running tests against Test::Harness
170 =head1 SYNOPSIS
172 prove [options] [files/directories]
174 Options:
176 -b, --blib Adds blib/lib to the path for your tests, a la "use blib".
177 -d, --debug Includes extra debugging information.
178 -D, --dry Dry run: Show the tests to run, but don't run them.
179 --ext=x Extensions (defaults to .t)
180 -h, --help Display this help
181 -H, --man Longer manpage for prove
182 -I Add libraries to @INC, as Perl's -I
183 -l, --lib Add lib to the path for your tests.
184 -r, --recurse Recursively descend into directories.
185 -s, --shuffle Run the tests in a random order.
186 -T Enable tainting checks
187 -t Enable tainting warnings
188 --timer Print elapsed time after each test file
189 -v, --verbose Display standard output of test scripts while running them.
190 -V, --version Display version info
192 Single-character options may be stacked. Default options may be set by
193 specifying the PROVE_SWITCHES environment variable.
195 =head1 OVERVIEW
197 F<prove> is a command-line interface to the test-running functionality
198 of C<Test::Harness>. With no arguments, it will run all tests in the
199 current directory.
201 Shell metacharacters may be used with command lines options and will be exanded
202 via C<glob>.
204 =head1 PROVE VS. "MAKE TEST"
206 F<prove> has a number of advantages over C<make test> when doing development.
208 =over 4
210 =item * F<prove> is designed as a development tool
212 Perl users typically run the test harness through a makefile via
213 C<make test>. That's fine for module distributions, but it's
214 suboptimal for a test/code/debug development cycle.
216 =item * F<prove> is granular
218 F<prove> lets your run against only the files you want to check.
219 Running C<prove t/live/ t/master.t> checks every F<*.t> in F<t/live>,
220 plus F<t/master.t>.
222 =item * F<prove> has an easy verbose mode
224 F<prove> has a C<-v> option to see the raw output from the tests.
225 To do this with C<make test>, you must set C<HARNESS_VERBOSE=1> in
226 the environment.
228 =item * F<prove> can run under taint mode
230 F<prove>'s C<-T> runs your tests under C<perl -T>, and C<-t> runs them
231 under C<perl -t>.
233 =item * F<prove> can shuffle tests
235 You can use F<prove>'s C<--shuffle> option to try to excite problems
236 that don't show up when tests are run in the same order every time.
238 =item * F<prove> doesn't rely on a make tool
240 Not everyone wants to write a makefile, or use L<ExtUtils::MakeMaker>
241 to do so. F<prove> has no external dependencies.
243 =item * Not everything is a module
245 More and more users are using Perl's testing tools outside the
246 context of a module distribution, and may not even use a makefile
247 at all.
249 =back
251 =head1 COMMAND LINE OPTIONS
253 =head2 -b, --blib
255 Adds blib/lib to the path for your tests, a la "use blib".
257 =head2 -d, --debug
259 Include debug information about how F<prove> is being run. This
260 option doesn't show the output from the test scripts. That's handled
261 by -v,--verbose.
263 =head2 -D, --dry
265 Dry run: Show the tests to run, but don't run them.
267 =head2 --ext=extension
269 Specify extensions of the test files to run. By default, these are .t,
270 but you may have other non-.t test files, most likely .sh shell scripts.
271 The --ext is repeatable.
273 =head2 -I
275 Add libraries to @INC, as Perl's -I.
277 =head2 -l, --lib
279 Add C<lib> to @INC. Equivalent to C<-Ilib>.
281 =head2 -r, --recurse
283 Descends into subdirectories of any directories specified, looking for tests.
285 =head2 -s, --shuffle
287 Sometimes tests are accidentally dependent on tests that have been
288 run before. This switch will shuffle the tests to be run prior to
289 running them, thus ensuring that hidden dependencies in the test
290 order are likely to be revealed. The author hopes the run the
291 algorithm on the preceding sentence to see if he can produce something
292 slightly less awkward.
294 =head2 -t
296 Runs test programs under perl's -t taint warning mode.
298 =head2 -T
300 Runs test programs under perl's -T taint mode.
302 =head2 --timer
304 Print elapsed time after each test file
306 =head2 -v, --verbose
308 Display standard output of test scripts while running them. Also sets
309 TEST_VERBOSE in case your tests rely on them.
311 =head2 -V, --version
313 Display version info.
315 =head1 BUGS
317 Please use the CPAN bug ticketing system at L<http://rt.cpan.org/>.
318 You can also mail bugs, fixes and enhancements to
319 C<< <bug-test-harness@rt.cpan.org> >>.
321 =head1 TODO
323 =over 4
325 =item *
327 Shuffled tests must be recreatable
329 =back
331 =head1 AUTHORS
333 Andy Lester C<< <andy@petdance.com> >>
335 =head1 COPYRIGHT
337 Copyright 2005 by Andy Lester C<< <andy@petdance.com> >>.
339 This program is free software; you can redistribute it and/or
340 modify it under the same terms as Perl itself.
342 See L<http://www.perl.com/perl/misc/Artistic.html>.
344 =cut