sysdeps/ia64/fpu/s_logb.S

   1 .file "logb.s"
   2
   3 // Copyright (c) 2000, 2001, Intel Corporation
   4 // All rights reserved.
   5 //
   6 // Contributed 2/2/2000 by John Harrison, Ted Kubaska, Bob Norin, Shane Story,
   7 // and Ping Tak Peter Tang of the Computational Software Lab, Intel Corporation.
   8 //
   9 // WARRANTY DISCLAIMER
  10 //
  11 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  12 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  13 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  14 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
  15 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  16 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  17 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  18 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  19 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
  20 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  21 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  22 //
  23 // Intel Corporation is the author of this code, and requests that all
  24 // problem reports or change requests be submitted to it directly at
  25 // http://developer.intel.com/opensource.
  26 //
  27 // History
  28 //==============================================================
  29 // 2/02/00  Initial version
  30 // 2/16/00  Modified to conform to C9X
  31 // 3/16/00  Improved speed
  32 // 4/04/00  Unwind support added
  33 // 5/30/00  Fixed bug when x double-extended denormal
  34 // 8/15/00  Bundle added after call to __libm_error_support to properly
  35 //          set [the previously overwritten] GR_Parameter_RESULT.
  36 //
  37 // API
  38 //==============================================================
  39 // double logb( double x);
  40 //
  41 // Overview of operation
  42 //==============================================================
  43 // The logb function extracts the exponent of x as an integer in
  44 // floating-point format.
  45 // logb computes log2 of x as a double
  46 //
  47 // logb is similar to ilogb but differs in the  following ways:
  48 //         +-inf
  49 //            ilogb: returns INT_MAX
  50 //             logb: returns +inf
  51 //         Nan  returns FP_LOGBNAN (which is either INT_MAX or INT_MIN)
  52 //            ilogb: returns INT_MAX (7fffffff)
  53 //             logb: returns QNAN (quietized SNAN)
  54 //         0    returns FP_ILOGB0 (which is either INT_MIN or -INT_MAX)
  55 //            ilogb: returns -INT_MAX (80000001)
  56 //             logb: returns -inf, raises the divide-by-zero exception,
  57 //                   and calls libm_error_support to set domain error
  58 //
  59 // Registers used
  60 //==============================================================
  61 // general registers used:
  62 // ar.pfs r32
  63 // r33 -> r37
  64 // r38 -> r41 used as parameters to error path
  65 //
  66 // predicate registers used:
  67 // p6, p7, p8
  68 // floating-point registers used:
  69 // f9, f10, f11
  70 // f8, input
  71
  72 #include "libm_support.h"
  73
  74 GR_SAVE_B0          = r34
  75 GR_SAVE_GP          = r35
  76 GR_SAVE_PFS         = r32
  77
  78 GR_Parameter_X      = r38
  79 GR_Parameter_Y      = r39
  80 GR_Parameter_RESULT = r40
  81
  82 .align 32
  83 .global logb#
  84
  85 .section .text
  86 .proc  logb#
  87 .align 32
  88
  89
  90 logb:
  91
  92 // qnan snan inf norm     unorm 0 -+
  93 // 0    0    0   0        1     0 11
  94 // 0                      b
  95 { .mfi
  96       alloc          r32=ar.pfs,1,5,4,0
  97 (p0)  fclass.m.unc  p8,p0 = f8, 0x0b
  98       nop.i 999
  99 }
 100 // X NORMAL
 101 // r37 = exp(f8) - - 0xffff
 102 // sig(f8) = r37
 103 // f8 = convert_to_fp (sig))
 104 { .mfi
 105 (p0)  getf.exp      r35 = f8
 106 (p0)  fnorm         f10=f8
 107       nop.i 999 ;;
 108 }
 109
 110 // qnan snan inf norm     unorm 0 -+
 111 // 1    1    1   0        0     0 11
 112 // e                      3
 113 { .mmf
 114 (p0)  mov      r33 = 0xffff
 115 (p0)  mov      r34 = 0x1ffff
 116 (p0)  fclass.m.unc  p6,p0 = f8, 0xe3 ;;
 117 }
 118
 119 { .mfb
 120 (p0)  and           r36 = r35, r34
 121 (p0)  fclass.m.unc  p7,p0 = f8, 0x07
 122 (p8)  br.cond.spnt  L(LOGB_DENORM) ;;
 123 }
 124
 125 { .mib
 126 (p0)  sub           r37 = r36, r33
 127       nop.i 999
 128 (p6)  br.cond.spnt  L(LOGB_NAN_INF) ;;
 129 }
 130
 131 { .mib
 132 (p0)  setf.sig      f9  = r37
 133       nop.i 999
 134 (p7)  br.cond.spnt  L(LOGB_ZERO) ;;
 135 }
 136
 137 { .mfi
 138       nop.m 999
 139 (p0)  fcvt.xf       f10 = f9
 140       nop.i 999 ;;
 141 }
 142
 143 { .mfb
 144       nop.m 999
 145 (p0)  fnorm.d       f8 = f10
 146 (p0)  br.ret.sptk    b0 ;;
 147 }
 148
 149 L(LOGB_DENORM):
 150 // Form signexp of 2^64 in case need to scale denormal
 151 // Check to see if double-extended denormal
 152 { .mfi
 153 (p0)  mov r38 = 0x1003f
 154 (p0)  fclass.m.unc  p8,p0 = f10, 0x0b
 155       nop.i 999 ;;
 156 }
 157
 158 // Form 2^64 in case need to scale denormal
 159 { .mfi
 160 (p0)  setf.exp f11 = r38
 161       nop.f 999
 162       nop.i 999 ;;
 163 }
 164
 165 // If double-extended denormal add 64 to exponent bias for scaling
 166 // If double-extended denormal form x * 2^64 which is normal
 167 { .mfi
 168 (p8)  add r33 = 64, r33
 169 (p8)  fmpy f10 = f10, f11
 170       nop.i 999 ;;
 171 }
 172
 173 // Logic is the same as normal path but use normalized input
 174 { .mmi
 175 (p0)  getf.exp      r35 = f10 ;;
 176       nop.m 999
 177       nop.i 999 ;;
 178 }
 179
 180 { .mmi
 181 (p0)  and           r36 = r35, r34 ;;
 182 (p0)  sub           r37 = r36, r33
 183       nop.i 999 ;;
 184 }
 185
 186 { .mmi
 187 (p0)  setf.sig      f9  = r37
 188       nop.m 999
 189       nop.i 999 ;;
 190 }
 191
 192 { .mfi
 193       nop.m 999
 194 (p0)  fcvt.xf       f10 = f9
 195       nop.i 999 ;;
 196 }
 197
 198 { .mfb
 199       nop.m 999
 200 (p0)  fnorm.d       f8 = f10
 201 (p0)  br.ret.sptk    b0 ;;
 202 }
 203
 204 L(LOGB_NAN_INF):
 205
 206 // X NAN or INFINITY, return f8 * f8
 207 { .mfb
 208       nop.m 999
 209 (p0)  fma.d      f8= f8,f8,f0
 210 (p0)  br.ret.sptk   b0 ;;
 211 }
 212
 213 .endp logb#
 214 ASM_SIZE_DIRECTIVE(logb)
 215
 216 // Stack operations when calling error support.
 217 //       (1)               (2)                          (3) (call)              (4)
 218 //   sp   -> +          psp -> +                     psp -> +                   sp -> +
 219 //           |                 |                            |                         |
 220 //           |                 | <- GR_Y               R3 ->| <- GR_RESULT            | -> f8
 221 //           |                 |                            |                         |
 222 //           | <-GR_Y      Y2->|                       Y2 ->| <- GR_Y                 |
 223 //           |                 |                            |                         |
 224 //           |                 | <- GR_X               X1 ->|                         |
 225 //           |                 |                            |                         |
 226 //  sp-64 -> +          sp ->  +                     sp ->  +                         +
 227 //    save ar.pfs          save b0                                               restore gp
 228 //    save gp                                                                    restore ar.pfs
 229
 230
 231
 232 .proc __libm_error_region
 233 __libm_error_region:
 234 L(LOGB_ZERO):
 235 .prologue
 236
 237 // f9  = |f8|
 238 // f10 = -f9 = -|f8|
 239 // f9  = 1.0/f10 = -1.0/-|f8|
 240
 241 { .mfi
 242       mov           r41 = 151      // Error code
 243 (p0)  fmerge.s      f9 = f0,f8
 244       nop.i 999
 245 }
 246 ;;
 247
 248
 249 { .mfi
 250       nop.m 999
 251       fmerge.ns     f10 = f0,f9
 252       nop.i 999
 253 }
 254 ;;
 255
 256 // (1)
 257 { .mfi
 258         add   GR_Parameter_Y=-32,sp             // Parameter 2 value
 259         frcpa         f9,p6 = f1,f10
 260 .save   ar.pfs,GR_SAVE_PFS
 261         mov  GR_SAVE_PFS=ar.pfs                 // Save ar.pfs
 262 }
 263 { .mfi
 264 .fframe 64
 265         add sp=-64,sp                          // Create new stack
 266         nop.f 0
 267         mov GR_SAVE_GP=gp                      // Save gp
 268 };;
 269
 270
 271 // (2)
 272 { .mmi
 273         stfd [GR_Parameter_Y] = f0,16         // STORE Parameter 2 on stack
 274         add GR_Parameter_X    = 16,sp         // Parameter 1 address
 275 .save   b0, GR_SAVE_B0
 276         mov GR_SAVE_B0=b0                     // Save b0
 277 };;
 278
 279 .body
 280 // (3)
 281 { .mib
 282         stfd [GR_Parameter_X] = f8            // STORE Parameter 1 on stack
 283         add   GR_Parameter_RESULT = 0,GR_Parameter_Y    // Parameter 3 address
 284         nop.b 0
 285 }
 286 { .mib
 287         stfd [GR_Parameter_Y] = f9            // Store Parameter 3 on stack
 288         add   GR_Parameter_Y = -16,GR_Parameter_Y
 289         br.call.sptk b0=__libm_error_support# // Call error handling function
 290 };;
 291 { .mmi
 292         nop.m 0
 293         nop.m 0
 294         add   GR_Parameter_RESULT = 48,sp
 295 };;
 296
 297 // (4)
 298 { .mmi
 299         ldfd  f8 = [GR_Parameter_RESULT]       // Get return result off stack
 300 .restore sp
 301         add   sp = 64,sp                       // Restore stack pointer
 302         mov   b0 = GR_SAVE_B0                  // Restore return address
 303 };;
 304 { .mib
 305         mov   gp = GR_SAVE_GP                  // Restore gp
 306         mov   ar.pfs = GR_SAVE_PFS             // Restore ar.pfs
 307         br.ret.sptk   b0
 308 };;
 309
 310 .endp __libm_error_region
 311 ASM_SIZE_DIRECTIVE(__libm_error_region)
 312
 313 .type   __libm_error_support#,@function
 314 .global __libm_error_support#