configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(vpath.c)                dnl A distinctive file to look for in srcdir.
   3 AC_CONFIG_HEADER(config.h)
   4
   5 # We want these before the checks, so the checks can modify their values.
   6 test -z "$CFLAGS" && CFLAGS=-g AC_SUBST(CFLAGS)
   7 test -z "$LDFLAGS" && LDFLAGS=-g AC_SUBST(LDFLAGS)
   8
   9 AC_PROG_CC
  10 AC_PROG_INSTALL
  11 AC_PROG_RANLIB
  12 AC_PROG_CPP                     dnl Later checks need this.
  13 AC_AIX
  14 AC_ISC_POSIX
  15 AC_MINIX
  16 AC_STDC_HEADERS
  17 AC_UNISTD_H
  18 AC_DIR_HEADER
  19 AC_UID_T                        dnl Also does gid_t.
  20 AC_GETGROUPS_T
  21 AC_PID_T
  22 AC_RETSIGTYPE
  23 AC_HAVE_HEADERS(limits.h sys/param.h fcntl.h string.h memory.h)
  24 AC_MINUS_C_MINUS_O
  25 AC_CONST                        dnl getopt needs this.
  26 AC_USG
  27
  28 AC_SUBST(LIBOBJS)
  29
  30 AC_HAVE_FUNCS(getdtablesize sys_siglist _sys_siglist psignal \
  31               dup2 getcwd sigsetmask getgroups setlinebuf \
  32               setreuid setregid)
  33 AC_ALLOCA
  34 AC_VFORK
  35 AC_SETVBUF_REVERSED
  36 AC_GETLOADAVG
  37 AC_STRCOLL
  38
  39 dnl Check out the wait reality.
  40 AC_HAVE_HEADERS(sys/wait.h) AC_HAVE_FUNCS(waitpid wait3)
  41 AC_COMPILE_CHECK(union wait, [#include <sys/types.h>
  42 #include <sys/wait.h>],
  43                  [union wait status; int pid; pid = wait (&status);
  44 #ifdef WEXITSTATUS
  45 /* Some POSIXoid systems have both the new-style macros and the old
  46    union wait type, and they do not work together.  If union wait
  47    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
  48 if (WEXITSTATUS (status) != 0) pid = -1;
  49 #endif
  50 #ifdef HAVE_WAITPID
  51 /* Make sure union wait works with waitpid.  */
  52 pid = waitpid (-1, &status, 0);
  53 #endif
  54 ],
  55                  AC_DEFINE(HAVE_UNION_WAIT))
  56
  57 AC_COMPILE_CHECK(sys_siglist declaration in signal.h,
  58                  [#include <signal.h>], [char *msg = *(sys_siglist + 1);],
  59                  AC_DEFINE(SYS_SIGLIST_DECLARED))
  60
  61 # The presence of the following is not meant to imply
  62 # that make necessarily works on those systems.
  63 AC_DYNIX_SEQ
  64 AC_XENIX_DIR
  65
  66 AC_SUBST(REMOTE) REMOTE=stub
  67 AC_WITH(customs, [REMOTE=cstms
  68 LIBS="$LIBS libcustoms.a"])
  69
  70 echo checking for location of SCCS get command
  71 if test -f /usr/sccs/get; then
  72   AC_DEFINE(SCCS_GET, "/usr/sccs/get")
  73 else
  74   AC_DEFINE(SCCS_GET, "get")
  75 fi
  76
  77 AC_OUTPUT(Makefile build.sh glob/Makefile)
  78
  79 dnl Local Variables:
  80 dnl comment-start: "dnl "
  81 dnl comment-end: ""
  82 dnl comment-start-skip: "\\bdnl\\b\\s *"
  83 dnl compile-command: "make configure config.h.in"
  84 dnl End: