From f3fcd291ec397ad25ef2a25f8cc3c2ffd90f7f1a Mon Sep 17 00:00:00 2001
From: Nedko Arnaudov <nedko@nedk.org>
Date: Thu, 2 Feb 2023 17:19:09 +0200
Subject: [PATCH] media-sound/jack2: add 2.22.0 ebuild

---
 media-sound/jack2/jack2-2.22.0.ebuild | 91 +++++++++++++++++++++++++++++++++++
 1 file changed, 91 insertions(+)
 create mode 100644 media-sound/jack2/jack2-2.22.0.ebuild

diff --git a/media-sound/jack2/jack2-2.22.0.ebuild b/media-sound/jack2/jack2-2.22.0.ebuild
new file mode 100644
index 0000000..842829c
--- /dev/null
+++ b/media-sound/jack2/jack2-2.22.0.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE="threads(+)"
+inherit flag-o-matic python-single-r1 waf-utils multilib-minimal
+inherit git-r3
+
+EGIT_REPO_URI="https://github.com/LADI/jack2.git"
+EGIT_BRANCH="stable"
+EGIT_COMMIT="79015efea2ca4b9d0fcda5703e999a2a938d2590"
+KEYWORDS="amd64 arm arm64 ~loong ppc ppc64 ~riscv x86"
+
+DESCRIPTION="LADI JACK2 is version of the jackdmp, a C++ version of the JACK low-latency audio server for multi-processor machines."
+HOMEPAGE="https://github.com/LADI/jack2"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="2"
+IUSE="+alsa doc ieee1394 libsamplerate metadata opus pam"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	alsa? ( media-libs/alsa-lib[${MULTILIB_USEDEP}] )
+	sys-apps/dbus[${MULTILIB_USEDEP}]
+	libsamplerate? ( media-libs/libsamplerate[${MULTILIB_USEDEP}] )
+	ieee1394? ( media-libs/libffado[${MULTILIB_USEDEP}] )
+	metadata? ( sys-libs/db:=[${MULTILIB_USEDEP}] )
+	opus? ( media-libs/opus[custom-modes,${MULTILIB_USEDEP}] )"
+RDEPEND="
+	${DEPEND}
+	pam? ( sys-auth/realtime-base )
+	!media-sound/jack-audio-connection-kit
+	!media-video/pipewire[jack-sdk(-)]"
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+PDEPEND=""
+
+DOCS=( AUTHORS.rst NEWS.rst README.rst README_NETJACK2 )
+
+PATCHES=( )
+
+src_prepare() {
+	default
+
+	python_fix_shebang waf
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	# clients crash if built with lto
+	# https://github.com/jackaudio/jack2/issues/485
+	filter-lto
+
+	local wafargs=(
+		--mandir="${EPREFIX}"/usr/share/man/man1 # override eclass' for man1
+
+		--alsa=$(usex alsa)
+		--celt=no
+		--db=$(usex metadata)
+		--doxygen=$(multilib_native_usex doc)
+		--firewire=$(usex ieee1394)
+		--iio=no
+		--opus=$(usex opus)
+		--portaudio=no
+		--samplerate=$(usex libsamplerate)
+		--systemd=no
+		--winmme=no
+
+		# obsolete options, migrated to media-sound/jack-example-tools
+		# and will be removed entirely next version
+		--example-tools=no
+		--readline=no
+		--sndfile=no
+		--zalsa=no
+	)
+
+	waf-utils_src_configure "${wafargs[@]}"
+}
+
+multilib_src_compile() {
+	waf-utils_src_compile
+}
+
+multilib_src_install() {
+	waf-utils_src_install
+}
-- 
2.11.4.GIT