sysdeps/powerpc/powerpc32/power7/fpu/s_finite.S

   1 /* finite().  PowerPC32/POWER7 version.
   2    Copyright (C) 2010, 2011 Free Software Foundation, Inc.
   3    Contributed by Luis Machado <luisgpm@br.ibm.com>.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <math_ldbl_opt.h>
  22
  23 /* int __finite(x)  */
  24         .section    .rodata.cst8,"aM",@progbits,8
  25         .align 3
  26 .LC0:   /* 1.0 */
  27         .quad       0x3ff0000000000000
  28
  29         .section    ".text"
  30         .type       __finite, @function
  31         .machine    power7
  32 ENTRY (__finite)
  33 #ifdef SHARED
  34         mflr    r11
  35         cfi_register(lr,r11)
  36
  37         SETUP_GOT_ACCESS(r9,got_label)
  38         addis   r9,r9,.LC0-got_label@ha
  39         lfd     fp0,.LC0-got_label@l(r9)
  40
  41         mtlr    r11
  42         cfi_same_value (lr)
  43 #else
  44         lis     r9,.LC0@ha
  45         lfd     fp0,.LC0@l(r9)
  46 #endif
  47         ftdiv   cr7,fp1,fp0
  48         li      r3,1
  49         bflr    30
  50
  51         /* We have -INF/+INF/NaN or a denormal.  */
  52
  53         stwu    r1,-16(r1)    /* Allocate stack space.  */
  54         stfd    fp1,8(r1)     /* Transfer FP to GPR's.  */
  55
  56         ori     2,2,0         /* Force a new dispatch group.  */
  57         lhz     r0,8(r1)      /* Fetch the upper portion of the high word of
  58                               the FP value (where the exponent and sign bits
  59                               are).  */
  60         clrlwi  r0,r0,17      /* r0 = abs(r0).  */
  61         addi    r1,r1,16      /* Reset the stack pointer.  */
  62         cmpwi   cr7,r0,0x7ff0 /* r4 == 0x7ff0?.  */
  63         bltlr   cr7           /* LT means we have a denormal.  */
  64         li      r3,0
  65         blr
  66         END (__finite)
  67
  68 hidden_def (__finite)
  69 weak_alias (__finite, finite)
  70
  71 /* It turns out that the 'double' version will also always work for
  72    single-precision.  */
  73 strong_alias (__finite, __finitef)
  74 hidden_def (__finitef)
  75 weak_alias (__finitef, finitef)
  76
  77 #ifdef NO_LONG_DOUBLE
  78 strong_alias (__finite, __finitel)
  79 weak_alias (__finite, finitel)
  80 #endif
  81
  82 #ifndef IS_IN_libm
  83 # if LONG_DOUBLE_COMPAT(libc, GLIBC_2_0)
  84 compat_symbol (libc, __finite, __finitel, GLIBC_2_0);
  85 compat_symbol (libc, finite, finitel, GLIBC_2_0);
  86 # endif
  87 #endif