rbutil/rbutilqt/rbutilqt.pro

   1
   2
   3 # ccache
   4 unix:!mac {
   5     CCACHE = $$system(which ccache)
   6     !isEmpty(CCACHE) {
   7         message("using ccache")
   8         QMAKE_CXX = ccache g++
   9         QMAKE_CC = ccache gcc
  10     }
  11 }
  12
  13 OBJECTS_DIR = $$OUT_PWD/build/o
  14 UI_DIR = $$OUT_PWD/build/ui
  15 MOC_DIR = $$OUT_PWD/build/moc
  16 RCC_DIR = $$OUT_PWD/build/rcc
  17
  18 # check version of Qt installation
  19 VER = $$find(QT_VERSION, ^4\.[3-9]+.*)
  20 isEmpty(VER) {
  21     !isEmpty(QT_VERSION) error("Qt found:" $$[QT_VERSION])
  22     error("Qt >= 4.3 required!")
  23 }
  24 message("Qt version used:" $$VER)
  25
  26 RBBASE_DIR = $$_PRO_FILE_PWD_
  27 RBBASE_DIR = $$replace(RBBASE_DIR,/rbutil/rbutilqt,)
  28
  29 message("Rockbox Base dir: "$$RBBASE_DIR)
  30
  31 # add a custom rule for pre-building librbspeex
  32 !mac {
  33 rbspeex.commands = @$(MAKE) TARGET_DIR=$$OUT_PWD/ -C $$RBBASE_DIR/tools/rbspeex librbspeex.a
  34 }
  35 mac {
  36 rbspeex.commands = @$(MAKE) TARGET_DIR=$$OUT_PWD/ -C $$RBBASE_DIR/tools/rbspeex librbspeex-universal
  37 }
  38 QMAKE_EXTRA_TARGETS += rbspeex
  39 PRE_TARGETDEPS += rbspeex
  40
  41 # rule for creating ctags file
  42 tags.commands = ctags -R --c++-kinds=+p --fields=+iaS --extra=+q $(SOURCES)
  43 tags.depends = $(SOURCES)
  44 QMAKE_EXTRA_TARGETS += tags
  45
  46 # add a custom rule for making the translations
  47 lrelease.commands = $$[QT_INSTALL_BINS]/lrelease -silent $$_PRO_FILE_
  48 QMAKE_EXTRA_TARGETS += lrelease
  49 !dbg {
  50     PRE_TARGETDEPS += lrelease
  51 }
  52
  53 #custom rules for libucl.a
  54 !mac {
  55 libucl.commands = @$(MAKE) TARGET_DIR=$$OUT_PWD/ -C $$RBBASE_DIR/tools/ucl/src libucl.a
  56 }
  57 mac {
  58 libucl.commands = @$(MAKE) TARGET_DIR=$$OUT_PWD/ -C $$RBBASE_DIR/tools/ucl/src libucl-universal
  59 }
  60 QMAKE_EXTRA_TARGETS += libucl
  61 PRE_TARGETDEPS += libucl
  62
  63 #custom rules for libmkamsboot.a
  64 !mac {
  65 libmkamsboot.commands = @$(MAKE) TARGET_DIR=$$OUT_PWD/ -C $$RBBASE_DIR/rbutil/mkamsboot libmkamsboot.a
  66 }
  67 mac {
  68 libmkamsboot.commands = @$(MAKE) TARGET_DIR=$$OUT_PWD/ -C $$RBBASE_DIR/rbutil/mkamsboot libmkamsboot-universal
  69 }
  70 QMAKE_EXTRA_TARGETS += libmkamsboot
  71 PRE_TARGETDEPS += libmkamsboot
  72
  73 SOURCES += rbutilqt.cpp \
  74  main.cpp \
  75  install.cpp \
  76  base/httpget.cpp \
  77  configure.cpp \
  78  zip/zip.cpp \
  79  zip/unzip.cpp \
  80  base/zipinstaller.cpp \
  81  progressloggergui.cpp \
  82  installtalkwindow.cpp \
  83  base/talkfile.cpp \
  84  base/talkgenerator.cpp \
  85  base/autodetection.cpp \
  86  ../ipodpatcher/ipodpatcher.c \
  87  ../sansapatcher/sansapatcher.c \
  88  ../chinachippatcher/chinachip.c \
  89  browsedirtree.cpp \
  90  themesinstallwindow.cpp \
  91  base/uninstall.cpp \
  92  uninstallwindow.cpp \
  93  base/utils.cpp \
  94  preview.cpp \
  95  base/encoders.cpp \
  96  encttscfggui.cpp \
  97  base/encttssettings.cpp \
  98  base/tts.cpp \
  99  ../../tools/wavtrim.c \
 100  ../../tools/voicefont.c \
 101  base/voicefile.cpp \
 102  createvoicewindow.cpp \
 103  base/rbsettings.cpp \
 104  base/rbunzip.cpp \
 105  base/rbzip.cpp \
 106  base/system.cpp \
 107  sysinfo.cpp \
 108  systrace.cpp \
 109  base/bootloaderinstallbase.cpp \
 110  base/bootloaderinstallmi4.cpp \
 111  base/bootloaderinstallhex.cpp \
 112  base/bootloaderinstallipod.cpp \
 113  base/bootloaderinstallsansa.cpp \
 114  base/bootloaderinstallfile.cpp \
 115  base/bootloaderinstallchinachip.cpp \
 116  base/bootloaderinstallams.cpp \
 117  ../../tools/mkboot.c \
 118  ../../tools/iriver.c
 119
 120 HEADERS += rbutilqt.h \
 121  install.h \
 122  base/httpget.h \
 123  configure.h \
 124  zip/zip.h \
 125  zip/unzip.h \
 126  zip/zipentry_p.h \
 127  zip/unzip_p.h \
 128  zip/zip_p.h \
 129  version.h \
 130  base/zipinstaller.h \
 131  installtalkwindow.h \
 132  base/talkfile.h \
 133  base/talkgenerator.h \
 134  base/autodetection.h \
 135  base/progressloggerinterface.h \
 136  progressloggergui.h \
 137  ../ipodpatcher/ipodpatcher.h \
 138  ../ipodpatcher/ipodio.h \
 139  ../ipodpatcher/parttypes.h \
 140  ../sansapatcher/sansapatcher.h \
 141  ../sansapatcher/sansaio.h \
 142  ../chinachippatcher/chinachip.h \
 143  irivertools/h100sums.h \
 144  irivertools/h120sums.h \
 145  irivertools/h300sums.h \
 146  browsedirtree.h \
 147  themesinstallwindow.h \
 148  base/uninstall.h \
 149  uninstallwindow.h \
 150  base/utils.h \
 151  preview.h \
 152  base/encoders.h \
 153  encttscfggui.h \
 154  base/encttssettings.h \
 155  base/tts.h \
 156  ../../tools/wavtrim.h \
 157  ../../tools/voicefont.h \
 158  base/voicefile.h \
 159  createvoicewindow.h \
 160  base/rbsettings.h \
 161  base/rbunzip.h \
 162  base/rbzip.h \
 163  sysinfo.h \
 164  base/system.h \
 165  systrace.h \
 166  base/bootloaderinstallbase.h \
 167  base/bootloaderinstallmi4.h \
 168  base/bootloaderinstallhex.h \
 169  base/bootloaderinstallipod.h \
 170  base/bootloaderinstallsansa.h \
 171  base/bootloaderinstallfile.h \
 172  base/bootloaderinstallchinachip.h \
 173  base/bootloaderinstallams.h \
 174  ../../tools/mkboot.h \
 175  ../../tools/iriver.h
 176
 177 # Needed by QT on Win
 178 INCLUDEPATH = $$_PRO_FILE_PWD_ $$_PRO_FILE_PWD_/irivertools $$_PRO_FILE_PWD_/zip $$_PRO_FILE_PWD_/zlib $$_PRO_FILE_PWD_/base
 179 INCLUDEPATH += $$RBBASE_DIR/rbutil/ipodpatcher $$RBBASE_DIR/rbutil/sansapatcher $$RBBASE_DIR/tools/rbspeex $$RBBASE_DIR/tools
 180
 181 LIBS += -L$$OUT_PWD -lrbspeex -lmkamsboot -lucl
 182
 183 TEMPLATE = app
 184 dbg {
 185     CONFIG += debug thread qt warn_on
 186     DEFINES -= QT_NO_DEBUG_OUTPUT
 187     message("debug")
 188 }
 189 !dbg {
 190     CONFIG += release thread qt
 191     DEFINES -= QT_NO_DEBUG_OUTPUT
 192     DEFINES += NODEBUG
 193     message("release")
 194 }
 195
 196 TARGET = rbutilqt
 197
 198 FORMS += rbutilqtfrm.ui \
 199  aboutbox.ui \
 200  installfrm.ui \
 201  progressloggerfrm.ui \
 202  configurefrm.ui \
 203  browsedirtreefrm.ui \
 204  installtalkfrm.ui \
 205  themesinstallfrm.ui \
 206  uninstallfrm.ui \
 207  previewfrm.ui \
 208  createvoicefrm.ui \
 209  sysinfofrm.ui \
 210  systracefrm.ui
 211
 212 RESOURCES += $$_PRO_FILE_PWD_/rbutilqt.qrc
 213 win32 {
 214     RESOURCES += $$_PRO_FILE_PWD_/rbutilqt-win.qrc
 215 }
 216 !dbg {
 217     RESOURCES += $$_PRO_FILE_PWD_/rbutilqt-lang.qrc
 218 }
 219
 220 TRANSLATIONS += lang/rbutil_de.ts \
 221  lang/rbutil_fi.ts \
 222  lang/rbutil_fr.ts \
 223  lang/rbutil_gr.ts \
 224  lang/rbutil_he.ts \
 225  lang/rbutil_ja.ts \
 226  lang/rbutil_nl.ts \
 227  lang/rbutil_pt.ts \
 228  lang/rbutil_pt_BR.ts \
 229  lang/rbutil_tr.ts \
 230  lang/rbutil_zh_CN.ts \
 231  lang/rbutil_zh_TW.ts \
 232
 233
 234 QT += network
 235 DEFINES += RBUTIL _LARGEFILE64_SOURCE
 236
 237 win32 {
 238     SOURCES +=  ../ipodpatcher/ipodio-win32.c
 239     SOURCES +=  ../ipodpatcher/ipodio-win32-scsi.c
 240     SOURCES +=  ../sansapatcher/sansaio-win32.c
 241     RC_FILE = rbutilqt.rc
 242     LIBS += -lsetupapi -lnetapi32
 243 }
 244
 245 unix {
 246     SOURCES +=  ../ipodpatcher/ipodio-posix.c
 247     SOURCES +=  ../sansapatcher/sansaio-posix.c
 248 }
 249 unix:!static:!libusb1 {
 250     LIBS += -lusb
 251 }
 252 unix:!static:libusb1 {
 253     DEFINES += LIBUSB1
 254     LIBS += -lusb-1.0
 255 }
 256
 257 unix:static {
 258     # force statically linking of libusb. Libraries that are appended
 259     # later will get linked dynamically again.
 260     LIBS += -Wl,-Bstatic -lusb -Wl,-Bdynamic
 261 }
 262
 263 macx {
 264     QMAKE_MAC_SDK=/Developer/SDKs/MacOSX10.4u.sdk
 265     QMAKE_LFLAGS_PPC=-mmacosx-version-min=10.4 -arch ppc
 266     QMAKE_LFLAGS_X86=-mmacosx-version-min=10.4 -arch i386
 267     CONFIG+=x86 ppc
 268     LIBS += -L/usr/local/lib -framework IOKit
 269     INCLUDEPATH += /usr/local/include
 270     QMAKE_INFO_PLIST = Info.plist
 271     RC_FILE = icons/rbutilqt.icns
 272
 273     # rule for creating a dmg file
 274     dmg.commands = hdiutil create -ov -srcfolder rbutilqt.app/ rbutil.dmg
 275     QMAKE_EXTRA_TARGETS += dmg
 276 }
 277
 278 static {
 279     QTPLUGIN += qtaccessiblewidgets
 280     LIBS += -L$$(QT_BUILD_TREE)/plugins/accessible -lqtaccessiblewidgets
 281     LIBS += -L.
 282     DEFINES += STATIC
 283     message("using static plugin")
 284 }
 285
 286 unix {
 287     target.path = /usr/local/bin
 288     INSTALLS += target
 289 }
 290
 291
 292