configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #
   3 # Copyright (C) 1993-2012 Free Software Foundation, Inc.
   4 # This file is part of GNU Make.
   5 #
   6 # GNU Make is free software; you can redistribute it and/or modify it under
   7 # the terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 3 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # GNU Make is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  13 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  14 # details.
  15 #
  16 # You should have received a copy of the GNU General Public License along with
  17 # this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 AC_INIT([GNU make],[3.82.90],[bug-make@gnu.org])
  20
  21 AC_PREREQ([2.59])
  22 AC_REVISION([$Id: configure.in,v 1.164 2012/03/05 14:10:42 psmith Exp $])
  23
  24 # Autoconf setup
  25 AC_CONFIG_AUX_DIR([config])
  26 AC_CONFIG_SRCDIR([vpath.c])
  27 AC_CONFIG_HEADERS([config.h])
  28
  29 # Automake setup
  30 AM_INIT_AUTOMAKE([1.9])
  31
  32 # Checks for programs.
  33 AC_PROG_CC
  34 AC_PROG_INSTALL
  35 AC_PROG_RANLIB
  36 AC_PROG_CPP
  37 AC_CHECK_PROG([AR], [ar], [ar], [ar])
  38 # Perl is needed for the test suite (only)
  39 AC_CHECK_PROG([PERL], [perl], [perl], [perl])
  40
  41 # Specialized system macros
  42 AC_CANONICAL_HOST
  43 AC_AIX
  44 AC_ISC_POSIX
  45 AC_MINIX
  46
  47 # Enable gettext, in "external" mode.
  48
  49 AM_GNU_GETTEXT_VERSION([0.14.1])
  50 AM_GNU_GETTEXT([external])
  51
  52 # This test must come as early as possible after the compiler configuration
  53 # tests, because the choice of the file model can (in principle) affect
  54 # whether functions and headers are available, whether they work, etc.
  55 AC_SYS_LARGEFILE
  56
  57 # Checks for libraries.
  58 AC_SEARCH_LIBS([getpwnam], [sun])
  59
  60 # Checks for header files.
  61 AC_HEADER_STDC
  62 AC_HEADER_DIRENT
  63 AC_HEADER_STAT
  64 AC_HEADER_TIME
  65 AC_CHECK_HEADERS([stdlib.h locale.h unistd.h limits.h fcntl.h string.h \
  66                   memory.h sys/param.h sys/resource.h sys/time.h sys/timeb.h])
  67
  68 # Set a flag if we have an ANSI C compiler
  69 AS_IF([test "$ac_cv_prog_cc_stdc" != no],
  70 [ AC_DEFINE([HAVE_ANSI_COMPILER], [1],
  71             [Define to 1 if your compiler conforms to the ANSI C standard.])
  72 ])
  73
  74
  75 # Determine what kind of variadic function calls we support
  76 AC_CHECK_HEADERS([stdarg.h varargs.h], [break])
  77
  78 AM_PROG_CC_C_O
  79 AC_C_CONST
  80 AC_TYPE_SIGNAL
  81 AC_TYPE_UID_T
  82 AC_TYPE_PID_T
  83
  84 # Find some definition for uintmax_t
  85
  86 AC_CHECK_TYPE([uintmax_t],[],
  87 [ uintmax_t="unsigned long"
  88   AC_CHECK_TYPE([unsigned long long],[uintmax_t="unsigned long long"])
  89   AC_DEFINE_UNQUOTED([uintmax_t], [$uintmax_t],
  90     [Define uintmax_t if not defined in <stdint.h> or <inttypes.h>.])
  91 ])
  92
  93 # Find out whether our struct stat returns nanosecond resolution timestamps.
  94
  95 AC_STRUCT_ST_MTIM_NSEC
  96 AC_CACHE_CHECK([whether to use high resolution file timestamps],
  97                [make_cv_file_timestamp_hi_res],
  98 [ make_cv_file_timestamp_hi_res=no
  99   AS_IF([test "$ac_cv_struct_st_mtim_nsec" != no],
 100         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 101 #if HAVE_INTTYPES_H
 102 # include <inttypes.h>
 103 #endif]],
 104                       [[char a[0x7fffffff < (uintmax_t)-1 >> 30 ? 1 : -1];]])],
 105         [make_cv_file_timestamp_hi_res=yes])
 106   ])])
 107 AS_IF([test "$make_cv_file_timestamp_hi_res" = yes], [val=1], [val=0])
 108 AC_DEFINE_UNQUOTED([FILE_TIMESTAMP_HI_RES], [$val],
 109                    [Use high resolution file timestamps if nonzero.])
 110
 111 AS_IF([test "$make_cv_file_timestamp_hi_res" = yes],
 112 [ # Solaris 2.5.1 needs -lposix4 to get the clock_gettime function.
 113   # Solaris 7 prefers the library name -lrt to the obsolescent name -lposix4.
 114   AC_SEARCH_LIBS([clock_gettime], [rt posix4])
 115   AS_IF([test "$ac_cv_search_clock_gettime" != no],
 116   [ AC_DEFINE([HAVE_CLOCK_GETTIME], [1],
 117               [Define to 1 if you have the clock_gettime function.])
 118   ])
 119 ])
 120
 121 # Check for DOS-style pathnames.
 122 pds_AC_DOS_PATHS
 123
 124 # See if we have a standard version of gettimeofday().  Since actual
 125 # implementations can differ, just make sure we have the most common
 126 # one.
 127 AC_CACHE_CHECK([for standard gettimeofday], [ac_cv_func_gettimeofday],
 128   [ac_cv_func_gettimeofday=no
 129    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/time.h>
 130                   int main ()
 131                   {
 132                     struct timeval t; t.tv_sec = -1; t.tv_usec = -1;
 133                     exit (gettimeofday (&t, 0) != 0
 134                           || t.tv_sec < 0 || t.tv_usec < 0);
 135                   }]])],
 136                   [ac_cv_func_gettimeofday=yes],
 137                   [ac_cv_func_gettimeofday=no],
 138                   [ac_cv_func_gettimeofday="no (cross-compiling)"])])
 139 AS_IF([test "$ac_cv_func_gettimeofday" = yes],
 140 [ AC_DEFINE([HAVE_GETTIMEOFDAY], [1],
 141             [Define to 1 if you have a standard gettimeofday function])
 142 ])
 143
 144 AC_CHECK_FUNCS([strdup strndup mkstemp mktemp fdopen fileno \
 145                 dup2 getcwd realpath sigsetmask sigaction \
 146                 getgroups seteuid setegid setlinebuf setreuid setregid \
 147                 getrlimit setrlimit setvbuf pipe strerror strsignal \
 148                 lstat readlink atexit])
 149
 150 # We need to check declarations, not just existence, because on Tru64 this
 151 # function is not declared without special flags, which themselves cause
 152 # other problems.  We'll just use our own.
 153 AC_CHECK_DECLS([bsd_signal], [], [], [[#include <signal.h>]])
 154
 155 AC_FUNC_SETVBUF_REVERSED
 156
 157 # Rumor has it that strcasecmp lives in -lresolv on some odd systems.
 158 # It doesn't hurt much to use our own if we can't find it so I don't
 159 # make the effort here.
 160 AC_CHECK_FUNCS([strcasecmp strncasecmp strcmpi strncmpi stricmp strnicmp])
 161
 162 # strcoll() is used by the GNU glob library
 163 AC_FUNC_STRCOLL
 164
 165 AC_FUNC_ALLOCA
 166 AC_FUNC_FORK([])
 167 AC_FUNC_VPRINTF
 168 AC_FUNC_CLOSEDIR_VOID
 169
 170 # See if the user wants to add (or not) GNU Guile support
 171 PKG_PROG_PKG_CONFIG
 172 AC_ARG_WITH([guile], [AS_HELP_STRING([--with-guile],
 173             [Support GNU Guile for embedded scripting])])
 174
 175 # For some strange reason, at least on Ubuntu, each version of Guile
 176 # comes with it's own PC file so we have to specify them as individual
 177 # packages.  Ugh.
 178 AS_IF([test "x$with_guile" != xno],
 179 [ PKG_CHECK_MODULES([GUILE], [guile-2.0], [have_guile=yes],
 180   [PKG_CHECK_MODULES([GUILE], [guile-1.8], [have_guile=yes],
 181     [have_guile=no])])
 182 ])
 183
 184 AS_IF([test "$have_guile" = yes],
 185       [AC_DEFINE([HAVE_GUILE], [1], [Embed GNU Guile support])])
 186
 187 AM_CONDITIONAL([HAVE_GUILE], [test "$have_guile" = yes])
 188
 189 AC_FUNC_GETLOADAVG
 190
 191 # AC_FUNC_GETLOADAVG is documented to set the NLIST_STRUCT value, but it
 192 # doesn't.  So, we will.
 193
 194 AS_IF([test "$ac_cv_header_nlist_h" = yes],
 195 [ AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <nlist.h>]],
 196         [[struct nlist nl;
 197           nl.n_name = "string";
 198           return 0;]])],
 199         [make_cv_nlist_struct=yes],
 200         [make_cv_nlist_struct=no])
 201   AS_IF([test "$make_cv_nlist_struct" = yes],
 202   [ AC_DEFINE([NLIST_STRUCT], [1],
 203        [Define to 1 if struct nlist.n_name is a pointer rather than an array.])
 204   ])
 205 ])
 206
 207 AC_CHECK_DECLS([sys_siglist, _sys_siglist, __sys_siglist], , ,
 208   [AC_INCLUDES_DEFAULT
 209 #include <signal.h>
 210 /* NetBSD declares sys_siglist in unistd.h.  */
 211 #if HAVE_UNISTD_H
 212 # include <unistd.h>
 213 #endif
 214 ])
 215
 216
 217 # Check out the wait reality.
 218 AC_CHECK_HEADERS([sys/wait.h],[],[],[[#include <sys/types.h>]])
 219 AC_CHECK_FUNCS([waitpid wait3])
 220 AC_CACHE_CHECK([for union wait], [make_cv_union_wait],
 221 [ AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 222 #include <sys/wait.h>]],
 223      [[union wait status; int pid; pid = wait (&status);
 224 #ifdef WEXITSTATUS
 225 /* Some POSIXoid systems have both the new-style macros and the old
 226    union wait type, and they do not work together.  If union wait
 227    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 228         if (WEXITSTATUS (status) != 0) pid = -1;
 229 #ifdef WTERMSIG
 230         /* If we have WEXITSTATUS and WTERMSIG, just use them on ints.  */
 231         -- blow chunks here --
 232 #endif
 233 #endif
 234 #ifdef HAVE_WAITPID
 235         /* Make sure union wait works with waitpid.  */
 236         pid = waitpid (-1, &status, 0);
 237 #endif
 238       ]])],
 239     [make_cv_union_wait=yes],
 240     [make_cv_union_wait=no])
 241 ])
 242 AS_IF([test "$make_cv_union_wait" = yes],
 243 [ AC_DEFINE([HAVE_UNION_WAIT], [1],
 244             [Define to 1 if you have the 'union wait' type in <sys/wait.h>.])
 245 ])
 246
 247
 248 # If we're building on Windows/DOS/OS/2, add some support for DOS drive specs.
 249 AS_IF([test "$PATH_SEPARATOR" = ';'],
 250 [ AC_DEFINE([HAVE_DOS_PATHS], [1],
 251             [Define to 1 if your system requires backslashes or drive specs in pathnames.])
 252 ])
 253
 254
 255 # See if the user wants to use pmake's "customs" distributed build capability
 256
 257 AC_SUBST([REMOTE]) REMOTE=stub
 258 use_customs=false
 259 AC_ARG_WITH([customs],
 260 [ AC_HELP_STRING([--with-customs=DIR],
 261                  [enable remote jobs via Customs--see README.customs])],
 262 [ AS_CASE([$withval], [n|no], [:],
 263     [make_cppflags="$CPPFLAGS"
 264      AS_CASE([$withval],
 265              [y|ye|yes], [:],
 266              [CPPFLAGS="$CPPFLAGS -I$with_customs/include/customs"
 267               make_ldflags="$LDFLAGS -L$with_customs/lib"])
 268      CF_NETLIBS
 269      AC_CHECK_HEADER([customs.h],
 270                      [use_customs=true
 271                       REMOTE=cstms
 272                       LIBS="$LIBS -lcustoms" LDFLAGS="$make_ldflags"],
 273                      [with_customs=no
 274                       CPPFLAGS="$make_cppflags" make_badcust=yes])
 275     ])
 276 ])
 277
 278 # Tell automake about this, so it can include the right .c files.
 279 AM_CONDITIONAL([USE_CUSTOMS], [test "$use_customs" = true])
 280
 281 # See if the user asked to handle case insensitive file systems.
 282
 283 AH_TEMPLATE([HAVE_CASE_INSENSITIVE_FS], [Use case insensitive file names])
 284 AC_ARG_ENABLE([case-insensitive-file-system],
 285   AC_HELP_STRING([--enable-case-insensitive-file-system],
 286                  [assume file systems are case insensitive]),
 287   [AS_IF([test "$enableval" = yes], [AC_DEFINE([HAVE_CASE_INSENSITIVE_FS])])])
 288
 289 # See if we can handle the job server feature, and if the user wants it.
 290
 291 AC_ARG_ENABLE([job-server],
 292   AC_HELP_STRING([--disable-job-server],
 293                  [disallow recursive make communication during -jN]),
 294   [make_cv_job_server="$enableval" user_job_server="$enableval"],
 295   [make_cv_job_server="yes"])
 296
 297 AS_IF([test "$ac_cv_func_waitpid" = no && test "$ac_cv_func_wait3" = no],
 298       [has_wait_nohang=no],
 299       [has_wait_nohang=yes])
 300
 301 AC_CACHE_CHECK([for SA_RESTART], [make_cv_sa_restart], [
 302   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]],
 303       [[return SA_RESTART;]])],
 304     [make_cv_sa_restart=yes],
 305     [make_cv_sa_restart=no])])
 306
 307 AS_IF([test "$make_cv_sa_restart" != no],
 308 [ AC_DEFINE([HAVE_SA_RESTART], [1],
 309      [Define to 1 if <signal.h> defines the SA_RESTART constant.])
 310 ])
 311
 312 # Only allow jobserver on systems that support it
 313 AS_CASE([/$ac_cv_func_pipe/$ac_cv_func_sigaction/$make_cv_sa_restart/$has_wait_nohang/],
 314   [*/no/*], [make_cv_job_server=no])
 315
 316 # Also supported on OS2 and MinGW
 317 AS_CASE([$host_os], [os2*|mingw*], [make_cv_job_server=yes])
 318
 319 # If we support it and the user didn't disable it, build with jobserver
 320 AS_CASE([/$make_cv_job_server/$user_job_server/],
 321   [*/no/*], [: no jobserver],
 322   [AC_DEFINE(MAKE_JOBSERVER, 1,
 323              [Define to 1 to enable job server support in GNU make.])
 324   ])
 325
 326 # if we have both lstat() and readlink() then we can support symlink
 327 # timechecks.
 328 AS_IF([test "$ac_cv_func_lstat" = yes && test "$ac_cv_func_readlink" = yes],
 329 [ AC_DEFINE([MAKE_SYMLINKS], [1],
 330             [Define to 1 to enable symbolic link timestamp checking.])
 331 ])
 332
 333 # Find the SCCS commands, so we can include them in our default rules.
 334
 335 AC_CACHE_CHECK([for location of SCCS get command], [make_cv_path_sccs_get], [
 336   AS_IF([test -f /usr/sccs/get],
 337         [make_cv_path_sccs_get=/usr/sccs/get],
 338         [make_cv_path_sccs_get=get])
 339 ])
 340 AC_DEFINE_UNQUOTED([SCCS_GET], ["$make_cv_path_sccs_get"],
 341                    [Define to the name of the SCCS 'get' command.])
 342
 343 ac_clean_files="$ac_clean_files s.conftest conftoast" # Remove these later.
 344 AS_IF([(/usr/sccs/admin -n s.conftest || admin -n s.conftest) >/dev/null 2>&1 &&
 345    test -f s.conftest],
 346 [ # We successfully created an SCCS file.
 347   AC_CACHE_CHECK([if SCCS get command understands -G], [make_cv_sys_get_minus_G],
 348     [AS_IF([$make_cv_path_sccs_get -Gconftoast s.conftest >/dev/null 2>&1 &&
 349             test -f conftoast],
 350            [make_cv_sys_get_minus_G=yes],
 351            [make_cv_sys_get_minus_G=no])
 352     ])
 353   AS_IF([test "$make_cv_sys_get_minus_G" = yes],
 354     [AC_DEFINE([SCCS_GET_MINUS_G], [1],
 355      [Define to 1 if the SCCS 'get' command understands the '-G<file>' option.])
 356     ])
 357 ])
 358 rm -f s.conftest conftoast
 359
 360 # Check the system to see if it provides GNU glob.  If not, use our
 361 # local version.
 362 AC_CACHE_CHECK([if system libc has GNU glob], [make_cv_sys_gnu_glob],
 363 [ AC_EGREP_CPP([gnu glob],[
 364 #include <features.h>
 365 #include <glob.h>
 366 #include <fnmatch.h>
 367
 368 #define GLOB_INTERFACE_VERSION 1
 369 #if !defined _LIBC && defined __GNU_LIBRARY__ && __GNU_LIBRARY__ > 1
 370 # include <gnu-versions.h>
 371 # if _GNU_GLOB_INTERFACE_VERSION == GLOB_INTERFACE_VERSION
 372    gnu glob
 373 # endif
 374 #endif],
 375         [make_cv_sys_gnu_glob=yes],
 376         [make_cv_sys_gnu_glob=no])])
 377 AS_IF([test "$make_cv_sys_gnu_glob" = no],
 378 [ GLOBINC='-I$(srcdir)/glob'
 379   GLOBLIB=glob/libglob.a
 380 ])
 381 AC_SUBST([GLOBINC])
 382 AC_SUBST([GLOBLIB])
 383
 384 # Tell automake about this, so it can build the right .c files.
 385 AM_CONDITIONAL([USE_LOCAL_GLOB], [test "$make_cv_sys_gnu_glob" = no])
 386
 387 # Let the makefile know what our build host is
 388
 389 AC_DEFINE_UNQUOTED([MAKE_HOST],["$host"],[Build host information.])
 390 MAKE_HOST="$host"
 391 AC_SUBST([MAKE_HOST])
 392
 393 w32_target_env=no
 394 AM_CONDITIONAL([WINDOWSENV], [false])
 395
 396 AS_CASE([$host],
 397   [*-*-mingw32],
 398    [AM_CONDITIONAL([WINDOWSENV], [true])
 399     w32_target_env=yes
 400     AC_DEFINE([WINDOWS32], [1], [Use platform specific coding])
 401     AC_DEFINE([HAVE_DOS_PATHS], [1], [Use platform specific coding])
 402   ])
 403
 404 AC_DEFINE_UNQUOTED([PATH_SEPARATOR_CHAR],['$PATH_SEPARATOR'],
 405         [Define to the character that separates directories in PATH.])
 406
 407 # Include the Maintainer's Makefile section, if it's here.
 408
 409 MAINT_MAKEFILE=/dev/null
 410 AS_IF([test -r "$srcdir/maintMakefile"],
 411 [ MAINT_MAKEFILE="$srcdir/maintMakefile"
 412 ])
 413 AC_SUBST_FILE([MAINT_MAKEFILE])
 414
 415 # Allow building with dmalloc
 416 AM_WITH_DMALLOC
 417
 418 # Forcibly disable SET_MAKE.  If it's set it breaks things like the test
 419 # scripts, etc.
 420 SET_MAKE=
 421
 422 # Sanity check and inform the user of what we found
 423
 424 AS_IF([test "x$make_badcust" = xyes], [
 425 echo
 426 echo "WARNING: --with-customs specified but no customs.h could be found;"
 427 echo "         disabling Customs support."
 428 echo
 429 ])
 430
 431 AS_CASE([$with_customs],
 432 [""|n|no|y|ye|yes], [:],
 433 [AS_IF([test -f "$with_customs/lib/libcustoms.a"], [:],
 434 [ echo
 435   echo "WARNING: '$with_customs/lib' does not appear to contain the"
 436   echo "         Customs library.  You must build and install Customs"
 437   echo "         before compiling GNU make."
 438   echo
 439 ])])
 440
 441 AS_IF([test "x$has_wait_nohang" = xno],
 442 [ echo
 443   echo "WARNING: Your system has neither waitpid() nor wait3()."
 444   echo "         Without one of these, signal handling is unreliable."
 445   echo "         You should be aware that running GNU make with -j"
 446   echo "         could result in erratic behavior."
 447   echo
 448 ])
 449
 450 AS_IF([test "x$make_cv_job_server" = xno && test "x$user_job_server" = xyes],
 451 [ echo
 452   echo "WARNING: Make job server requires a POSIX-ish system that"
 453   echo "         supports the pipe(), sigaction(), and either"
 454   echo "         waitpid() or wait3() functions.  Your system doesn't"
 455   echo "         appear to provide one or more of those."
 456   echo "         Disabling job server support."
 457   echo
 458 ])
 459
 460 # Specify what files are to be created.
 461 AC_CONFIG_FILES([Makefile glob/Makefile po/Makefile.in config/Makefile \
 462                  doc/Makefile w32/Makefile])
 463
 464 # OK, do it!
 465
 466 AC_OUTPUT
 467
 468 # We only generate the build.sh if we have a build.sh.in; we won't have
 469 # one before we've created a distribution.
 470 AS_IF([test -f "$srcdir/build.sh.in"],
 471 [ ./config.status --file build.sh
 472   chmod +x build.sh
 473 ])
 474
 475 dnl Local Variables:
 476 dnl comment-start: "dnl "
 477 dnl comment-end: ""
 478 dnl comment-start-skip: "\\bdnl\\b\\s *"
 479 dnl compile-command: "make configure config.h.in"
 480 dnl End: