| blob | c8aca1742f78b48f88d14f6f57ae0d42e5c69fa7 |
1 .file "remainder.asm"
2 // Copyright (c) 2000, 2001, Intel Corporation
3 // All rights reserved.
4 //
5 // Contributed 2/2/2000 by John Harrison, Cristina Iordache, Ted Kubaska, Bob Norin,
6 // Shane Story, and Ping Tak Peter Tang of the Computational Software Lab,
7 // Intel Corporation.
8 //
9 // WARRANTY DISCLAIMER
10 //
11 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
12 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
13 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
14 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
15 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
16 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
17 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
18 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
19 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
20 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
21 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
22 //
23 // Intel Corporation is the author of this code, and requests that all
24 // problem reports or change requests be submitted to it directly at
25 // http://developer.intel.com/opensource.
26 //
27 // History
28 //====================================================================
29 // 2/02/00 Initial version
30 // 3/02/00 New Algorithm
31 // 4/04/00 Unwind support added
32 // 7/21/00 Fixed quotient=2^{24*m+23}*1.q1...q23 1 bug
33 // 8/15/00 Bundle added after call to __libm_error_support to properly
34 // set [the previously overwritten] GR_Parameter_RESULT.
35 //11/29/00 Set FR_Y to f9
36 //
37 // API
38 //====================================================================
39 // double remainder(double,double);
40 //
41 // Overview of operation
42 //====================================================================
43 // remainder(a,b)=a-i*b,
44 // where i is an integer such that, if b!=0 and a is finite,
45 // |a/b-i|<=1/2. If |a/b-i|=1/2, i is even.
46 //
47 // Algorithm
48 //====================================================================
49 // a). eliminate special cases
50 // b). if |a/b|<0.25 (first quotient estimate), return a
51 // c). use single precision divide algorithm to get quotient q
52 // rounded to 24 bits of precision
53 // d). calculate partial remainders (using both q and q-ulp);
54 // select one and RZ(a/b) based on the sign of |a|-|b|*q
55 // e). if the exponent difference (exponent(a)-exponent(b))
56 // is less than 24 (quotient estimate<2^{24}-2), use RZ(a/b)
57 // and sticky bits to round to integer; exit loop and
58 // calculate final remainder
59 // f). if exponent(a)-exponent(b)>=24, select new value of a as
60 // the partial remainder calculated using RZ(a/b);
61 // repeat from c).
62 //
63 // Special cases
64 //====================================================================
65 // a=+/- Inf, or b=+/-0: return NaN, call libm_error_support
66 // a=NaN or b=NaN: return NaN
68 #include "libm_support.h"
70 // Registers used
71 //====================================================================
72 // Predicate registers: p6-p14
73 // General registers: r2,r3,r28,r29,r32 (ar.pfs), r33-r39
74 // Floating point registers: f6-f15,f32
76 .section .text
78 GR_SAVE_B0 = r33
79 GR_SAVE_PFS = r34
80 GR_SAVE_GP = r35
81 GR_SAVE_SP = r36
83 GR_Parameter_X = r37
84 GR_Parameter_Y = r38
85 GR_Parameter_RESULT = r39
86 GR_Parameter_TAG = r40
88 FR_X = f10
89 FR_Y = f9
90 FR_RESULT = f8
94 .proc remainder#
95 .align 32
96 .global remainder#
97 .align 32
99 remainder:
100 #ifdef _LIBC
101 .global __remainder
102 .type __remainder,@function
103 __remainder:
104 #endif
105 // inputs in f8, f9
106 // result in f8
108 { .mfi
109 alloc r32=ar.pfs,1,4,4,0
110 // f13=|a|
111 fmerge.s f13=f0,f8
112 nop.i 0
113 }
114 {.mfi
115 nop.m 0
116 // f14=|b|
117 fmerge.s f14=f0,f9
118 nop.i 0;;
119 }
120 {.mlx
121 mov r28=0x2ffdd
122 // r2=2^{23}
123 movl r3=0x4b000000;;
124 }
126 // Y +-NAN, +-inf, +-0? p11
127 { .mfi
128 setf.exp f32=r28
129 (p0) fclass.m.unc p11,p0 = f9, 0xe7
130 nop.i 999
131 }
132 // qnan snan inf norm unorm 0 -+
133 // 1 1 1 0 0 0 11
134 // e 3
135 // X +-NAN, +-inf, ? p9
136 { .mfi
137 nop.m 999
138 (p0) fclass.m.unc p9,p0 = f8, 0xe3
139 nop.i 999;;
140 }
142 {.mfi
143 nop.m 0
144 mov f12=f0
145 nop.i 0
146 }
147 { .mfi
148 // set p7=1
149 cmp.eq.unc p7,p0=r0,r0
150 // Step (1)
151 // y0 = 1 / b in f10
152 frcpa.s1 f10,p6=f13,f14
153 nop.i 0;;
154 }
156 {.bbb
157 (p9) br.cond.spnt L(FREM_X_NAN_INF)
158 (p11) br.cond.spnt L(FREM_Y_NAN_INF_ZERO)
159 nop.b 0
160 } {.mfi
161 nop.m 0
162 // set D flag if a (f8) is denormal
163 fnma.s0 f6=f8,f1,f8
164 nop.i 0;;
165 }
168 L(remloop24):
169 { .mfi
170 nop.m 0
171 // Step (2)
172 // q0 = a * y0 in f12
173 (p6) fma.s1 f12=f13,f10,f0
174 nop.i 0
175 } { .mfi
176 nop.m 0
177 // Step (3)
178 // e0 = 1 - b * y0 in f7
179 (p6) fnma.s1 f7=f14,f10,f1
180 nop.i 0;;
181 } {.mlx
182 nop.m 0
183 // r2=1.25*2^{-24}
184 movl r2=0x33a00000;;
185 }
187 {.mfi
188 nop.m 0
189 // q1=q0*(1+e0)
190 fma.s1 f15=f12,f7,f12
191 nop.i 0
192 }
193 { .mfi
194 nop.m 0
195 // Step (4)
196 // e1 = e0 * e0 + E in f7
197 (p6) fma.s1 f7=f7,f7,f32
198 nop.i 0;;
199 }
200 {.mii
201 (p7) getf.exp r29=f12
202 (p7) mov r28=0xfffd
203 nop.i 0;;
204 }
205 { .mfi
206 // f12=2^{23}
207 setf.s f12=r3
208 // Step (5)
209 // q2 = q1 + e1 * q1 in f11
210 (p6) fma.s.s1 f11=f7,f15,f15
211 nop.i 0
212 } { .mfi
213 nop.m 0
214 // Step (6)
215 // q2 = q1 + e1 * q1 in f6
216 (p6) fma.s1 f6=f7,f15,f15
217 nop.i 0;;
218 }
220 {.mmi
221 // f15=1.25*2^{-24}
222 setf.s f15=r2
223 // q<1/4 ? (i.e. expon< -2)
224 (p7) cmp.gt p7,p0=r28,r29
225 nop.i 0;;
226 }
228 {.mfb
229 // r29= -32+bias
230 mov r29=0xffdf
231 // if |a/b|<1/4, set D flag before returning
232 (p7) fma.d.s0 f9=f9,f0,f8
233 nop.b 0;;
234 }
235 {.mfb
236 nop.m 0
237 // can be combined with bundle above if sign of 0 or
238 // FTZ enabled are not important
239 (p7) fmerge.s f8=f8,f9
240 // return if |a|<4*|b| (estimated quotient < 1/4)
241 (p7) br.ret.spnt b0;;
242 }
243 {.mfi
244 // f7=2^{-32}
245 setf.exp f7=r29
246 // set f8 to current a value | sign
247 fmerge.s f8=f8,f13
248 nop.i 0;;
249 }
252 {.mfi
253 getf.exp r28=f6
254 // last step ? (q<2^{23})
255 fcmp.lt.unc.s1 p0,p12=f6,f12
256 nop.i 0;;
257 }
258 {.mfi
259 nop.m 0
260 // r=a-b*q
261 fnma.s1 f6=f14,f11,f13
262 nop.i 0
263 } {.mfi
264 // r2=23+bias
265 mov r2=0xffff+23
266 // q'=q-q*(1.25*2^{-24}) (q'=q-ulp)
267 fnma.s.s1 f15=f11,f15,f11
268 nop.i 0;;
269 }
270 {.mmi
271 nop.m 0
272 cmp.eq p11,p14=r2,r28
273 nop.i 0;;
274 }
276 .pred.rel "mutex",p11,p14
277 {.mfi
278 nop.m 0
279 // if exp_q=2^23, then r=a-b*2^{23}
280 (p11) fnma.s1 f13=f12,f14,f13
281 nop.i 0
282 }
283 {.mfi
284 nop.m 0
285 // r2=a-b*q'
286 (p14) fnma.s1 f13=f14,f15,f13
287 nop.i 0;;
288 }
289 {.mfi
290 nop.m 0
291 // r>0 iff q=RZ(a/b) and inexact
292 fcmp.gt.unc.s1 p8,p0=f6,f0
293 nop.i 0
294 } {.mfi
295 nop.m 0
296 // r<0 iff q'=RZ(a/b) and inexact
297 (p14) fcmp.lt.unc.s1 p9,p10=f6,f0
298 nop.i 0;;
299 }
301 .pred.rel "mutex",p8,p9
302 {.mfi
303 nop.m 0
304 // (p8) Q=q+(last iteration ? sticky bits:0)
305 // i.e. Q=q+q*x (x=2^{-32} or 0)
306 (p8) fma.s1 f11=f11,f7,f11
307 nop.i 0
308 } {.mfi
309 nop.m 0
310 // (p9) Q=q'+(last iteration ? sticky bits:0)
311 // i.e. Q=q'+q'*x (x=2^{-32} or 0)
312 (p9) fma.s1 f11=f15,f7,f15
313 nop.i 0;;
314 }
316 {.mfb
317 nop.m 0
318 // (p9) set r=r2 (new a, if not last iteration)
319 // (p10) new a =r
320 (p10) mov f13=f6
321 (p12) br.cond.sptk L(remloop24);;
322 }
324 // last iteration
325 {.mfi
326 nop.m 0
327 // set f9=|b|*sgn(a)
328 fmerge.s f9=f8,f9
329 nop.i 0
330 }
331 {.mfi
332 nop.m 0
333 // round to integer
334 fcvt.fx.s1 f11=f11
335 nop.i 0;;
336 }
337 {.mfi
338 nop.m 0
339 // save sign of a
340 fmerge.s f7=f8,f8
341 nop.i 0
342 } {.mfi
343 nop.m 0
344 // normalize
345 fcvt.xf f11=f11
346 nop.i 0;;
347 }
348 {.mfi
349 nop.m 0
350 // This can be removed if sign of 0 is not important
351 // get remainder using sf1
352 fnma.d.s1 f12=f9,f11,f8
353 nop.i 0
354 }
355 {.mfi
356 nop.m 0
357 // get remainder
358 fnma.d.s0 f8=f9,f11,f8
359 nop.i 0;;
360 }
361 {.mfi
362 nop.m 0
363 // f12=0?
364 // This can be removed if sign of 0 is not important
365 fcmp.eq.unc.s1 p8,p0=f12,f0
366 nop.i 0;;
367 }
368 {.mfb
369 nop.m 0
370 // if f8=0, set sign correctly
371 // This can be removed if sign of 0 is not important
372 (p8) fmerge.s f8=f7,f8
373 // return
374 br.ret.sptk b0;;
375 }
378 L(FREM_X_NAN_INF):
380 // Y zero ?
381 {.mfi
382 nop.m 0
383 fma.s1 f10=f9,f1,f0
384 nop.i 0;;
385 }
386 {.mfi
387 nop.m 0
388 fcmp.eq.unc.s1 p11,p0=f10,f0
389 nop.i 0;;
390 }
391 {.mib
392 nop.m 0
393 nop.i 0
394 // if Y zero
395 (p11) br.cond.spnt L(FREM_Y_ZERO);;
396 }
398 // X infinity? Return QNAN indefinite
399 { .mfi
400 nop.m 999
401 (p0) fclass.m.unc p8,p0 = f8, 0x23
402 nop.i 999
403 }
404 // X infinity? Return QNAN indefinite
405 { .mfi
406 nop.m 999
407 (p0) fclass.m.unc p11,p0 = f8, 0x23
408 nop.i 999;;
409 }
410 // Y NaN ?
411 {.mfi
412 nop.m 999
413 (p8) fclass.m.unc p0,p8=f9,0xc3
414 nop.i 0;;
415 }
416 {.mfi
417 nop.m 999
418 // also set Denormal flag if necessary
419 (p8) fma.s0 f9=f9,f1,f0
420 nop.i 0
421 }
422 { .mfi
423 nop.m 999
424 (p8) frcpa.s0 f8,p7 = f8,f8
425 nop.i 999 ;;
426 }
428 {.mfi
429 nop.m 999
430 (p11) mov f10=f8
431 nop.i 0
432 }
433 { .mfi
434 nop.m 999
435 (p8) fma.d f8=f8,f1,f0
436 nop.i 0 ;;
437 }
439 { .mfb
440 nop.m 999
441 frcpa.s0 f8,p7=f8,f9
442 (p11) br.cond.spnt L(EXP_ERROR_RETURN);;
443 }
444 { .mib
445 nop.m 0
446 nop.i 0
447 br.ret.spnt b0 ;;
448 }
451 L(FREM_Y_NAN_INF_ZERO):
453 // Y INF
454 { .mfi
455 nop.m 999
456 (p0) fclass.m.unc p7,p0 = f9, 0x23
457 nop.i 999 ;;
458 }
460 { .mfb
461 nop.m 999
462 (p7) fma.d f8=f8,f1,f0
463 (p7) br.ret.spnt b0 ;;
464 }
466 // Y NAN?
467 { .mfi
468 nop.m 999
469 (p0) fclass.m.unc p9,p0 = f9, 0xc3
470 nop.i 999 ;;
471 }
473 { .mfb
474 nop.m 999
475 (p9) fma.d f8=f9,f1,f0
476 (p9) br.ret.spnt b0 ;;
477 }
479 L(FREM_Y_ZERO):
480 // Y zero? Must be zero at this point
481 // because it is the only choice left.
482 // Return QNAN indefinite
484 // X NAN?
485 { .mfi
486 nop.m 999
487 (p0) fclass.m.unc p9,p10 = f8, 0xc3
488 nop.i 999 ;;
489 }
490 { .mfi
491 nop.m 999
492 (p10) fclass.nm p9,p10 = f8, 0xff
493 nop.i 999 ;;
494 }
496 {.mfi
497 nop.m 999
498 (p9) frcpa f11,p7=f8,f0
499 nop.i 0;;
500 }
502 { .mfi
503 nop.m 999
504 (p10) frcpa f11,p7 = f0,f0
505 nop.i 999;;
506 }
508 { .mfi
509 nop.m 999
510 (p0) fmerge.s f10 = f8, f8
511 nop.i 999
512 }
514 { .mfi
515 nop.m 999
516 (p0) fma.d f8=f11,f1,f0
517 nop.i 999
518 }
521 L(EXP_ERROR_RETURN):
523 { .mib
524 (p0) mov GR_Parameter_TAG = 124
525 nop.i 999
526 (p0) br.sptk __libm_error_region;;
527 }
529 .endp remainder
530 ASM_SIZE_DIRECTIVE(remainder)
531 #ifdef _LIBC
532 ASM_SIZE_DIRECTIVE(__remainder)
533 #endif
537 .proc __libm_error_region
538 __libm_error_region:
539 .prologue
540 { .mfi
541 add GR_Parameter_Y=-32,sp // Parameter 2 value
542 nop.f 0
543 .save ar.pfs,GR_SAVE_PFS
544 mov GR_SAVE_PFS=ar.pfs // Save ar.pfs
545 }
546 { .mfi
547 .fframe 64
548 add sp=-64,sp // Create new stack
549 nop.f 0
550 mov GR_SAVE_GP=gp // Save gp
551 };;
552 { .mmi
553 stfd [GR_Parameter_Y] = FR_Y,16 // Save Parameter 2 on stack
554 add GR_Parameter_X = 16,sp // Parameter 1 address
555 .save b0, GR_SAVE_B0
556 mov GR_SAVE_B0=b0 // Save b0
557 };;
558 .body
559 { .mib
560 stfd [GR_Parameter_X] = FR_X // Store Parameter 1 on stack
561 add GR_Parameter_RESULT = 0,GR_Parameter_Y
562 nop.b 0 // Parameter 3 address
563 }
564 { .mib
565 stfd [GR_Parameter_Y] = FR_RESULT // Store Parameter 3 on stack
566 add GR_Parameter_Y = -16,GR_Parameter_Y
567 br.call.sptk b0=__libm_error_support# // Call error handling function
568 };;
569 { .mmi
570 nop.m 0
571 nop.m 0
572 add GR_Parameter_RESULT = 48,sp
573 };;
574 { .mmi
575 ldfd f8 = [GR_Parameter_RESULT] // Get return result off stack
576 .restore sp
577 add sp = 64,sp // Restore stack pointer
578 mov b0 = GR_SAVE_B0 // Restore return address
579 };;
580 { .mib
581 mov gp = GR_SAVE_GP // Restore gp
582 mov ar.pfs = GR_SAVE_PFS // Restore ar.pfs
583 br.ret.sptk b0 // Return
584 };;
586 .endp __libm_error_region
587 ASM_SIZE_DIRECTIVE(__libm_error_region)
591 .type __libm_error_support#,@function
592 .global __libm_error_support#