configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #
   3 # Copyright (C) 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
   4 # 2003, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5 # This file is part of GNU Make.
   6 #
   7 # GNU Make is free software; you can redistribute it and/or modify it under
   8 # the terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 3 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # GNU Make is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  14 # FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  15 # details.
  16 #
  17 # You should have received a copy of the GNU General Public License along with
  18 # this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_INIT([GNU make],[3.81.90],[bug-make@gnu.org])
  21
  22 AC_PREREQ(2.59)
  23 AC_REVISION([[$Id: configure.in,v 1.151 2009/08/01 22:09:40 psmith Exp $]])
  24
  25 # Autoconf setup
  26 AC_CONFIG_AUX_DIR(config)
  27 AC_CONFIG_SRCDIR(vpath.c)
  28 AC_CONFIG_HEADERS(config.h)
  29
  30 # Automake setup
  31 AM_INIT_AUTOMAKE([1.9])
  32
  33 # Checks for programs.
  34 AC_PROG_CC
  35 AC_PROG_INSTALL
  36 AC_PROG_RANLIB
  37 AC_PROG_CPP
  38 AC_CHECK_PROG(AR, ar, ar, ar)
  39 # Perl is needed for the test suite (only)
  40 AC_CHECK_PROG(PERL, perl, perl, perl)
  41
  42 # Specialized system macros
  43 AC_CANONICAL_HOST
  44 AC_AIX
  45 AC_ISC_POSIX
  46 AC_MINIX
  47
  48 # Enable gettext, in "external" mode.
  49
  50 AM_GNU_GETTEXT_VERSION(0.14.1)
  51 AM_GNU_GETTEXT([external])
  52
  53 # This test must come as early as possible after the compiler configuration
  54 # tests, because the choice of the file model can (in principle) affect
  55 # whether functions and headers are available, whether they work, etc.
  56 AC_SYS_LARGEFILE
  57
  58 # Checks for libraries.
  59 AC_SEARCH_LIBS(getpwnam, [sun])
  60
  61 # Checks for header files.
  62 AC_HEADER_STDC
  63 AC_HEADER_DIRENT
  64 AC_HEADER_STAT
  65 AC_HEADER_TIME
  66 AC_CHECK_HEADERS(stdlib.h locale.h unistd.h limits.h fcntl.h string.h \
  67                  memory.h sys/param.h sys/resource.h sys/time.h sys/timeb.h)
  68
  69 # Set a flag if we have an ANSI C compiler
  70 if test "$ac_cv_prog_cc_stdc" != no; then
  71   AC_DEFINE(HAVE_ANSI_COMPILER, 1,
  72               [Define to 1 if your compiler conforms to the ANSI C standard.])
  73 fi
  74
  75
  76 # Determine what kind of variadic function calls we support
  77 AC_CHECK_HEADERS(stdarg.h varargs.h, break)
  78
  79 AM_PROG_CC_C_O
  80 AC_C_CONST
  81 AC_TYPE_SIGNAL
  82 AC_TYPE_UID_T
  83 AC_TYPE_PID_T
  84
  85 # Find some definition for uintmax_t
  86
  87 AC_CHECK_TYPE(uintmax_t,,[
  88   uintmax_t="unsigned long"
  89   AC_CHECK_TYPE(unsigned long long,[uintmax_t="unsigned long long"])
  90   AC_DEFINE_UNQUOTED(uintmax_t,$uintmax_t,
  91     [Define uintmax_t if not defined in <stdint.h> or <inttypes.h>.])])
  92
  93 # Find out whether our struct stat returns nanosecond resolution timestamps.
  94
  95 AC_STRUCT_ST_MTIM_NSEC
  96 AC_MSG_CHECKING([whether to use high resolution file timestamps])
  97 AC_CACHE_VAL(make_cv_file_timestamp_hi_res, [
  98   make_cv_file_timestamp_hi_res=no
  99   if test "$ac_cv_struct_st_mtim_nsec" != no; then
 100     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 101 #       if HAVE_INTTYPES_H
 102 #        include <inttypes.h>
 103 #       endif]],
 104                       [[char a[0x7fffffff < (uintmax_t)-1 >> 30 ? 1 : -1];]])],
 105       [make_cv_file_timestamp_hi_res=yes],
 106       [])
 107   fi])
 108 AC_MSG_RESULT($make_cv_file_timestamp_hi_res)
 109 if test "$make_cv_file_timestamp_hi_res" = yes; then
 110   val=1
 111 else
 112   val=0
 113 fi
 114 AC_DEFINE_UNQUOTED(FILE_TIMESTAMP_HI_RES, $val,
 115                    [Use high resolution file timestamps if nonzero.])
 116
 117 if test "$make_cv_file_timestamp_hi_res" = yes; then
 118   # Solaris 2.5.1 needs -lposix4 to get the clock_gettime function.
 119   # Solaris 7 prefers the library name -lrt to the obsolescent name -lposix4.
 120   AC_SEARCH_LIBS(clock_gettime, [rt posix4])
 121   if test "$ac_cv_search_clock_gettime" != no; then
 122     AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 123               [Define to 1 if you have the clock_gettime function.])
 124   fi
 125 fi
 126
 127 # Check for DOS-style pathnames.
 128 pds_AC_DOS_PATHS
 129
 130 # See if we have a standard version of gettimeofday().  Since actual
 131 # implementations can differ, just make sure we have the most common
 132 # one.
 133 AC_CACHE_CHECK([for standard gettimeofday], ac_cv_func_gettimeofday,
 134   [ac_cv_func_gettimeofday=no
 135    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/time.h>
 136                   int main ()
 137                   {
 138                     struct timeval t; t.tv_sec = -1; t.tv_usec = -1;
 139                     exit (gettimeofday (&t, 0) != 0
 140                           || t.tv_sec < 0 || t.tv_usec < 0);
 141                   }]])],
 142                   [ac_cv_func_gettimeofday=yes],
 143                   [ac_cv_func_gettimeofday=no],
 144                   [ac_cv_func_gettimeofday="no (cross-compiling)"])])
 145 if test "$ac_cv_func_gettimeofday" = yes; then
 146   AC_DEFINE(HAVE_GETTIMEOFDAY, 1,
 147             [Define to 1 if you have a standard gettimeofday function])
 148 fi
 149
 150 AC_CHECK_FUNCS( strdup strndup mkstemp mktemp fdopen fileno \
 151                 bsd_signal dup2 getcwd realpath sigsetmask sigaction \
 152                 getgroups seteuid setegid setlinebuf setreuid setregid \
 153                 getrlimit setrlimit setvbuf pipe strerror strsignal \
 154                 lstat readlink atexit)
 155
 156 AC_FUNC_SETVBUF_REVERSED
 157
 158 # Rumor has it that strcasecmp lives in -lresolv on some odd systems.
 159 # It doesn't hurt much to use our own if we can't find it so I don't
 160 # make the effort here.
 161 AC_CHECK_FUNCS(strcasecmp strcmpi stricmp)
 162
 163 # strcoll() is used by the GNU glob library
 164 AC_FUNC_STRCOLL
 165
 166 AC_FUNC_ALLOCA
 167 AC_FUNC_FORK([])
 168 AC_FUNC_VPRINTF
 169 AC_FUNC_CLOSEDIR_VOID
 170
 171 AC_FUNC_GETLOADAVG
 172
 173 # AC_FUNC_GETLOADAVG is documented to set the NLIST_STRUCT value, but it
 174 # doesn't.  So, we will.
 175
 176 if test "$ac_cv_header_nlist_h" = yes; then
 177   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <nlist.h>]],
 178         [[struct nlist nl;
 179           nl.n_name = "string";
 180           return 0;]])],
 181         [make_cv_nlist_struct=yes],
 182         [make_cv_nlist_struct=no])
 183   if test "$make_cv_nlist_struct" = yes; then
 184     AC_DEFINE(NLIST_STRUCT, 1,
 185        [Define to 1 if struct nlist.n_name is a pointer rather than an array.])
 186   fi
 187 fi
 188
 189 AC_CHECK_DECLS([sys_siglist, _sys_siglist, __sys_siglist], , ,
 190   [AC_INCLUDES_DEFAULT
 191 #include <signal.h>
 192 /* NetBSD declares sys_siglist in unistd.h.  */
 193 #if HAVE_UNISTD_H
 194 # include <unistd.h>
 195 #endif
 196 ])
 197
 198
 199 # Check out the wait reality.
 200 AC_CHECK_HEADERS(sys/wait.h,,,[[#include <sys/types.h>]])
 201 AC_CHECK_FUNCS(waitpid wait3)
 202 AC_MSG_CHECKING(for union wait)
 203 AC_CACHE_VAL(make_cv_union_wait, [dnl
 204     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 205 #include <sys/wait.h>]],
 206      [[union wait status; int pid; pid = wait (&status);
 207 #ifdef WEXITSTATUS
 208 /* Some POSIXoid systems have both the new-style macros and the old
 209    union wait type, and they do not work together.  If union wait
 210    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 211         if (WEXITSTATUS (status) != 0) pid = -1;
 212 #ifdef WTERMSIG
 213         /* If we have WEXITSTATUS and WTERMSIG, just use them on ints.  */
 214         -- blow chunks here --
 215 #endif
 216 #endif
 217 #ifdef HAVE_WAITPID
 218         /* Make sure union wait works with waitpid.  */
 219         pid = waitpid (-1, &status, 0);
 220 #endif
 221       ]])],
 222     [make_cv_union_wait=yes],
 223     [make_cv_union_wait=no])])
 224 if test "$make_cv_union_wait" = yes; then
 225   AC_DEFINE(HAVE_UNION_WAIT, 1,
 226             [Define to 1 if you have the \`union wait' type in <sys/wait.h>.])
 227 fi
 228 AC_MSG_RESULT($make_cv_union_wait)
 229
 230
 231 # If we're building on Windows/DOS/OS/2, add some support for DOS drive specs.
 232 if test "$PATH_SEPARATOR" = ';'; then
 233   AC_DEFINE(HAVE_DOS_PATHS, 1,
 234             [Define to 1 if your system requires backslashes or drive specs in pathnames.])
 235 fi
 236
 237
 238 # See if the user wants to use pmake's "customs" distributed build capability
 239
 240 AC_SUBST(REMOTE) REMOTE=stub
 241 use_customs=false
 242 AC_ARG_WITH(customs,
 243   AC_HELP_STRING([--with-customs=DIR],
 244                  [enable remote jobs via Customs--see README.customs]),
 245   [case $withval in
 246     n|no) : ;;
 247     *) make_cppflags="$CPPFLAGS"
 248        case $withval in
 249          y|ye|yes) : ;;
 250          *) CPPFLAGS="$CPPFLAGS -I$with_customs/include/customs"
 251             make_ldflags="$LDFLAGS -L$with_customs/lib" ;;
 252        esac
 253        CF_NETLIBS
 254        AC_CHECK_HEADER(customs.h,
 255                        [use_customs=true
 256                          REMOTE=cstms
 257                          LIBS="$LIBS -lcustoms" LDFLAGS="$make_ldflags"],
 258                        [with_customs=no
 259                          CPPFLAGS="$make_cppflags" make_badcust=yes])
 260        ;;
 261   esac])
 262 # Tell automake about this, so it can include the right .c files.
 263 AM_CONDITIONAL(USE_CUSTOMS, test "$use_customs" = true)
 264
 265 # See if the user asked to handle case insensitive file systems.
 266
 267 AH_TEMPLATE(HAVE_CASE_INSENSITIVE_FS, [Use case insensitive file names])
 268 AC_ARG_ENABLE(case-insensitive-file-system,
 269   AC_HELP_STRING([--enable-case-insensitive-file-system],
 270                  [assume file systems are case insensitive]),
 271   [case $enableval in
 272      yes) AC_DEFINE(HAVE_CASE_INSENSITIVE_FS) ;;
 273    esac])
 274
 275 # See if we can handle the job server feature, and if the user wants it.
 276
 277 AC_ARG_ENABLE(job-server,
 278   AC_HELP_STRING([--disable-job-server],
 279                  [disallow recursive make communication during -jN]),
 280   [make_cv_job_server="$enableval" user_job_server="$enableval"],
 281   [make_cv_job_server="yes"])
 282
 283 has_wait_nohang=yes
 284 case "$ac_cv_func_waitpid/$ac_cv_func_wait3" in
 285   no/no) has_wait_nohang=no ;;
 286 esac
 287
 288 AC_CACHE_CHECK(for SA_RESTART, make_cv_sa_restart, [
 289   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]],
 290       [[return SA_RESTART;]])],
 291     [make_cv_sa_restart=yes],
 292     [make_cv_sa_restart=no])])
 293
 294 if test "$make_cv_sa_restart" != no; then
 295   AC_DEFINE(HAVE_SA_RESTART, 1,
 296      [Define to 1 if <signal.h> defines the SA_RESTART constant.])
 297 fi
 298
 299 # enable make_cv_sa_restart for OS/2 so that the jobserver will be enabled,
 300 # but do it after HAVE_SA_RESTART has been defined.
 301 case "$host_os" in
 302   os2*) make_cv_sa_restart=yes ;;
 303 esac
 304
 305 case "$ac_cv_func_pipe/$ac_cv_func_sigaction/$make_cv_sa_restart/$has_wait_nohang/$make_cv_job_server" in
 306   yes/yes/yes/yes/yes)
 307     AC_DEFINE(MAKE_JOBSERVER, 1,
 308               [Define to 1 to enable job server support in GNU make.]);;
 309 esac
 310
 311 # if we have both lstat() and readlink() then we can support symlink
 312 # timechecks.
 313 case "$ac_cv_func_lstat/$ac_cv_func_readlink" in
 314   yes/yes)
 315     AC_DEFINE(MAKE_SYMLINKS, 1,
 316               [Define to 1 to enable symbolic link timestamp checking.]);;
 317 esac
 318
 319 # Find the SCCS commands, so we can include them in our default rules.
 320
 321 AC_CACHE_CHECK(for location of SCCS get command, make_cv_path_sccs_get, [
 322 if test -f /usr/sccs/get; then
 323   make_cv_path_sccs_get=/usr/sccs/get
 324 else
 325   make_cv_path_sccs_get=get
 326 fi])
 327 AC_DEFINE_UNQUOTED(SCCS_GET, ["$make_cv_path_sccs_get"],
 328                    [Define to the name of the SCCS 'get' command.])
 329
 330 ac_clean_files="$ac_clean_files s.conftest conftoast" # Remove these later.
 331 if ( /usr/sccs/admin -n s.conftest || admin -n s.conftest ) >/dev/null 2>&1 &&
 332    test -f s.conftest; then
 333   # We successfully created an SCCS file.
 334   AC_CACHE_CHECK(if SCCS get command understands -G, make_cv_sys_get_minus_G, [
 335     if $make_cv_path_sccs_get -Gconftoast s.conftest >/dev/null 2>&1 &&
 336        test -f conftoast; then
 337        make_cv_sys_get_minus_G=yes
 338     else
 339        make_cv_sys_get_minus_G=no
 340     fi])
 341   case "$make_cv_sys_get_minus_G" in
 342     yes) AC_DEFINE(SCCS_GET_MINUS_G, 1,
 343            [Define to 1 if the SCCS 'get' command understands the '-G<file>' option.]);;
 344   esac
 345 fi
 346 rm -f s.conftest conftoast
 347
 348 # Check the system to see if it provides GNU glob.  If not, use our
 349 # local version.
 350 AC_MSG_CHECKING(if system libc has GNU glob)
 351 AC_CACHE_VAL(make_cv_sys_gnu_glob, [
 352  AC_EGREP_CPP(gnu glob,[
 353 #include <features.h>
 354 #include <glob.h>
 355 #include <fnmatch.h>
 356
 357 #define GLOB_INTERFACE_VERSION 1
 358 #if !defined _LIBC && defined __GNU_LIBRARY__ && __GNU_LIBRARY__ > 1
 359 # include <gnu-versions.h>
 360 # if _GNU_GLOB_INTERFACE_VERSION == GLOB_INTERFACE_VERSION
 361    gnu glob
 362 # endif
 363 #endif
 364  ], [AC_MSG_RESULT(yes)
 365 make_cv_sys_gnu_glob=yes], [AC_MSG_RESULT([no; using local copy])
 366 make_cv_sys_gnu_glob=no])])
 367 if test "$make_cv_sys_gnu_glob" = no; then
 368   GLOBINC='-I$(srcdir)/glob'
 369   GLOBLIB=glob/libglob.a
 370 fi
 371 AC_SUBST(GLOBINC)
 372 AC_SUBST(GLOBLIB)
 373
 374 # Tell automake about this, so it can build the right .c files.
 375 AM_CONDITIONAL(USE_LOCAL_GLOB, test "$make_cv_sys_gnu_glob" = no)
 376
 377 # Let the makefile know what our build host is
 378
 379 AC_DEFINE_UNQUOTED(MAKE_HOST,"$host",[Build host information.])
 380 MAKE_HOST="$host"
 381 AC_SUBST(MAKE_HOST)
 382
 383 w32_target_env=no
 384 AM_CONDITIONAL([WINDOWSENV], false)
 385
 386 case "$host" in
 387   *-*-mingw32)
 388     AM_CONDITIONAL(WINDOWSENV, true)
 389     w32_target_env=yes
 390     AC_DEFINE([WINDOWS32], [1], [Use platform specific coding])
 391     AC_DEFINE([HAVE_DOS_PATHS], [1], [Use platform specific coding])
 392     ;;
 393 esac
 394
 395 AC_DEFINE_UNQUOTED(PATH_SEPARATOR_CHAR,'$PATH_SEPARATOR',[Define to the character that separates directories in PATH.])
 396
 397 # Include the Maintainer's Makefile section, if it's here.
 398
 399 MAINT_MAKEFILE=/dev/null
 400 if test -r "$srcdir/maintMakefile"; then
 401   MAINT_MAKEFILE="$srcdir/maintMakefile"
 402 fi
 403 AC_SUBST_FILE(MAINT_MAKEFILE)
 404
 405 # Allow building with dmalloc
 406 AM_WITH_DMALLOC
 407
 408 # Forcibly disable SET_MAKE.  If it's set it breaks things like the test
 409 # scripts, etc.
 410 SET_MAKE=
 411
 412 # Sanity check and inform the user of what we found
 413
 414 case "$make_badcust" in
 415   yes) echo
 416        echo "WARNING: --with-customs specified but no customs.h could be found;"
 417        echo "         disabling Customs support."
 418        echo ;;
 419 esac
 420
 421 case "$with_customs" in
 422   ""|n|no|y|ye|yes) ;;
 423   *) if test -f "$with_customs/lib/libcustoms.a"; then
 424        :
 425      else
 426        echo
 427        echo "WARNING: '$with_customs/lib' does not appear to contain the"
 428        echo "         Customs library.  You must build and install Customs"
 429        echo "         before compiling GNU make."
 430        echo
 431      fi ;;
 432 esac
 433
 434 case "$has_wait_nohang" in
 435   no) echo
 436       echo "WARNING: Your system has neither waitpid() nor wait3()."
 437       echo "         Without one of these, signal handling is unreliable."
 438       echo "         You should be aware that running GNU make with -j"
 439       echo "         could result in erratic behavior."
 440       echo ;;
 441 esac
 442
 443 case "$make_cv_job_server/$user_job_server" in
 444   no/yes) echo
 445           echo "WARNING: Make job server requires a POSIX-ish system that"
 446           echo "         supports the pipe(), sigaction(), and either"
 447           echo "         waitpid() or wait3() functions.  Your system doesn't"
 448           echo "         appear to provide one or more of those."
 449           echo "         Disabling job server support."
 450           echo ;;
 451 esac
 452
 453
 454 # Specify what files are to be created.
 455 AC_CONFIG_FILES(Makefile glob/Makefile po/Makefile.in config/Makefile doc/Makefile w32/Makefile)
 456
 457 # OK, do it!
 458
 459 AC_OUTPUT
 460
 461 # We only generate the build.sh if we have a build.sh.in; we won't have
 462 # one before we've created a distribution.
 463 if test -f "$srcdir/build.sh.in"; then
 464   ./config.status --file build.sh
 465   chmod +x build.sh
 466 fi
 467
 468 dnl Local Variables:
 469 dnl comment-start: "dnl "
 470 dnl comment-end: ""
 471 dnl comment-start-skip: "\\bdnl\\b\\s *"
 472 dnl compile-command: "make configure config.h.in"
 473 dnl End: