CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 # PROJECT_VERSION should have the following structure:
   6 # VERSION[-dev-SUFFIX] where the VERSION can have any form and the suffix
   7 set(PROJECT_VERSION "4.5-beta3"
   8     CACHE STRING "Gromacs version string")
   9
  10 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  11 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  12
  13 if(NOT CMAKE_BUILD_TYPE)
  14     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  15 endif(NOT CMAKE_BUILD_TYPE)
  16
  17 enable_language(C)
  18
  19 ########################################################################
  20 # Fix stupid flags on MSVC
  21 ########################################################################
  22 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  23     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  24     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  25     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  26     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  27 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  28
  29 set(GMX_EXTRA_LIBRARIES)
  30
  31 ######################################################################
  32 # compiler tests
  33 # these need ot be done early (before further tests).
  34 #####################################################################
  35
  36 include(CheckCCompilerFlag)
  37 include(CheckCXXCompilerFlag)
  38
  39 include(gmxCFlags)
  40 gmx_c_flags()
  41
  42 ########################################################################
  43 # User input options                                                   #
  44 ########################################################################
  45 option(GMX_DOUBLE "Use double precision" OFF)
  46 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  47 option(GMX_THREADS    "Build a parallel (threaded-based) version of GROMACS)" ON)
  48 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  49 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  50 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library" OFF)
  51 set(GMX_ACCELERATION "auto"
  52     CACHE STRING "Accelerated kernels. Pick one of: none, SSE, BlueGene, Power6, ia64, altivec")
  53
  54 set(GMX_FFT_LIBRARY "fftw3"
  55     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  56 option(GMX_DISABLE_FFTW_MEASURE
  57        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  58 set(GMX_QMMM_PROGRAM "none"
  59     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
  60 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
  61 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI)" OFF)
  62 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
  63 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
  64 mark_as_advanced(GMX_MPI_IN_PLACE)
  65
  66
  67 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
  68 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
  69
  70 option(USE_VERSION_H "Generate development version string/information" ON)
  71
  72 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries.")
  73
  74
  75 ########################################################################
  76 #Process MPI settings
  77 ########################################################################
  78 if(GMX_MPI)
  79         MESSAGE(WARNING "
  80             There are known problems with some MPI implementations:
  81                      OpenMPI version < 1.4.1
  82                      MVAPICH2 version <= 1.4.1                               *")
  83     if(GMX_THREADS)
  84         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
  85         set(GMX_THREADS OFF CACHE BOOL
  86             "Thread-based parallelization conflicts with MPI." FORCE)
  87     endif(GMX_THREADS)
  88     find_package(MPI)
  89     if(MPI_FOUND)
  90         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
  91         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
  92
  93         include_directories(${MPI_INCLUDE_PATH})
  94         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
  95         add_definitions( -DMPI ) #for FAHCORE
  96         include(gmxTestMPI_IN_PLACE)
  97         if (GMX_MPI_IN_PLACE)
  98             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
  99         endif (GMX_MPI_IN_PLACE)
 100     else(MPI_FOUND)
 101         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 102     endif(MPI_FOUND)
 103     include(gmxTestCatamount)
 104     gmx_test_catamount(GMX_CRAY_XT3)
 105     if(GMX_CRAY_XT3)
 106         set(GMX_NO_SYSTEM 1)
 107         set(GMX_NO_NICE 1)
 108     endif(GMX_CRAY_XT3)
 109     set(GMX_LIB_MPI 1)
 110 endif(GMX_MPI)
 111
 112
 113 #######################################################################
 114 # Check for options incompatible with OpenMM build                    #
 115 #######################################################################
 116 if(GMX_OPENMM)
 117     cmake_minimum_required(VERSION 2.6.4)
 118     # we'll use the built-in fft to avoid unnecessary dependencies
 119     set (GMX_FFT_LIBRARY "fftpack")
 120     if(GMX_MPI)
 121         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 122     endif(GMX_MPI)
 123     if(GMX_THREADS)
 124         message(STATUS "Threads not compatible with OpenMM build, disabled")
 125         set(GMX_THREADS OFF)
 126     endif(GMX_THREADS)
 127     if(GMX_SOFTWARE_INVSQRT)
 128         set(GMX_SOFTWARE_INVSQRT OFF)
 129     endif(GMX_SOFTWARE_INVSQRT)
 130     if(NOT GMX_ACCELERATION MATCHES "auto|none|None|NONE" OR NOT ${GMX_ACCELERATION} STREQUAL "")
 131         message(WARNING "The OpenMM build does not support other acceleration modes!")
 132         set(GMX_ACCELERATION "none")
 133     endif()
 134     if(GMX_FAHCORE)
 135         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 136     endif(GMX_FAHCORE)
 137 endif(GMX_OPENMM)
 138
 139
 140 ########################################################################
 141 # Basic system tests (standard libraries, headers, functions, types)   #
 142 ########################################################################
 143 include(CheckIncludeFiles)
 144 check_include_files(string.h     HAVE_STRING_H)
 145 check_include_files(math.h       HAVE_MATH_H)
 146 check_include_files(limits.h     HAVE_LIMITS_H)
 147 check_include_files(memory.h     HAVE_MEMORY_H)
 148 check_include_files(unistd.h     HAVE_UNISTD_H)
 149 check_include_files(pwd.h        HAVE_PWD_H)
 150 check_include_files(stdint.h     HAVE_STDINT_H)
 151 check_include_files(stdlib.h     HAVE_STDLIB_H)
 152 check_include_files(pthread.h    HAVE_PTHREAD_H)
 153 check_include_files(dirent.h     HAVE_DIRENT_H)
 154 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 155 check_include_files(regex.h      HAVE_REGEX_H)
 156 check_include_files(copyfile.h   HAVE_COPYFILE_H)
 157 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 158 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 159 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 160 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 161 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 162 # SSE support
 163 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 164 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 165 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 166 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 167 check_include_files(io.h                 HAVE_IO_H)
 168
 169
 170 include(CheckFunctionExists)
 171 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 172 check_function_exists(strdup            HAVE_STRDUP)
 173 check_function_exists(vprintf           HAVE_VPRINTF)
 174 check_function_exists(memcmp            HAVE_MEMCMP)
 175 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 176 check_function_exists(memalign          HAVE_MEMALIGN)
 177 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 178 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 179 check_function_exists(isnan             HAVE_ISNAN)
 180 check_function_exists(_isnan            HAVE__ISNAN)
 181 check_function_exists(isfinite          HAVE_ISFINITE)
 182 check_function_exists(_isfinite         HAVE__ISFINITE)
 183 check_function_exists(fsync             HAVE_FSYNC)
 184 check_function_exists(_fileno           HAVE__FILENO)
 185 check_function_exists(fileno            HAVE_FILENO)
 186 check_function_exists(_commit           HAVE__COMMIT)
 187 check_function_exists(copyfile          HAVE_COPYFILE)
 188 # check_function_exists(CopyFile          HAVE_WIN_COPYFILE)
 189
 190 include(CheckLibraryExists)
 191 check_library_exists(m sqrt "" HAVE_LIBM)
 192 check_library_exists(m cbrt "" HAVE_CBRT)
 193
 194
 195 include(CheckTypeSize)
 196
 197 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 198 check_type_size("int"           SIZEOF_INT)
 199 check_type_size("long int"      SIZEOF_LONG_INT)
 200 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 201 check_type_size("off_t"         SIZEOF_OFF_T)
 202 check_type_size("void *"        SIZEOF_VOIDP)
 203
 204 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 205     set(GMX_64_BIT TRUE)
 206 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 207     set(GMX_64_BIT FALSE)
 208 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 209
 210 # Check for some basic types that we *need*, so set these to int if they are not present
 211 check_type_size(uid_t uid_t)
 212 if(NOT uid_t)
 213   set(uid_t int)
 214 else(NOT uid_t)
 215   set(uid_t 0)
 216 endif(NOT uid_t)
 217
 218 check_type_size(gid_t gid_t)
 219 if(NOT gid_t)
 220   set(gid_t 1)
 221 else(NOT gid_t)
 222   set(gid_t 0)
 223 endif(NOT gid_t)
 224
 225 check_type_size(size_t size_t)
 226 if(NOT size_t)
 227   set(size_t int)
 228 else(NOT size_t)
 229   set(size_t 0)
 230 endif(NOT size_t)
 231
 232 check_type_size(off_t off_t)
 233 if(NOT off_t)
 234   set(off_t int)
 235 else(NOT off_t)
 236   set(off_t 0)
 237 endif(NOT off_t)
 238
 239 include(TestBigEndian)
 240 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 241
 242
 243
 244
 245 ########################################################################
 246 # Find external packages                                               #
 247 ########################################################################
 248
 249 find_package(LibXml2)
 250 set(PKG_XML "")
 251 if(LIBXML2_FOUND)
 252     include_directories(${LIBXML2_INCLUDE_DIR})
 253     set(PKG_XML libxml-2.0)
 254     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 255     set(HAVE_LIBXML2 1)
 256 endif(LIBXML2_FOUND)
 257
 258 find_package(X11)
 259 # X11 includes/libraries are only set in the ngmx subdirectory!
 260 if(X11_FOUND)
 261     set(HAVE_X11 1)
 262 endif(X11_FOUND)
 263
 264 if(GMX_THREADS)
 265     include(ThreadMPI)
 266     set(THREAD_MPI_LIB thread_mpi)
 267     set(GMX_MPI 1)
 268     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 269     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 270         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 271     endif()
 272 endif(GMX_THREADS)
 273
 274 if(GMX_OPENMM)
 275     set(CUDA_BUILD_EMULATION OFF)
 276     find_package(CUDA 3.1 REQUIRED)
 277     add_definitions(-DGMX_OPENMM)
 278     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 279         set(CUDA_VERBOSE_BUILD ON)
 280     endif()
 281     find_package(OpenMM)
 282 endif(GMX_OPENMM)
 283
 284 if(APPLE)
 285    find_library(ACCELERATE_FRAMEWORK Accelerate)
 286    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 287 endif(APPLE)
 288
 289 # only bother with finding git and using version.h if the source is a git repo
 290 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 291     if(USE_VERSION_H)
 292         # We need at least git v1.5.1 be able to parse git's date output. If not
 293         # fund or the version is too small, we can't generate version information.
 294         find_package(Git 1.5.1)
 295         # this should at some point become VERSION_LESS
 296         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 297             message("No compatible git version found, won't be able to generate proper development version information.")
 298         endif()
 299     endif()
 300 else()
 301     set(USE_VERSION_H OFF)
 302 endif()
 303
 304 if (GMX_DLOPEN)
 305     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 306 endif (GMX_DLOPEN)
 307
 308 ########################################################################
 309 # Generate development version info for cache
 310 ########################################################################
 311 # set(GEN_VERSION_INFO_INTERNAL "ON")
 312 # include(gmxGenerateVersionString)
 313
 314 ########################################################################
 315 # Our own GROMACS tests
 316 ########################################################################
 317
 318 add_definitions( -DHAVE_CONFIG_H )
 319 include_directories(${CMAKE_BINARY_DIR}/src)
 320 include_directories(${CMAKE_SOURCE_DIR}/include)
 321
 322 include(gmxCheckBuildUserTime)
 323 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 324
 325 include(gmxTestFloatFormat)
 326 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 327                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 328                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 329
 330 include(gmxTestLargeFiles)
 331 gmx_test_large_files(GMX_LARGEFILES)
 332 check_function_exists(fseeko     HAVE_FSEEKO)
 333
 334 include(gmxTestSignal)
 335 gmx_test_retsigtype(RETSIGTYPE)
 336
 337 include(gmxTestInline)
 338 gmx_test_inline(INLINE_KEYWORD)
 339
 340 include(gmxTestRestrict)
 341 gmx_test_inline(RESTRICT_KEYWORD)
 342
 343 include(gmxTestPipes)
 344 gmx_test_pipes(HAVE_PIPES)
 345
 346 include(gmxTestInlineASM)
 347 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 348 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 349
 350 # turn on SSE if supported with reasonable defaults.
 351 if (${GMX_ACCELERATION} STREQUAL "auto")
 352   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)")
 353
 354     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 355
 356     if (GMX_64_BIT)
 357       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 358     else (GMX_64_BIT)
 359       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 360     endif (GMX_64_BIT)
 361
 362     # Determine the assembler/compiler to use
 363   else()
 364     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 365   endif()
 366 endif (${GMX_ACCELERATION} STREQUAL "auto")
 367
 368
 369 include(gmxTestXDR)
 370 gmx_test_xdr(GMX_SYSTEM_XDR)
 371 if(NOT GMX_SYSTEM_XDR)
 372     set(GMX_INTERNAL_XDR 1)
 373 endif(NOT GMX_SYSTEM_XDR)
 374
 375 if(GMX_FORTRAN OR GMX_POWER6)
 376     enable_language(Fortran)
 377     include(FortranCInterface)
 378     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 379     if(extra_under_score)
 380         set(extrasuffix "_")
 381     endif(extra_under_score)
 382
 383     if(isupper)
 384         set(F77_FUNCDEF   "${prefix} ## NAME ## ${suffix}")
 385         set(F77_FUNCDEF_  "${prefix} ## NAME ## ${suffix}${extrasuffix}")
 386     else(isupper)
 387         set(F77_FUNCDEF   "${prefix} ## name ## ${suffix}")
 388         set(F77_FUNCDEF_  "${prefix} ## name ## ${suffix}${extrasuffix}")
 389     endif(isupper)
 390 else(GMX_FORTRAN OR GMX_POWER6)
 391         set(F77_FUNCDEF   "name ## _")
 392         set(F77_FUNCDEF_  "name ## _")
 393 endif(GMX_FORTRAN OR GMX_POWER6)
 394
 395
 396 # Process nonbonded accelerated kernels settings
 397 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 398 if(${GMX_ACCELERATION} STREQUAL "NONE")
 399   # nothing to do
 400 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 401
 402     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 403       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 404     else(CMAKE_GENERATOR MATCHES "Visual Studio")
 405       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 406     endif(CMAKE_GENERATOR MATCHES "Visual Studio")
 407     if (NOT GMX_64_BIT)
 408         # for 32-bit compiles, we might need to turn on sse
 409         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 410         if (XFLAGS_SSE)
 411             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 412         endif (XFLAGS_SSE)
 413         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 414         if (XXFLAGS_SSE)
 415             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 416         endif (XXFLAGS_SSE)
 417     endif (NOT GMX_64_BIT)
 418
 419     if(GMX_IA32_ASM)
 420       if(GMX_DOUBLE)
 421         set(GMX_IA32_SSE2 1)
 422       else()
 423         set(GMX_IA32_SSE 1)
 424       endif()
 425     elseif(GMX_X86_64_ASM)
 426       if(GMX_DOUBLE)
 427         set(GMX_X86_64_SSE2 1)
 428       else()
 429         set(GMX_X86_64_SSE 1)
 430       endif()
 431     endif()
 432
 433 #    if(HAVE_PMMINTRIN_H)
 434 #        set(GMX_SSE3 1)
 435 #    endif(HAVE_PMMINTRIN_H)
 436 #    if(HAVE_SMMINTRIN_H)
 437 #        set(GMX_SSE4_1 1)
 438 #    endif(HAVE_SMMINTRIN_H)
 439
 440 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 441     set(GMX_FORTRAN 1)
 442 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 443     set(GMX_BLUEGENE 1)
 444 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 445     set(GMX_POWER6 1)
 446 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 447     set(GMX_IA64_ASM 1)
 448     set(DISABLE_WATERWATER_NLIST 1)
 449     set(DISABLE_WATER_NLIST 1)
 450 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 451     check_include_files(altivec.h HAVE_ALTIVEC_H)
 452     if(HAVE_ALTIVEC_H)
 453         set(GMX_PPC_ALTIVEC 1)
 454     endif(HAVE_ALTIVEC_H)
 455 else(${GMX_ACCELERATION} STREQUAL "NONE")
 456     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 457 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 458
 459
 460
 461
 462
 463
 464
 465 # Process QM/MM Settings
 466 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 467 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 468     set(GMX_QMMM_GAUSSIAN 1)
 469 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 470     set(GMX_QMMM_MOPAC 1)
 471 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 472     set(GMX_QMMM_GAMESS 1)
 473 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 474     set(GMX_QMMM_ORCA 1)
 475 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 476     # nothing to do
 477 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 478     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 479 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 480
 481 # Process FFT library settings - if not OpenMM build
 482 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 483 set(PKG_FFT "")
 484 set(PKG_FFT_LIBS "")
 485 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 486 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 487     if(GMX_DOUBLE)
 488         find_package(FFTW3 REQUIRED)
 489                 include_directories(${FFTW3_INCLUDE_DIR})
 490         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 491         set(PKG_FFT "fftw3")
 492     else(GMX_DOUBLE)
 493         find_package(FFTW3F REQUIRED)
 494         include_directories(${FFTW3F_INCLUDE_DIR})
 495         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 496         set(PKG_FFT "fftw3f")
 497     endif(GMX_DOUBLE)
 498
 499     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 500         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 501     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 502
 503     set(GMX_FFT_FFTW3 1)
 504
 505 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 506 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 507     if(GMX_DOUBLE)
 508         find_package(FFTW2 REQUIRED)
 509     else(GMX_DOUBLE)
 510         find_package(FFTW2F REQUIRED)
 511     endif(GMX_DOUBLE)
 512
 513     if(NOT FFTW2_FOUND)
 514            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 515     endif(NOT FFTW2_FOUND)
 516     include_directories(${FFTW2_INCLUDE_DIR})
 517     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 518     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 519
 520     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 521         set(FFTW2_NAME_DFFTW 1)
 522     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 523         set(FFTW2_NAME_SFFTW 1)
 524     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 525         set(FFTW2_NAME_FFTW 1)
 526     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 527
 528     set(GMX_FFT_FFTW2 1)
 529 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 530 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 531     find_package(MKL REQUIRED)
 532     include_directories(${MKL_INCLUDE_DIR})
 533     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 534     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 535
 536     set(GMX_FFT_MKL 1)
 537     set(HAVE_MKL 1)
 538
 539 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 540 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 541 #    set(GMX_FFT_ACML 1)
 542 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 543     MESSAGE(STATUS "Using internal FFT library - fftpack")
 544     set(GMX_FFT_FFTPACK 1)
 545 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 546     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 547 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 548
 549 # MKL has BLAS/LAPACK routines
 550 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 551   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 552   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 553 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 554   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 555   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 556 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 557
 558 # Math and thread libraries must often come after all others when linking...
 559 if(HAVE_LIBM)
 560     list(APPEND GMX_EXTRA_LIBRARIES m)
 561 endif(HAVE_LIBM)
 562
 563
 564
 565 if(GMX_FAHCORE)
 566   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 567       "Path to swindirect.h")
 568   include_directories(${COREWRAP_INCLUDE_DIR})
 569 endif(GMX_FAHCORE)
 570
 571 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 572 # these are set after everything else
 573 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 574     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 575         FORCE)
 576     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 577         "Flags used by the compiler during all build types" FORCE)
 578     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 579         "Flags used by the compiler during all build types" FORCE)
 580     set(CMAKE_EXE_LINKER_FLAGS
 581         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 582         CACHE STRING "Linker flags" FORCE)
 583 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 584
 585 ########################################################################
 586 # Specify install locations and which subdirectories to process        #
 587 ########################################################################
 588 set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 589 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 590 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 591 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 592 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 593
 594 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 595
 596
 597 add_subdirectory(share)
 598 add_subdirectory(include)
 599 add_subdirectory(man)
 600 add_subdirectory(src)
 601 add_subdirectory(scripts)
 602
 603 #######################
 604 ## uninstall target
 605 #######################
 606     CONFIGURE_FILE(
 607                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 608                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 609                    IMMEDIATE @ONLY)
 610 ###########################
 611 ADD_CUSTOM_TARGET(uninstall
 612                   "${CMAKE_COMMAND}" -P
 613                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 614 ###########################
 615
 616
 617 ########################################################################
 618 # Tests                                                                #
 619 ########################################################################
 620
 621 enable_testing()
 622 add_test(TestBuildAll make)
 623
 624 add_subdirectory(tests)