m4/wcsdup.m4

   1 # wcsdup.m4 serial 3
   2 dnl Copyright (C) 2011-2020 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_WCSDUP],
   8 [
   9   AC_REQUIRE([gl_WCHAR_H_DEFAULTS])
  10   AC_CACHE_CHECK([for wcsdup],
  11     [gl_cv_func_wcsdup],
  12     [AC_LINK_IFELSE(
  13        [AC_LANG_PROGRAM(
  14           [[
  15 /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
  16    <wchar.h>.
  17    BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be included
  18    before <wchar.h>.  */
  19 #include <stddef.h>
  20 #include <stdio.h>
  21 #include <time.h>
  22 #include <wchar.h>
  23           ]GL_MDA_DEFINES],
  24           [[return wcsdup (L"hello") != NULL;]])
  25        ],
  26        [gl_cv_func_wcsdup=yes],
  27        [gl_cv_func_wcsdup=no])
  28     ])
  29   if test $gl_cv_func_wcsdup = no; then
  30     HAVE_WCSDUP=0
  31   fi
  32 ])