Modules/FindSDL_ttf.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4 #[=======================================================================[.rst:
   5 FindSDL_ttf
   6 -----------
   7
   8 Locate SDL_ttf library
   9
  10 This module defines:
  11
  12 ::
  13
  14   SDL_TTF_LIBRARIES, the name of the library to link against
  15   SDL_TTF_INCLUDE_DIRS, where to find the headers
  16   SDL_TTF_FOUND, if false, do not try to link against
  17   SDL_TTF_VERSION_STRING - human-readable string containing the version of SDL_ttf
  18
  19
  20
  21 For backward compatibility the following variables are also set:
  22
  23 ::
  24
  25   SDLTTF_LIBRARY (same value as SDL_TTF_LIBRARIES)
  26   SDLTTF_INCLUDE_DIR (same value as SDL_TTF_INCLUDE_DIRS)
  27   SDLTTF_FOUND (same value as SDL_TTF_FOUND)
  28
  29
  30
  31 $SDLDIR is an environment variable that would correspond to the
  32 ./configure --prefix=$SDLDIR used in building SDL.
  33 #]=======================================================================]
  34
  35 cmake_policy(PUSH)
  36 cmake_policy(SET CMP0159 NEW) # file(STRINGS) with REGEX updates CMAKE_MATCH_<n>
  37
  38 if(NOT SDL_TTF_INCLUDE_DIR AND SDLTTF_INCLUDE_DIR)
  39   set(SDL_TTF_INCLUDE_DIR ${SDLTTF_INCLUDE_DIR} CACHE PATH "directory cache
  40 entry initialized from old variable name")
  41 endif()
  42 find_path(SDL_TTF_INCLUDE_DIR SDL_ttf.h
  43   HINTS
  44     ENV SDLTTFDIR
  45     ENV SDLDIR
  46   PATH_SUFFIXES SDL
  47                 # path suffixes to search inside ENV{SDLDIR}
  48                 include/SDL include/SDL12 include/SDL11 include
  49 )
  50
  51 if(CMAKE_SIZEOF_VOID_P EQUAL 8)
  52   set(VC_LIB_PATH_SUFFIX lib/x64)
  53 else()
  54   set(VC_LIB_PATH_SUFFIX lib/x86)
  55 endif()
  56
  57 if(NOT SDL_TTF_LIBRARY AND SDLTTF_LIBRARY)
  58   set(SDL_TTF_LIBRARY ${SDLTTF_LIBRARY} CACHE FILEPATH "file cache entry
  59 initialized from old variable name")
  60 endif()
  61 find_library(SDL_TTF_LIBRARY
  62   NAMES SDL_ttf
  63   HINTS
  64     ENV SDLTTFDIR
  65     ENV SDLDIR
  66   PATH_SUFFIXES lib ${VC_LIB_PATH_SUFFIX}
  67 )
  68
  69 if(SDL_TTF_INCLUDE_DIR AND EXISTS "${SDL_TTF_INCLUDE_DIR}/SDL_ttf.h")
  70   file(STRINGS "${SDL_TTF_INCLUDE_DIR}/SDL_ttf.h" SDL_TTF_VERSION_MAJOR_LINE REGEX "^#define[ \t]+SDL_TTF_MAJOR_VERSION[ \t]+[0-9]+$")
  71   file(STRINGS "${SDL_TTF_INCLUDE_DIR}/SDL_ttf.h" SDL_TTF_VERSION_MINOR_LINE REGEX "^#define[ \t]+SDL_TTF_MINOR_VERSION[ \t]+[0-9]+$")
  72   file(STRINGS "${SDL_TTF_INCLUDE_DIR}/SDL_ttf.h" SDL_TTF_VERSION_PATCH_LINE REGEX "^#define[ \t]+SDL_TTF_PATCHLEVEL[ \t]+[0-9]+$")
  73   string(REGEX REPLACE "^#define[ \t]+SDL_TTF_MAJOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL_TTF_VERSION_MAJOR "${SDL_TTF_VERSION_MAJOR_LINE}")
  74   string(REGEX REPLACE "^#define[ \t]+SDL_TTF_MINOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL_TTF_VERSION_MINOR "${SDL_TTF_VERSION_MINOR_LINE}")
  75   string(REGEX REPLACE "^#define[ \t]+SDL_TTF_PATCHLEVEL[ \t]+([0-9]+)$" "\\1" SDL_TTF_VERSION_PATCH "${SDL_TTF_VERSION_PATCH_LINE}")
  76   set(SDL_TTF_VERSION_STRING ${SDL_TTF_VERSION_MAJOR}.${SDL_TTF_VERSION_MINOR}.${SDL_TTF_VERSION_PATCH})
  77   unset(SDL_TTF_VERSION_MAJOR_LINE)
  78   unset(SDL_TTF_VERSION_MINOR_LINE)
  79   unset(SDL_TTF_VERSION_PATCH_LINE)
  80   unset(SDL_TTF_VERSION_MAJOR)
  81   unset(SDL_TTF_VERSION_MINOR)
  82   unset(SDL_TTF_VERSION_PATCH)
  83 endif()
  84
  85 set(SDL_TTF_LIBRARIES ${SDL_TTF_LIBRARY})
  86 set(SDL_TTF_INCLUDE_DIRS ${SDL_TTF_INCLUDE_DIR})
  87
  88 include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
  89
  90 FIND_PACKAGE_HANDLE_STANDARD_ARGS(SDL_ttf
  91                                   REQUIRED_VARS SDL_TTF_LIBRARIES SDL_TTF_INCLUDE_DIRS
  92                                   VERSION_VAR SDL_TTF_VERSION_STRING)
  93
  94 # for backward compatibility
  95 set(SDLTTF_LIBRARY ${SDL_TTF_LIBRARIES})
  96 set(SDLTTF_INCLUDE_DIR ${SDL_TTF_INCLUDE_DIRS})
  97 set(SDLTTF_FOUND ${SDL_TTF_FOUND})
  98
  99 mark_as_advanced(SDL_TTF_LIBRARY SDL_TTF_INCLUDE_DIR)
 100
 101 cmake_policy(POP)