scripts/versionlist.awk

   1 # Extract ordered list of version sets from Versions files.
   2 # Copyright (C) 2014 Free Software Foundation, Inc.
   3
   4 BEGIN { in_lib = ""; in_version = 0 }
   5
   6 !in_lib && NF == 2 && $2 == "{" { in_lib = $1; next }
   7 !in_lib { next }
   8
   9 NF == 2 && $2 == "{" {
  10   in_version = 1;
  11   libs[in_lib] = libs[in_lib] "  " $1 "\n";
  12   lib_versions[in_lib, $1] = 1;
  13   all_versions[$1] = 1;
  14   next
  15 }
  16
  17 in_version && $1 == "}" { in_version = 0; next }
  18 in_version { next }
  19
  20 $1 == "}" { in_lib = ""; next }
  21
  22 END {
  23   nlibs = asorti(libs, libs_order);
  24   for (i = 1; i <= nlibs; ++i) {
  25     lib = libs_order[i];
  26
  27     for (v in all_versions) {
  28       if (!((in_lib, v) in lib_versions)) {
  29         libs[lib] = libs[lib] "  " v "\n";
  30       }
  31     }
  32
  33     print lib, "{";
  34     sort = "sort -u -t. -k 1,1 -k 2n,2n -k 3";
  35     printf "%s", libs[lib] | sort;
  36     close(sort);
  37     print "}";
  38   }
  39 }