| blob | 4098fd63f5ea90c8955675b4eb73d8fd77429a02 |
1 /* setjmp for PowerPC64.
2 Copyright (C) 1995-2003, 2004, 2005 Free Software Foundation, Inc.
3 This file is part of the GNU C Library.
5 The GNU C Library is free software; you can redistribute it and/or
6 modify it under the terms of the GNU Lesser General Public
7 License as published by the Free Software Foundation; either
8 version 2.1 of the License, or (at your option) any later version.
10 The GNU C Library is distributed in the hope that it will be useful,
11 but WITHOUT ANY WARRANTY; without even the implied warranty of
12 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 Lesser General Public License for more details.
15 You should have received a copy of the GNU Lesser General Public
16 License along with the GNU C Library; if not, write to the Free
17 Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
18 02111-1307 USA. */
20 #include <sysdep.h>
21 #define _ASM
22 #define _SETJMP_H
23 #ifdef __NO_VMX__
24 #include <novmxsetjmp.h>
25 #else
26 #include <bits/setjmp.h>
27 #endif
28 #include <bp-sym.h>
29 #include <bp-asm.h>
31 #ifndef __NO_VMX__
32 .section ".toc","aw"
33 .LC__dl_hwcap:
34 # ifdef SHARED
35 .tc _rtld_global_ro[TC],_rtld_global_ro
36 # else
37 .tc _dl_hwcap[TC],_dl_hwcap
38 # endif
39 .section ".text"
40 #endif
42 .machine "altivec"
43 ENTRY (BP_SYM (__sigsetjmp))
44 CALL_MCOUNT 2
45 .globl JUMPTARGET(GLUE(__sigsetjmp,_ent))
46 .hidden JUMPTARGET(GLUE(__sigsetjmp,_ent))
47 JUMPTARGET(GLUE(__sigsetjmp,_ent)):
48 CHECK_BOUNDS_BOTH_WIDE_LIT (r3, r8, r9, JB_SIZE)
49 std r1,(JB_GPR1*8)(3)
50 mflr r0
51 #if defined SHARED && !defined IS_IN_rtld
52 ld r5,40(r1) /* Retrieve the callers TOC. */
53 std r5,(JB_GPR2*8)(3)
54 #else
55 std r2,(JB_GPR2*8)(3)
56 #endif
57 std r14,((JB_GPRS+0)*8)(3)
58 stfd fp14,((JB_FPRS+0)*8)(3)
59 #ifdef PTR_MANGLE
60 PTR_MANGLE (r0, r10)
61 #endif
62 std r0,(JB_LR*8)(3)
63 std r15,((JB_GPRS+1)*8)(3)
64 stfd fp15,((JB_FPRS+1)*8)(3)
65 mfcr r0
66 std r16,((JB_GPRS+2)*8)(3)
67 stfd fp16,((JB_FPRS+2)*8)(3)
68 std r0,(JB_CR*8)(3)
69 std r17,((JB_GPRS+3)*8)(3)
70 stfd fp17,((JB_FPRS+3)*8)(3)
71 std r18,((JB_GPRS+4)*8)(3)
72 stfd fp18,((JB_FPRS+4)*8)(3)
73 std r19,((JB_GPRS+5)*8)(3)
74 stfd fp19,((JB_FPRS+5)*8)(3)
75 std r20,((JB_GPRS+6)*8)(3)
76 stfd fp20,((JB_FPRS+6)*8)(3)
77 std r21,((JB_GPRS+7)*8)(3)
78 stfd fp21,((JB_FPRS+7)*8)(3)
79 std r22,((JB_GPRS+8)*8)(3)
80 stfd fp22,((JB_FPRS+8)*8)(3)
81 std r23,((JB_GPRS+9)*8)(3)
82 stfd fp23,((JB_FPRS+9)*8)(3)
83 std r24,((JB_GPRS+10)*8)(3)
84 stfd fp24,((JB_FPRS+10)*8)(3)
85 std r25,((JB_GPRS+11)*8)(3)
86 stfd fp25,((JB_FPRS+11)*8)(3)
87 std r26,((JB_GPRS+12)*8)(3)
88 stfd fp26,((JB_FPRS+12)*8)(3)
89 std r27,((JB_GPRS+13)*8)(3)
90 stfd fp27,((JB_FPRS+13)*8)(3)
91 std r28,((JB_GPRS+14)*8)(3)
92 stfd fp28,((JB_FPRS+14)*8)(3)
93 std r29,((JB_GPRS+15)*8)(3)
94 stfd fp29,((JB_FPRS+15)*8)(3)
95 std r30,((JB_GPRS+16)*8)(3)
96 stfd fp30,((JB_FPRS+16)*8)(3)
97 std r31,((JB_GPRS+17)*8)(3)
98 stfd fp31,((JB_FPRS+17)*8)(3)
99 #ifndef __NO_VMX__
100 ld r5,.LC__dl_hwcap@toc(r2)
101 # ifdef SHARED
102 /* Load _rtld-global._dl_hwcap. */
103 ld r5,RTLD_GLOBAL_RO_DL_HWCAP_OFFSET(r5)
104 # else
105 ld r5,0(r5) /* Load extern _dl_hwcap. */
106 # endif
107 andis. r5,r5,(PPC_FEATURE_HAS_ALTIVEC >> 16)
108 beq L(no_vmx)
109 la r5,((JB_VRS)*8)(3)
110 andi. r6,r5,0xf
111 mfspr r0,VRSAVE
112 stw r0,((JB_VRSAVE)*8)(3)
113 addi r6,r5,16
114 beq+ L(aligned_save_vmx)
115 lvsr v0,0,r5
116 vspltisb v1,-1 /* set v1 to all 1's */
117 vspltisb v2,0 /* set v2 to all 0's */
118 vperm v3,v2,v1,v0 /* v3 contains shift mask with num all 1 bytes
119 on left = misalignment */
122 /* Special case for v20 we need to preserve what is in save area
123 below v20 before obliterating it */
124 lvx v5,0,r5
125 vperm v20,v20,v20,v0
126 vsel v5,v5,v20,v3
127 vsel v20,v20,v2,v3
128 stvx v5,0,r5
130 # define save_2vmx_partial(savevr,prev_savevr,hivr,shiftvr,maskvr,savegpr,addgpr) \
131 addi addgpr,addgpr,32; \
132 vperm savevr,savevr,savevr,shiftvr; \
133 vsel hivr,prev_savevr,savevr,maskvr; \
134 stvx hivr,0,savegpr;
136 save_2vmx_partial(v21,v20,v5,v0,v3,r6,r5)
137 save_2vmx_partial(v22,v21,v5,v0,v3,r5,r6)
138 save_2vmx_partial(v23,v22,v5,v0,v3,r6,r5)
139 save_2vmx_partial(v24,v23,v5,v0,v3,r5,r6)
140 save_2vmx_partial(v25,v24,v5,v0,v3,r6,r5)
141 save_2vmx_partial(v26,v25,v5,v0,v3,r5,r6)
142 save_2vmx_partial(v27,v26,v5,v0,v3,r6,r5)
143 save_2vmx_partial(v28,v27,v5,v0,v3,r5,r6)
144 save_2vmx_partial(v29,v28,v5,v0,v3,r6,r5)
145 save_2vmx_partial(v30,v29,v5,v0,v3,r5,r6)
147 /* Special case for r31 we need to preserve what is in save area
148 above v31 before obliterating it */
149 addi r5,r5,32
150 vperm v31,v31,v31,v0
151 lvx v4,0,r5
152 vsel v5,v30,v31,v3
153 stvx v5,0,r6
154 vsel v4,v31,v4,v3
155 stvx v4,0,r5
156 b L(no_vmx)
158 L(aligned_save_vmx):
159 stvx 20,0,r5
160 addi r5,r5,32
161 stvx 21,0,r6
162 addi r6,r6,32
163 stvx 22,0,r5
164 addi r5,r5,32
165 stvx 23,0,r6
166 addi r6,r6,32
167 stvx 24,0,r5
168 addi r5,r5,32
169 stvx 25,0,r6
170 addi r6,r6,32
171 stvx 26,0,r5
172 addi r5,r5,32
173 stvx 27,0,r6
174 addi r6,r6,32
175 stvx 28,0,r5
176 addi r5,r5,32
177 stvx 29,0,r6
178 addi r6,r6,32
179 stvx 30,0,r5
180 stvx 31,0,r6
181 L(no_vmx):
182 #endif
183 #if defined NOT_IN_libc && defined IS_IN_rtld
184 li r3,0
185 blr
186 #else
187 b JUMPTARGET (BP_SYM (__sigjmp_save))
188 #endif
189 END (BP_SYM (__sigsetjmp))