sysdeps/powerpc/powerpc64/fpu/s_nearbyintf.S

   1 /* Round to int floating-point values.  PowerPC64 version.
   2    Copyright (C) 2011 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Adhemerval Zanella <azanella@br.ibm.com>, 2011
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 /* This has been coded in assembler because GCC makes such a mess of it
  21    when it's coded in C.  */
  22
  23 #include <sysdep.h>
  24
  25
  26 /* float [fp1] nearbyintf(float [fp1]) */
  27
  28         .section        ".toc","aw"
  29 .LC0:   /* 2**23 */
  30         .tc FD_4b000000_0[TC],0x4b00000000000000
  31         .section        ".text"
  32
  33 EALIGN (__nearbyintf, 4, 0)
  34         CALL_MCOUNT 0
  35         fabs    fp0,fp1
  36         lfs     fp13,.LC0@toc(2)
  37         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  38         bgelr   cr7
  39         fsubs   fp12,fp13,fp13  /* generate 0.0 */
  40         fcmpu   cr7,fp1,fp12    /* if (x > 0.0)  */
  41         ble     cr7, L(lessthanzero)
  42         mtfsb0  4*cr7+lt        /* Disable FE_INEXACT exception */
  43         fadds   fp1,fp1,fp13    /* x += TWO23 */
  44         fsubs   fp1,fp1,fp13    /* x -= TWO23 */
  45         fabs    fp1,fp1         /* if (x == 0.0) */
  46         mtfsb0  4*cr1+eq        /* Clear pending FE_INEXACT exception */
  47         blr                     /* x = 0.0; */
  48 L(lessthanzero):
  49         bgelr   cr7             /* if (x < 0.0) */
  50         mtfsb0  4*cr7+lt        /* Disable FE_INEXACT exception */
  51         fsubs   fp1,fp1,fp13    /* x -= TWO23 */
  52         fadds   fp1,fp1,fp13    /* x += TWO23 */
  53         fnabs   fp1,fp1         /* if (x == 0.0) */
  54         mtfsb0  4*cr1+eq        /* Clear pending FE_INEXACT exception */
  55         blr                     /* x = -0.0; */
  56 END (__nearbyintf)
  57
  58 weak_alias (__nearbyintf, nearbyintf)