MPUI_Setup.nsi

   1 ; ///////////////////////////////////////////////////////////////////////////////
   2 ; // MPlayer for Windows - Install Script
   3 ; // Copyright (C) 2004-2018 LoRd_MuldeR <MuldeR2@GMX.de>
   4 ; //
   5 ; // This program is free software; you can redistribute it and/or modify
   6 ; // it under the terms of the GNU General Public License as published by
   7 ; // the Free Software Foundation; either version 2 of the License, or
   8 ; // (at your option) any later version.
   9 ; //
  10 ; // This program is distributed in the hope that it will be useful,
  11 ; // but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ; // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ; // GNU General Public License for more details.
  14 ; //
  15 ; // You should have received a copy of the GNU General Public License along
  16 ; // with this program; if not, write to the Free Software Foundation, Inc.,
  17 ; // 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18 ; //
  19 ; // http://www.gnu.org/licenses/gpl-2.0.txt
  20 ; ///////////////////////////////////////////////////////////////////////////////
  21
  22
  23 ;--------------------------------------------------------------------------------
  24 ; BASIC DEFINES
  25 ;--------------------------------------------------------------------------------
  26
  27 !ifndef NSIS_UNICODE
  28   !error "NSIS_UNICODE is undefined, please compile with Unicode NSIS !!!"
  29 !endif
  30
  31 !ifndef MPLAYER_BUILDNO
  32   !error "MPLAYER_BUILDNO is not defined !!!"
  33 !endif
  34
  35 !ifndef MPLAYER_REVISION
  36   !error "MPLAYER_REVISION is not defined !!!"
  37 !endif
  38
  39 !ifndef MPLAYER_DATE
  40   !error "MPLAYER_DATE is not defined !!!"
  41 !endif
  42
  43 !ifndef SMPLAYER_VERSION
  44   !error "SMPLAYER_VERSION is not defined !!!"
  45 !endif
  46
  47 !ifndef MPUI_VERSION
  48   !error "MPUI_VERSION is not defined !!!"
  49 !endif
  50
  51 !ifndef CODECS_DATE
  52   !error "CODECS_DATE is not defined !!!"
  53 !endif
  54
  55 !ifndef MPLAYER_OUTFILE
  56   !error "MPLAYER_OUTFILE is not defined !!!"
  57 !endif
  58
  59 !ifndef UPX_PATH
  60   !error "UPX_PATH is not defined !!!"
  61 !endif
  62
  63 ; UUID
  64 !define MPlayerRegPath "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{97D341C8-B0D1-4E4A-A49A-C30B52F168E9}"
  65
  66 ; Web-Site
  67 !define MPlayerWebSite "http://mplayerhq.hu/"
  68
  69
  70 ;--------------------------------------------------------------------------------
  71 ; INSTALLER ATTRIBUTES
  72 ;--------------------------------------------------------------------------------
  73
  74 RequestExecutionLevel admin
  75 ShowInstDetails show
  76 ShowUninstDetails show
  77
  78 Name "$(MPLAYER_LANG_MPLAYER_WIN32) ${MPLAYER_DATE} (Build #${MPLAYER_BUILDNO})"
  79 Caption "$(MPLAYER_LANG_MPLAYER_WIN32) ${MPLAYER_DATE} (Build #${MPLAYER_BUILDNO})"
  80 BrandingText "MPlayer-Win32 (Build #${MPLAYER_BUILDNO})"
  81 InstallDir "$PROGRAMFILES\MPlayer for Windows"
  82 InstallDirRegKey HKLM "${MPlayerRegPath}" "InstallLocation"
  83 OutFile "${MPLAYER_OUTFILE}"
  84
  85
  86 ;--------------------------------------------------------------------------------
  87 ; COMPRESSOR
  88 ;--------------------------------------------------------------------------------
  89
  90 SetCompressor /SOLID /FINAL LZMA
  91 SetCompressorDictSize 112
  92
  93 !tempfile PACKHDRTEMP
  94 !packhdr "${PACKHDRTEMP}" '"Utils\MT.exe" -manifest "Resources\Setup.manifest" -outputresource:"${PACKHDRTEMP};1"'
  95
  96 !packhdr "$%TEMP%\exehead.tmp" '"${UPX_PATH}\upx.exe" --brute "$%TEMP%\exehead.tmp"'
  97
  98
  99 ;--------------------------------------------------------------------------------
 100 ; RESERVE FILES
 101 ;--------------------------------------------------------------------------------
 102
 103 ReserveFile "${NSISDIR}\Plugins\Aero.dll"
 104 ReserveFile "${NSISDIR}\Plugins\Banner.dll"
 105 ReserveFile "${NSISDIR}\Plugins\CPUFeatures.dll"
 106 ReserveFile "${NSISDIR}\Plugins\InstallOptions.dll"
 107 ReserveFile "${NSISDIR}\Plugins\LangDLL.dll"
 108 ReserveFile "${NSISDIR}\Plugins\LockedList.dll"
 109 ReserveFile "${NSISDIR}\Plugins\LockedList64.dll"
 110 ReserveFile "${NSISDIR}\Plugins\nsDialogs.dll"
 111 ReserveFile "${NSISDIR}\Plugins\nsExec.dll"
 112 ReserveFile "${NSISDIR}\Plugins\StartMenu.dll"
 113 ReserveFile "${NSISDIR}\Plugins\StdUtils.dll"
 114 ReserveFile "${NSISDIR}\Plugins\System.dll"
 115 ReserveFile "${NSISDIR}\Plugins\UserInfo.dll"
 116 ReserveFile "Dialogs\Page_CPU.ini"
 117 ReserveFile "Resources\Splash.gif"
 118
 119
 120 ;--------------------------------------------------------------------------------
 121 ; INCLUDES
 122 ;--------------------------------------------------------------------------------
 123
 124 !include `MUI2.nsh`
 125 !include `InstallOptions.nsh`
 126 !include `WinVer.nsh`
 127 !include `x64.nsh`
 128 !include `StrFunc.nsh`
 129 !include `StdUtils.nsh`
 130 !include `CPUFeatures.nsh`
 131 !include `MPUI_Common.nsh`
 132
 133 ; Enable functions
 134 ${StrRep}
 135
 136
 137 ;--------------------------------------------------------------------------------
 138 ; GLOBAL VARIABLES
 139 ;--------------------------------------------------------------------------------
 140
 141 Var StartMenuFolder
 142 Var DetectedCPUType
 143 Var DetectedCPUCores
 144 Var SelectedCPUType
 145 Var SelectedTweaks
 146 Var NotUpdateInstall
 147
 148
 149 ;--------------------------------------------------------------------------------
 150 ; VERSION INFO
 151 ;--------------------------------------------------------------------------------
 152
 153 !searchreplace PRODUCT_VERSION_DATE "${MPLAYER_DATE}" "-" "."
 154 VIProductVersion "${PRODUCT_VERSION_DATE}.${MPLAYER_BUILDNO}"
 155
 156 VIAddVersionKey "Author" "LoRd_MuldeR <mulder2@gmx.de>"
 157 VIAddVersionKey "Comments" "This program is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation; either version 2 of the License, or (at your option) any later version."
 158 VIAddVersionKey "CompanyName" "Free Software Foundation"
 159 VIAddVersionKey "FileDescription" "MPlayer for Windows (Build #${MPLAYER_BUILDNO})"
 160 VIAddVersionKey "FileVersion" "${PRODUCT_VERSION_DATE}.${MPLAYER_BUILDNO}"
 161 VIAddVersionKey "LegalCopyright" "Copyright 2000-2018 The MPlayer Project"
 162 VIAddVersionKey "LegalTrademarks" "GNU"
 163 VIAddVersionKey "OriginalFilename" "MPUI-Setup.exe"
 164 VIAddVersionKey "ProductName" "MPlayer for Windows"
 165 VIAddVersionKey "ProductVersion" "Build #${MPLAYER_BUILDNO} (${MPLAYER_DATE})"
 166 VIAddVersionKey "Website" "${MPlayerWebSite}"
 167
 168
 169 ;--------------------------------------------------------------------------------
 170 ; MUI2 INTERFACE SETTINGS
 171 ;--------------------------------------------------------------------------------
 172
 173 !define MUI_ABORTWARNING
 174 !define MUI_STARTMENUPAGE_REGISTRY_ROOT HKLM
 175 !define MUI_STARTMENUPAGE_REGISTRY_KEY "${MPlayerRegPath}"
 176 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "StartmenuFolder"
 177 !define MUI_LANGDLL_REGISTRY_ROOT HKLM
 178 !define MUI_LANGDLL_REGISTRY_KEY "${MPlayerRegPath}"
 179 !define MUI_LANGDLL_REGISTRY_VALUENAME "SetupLanguage"
 180 !define MUI_STARTMENUPAGE_DEFAULTFOLDER "MPlayer for Windows"
 181 !define MUI_FINISHPAGE_NOAUTOCLOSE
 182 !define MUI_UNFINISHPAGE_NOAUTOCLOSE
 183 !define MUI_FINISHPAGE_RUN
 184 !define MUI_FINISHPAGE_RUN_FUNCTION RunAppFunction
 185 !define MUI_FINISHPAGE_SHOWREADME
 186 !define MUI_FINISHPAGE_SHOWREADME_FUNCTION ShowReadmeFunction
 187 !define MUI_FINISHPAGE_LINK ${MPlayerWebSite}
 188 !define MUI_FINISHPAGE_LINK_LOCATION ${MPlayerWebSite}
 189 !define MUI_ICON "${NSISDIR}\Contrib\Graphics\Icons\orange-install.ico"
 190 !define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\orange-uninstall.ico"
 191 !define MUI_WELCOMEFINISHPAGE_BITMAP "Artwork\wizard.bmp"
 192 !define MUI_UNWELCOMEFINISHPAGE_BITMAP "Artwork\wizard-un.bmp"
 193 !define MUI_HEADERIMAGE
 194 !define MUI_HEADERIMAGE_BITMAP "Artwork\header.bmp"
 195 !define MUI_HEADERIMAGE_UNBITMAP "Artwork\header-un.bmp"
 196 !define MUI_LANGDLL_ALLLANGUAGES
 197 !define MUI_CUSTOMFUNCTION_GUIINIT MyGuiInit
 198 !define MUI_CUSTOMFUNCTION_UNGUIINIT un.MyGuiInit
 199 !define MUI_LANGDLL_ALWAYSSHOW
 200 !define MUI_COMPONENTSPAGE_SMALLDESC
 201
 202
 203 ;--------------------------------------------------------------------------------
 204 ; MUI2 PAGE SETUP
 205 ;--------------------------------------------------------------------------------
 206
 207 ; Installer
 208 !define MUI_WELCOMEPAGE_TITLE_3LINES
 209 !define MUI_FINISHPAGE_TITLE_3LINES
 210 !insertmacro MUI_PAGE_WELCOME
 211 !insertmacro MUI_PAGE_LICENSE "Docs\License.txt"
 212 !define MUI_PAGE_CUSTOMFUNCTION_SHOW CheckForUpdate
 213 !insertmacro MUI_PAGE_DIRECTORY
 214 !insertmacro  MUI_PAGE_COMPONENTS
 215 !insertmacro MUI_PAGE_STARTMENU Application $StartMenuFolder
 216 Page Custom SelectCPUPage_Show SelectCPUPage_Validate
 217 Page Custom SetTweaksPage_Show
 218 Page Custom LockedListPage_Show
 219 !insertmacro MUI_PAGE_INSTFILES
 220 !insertmacro MUI_PAGE_FINISH
 221
 222 ; Un-Installer
 223 !define MUI_WELCOMEPAGE_TITLE_3LINES
 224 !define MUI_FINISHPAGE_TITLE_3LINES
 225 !insertmacro MUI_UNPAGE_WELCOME
 226 !insertmacro MUI_UNPAGE_CONFIRM
 227 UninstPage Custom un.LockedListPage_Show
 228 !insertmacro MUI_UNPAGE_INSTFILES
 229 !insertmacro MUI_UNPAGE_FINISH
 230
 231
 232 ;--------------------------------------------------------------------------------
 233 ; LANGUAGE
 234 ;--------------------------------------------------------------------------------
 235
 236 !insertmacro MUI_LANGUAGE "English"
 237 !insertmacro MUI_LANGUAGE "German"
 238
 239 ; Translation files
 240 !include "Language\MPUI_EN.nsh"
 241 !include "Language\MPUI_DE.nsh"
 242
 243
 244 ;--------------------------------------------------------------------------------
 245 ; INSTALL TYPES
 246 ;--------------------------------------------------------------------------------
 247
 248 InstType "$(MPLAYER_LANG_INSTTYPE_COMPLETE)"
 249 InstType "$(MPLAYER_LANG_INSTTYPE_MINIMAL)"
 250
 251
 252 ;--------------------------------------------------------------------------------
 253 ; INITIALIZATION
 254 ;--------------------------------------------------------------------------------
 255
 256 Function .onInit
 257         StrCpy $SelectedCPUType 0
 258         StrCpy $DetectedCPUType 0
 259         StrCpy $DetectedCPUCores 0
 260         StrCpy $SelectedTweaks 1
 261         StrCpy $NotUpdateInstall 1
 262
 263         InitPluginsDir
 264
 265         ; --------
 266
 267         System::Call 'kernel32::CreateMutexA(i 0, i 0, t "{B800490C-C100-4B12-9F09-1A54DF063049}") i .r1 ?e'
 268         Pop $0
 269         ${If} $0 <> 0
 270                 MessageBox MB_ICONSTOP|MB_TOPMOST "Oups, the installer is already running!"
 271                 Quit
 272         ${EndIf}
 273
 274         ; --------
 275
 276         # Running on Windows NT family?
 277         ${IfNot} ${IsNT}
 278                 MessageBox MB_TOPMOST|MB_ICONSTOP "Sorry, this application does *not* support Windows 9x or Windows ME!"
 279                 ExecShell "open" "http://windows.microsoft.com/"
 280                 Quit
 281         ${EndIf}
 282
 283         # Running on Windows XP or later?
 284         ${If} ${AtMostWin2000}
 285                 MessageBox MB_TOPMOST|MB_ICONSTOP "Sorry, but your operating system is *not* supported anymore.$\nInstallation will be aborted!$\n$\nThe minimum required platform is Windows XP."
 286                 ExecShell "open" "http://windows.microsoft.com/"
 287                 Quit
 288         ${EndIf}
 289
 290         ; --------
 291
 292         UserInfo::GetAccountType
 293         Pop $0
 294         ${If} $0 != "Admin"
 295                 MessageBox MB_ICONSTOP|MB_TOPMOST "Your system requires administrative permissions in order to install this software."
 296                 SetErrorLevel 740 ;ERROR_ELEVATION_REQUIRED
 297                 Quit
 298         ${EndIf}
 299
 300         ; --------
 301
 302         !insertmacro MUI_LANGDLL_DISPLAY
 303
 304         !insertmacro INSTALLOPTIONS_EXTRACT_AS "Dialogs\Page_CPU.ini"    "Page_CPU.ini"
 305         !insertmacro INSTALLOPTIONS_EXTRACT_AS "Dialogs\Page_Tweaks.ini" "Page_Tweaks.ini"
 306
 307         !ifdef PRE_RELEASE
 308                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OKCANCEL|MB_DEFBUTTON2 "Note: This is an early pre-release version for test only!" IDCANCEL ${||} Quit ${|}
 309         !endif
 310
 311         ; --------
 312
 313         ${IfNot} ${Silent}
 314                 File "/oname=$PLUGINSDIR\Splash.gif" "Resources\Splash.gif"
 315                 newadvsplash::show 3000 1000 500 -1 /NOCANCEL "$PLUGINSDIR\Splash.gif"
 316                 Delete /REBOOTOK "$PLUGINSDIR\Splash.gif"
 317         ${EndIf}
 318 FunctionEnd
 319
 320 Function un.onInit
 321         InitPluginsDir
 322
 323         System::Call 'kernel32::CreateMutexA(i 0, i 0, t "{B800490C-C100-4B12-9F09-1A54DF063049}") i .r1 ?e'
 324         Pop $0
 325         ${If} $0 <> 0
 326                 MessageBox MB_ICONSTOP|MB_TOPMOST "Sorry, the un-installer is already running!"
 327                 Quit
 328         ${EndIf}
 329
 330         ; --------
 331
 332         UserInfo::GetAccountType
 333         Pop $0
 334         ${If} $0 != "Admin"
 335                 MessageBox MB_ICONSTOP|MB_TOPMOST "Your system requires administrative permissions in order to un-install this software."
 336                 SetErrorLevel 740 ;ERROR_ELEVATION_REQUIRED
 337                 Quit
 338         ${EndIf}
 339
 340         ; --------
 341
 342         !insertmacro MUI_LANGDLL_DISPLAY
 343 FunctionEnd
 344
 345
 346 ;--------------------------------------------------------------------------------
 347 ; GUI INITIALIZATION
 348 ;--------------------------------------------------------------------------------
 349
 350 Function MyGuiInit
 351         StrCpy $0 $HWNDPARENT
 352         System::Call "user32::SetWindowPos(i r0, i -1, i 0, i 0, i 0, i 0, i 3)"
 353         Aero::Apply
 354 FunctionEnd
 355
 356 Function un.MyGuiInit
 357         StrCpy $0 $HWNDPARENT
 358         System::Call "user32::SetWindowPos(i r0, i -1, i 0, i 0, i 0, i 0, i 3)"
 359         Aero::Apply
 360 FunctionEnd
 361
 362
 363 ;--------------------------------------------------------------------------------
 364 ; INSTALL SECTIONS
 365 ;--------------------------------------------------------------------------------
 366
 367 Section "-Check Current Version"
 368         ${StdUtils.TestParameter} $0 "Update"
 369         ${IfNot} "$0" == "true"
 370         ${AndIf} ${FileExists} "$INSTDIR\MPlayer.exe"
 371         ${AndIf} ${FileExists} "$INSTDIR\version.tag"
 372                 ReadINIStr $0 "$INSTDIR\version.tag" "mplayer_version" "build_no"
 373                 ${If} $0 > ${MPLAYER_BUILDNO}
 374                         MessageBox MB_OK|MB_ICONEXCLAMATION|MB_TOPMOST "$(MPLAYER_LANG_CAN_NOT_UPDATE)"
 375                         Quit
 376                 ${EndIf}
 377         ${EndIf}
 378 SectionEnd
 379
 380 Section "-Clean Up"
 381         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_CLEAN)"
 382
 383         SetShellVarContext all
 384         SetOutPath "$INSTDIR"
 385
 386         ; Uninstall old version (aka "Setup v1")
 387         ClearErrors
 388         ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{DB9E4EAB-2717-499F-8D56-4CC8A644AB60}" "InstallLocation"
 389         ${IfNot} ${Errors}
 390                 MessageBox MB_ICONINFORMATION|MB_OK "$(MPLAYER_LANG_UNINSTALL_OLDVER)"
 391                 File "/oname=$PLUGINSDIR\Uninstall-V1.exe" "Resources\Uninstall-V1.exe"
 392                 HideWindow
 393                 ExecWait '"$PLUGINSDIR\Uninstall-V1.exe" _?=$0'
 394                 Delete /REBOOTOK "$PLUGINSDIR\Uninstall-V1.exe"
 395                 BringToFront
 396         ${EndIf}
 397
 398         ; Clean registry
 399         DeleteRegKey HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{DB9E4EAB-2717-499F-8D56-4CC8A644AB60}"
 400         DeleteRegKey HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{DB9E4EAB-2717-499F-8D56-4CC8A644AB60}"
 401         DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_UpdateReminder"
 402         DeleteRegValue HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_UpdateReminder"
 403
 404         ; Make sure MPlayer isn't running
 405         ${Do}
 406                 ClearErrors
 407                 Delete "$INSTDIR\MPlayer.exe"
 408                 Delete "$INSTDIR\SMPlayer.exe"
 409                 Delete "$INSTDIR\MPUI.exe"
 410                 ${If} ${Errors}
 411                         ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OKCANCEL "$(MPLAYER_LANG_STILL_RUNNING)" IDCANCEL ${||} Abort ${|}
 412                 ${Else}
 413                         ${Break}
 414                 ${EndIf}
 415         ${Loop}
 416
 417         ; Clean the install folder
 418         Delete "$INSTDIR\*.exe"
 419         Delete "$INSTDIR\*.dll"
 420         Delete "$INSTDIR\*.ini"
 421         Delete "$INSTDIR\*.txt"
 422         Delete "$INSTDIR\*.html"
 423         Delete "$INSTDIR\*.htm"
 424         Delete "$INSTDIR\*.ass"
 425         Delete "$INSTDIR\*.m3u8"
 426         Delete "$INSTDIR\*.tag"
 427
 428         RMDir /r "$INSTDIR\codecs"
 429         RMDir /r "$INSTDIR\fonts"
 430         RMDir /r "$INSTDIR\imageformats"
 431         RMDir /r "$INSTDIR\legal_stuff"
 432         RMDir /r "$INSTDIR\locale"
 433         RMDir /r "$INSTDIR\mplayer"
 434         RMDir /r "$INSTDIR\platforms"
 435         RMDir /r "$INSTDIR\shortcuts"
 436         RMDir /r "$INSTDIR\themes"
 437         RMDir /r "$INSTDIR\translations"
 438
 439         ; Now deal with Virtual Store
 440         ${GetVirtualStorePath} $0 "$INSTDIR"
 441         ${If} ${FileExists} "$0\*.*"
 442                 RMDir /r "$0"
 443         ${EndIf}
 444 SectionEnd
 445
 446 Section "!MPlayer r${MPLAYER_REVISION}" SECID_MPLAYER
 447         SectionIn 1 2 RO
 448         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_MPLAYER)"
 449         SetOutPath "$INSTDIR"
 450
 451         ; Detect
 452         ${If} ${Silent}
 453                 Call DetectCPUType
 454                 StrCpy $SelectedCPUType $DetectedCPUType
 455         ${EndIf}
 456
 457         ; MPlayer.exe
 458         ${Select} $SelectedCPUType
 459                 ${Case} "2"
 460                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): core2"
 461                         File "Builds\MPlayer-core2\MPlayer.exe"
 462                 ${Case} "3"
 463                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): corei7"
 464                         File "Builds\MPlayer-corei7\MPlayer.exe"
 465                 ${Case} "4"
 466                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): k8-sse3"
 467                         File "Builds\MPlayer-k8-sse3\MPlayer.exe"
 468                 ${Case} "5"
 469                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): generic"
 470                         File "Builds\MPlayer-generic\MPlayer.exe"
 471                 ${CaseElse}
 472                         MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OK "Internal error: Invalid CPU type selection detected!"
 473                         Abort
 474         ${EndSelect}
 475
 476         ; Utilities
 477         File ".Compile\Updater.exe"
 478         File "Resources\AppRegGUI.exe"
 479
 480         ; Other MPlayer-related files
 481         File "Builds\MPlayer-generic\*.dll"
 482         ${ExtractSubDir} "Builds\MPlayer-generic" "mplayer"
 483         ${ExtractSubDir} "Builds\MPlayer-generic" "fonts"
 484
 485         ; Documents
 486         SetOutPath "$INSTDIR"
 487         File "GPL.txt"
 488         File "/oname=Manual.html" "Builds\MPlayer-generic\MPlayer.man.html"
 489         File "Docs\Readme.html"
 490         SetOutPath "$INSTDIR\legal_stuff"
 491         File "Docs\legal_stuff\*.txt"
 492
 493         ; Write version tag
 494         ${Do}
 495                 ClearErrors
 496                 Delete "$INSTDIR\version.tag"
 497                 ${If} ${Errors}
 498                         ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OKCANCEL "$(MPLAYER_LANG_TAG_WRITE)" IDCANCEL ${||} Abort ${|}
 499                 ${Else}
 500                         ${Break}
 501                 ${EndIf}
 502         ${Loop}
 503         WriteINIStr "$INSTDIR\version.tag" "mplayer_version" "build_no" "${MPLAYER_BUILDNO}"
 504         WriteINIStr "$INSTDIR\version.tag" "mplayer_version" "pkg_date" "${MPLAYER_DATE}"
 505         SetFileAttributes "$INSTDIR\version.tag" FILE_ATTRIBUTE_READONLY
 506
 507         ; Set file access rights
 508         ${MakePathPublic} "$INSTDIR"
 509         ${MakeFilePublic} "$INSTDIR\mplayer\config"
 510         ${MakeFilePublic} "$INSTDIR\fonts\fonts.conf"
 511 SectionEnd
 512
 513 Section "!MPUI $(MPLAYER_LANG_FRONT_END) v${MPUI_VERSION}" SECID_MPUI
 514         SectionIn 1 2
 515         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_MPUI)"
 516
 517         ; Extract files
 518         SetOutPath "$INSTDIR"
 519         File "MPUI\MPUI.exe"
 520
 521         ; Extract locales
 522         SetOutPath "$INSTDIR\locale"
 523         File "MPUI\locale\*.txt"
 524
 525         ; Set file access rights
 526         ${MakeFilePublic} "$INSTDIR\MPUI.ini"
 527
 528         ; Setup initial config
 529         ClearErrors
 530         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Params" "-vo direct3d -lavdopts threads=$DetectedCPUCores"
 531         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Locale" "$(MPLAYER_LANG_MPUI_DEFAULT_LANGUAGE)"
 532         ${If} ${Errors}
 533                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONSTOP|MB_DEFBUTTON2|MB_OKCANCEL "$(MPLAYER_LANG_CONFIG_MPUI)" IDCANCEL ${||} Abort ${|}
 534         ${EndIf}
 535 SectionEnd
 536
 537 Section "!SMPlayer $(MPLAYER_LANG_FRONT_END) v${SMPLAYER_VERSION}" SECID_SMPLAYER
 538         SectionIn 1
 539         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_SMPLAYER)"
 540
 541         ; SMPlayer program files
 542         SetOutPath "$INSTDIR"
 543         File "SMPlayer\*.exe"
 544         File "SMPlayer\*.dll"
 545
 546         ; Additional SMPlayer files
 547         ${ExtractSubDir} "SMPlayer" "imageformats"
 548         ${ExtractSubDir} "SMPlayer" "platforms"
 549         ${ExtractSubDir} "SMPlayer" "shortcuts"
 550         ${ExtractSubDir} "SMPlayer" "themes"
 551         ${ExtractSubDir} "SMPlayer" "translations"
 552
 553         ; Set file access rights
 554         ${MakeFilePublic} "$INSTDIR\SMPlayer.ini"
 555         ${MakeFilePublic} "$INSTDIR\SMPlayer_files.ini"
 556         ${MakeFilePublic} "$INSTDIR\player_info.ini"
 557         ${MakeFilePublic} "$INSTDIR\playlist.ini"
 558         ${MakeFilePublic} "$INSTDIR\favorites.m3u8"
 559         ${MakeFilePublic} "$INSTDIR\radio.m3u8"
 560         ${MakeFilePublic} "$INSTDIR\tv.m3u8"
 561         ${MakeFilePublic} "$INSTDIR\styles.ass"
 562         ${MakeFilePublic} "$INSTDIR\shortcuts\default.keys"
 563
 564         ; Setup initial config
 565         ${StrRep} $0 "$INSTDIR\MPlayer.exe" "\" "/"
 566         ClearErrors
 567         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "autosync"                      "true"
 568         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "autosync_factor"               "30"
 569         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "config_version"                "5"
 570         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "driver\vo"                     "direct3d"
 571         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "file_settings_method"          "normal"
 572         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "mplayer_bin"                   "$0"
 573         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "osd"                           "1"
 574         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "use_audio_equalizer"           "false"
 575         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "use_scaletempo"                "0"
 576         WriteINIStr "$INSTDIR\SMPlayer.ini" "advanced"       "mplayer_additional_options"    ""
 577         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui"            "gui"                           "DefaultGUI"
 578         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui"            "iconset"                       "Numix-remix"
 579         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui"            "qt_style"                      "WindowsVista"
 580         WriteINIStr "$INSTDIR\SMPlayer.ini" "mplayer_info"   "is_mplayer2"                   "false"
 581         WriteINIStr "$INSTDIR\SMPlayer.ini" "mplayer_info"   "mplayer_detected_version"      "${MPLAYER_REVISION}"
 582         WriteINIStr "$INSTDIR\SMPlayer.ini" "mplayer_info"   "mplayer_user_supplied_version" "-1"
 583         WriteINIStr "$INSTDIR\SMPlayer.ini" "performance"    "frame_drop"                    "true"
 584         WriteINIStr "$INSTDIR\SMPlayer.ini" "performance"    "priority"                      "1"
 585         WriteINIStr "$INSTDIR\SMPlayer.ini" "performance"    "threads"                       "$DetectedCPUCores"
 586         WriteINIStr "$INSTDIR\SMPlayer.ini" "smplayer"       "check_for_new_version"         "false"
 587         WriteINIStr "$INSTDIR\SMPlayer.ini" "smplayer"       "check_if_upgraded"             "false"
 588         WriteINIStr "$INSTDIR\SMPlayer.ini" "update_checker" "enabled"                       "false"
 589
 590         ${If} ${Errors}
 591                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONSTOP|MB_DEFBUTTON2|MB_OKCANCEL "$(MPLAYER_LANG_CONFIG_SMPLAYER)" IDCANCEL ${||} Abort ${|}
 592         ${EndIf}
 593 SectionEnd
 594
 595 Section "!$(MPLAYER_LANG_BIN_CODECS) (${CODECS_DATE})"
 596         SectionIn 1
 597         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_CODECS)"
 598
 599         SetOutPath "$INSTDIR\codecs"
 600
 601         File "Codecs\*.0"
 602         File "Codecs\*.acm"
 603         File "Codecs\*.ax"
 604         File "Codecs\*.dll"
 605         File "Codecs\*.qtx"
 606         File "Codecs\*.so"
 607         File "Codecs\*.vwp"
 608         File "Codecs\*.xa"
 609 SectionEnd
 610
 611 Section "-Write Uninstaller"
 612         ${PrintProgress} "$(MPLAYER_LANG_STATUS_MAKEUNINST)"
 613         WriteUninstaller "$INSTDIR\Uninstall.exe"
 614 SectionEnd
 615
 616 Section "-Create Shortcuts"
 617         !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
 618                 ${PrintProgress} "$(MPLAYER_LANG_STATUS_SHORTCUTS)"
 619                 CreateDirectory "$SMPROGRAMS\$StartMenuFolder"
 620
 621                 SetShellVarContext current
 622                 Delete "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 623                 Delete "$SMPROGRAMS\$StartMenuFolder\*.pif"
 624                 Delete "$SMPROGRAMS\$StartMenuFolder\*.url"
 625
 626                 SetShellVarContext all
 627                 Delete "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 628                 Delete "$SMPROGRAMS\$StartMenuFolder\*.pif"
 629                 Delete "$SMPROGRAMS\$StartMenuFolder\*.url"
 630
 631                 ${If} ${FileExists} "$INSTDIR\MPUI.exe"
 632                         CreateShortCut "$SMPROGRAMS\$StartMenuFolder\MPUI.lnk" "$INSTDIR\MPUI.exe"
 633                         CreateShortCut "$DESKTOP\MPUI.lnk" "$INSTDIR\MPUI.exe"
 634                 ${EndIf}
 635                 ${If} ${FileExists} "$INSTDIR\SMPlayer.exe"
 636                         CreateShortCut "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" "$INSTDIR\SMPlayer.exe"
 637                         CreateShortCut "$DESKTOP\SMPlayer.lnk" "$INSTDIR\SMPlayer.exe"
 638                 ${EndIf}
 639
 640                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_UPDATE).lnk" "$INSTDIR\Updater.exe" "/L=$LANGUAGE"
 641                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_README).lnk" "$INSTDIR\Readme.html"
 642                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_MANUAL).lnk" "$INSTDIR\Manual.html"
 643
 644                 ${If} ${AtLeastWinVista}
 645                         CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_APPREG).lnk" "$INSTDIR\AppRegGUI.exe"
 646                 ${EndIf}
 647
 648                 ${CreateWebLink} "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_SITE_MULDERS).url" "http://muldersoft.com/"
 649                 ${CreateWebLink} "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_SITE_MPWIN32).url" "http://oss.netfarm.it/mplayer-win32.php"
 650                 ${CreateWebLink} "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_SITE_MPLAYER).url" "http://www.mplayerhq.hu/"
 651
 652                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk"
 653                         ${StdUtils.InvokeShellVerb} $R1 "$SMPROGRAMS\$StartMenuFolder" "SMPlayer.lnk" ${StdUtils.Const.ShellVerb.PinToTaskbar}
 654                         DetailPrint 'Pin: "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" -> $R1'
 655                 ${EndIf}
 656         !insertmacro MUI_STARTMENU_WRITE_END
 657 SectionEnd
 658
 659 Section "-ApplyTweaks"
 660         ${PrintProgress} "$(MPLAYER_LANG_STATUS_TWEAKS)"
 661         DetailPrint "$(MPLAYER_LANG_APPLYING_TWEAKS)"
 662
 663         IntOp $0 $SelectedTweaks & 1
 664         ${If} $0 <> 0
 665         ${AndIf} ${FileExists} "$INSTDIR\SMPlayer.ini"
 666                 DetailPrint "SMPlayer: Enable tweak 'gui=SkinGUI'"
 667                 WriteINIStr "$INSTDIR\SMPlayer.ini" "gui" "gui"      "SkinGUI"
 668                 WriteINIStr "$INSTDIR\SMPlayer.ini" "gui" "qt_style" "Fusion"
 669                 WriteINIStr "$INSTDIR\SMPlayer.ini" "gui" "iconset"  "Modern"
 670         ${EndIf}
 671
 672         IntOp $0 $SelectedTweaks & 2
 673         ${If} $0 <> 0
 674         ${AndIf} ${FileExists} "$INSTDIR\MPUI.ini"
 675                 DetailPrint "MPUI: Enable tweak '-vo gl'"
 676                 WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Params" "-vo gl -lavdopts threads=$DetectedCPUCores"
 677         ${EndIf}
 678         ${If} $0 <> 0
 679         ${AndIf} ${FileExists} "$INSTDIR\SMPlayer.ini"
 680                 DetailPrint "SMPlayer: Enable tweak '-vo gl'"
 681                 WriteINIStr "$INSTDIR\SMPlayer.ini" "%General" "driver\vo" "gl"
 682         ${EndIf}
 683
 684         IntOp $0 $SelectedTweaks & 4
 685         ${If} $0 <> 0
 686         ${AndIf} ${FileExists} "$INSTDIR\MPUI.ini"
 687                 DetailPrint "MPUI: Enable tweak '-af volnorm=2'"
 688                 ReadINIStr $1 "$INSTDIR\MPUI.ini" "MPUI" "Params"
 689                 WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Params" "$1 -af volnorm=2"
 690         ${EndIf}
 691         ${If} $0 <> 0
 692         ${AndIf} ${FileExists} "$INSTDIR\SMPlayer.ini"
 693                 DetailPrint "SMPlayer: Enable tweak 'initial_volnorm=true'"
 694                 WriteINIStr "$INSTDIR\SMPlayer.ini" "defaults" "initial_volnorm" "true"
 695         ${EndIf}
 696 SectionEnd
 697
 698 Section "$(MPLAYER_LANG_COMPRESS_FILES)"
 699         SectionIn 1 2
 700         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_COMPRESS)"
 701
 702         File "/oname=$PLUGINSDIR\UPX.exe" "${UPX_PATH}\UPX.exe"
 703
 704         ${PackAll} "$INSTDIR" "*.exe"
 705         ${PackAll} "$INSTDIR" "*.dll"
 706         ${PackAll} "$INSTDIR\codecs" "*.acm"
 707         ${PackAll} "$INSTDIR\codecs" "*.ax"
 708         ${PackAll} "$INSTDIR\codecs" "*.dll"
 709         ${PackAll} "$INSTDIR\codecs" "*.qtx"
 710
 711         Delete "$PLUGINSDIR\UPX.exe"
 712 SectionEnd
 713
 714 Section "-Update Font Cache"
 715         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_FONTCACHE)"
 716
 717         SetShellVarContext current
 718         Delete "$APPDATA\fontconfig\cache\*.*"
 719         Delete "$LOCALAPPDATA\fontconfig\cache\*.*"
 720
 721         SetShellVarContext all
 722         Delete "$APPDATA\fontconfig\cache\*.*"
 723         Delete "$LOCALAPPDATA\fontconfig\cache\*.*"
 724
 725         File "/oname=$PLUGINSDIR\Sample.avi" "Resources\Sample.avi"
 726         DetailPrint "$(MPLAYER_LANG_UPDATING_FONTCACHE)"
 727         NsExec::Exec '"$INSTDIR\MPlayer.exe" -fontconfig -ass -vo null -ao null "$PLUGINSDIR\Sample.avi"'
 728         Delete "Resources\Sample.avi"
 729 SectionEnd
 730
 731 Section "-Update Registry"
 732         ${PrintProgress} "$(MPLAYER_LANG_STATUS_REGISTRY)"
 733         DetailPrint "$(MPLAYER_LANG_WRITING_REGISTRY)"
 734
 735         ; Clean up
 736         DeleteRegKey HKLM "${MPlayerRegPath}"
 737         DeleteRegKey HKCU "${MPlayerRegPath}"
 738         DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 739         DeleteRegValue HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 740
 741         ; Uninstaller
 742         WriteRegStr HKLM "${MPlayerRegPath}" "InstallLocation" "$INSTDIR"
 743         WriteRegStr HKLM "${MPlayerRegPath}" "UninstallString" '"$INSTDIR\Uninstall.exe"'
 744         WriteRegStr HKLM "${MPlayerRegPath}" "DisplayName" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 745         WriteRegStr HKLM "${MPlayerRegPath}" "DisplayIcon" "$INSTDIR\MPlayer.exe,0"
 746         WriteRegStr HKLM "${MPlayerRegPath}" "DisplayVersion" "${MPLAYER_DATE}"
 747         WriteRegStr HKLM "${MPlayerRegPath}" "URLInfoAbout" "http://muldersoft.com/"
 748         WriteRegStr HKLM "${MPlayerRegPath}" "URLUpdateInfo" "http://muldersoft.com/"
 749         WriteRegStr HKLM "${MPlayerRegPath}" "Publisher" "The MPlayer Team"
 750         WriteRegDWORD HKLM "${MPlayerRegPath}" "NoModify" 1
 751         WriteRegDWORD HKLM "${MPlayerRegPath}" "NoRepair" 1
 752
 753         ; Shell
 754         DeleteRegKey HKCR "MPlayerForWindowsV2.File"
 755         DeleteRegKey HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 756         DeleteRegKey HKCU "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 757         ${If} ${FileExists} "$INSTDIR\MPUI.exe"
 758                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\shell\open\command" "" '"$INSTDIR\MPUI.exe" "%1"'
 759                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\DefaultIcon" "" "$INSTDIR\MPUI.exe,0"
 760         ${EndIf}
 761         ${If} ${FileExists} "$INSTDIR\SMPlayer.exe"
 762                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\shell\open\command" "" '"$INSTDIR\SMPlayer.exe" "%1"'
 763                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\DefaultIcon" "" "$INSTDIR\SMPlayer.exe,1"
 764         ${EndIf}
 765
 766         ; Register App
 767         DeleteRegValue HKCU "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2"
 768         WriteRegStr HKLM "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2" "${MPlayerRegPath}\Capabilities"
 769
 770         ; Capabilities
 771         WriteRegStr HKLM "${MPlayerRegPath}\Capabilities" "ApplicationName" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 772         WriteRegStr HKLM "${MPlayerRegPath}\Capabilities" "ApplicationDescription" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 773         WriteRegStr HKLM "${MPlayerRegPath}\Capabilities" "ApplicationDescription" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 774
 775         ; File Associations
 776         ${RegisterFileExtCapability} "256"
 777         ${RegisterFileExtCapability} "3GP"
 778         ${RegisterFileExtCapability} "AAC"
 779         ${RegisterFileExtCapability} "ASF"
 780         ${RegisterFileExtCapability} "AVI"
 781         ${RegisterFileExtCapability} "BIN"
 782         ${RegisterFileExtCapability} "DAT"
 783         ${RegisterFileExtCapability} "DIVX"
 784         ${RegisterFileExtCapability} "EVO"
 785         ${RegisterFileExtCapability} "FLV"
 786         ${RegisterFileExtCapability} "M2V"
 787         ${RegisterFileExtCapability} "M2TS"
 788         ${RegisterFileExtCapability} "M4A"
 789         ${RegisterFileExtCapability} "MKA"
 790         ${RegisterFileExtCapability} "MKV"
 791         ${RegisterFileExtCapability} "MOV"
 792         ${RegisterFileExtCapability} "MP2"
 793         ${RegisterFileExtCapability} "MP3"
 794         ${RegisterFileExtCapability} "MP4"
 795         ${RegisterFileExtCapability} "MPEG"
 796         ${RegisterFileExtCapability} "MPG"
 797         ${RegisterFileExtCapability} "MPV"
 798         ${RegisterFileExtCapability} "NSV"
 799         ${RegisterFileExtCapability} "OGG"
 800         ${RegisterFileExtCapability} "OGM"
 801         ${RegisterFileExtCapability} "RM"
 802         ${RegisterFileExtCapability} "RMVB"
 803         ${RegisterFileExtCapability} "TS"
 804         ${RegisterFileExtCapability} "VOB"
 805         ${RegisterFileExtCapability} "WAV"
 806         ${RegisterFileExtCapability} "WEBM"
 807         ${RegisterFileExtCapability} "WMV"
 808
 809         ; Reset auto update interval
 810         DeleteRegValue HKLM "${MPlayerRegPath}" "LastUpdateCheck"
 811         DeleteRegValue HKCU "${MPlayerRegPath}" "LastUpdateCheck"
 812 SectionEnd
 813
 814 Section "$(MPLAYER_LANG_INST_AUTOUPDATE)" SECID_AUTOUPDATE
 815         SectionIn 1 2
 816         DetailPrint "$(MPLAYER_LANG_SCHEDULE_UPDATE)"
 817         WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2" '"$INSTDIR\Updater.exe" /L=$LANGUAGE /AutoCheck'
 818 SectionEnd
 819
 820 Section "-Protect Files"
 821         SetFileAttributes "$INSTDIR\AppRegGUI.exe"       FILE_ATTRIBUTE_READONLY
 822         SetFileAttributes "$INSTDIR\mplayer.exe"         FILE_ATTRIBUTE_READONLY
 823         SetFileAttributes "$INSTDIR\MPUI.exe"            FILE_ATTRIBUTE_READONLY
 824         SetFileAttributes "$INSTDIR\smplayer.exe"        FILE_ATTRIBUTE_READONLY
 825         SetFileAttributes "$INSTDIR\Updater.exe"         FILE_ATTRIBUTE_READONLY
 826
 827         SetFileAttributes "$INSTDIR\dsnative.dll"        FILE_ATTRIBUTE_READONLY
 828         SetFileAttributes "$INSTDIR\libeay32.dll"        FILE_ATTRIBUTE_READONLY
 829         SetFileAttributes "$INSTDIR\libgcc_s_dw2-1.dll"  FILE_ATTRIBUTE_READONLY
 830         SetFileAttributes "$INSTDIR\libstdc++-6.dll"     FILE_ATTRIBUTE_READONLY
 831         SetFileAttributes "$INSTDIR\libwinpthread-1.dll" FILE_ATTRIBUTE_READONLY
 832         SetFileAttributes "$INSTDIR\Qt5Core.dll"         FILE_ATTRIBUTE_READONLY
 833         SetFileAttributes "$INSTDIR\Qt5Gui.dll"          FILE_ATTRIBUTE_READONLY
 834         SetFileAttributes "$INSTDIR\Qt5Network.dll"      FILE_ATTRIBUTE_READONLY
 835         SetFileAttributes "$INSTDIR\Qt5Script.dll"       FILE_ATTRIBUTE_READONLY
 836         SetFileAttributes "$INSTDIR\Qt5Widgets.dll"      FILE_ATTRIBUTE_READONLY
 837         SetFileAttributes "$INSTDIR\Qt5Xml.dll"          FILE_ATTRIBUTE_READONLY
 838         SetFileAttributes "$INSTDIR\ssleay32.dll"        FILE_ATTRIBUTE_READONLY
 839         SetFileAttributes "$INSTDIR\zlib1.dll"           FILE_ATTRIBUTE_READONLY
 840 SectionEnd
 841
 842 Section "-Finished"
 843         ${PrintStatus} "$(MUI_TEXT_FINISH_TITLE)"
 844 SectionEnd
 845
 846
 847 ;--------------------------------------------------------------------------------
 848 ; UN-INSTALL SECTIONS
 849 ;--------------------------------------------------------------------------------
 850
 851 Section "Uninstall"
 852         SetOutPath "$TEMP"
 853         ${PrintProgress} "$(MPLAYER_LANG_STATUS_UNINSTALL)"
 854
 855         ; Validate uninstall path
 856         ${IfThen} "$INSTDIR" == "" ${|} Abort ${|}
 857         StrCpy $0 "$INSTDIR" "" -2
 858         ${IfThen} $0 == ":\" ${|} Abort ${|}
 859
 860         ; Startmenu
 861         !insertmacro MUI_STARTMENU_GETFOLDER Application $StartMenuFolder
 862         ${IfNot} "$StartMenuFolder" == ""
 863                 SetShellVarContext current
 864                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk"
 865                         ${StdUtils.InvokeShellVerb} $R1 "$SMPROGRAMS\$StartMenuFolder" "SMPlayer.lnk" ${StdUtils.Const.ShellVerb.UnpinFromTaskbar}
 866                         DetailPrint 'Unpin: "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" -> $R1'
 867                 ${EndIf}
 868                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\*.*"
 869                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 870                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.url"
 871                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.pif"
 872                         RMDir "$SMPROGRAMS\$StartMenuFolder"
 873                 ${EndIf}
 874                 SetShellVarContext all
 875                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk"
 876                         ${StdUtils.InvokeShellVerb} $R1 "$SMPROGRAMS\$StartMenuFolder" "SMPlayer.lnk" ${StdUtils.Const.ShellVerb.UnpinFromTaskbar}
 877                         DetailPrint 'Unpin: "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" -> $R1'
 878                 ${EndIf}
 879                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\*.*"
 880                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 881                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.url"
 882                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.pif"
 883                         RMDir "$SMPROGRAMS\$StartMenuFolder"
 884                 ${EndIf}
 885         ${EndIf}
 886
 887         ; Desktop icons
 888         Delete /REBOOTOK "$DESKTOP\MPUI.lnk"
 889         Delete /REBOOTOK "$DESKTOP\SMPlayer.lnk"
 890
 891         ; Files
 892         RMDir /r "$INSTDIR"
 893
 894         ; Virtual Store
 895         ${GetVirtualStorePath} $0 "$INSTDIR"
 896         ${If} ${FileExists} "$0\*.*"
 897                 RMDir /r "$0"
 898         ${EndIf}
 899
 900         ; Registry Keys
 901         DeleteRegKey HKLM "${MPlayerRegPath}"
 902         DeleteRegKey HKCU "${MPlayerRegPath}"
 903         DeleteRegValue HKLM "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2"
 904         DeleteRegValue HKCU "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2"
 905
 906         ; Auto Update
 907         DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 908         DeleteRegValue HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 909
 910         ; Shell
 911         DeleteRegKey HKCR "MPlayerForWindowsV2.File"
 912         DeleteRegKey HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 913         DeleteRegKey HKCU "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 914
 915         ${PrintStatus} "$(MUI_UNTEXT_FINISH_TITLE)"
 916 SectionEnd
 917
 918
 919 ;--------------------------------------------------------------------------------
 920 ; SECTION SELECTION CHANGED
 921 ;--------------------------------------------------------------------------------
 922
 923 Function .onSelChange
 924         ${IfNot} ${SectionIsSelected} ${SECID_MPUI}
 925         ${AndIfNot} ${SectionIsSelected} ${SECID_SMPLAYER}
 926                 MessageBox MB_TOPMOST|MB_ICONEXCLAMATION "$(MPLAYER_LANG_SELCHANGE)"
 927                 SectionGetFlags ${SECID_MPUI} $0
 928                 IntOp $0 $0 | ${SF_SELECTED}
 929                 SectionSetFlags ${SECID_MPUI} $0
 930         ${EndIf}
 931
 932         ${IfNot} ${SectionIsSelected} ${SECID_AUTOUPDATE}
 933                 StrCpy $0 "nope"
 934                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_YESNO|MB_DEFBUTTON2 "$(MPLAYER_LANG_SEL_AUTOUPDATE)" IDNO ${||} StrCpy $0 "ok" ${|}
 935                 ${If} "$0" == "ok"
 936                         SectionGetFlags ${SECID_AUTOUPDATE} $0
 937                         IntOp $0 $0 | ${SF_SELECTED}
 938                         SectionSetFlags ${SECID_AUTOUPDATE} $0
 939                 ${EndIf}
 940         ${EndIf}
 941 FunctionEnd
 942
 943
 944 ;--------------------------------------------------------------------------------
 945 ; LOCKED-LIST PLUGIN
 946 ;--------------------------------------------------------------------------------
 947
 948 !macro LockedListPage_Function
 949         !insertmacro MUI_HEADER_TEXT "$(MPLAYER_LANG_LOCKEDLIST_HEADER)" "$(MPLAYER_LANG_LOCKEDLIST_TEXT)"
 950
 951         InitPluginsDir
 952         File /oname=$PLUGINSDIR\LockedList64.dll `${NSISDIR}\Plugins\LockedList64.dll`
 953
 954         LockedList::AddModule "\MPlayer.exe"
 955         LockedList::AddModule "\SMPlayer.exe"
 956         LockedList::AddModule "\MPUI.exe"
 957         LockedList::AddModule "${NSISDIR}\Qt5Core.dll"
 958
 959         LockedList::Dialog /autonext /ignore "$(MPLAYER_LANG_IGNORE)" /heading "$(MPLAYER_LANG_LOCKEDLIST_HEADING)" /noprograms "$(MPLAYER_LANG_LOCKEDLIST_NOPROG)" /searching  "$(MPLAYER_LANG_LOCKEDLIST_SEARCH)" /colheadings "$(MPLAYER_LANG_LOCKEDLIST_COLHDR1)" "$(MPLAYER_LANG_LOCKEDLIST_COLHDR2)"
 960         Pop $R0
 961 !macroend
 962
 963 Function LockedListPage_Show
 964         !insertmacro LockedListPage_Function
 965 FunctionEnd
 966
 967 Function un.LockedListPage_Show
 968         !insertmacro LockedListPage_Function
 969 FunctionEnd
 970
 971
 972 ;--------------------------------------------------------------------------------
 973 ; CUSTOME PAGE: CPU SELECTOR
 974 ;--------------------------------------------------------------------------------
 975
 976 Function SelectCPUPage_Show
 977         ; Detect CPU type, if not detected yet
 978         ${If} $DetectedCPUType < 2
 979         ${OrIf} $DetectedCPUType > 5
 980                 Call DetectCPUType
 981                 !insertmacro INSTALLOPTIONS_READ $0 "Page_CPU.ini" "Field $DetectedCPUType" "Text"
 982                 !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field $DetectedCPUType" "Text" "$0  <---"
 983         ${EndIf}
 984
 985         ; Make sure the current selection is valid
 986         ${IfThen} $SelectedCPUType < 2 ${|} StrCpy $SelectedCPUType $DetectedCPUType ${|}
 987         ${IfThen} $SelectedCPUType > 5 ${|} StrCpy $SelectedCPUType $DetectedCPUType ${|}
 988
 989         ; Translate
 990         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field 1" "Text" "$(MPLAYER_LANG_SELECT_CPU_TYPE)"
 991         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field 6" "Text" "$(MPLAYER_LANG_SELECT_CPU_HINT)"
 992
 993         ; Apply current selection to dialog
 994         ${For} $0 2 5
 995                 ${If} $0 == $SelectedCPUType
 996                         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field $0" "State" "1"
 997                 ${Else}
 998                         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field $0" "State" "0"
 999                 ${EndIf}
