sysdeps/s390/s390-64/memcpy.S

   1 /* memcpy - copy a block from source to destination.  64 bit S/390 version.
   2    Copyright (C) 2000, 2001, 2003 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 /* INPUT PARAMETERS
  21      %r2 = address of destination memory area
  22      %r3 = address of source memory area
  23      %r4 = number of bytes to copy.  */
  24
  25 #include "sysdep.h"
  26 #include "asm-syntax.h"
  27
  28         .text
  29 ENTRY(memcpy)
  30         ltgr    %r4,%r4
  31         jz      .L3
  32         aghi    %r4,-1              # length - 1
  33         lgr     %r1,%r2             # copy destination address
  34         srlg    %r5,%r4,8
  35         ltgr    %r5,%r5             # < 256 bytes to mvoe ?
  36         jz      .L1
  37         chi     %r5,255             # > 1 MB to move ?
  38         jh      .L4
  39 .L0:    mvc     0(256,%r1),0(%r3)   # move in 256 byte chunks
  40         la      %r1,256(%r1)
  41         la      %r3,256(%r3)
  42         brctg   %r5,.L0
  43 .L1:    bras    %r5,.L2             # setup base pointer for execute
  44         mvc     0(1,%r1),0(%r3)     # instruction for execute
  45 .L2:    ex      %r4,0(%r5)          # execute mvc with length ((%r4)&255)+1
  46 .L3:    br      %r14
  47         # data copies > 1MB are faster with mvcle.
  48 .L4:    aghi    %r4,1               # length + 1
  49         lgr     %r5,%r4             # source length
  50         lgr     %r4,%r3             # source address
  51         lgr     %r3,%r5             # destination length = source length
  52 .L5:    mvcle   %r2,%r4,0           # thats it, MVCLE is your friend
  53         jo      .L5
  54         lgr     %r2,%r1             # return destination address
  55         br      %r14
  56 END(memcpy)
  57 libc_hidden_builtin_def (memcpy)