1000         ${Next}
1001
1002         ; Display dialog
1003         !insertmacro MUI_HEADER_TEXT "$(MPLAYER_LANG_SELECT_CPU_HEAD)" "$(MPLAYER_LANG_SELECT_CPU_TEXT)"
1004         !insertmacro INSTALLOPTIONS_DISPLAY "Page_CPU.ini"
1005
1006         ; Read new selection from dialog
1007         StrCpy $SelectedCPUType 0
1008         ${For} $0 2 5
1009                 !insertmacro INSTALLOPTIONS_READ $1 "Page_CPU.ini" "Field $0" "State"
1010                 ${IfThen} $1 == 1 ${|} StrCpy $SelectedCPUType $0 ${|}
1011         ${Next}
1012 FunctionEnd
1013
1014 Function SelectCPUPage_Validate
1015         ; Read new selection from dialog
1016         StrCpy $2 0
1017         ${For} $0 2 5
1018                 !insertmacro INSTALLOPTIONS_READ $1 "Page_CPU.ini" "Field $0" "State"
1019                 ${IfThen} $1 == 1 ${|} StrCpy $2 $0 ${|}
1020         ${Next}
1021
1022         ; Validate selection
1023         ${If} $2 < 2
1024         ${OrIf} $2 > 5
1025                 MessageBox MB_ICONSTOP "Oups, invalid selection detected!"
1026                 Abort
1027         ${EndIf}
1028 FunctionEnd
1029
1030 Function DetectCPUType
1031         StrCpy $DetectedCPUType 5 ;generic
1032         StrCpy $DetectedCPUCores 2
1033
1034         ${IfNot} ${Silent}
1035                 Banner::show /NOUNLOAD "$(MPLAYER_LANG_DETECTING)"
1036         ${EndIf}
1037
1038         ${CPUFeatures.GetCount} $0
1039         ${IfNot} $0 == "error"
1040                 StrCpy $DetectedCPUCores $0
1041         ${EndIf}
1042
1043         ; Debug Code
1044         !ifdef CPU_DETECT_DEBUG
1045                 ${CPUFeatures.GetVendor} $0
1046                 ${CPUFeatures.CheckFeature} "MMX1"   $1
1047                 ${CPUFeatures.CheckFeature} "3DNOW"  $2
1048                 ${CPUFeatures.CheckFeature} "SSE3"   $3
1049                 ${CPUFeatures.CheckFeature} "SSSE3"  $4
1050                 ${CPUFeatures.CheckFeature} "SSE4.2" $5
1051                 ${CPUFeatures.CheckFeature} "AVX1"   $6
1052                 ${CPUFeatures.CheckFeature} "FMA4"   $7
1053                 StrCpy $9 `Vendor = $0`
1054                 StrCpy $9 `$9$\n"MMX1" = $1`
1055                 StrCpy $9 `$9$\n"3DNOW" = $2`
1056                 StrCpy $9 `$9$\n"SSE3" = $3`
1057                 StrCpy $9 `$9$\n"SSSE3" = $4`
1058                 StrCpy $9 `$9$\n"SSE4.2" = $5`
1059                 StrCpy $9 `$9$\n"AVX1" = $6`
1060                 StrCpy $9 `$9$\n"FMA4" = $7`
1061                 MessageBox MB_TOPMOST `$9`
1062         !endif
1063
1064         ; Make sure we have at least MMX
1065         ${IfNot} ${CPUSupports} "MMX1"
1066                 Banner::destroy
1067                 Return
1068         ${EndIf}
1069
1070         ; Select the "best" model for Intel's
1071         ${If} ${CPUIsIntel}
1072                 ; Core2 (SSE3 + SSSE3)
1073                 ${If} ${CPUSupportsAll} "SSE3,SSSE3"
1074                         StrCpy $DetectedCPUType 2 ;
1075                 ${EndIf}
1076                 ; Nehalem (SSE3 + SSSE3 + SSE4.2)
1077                 ${If} ${CPUSupportsAll} "SSE3,SSSE3,SSE4.2"
1078                         StrCpy $DetectedCPUType 3
1079                 ${EndIf}
1080         ${EndIf}
1081
1082         ; Select the "best" model for AMD's
1083         ${If} ${CPUIsAMD}
1084                 ; K8+SSE3 (3DNow! + SSE3)
1085                 ${If} ${CPUSupportsAll} "3DNOW,SSE3"
1086                         StrCpy $DetectedCPUType 4
1087                 ${EndIf}
1088                 ; Bulldozer (SSE3 + SSSE3 + SSE4.2 + AVX + FMA4)
1089                 ;${If} ${CPUSupportsAll} "SSE3,SSSE3,SSE4.2,AVX1,FMA4"
1090                 ;       StrCpy $DetectedCPUType 5       #5 is now generic, as 'bdver1' build got dropped
1091                 ;${EndIf}
1092         ${EndIf}
1093
1094         Banner::destroy
1095 FunctionEnd
1096
1097
1098 ;--------------------------------------------------------------------------------
1099 ; CUSTOME PAGE: TWEAKS
1100 ;--------------------------------------------------------------------------------
1101
1102 Function SetTweaksPage_Show
1103         ; Apply current selection to dialog
1104         StrCpy $0 1
1105         ${For} $1 2 4
1106                 IntOp $2 $0 & $SelectedTweaks
1107                 ${If} $2 <> 0
1108                         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field $1" "State" "1"
1109                 ${Else}
1110                         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field $1" "State" "0"
1111                 ${EndIf}
1112                 IntOp $0 $0 << 1
1113         ${Next}
1114
1115         ; Translate
1116         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 1" "Text" "$(MPLAYER_LANG_TWEAKS_HINT)"
1117         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 2" "Text" "$(MPLAYER_LANG_TWEAKS_SKINNEDUI)"
1118         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 3" "Text" "$(MPLAYER_LANG_TWEAKS_OPENGL)"
1119         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 4" "Text" "$(MPLAYER_LANG_TWEAKS_VOLNORM)"
1120
1121         ; Display dialog
1122         !insertmacro MUI_HEADER_TEXT "$(MPLAYER_LANG_TWEAKS_HEAD)" "$(MPLAYER_LANG_TWEAKS_TEXT)"
1123         !insertmacro INSTALLOPTIONS_DISPLAY "Page_Tweaks.ini"
1124
1125         ; Read new selection from dialog
1126         StrCpy $0 1
1127         StrCpy $SelectedTweaks 0
1128         ${For} $1 2 4
1129                 !insertmacro INSTALLOPTIONS_READ $2 "Page_Tweaks.ini" "Field $1" "State"
1130                 ${IfThen} $2 = 1 ${|} IntOp $SelectedTweaks $SelectedTweaks | $0 ${|}
1131                 IntOp $0 $0 << 1
1132         ${Next}
1133 FunctionEnd
1134
1135
1136 ;--------------------------------------------------------------------------------
1137 ; CHECK FOR UPDATE MODE
1138 ;--------------------------------------------------------------------------------
1139
1140 !macro SetControlEnabled item_id enable
1141         FindWindow $0 "#32770" "" $HWNDPARENT
1142         ${IfNot} $0 == 0
1143                 GetDlgItem $1 $0 ${item_id}
1144                 EnableWindow $1 ${enable}
1145         ${EndIf}
1146 !macroend
1147
1148 !macro SkipToNextPage
1149         GetDlgItem $0 $HWNDPARENT 1
1150         System::Call "User32::PostMessage(i $HWNDPARENT, i ${WM_COMMAND}, i 1, i $R0)"
1151 !macroend
1152
1153 !macro EnablePathEditable flag show_msg
1154         !insertmacro SetControlEnabled 1019 ${flag}
1155         !insertmacro SetControlEnabled 1001 ${flag}
1156         ${IfNot} $NotUpdateInstall = ${flag}
1157                 !if ${show_msg} == 1
1158                         MessageBox MB_OK|MB_ICONINFORMATION "$(MPLAYER_LANG_FORCE_UPDATE)" /SD IDOK
1159                 !endif
1160                 StrCpy $NotUpdateInstall ${flag}
1161                 !insertmacro SkipToNextPage
1162         ${EndIf}
1163 !macroend
1164
1165 Function CheckForUpdate
1166         ${StdUtils.TestParameter} $0 "Update"
1167         ${If} "$0" == "true"
1168                 !insertmacro EnablePathEditable 0 0
1169                 Return
1170         ${EndIf}
1171
1172         ${If} ${FileExists} "$INSTDIR\MPlayer.exe"
1173                 ${If} $NotUpdateInstall = 1
1174                 ${AndIf} ${FileExists} "$INSTDIR\version.tag"
1175                         ReadINIStr $0 "$INSTDIR\version.tag" "mplayer_version" "build_no"
1176                         ${If} $0 > ${MPLAYER_BUILDNO}
1177                                 MessageBox MB_OK|MB_ICONEXCLAMATION "$(MPLAYER_LANG_CAN_NOT_UPDATE)"
1178                                 Quit
1179                         ${EndIf}
1180                         ${If} $0 = ${MPLAYER_BUILDNO}
1181                                 ${IfCmd} MessageBox MB_YESNO|MB_ICONEXCLAMATION "$(MPLAYER_LANG_CONFIRM_UPDATE)" /SD IDYES IDNO ${||} Quit ${|}
1182                         ${EndIf}
1183                 ${EndIf}
1184                 !insertmacro EnablePathEditable 0 1
1185                 Return
1186         ${EndIf}
1187
1188         !insertmacro EnablePathEditable 1 0
1189 FunctionEnd
1190
1191
1192 ;--------------------------------------------------------------------------------
1193 ; FINISHED
1194 ;--------------------------------------------------------------------------------
1195
1196 Function RunAppFunction
1197         !insertmacro DisableNextButton $R0
1198         ${If} ${FileExists} "$INSTDIR\SMPlayer.exe"
1199                 ${StdUtils.ExecShellAsUser} $R0 "$INSTDIR\SMPlayer.exe" "open" "https://www.youtube.com/watch?v=SkVqJ1SGeL0"
1200         ${Else}
1201                 ${StdUtils.ExecShellAsUser} $R0 "$INSTDIR\MPUI.exe" "open" "http://www.caminandes.com/download/03_caminandes_llamigos_1080p.mp4"
1202         ${EndIf}
1203 FunctionEnd
1204
1205 Function ShowReadmeFunction
1206         !insertmacro DisableNextButton $R0
1207         ${StdUtils.ExecShellAsUser} $R0 "$INSTDIR\Readme.html" "open" ""
1208 FunctionEnd
1209
1210 Function .onInstSuccess
1211         ${StdUtils.ExecShellAsUser} $R0 "$SMPROGRAMS\$StartMenuFolder" "explore" ""
1212 FunctionEnd
1213
1214
1215 ### EOF ###