sysdeps/unix/sysv/linux/i386/socket.S

   1 /* Copyright (C) 1995, 1996, 1997, 1998 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Library General Public License as
   6    published by the Free Software Foundation; either version 2 of the
   7    License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Library General Public License for more details.
  13
  14    You should have received a copy of the GNU Library General Public
  15    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  16    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  17    Boston, MA 02111-1307, USA.  */
  18
  19 #include <sysdep.h>
  20 #include <socketcall.h>
  21
  22 #define P(a, b) P2(a, b)
  23 #define P2(a, b) a##b
  24
  25         .text
  26 /* The socket-oriented system calls are handled unusally in Linux.
  27    They are all gated through the single `socketcall' system call number.
  28    `socketcall' takes two arguments: the first is the subcode, specifying
  29    which socket function is being called; and the second is a pointer to
  30    the arguments to the specific function.
  31
  32    The .S files for the other calls just #define socket and #include this.  */
  33
  34 #ifndef __socket
  35 #ifndef NO_WEAK_ALIAS
  36 #define __socket P(__,socket)
  37 #else
  38 #define __socket socket
  39 #endif
  40 #endif
  41
  42 .globl __socket
  43 ENTRY (__socket)
  44
  45         /* Save registers.  */
  46         movl %ebx, %edx
  47
  48         movl $SYS_ify(socketcall), %eax /* System call number in %eax.  */
  49
  50         /* Use ## so `socket' is a separate token that might be #define'd.  */
  51         movl $P(SOCKOP_,socket), %ebx   /* Subcode is first arg to syscall.  */
  52         lea 4(%esp), %ecx               /* Address of args is 2nd arg.  */
  53
  54         /* Do the system call trap.  */
  55         int $0x80
  56
  57         /* Restore registers.  */
  58         movl %edx, %ebx
  59
  60         /* %eax is < 0 if there was an error.  */
  61         cmpl $-125, %eax
  62         jae SYSCALL_ERROR_LABEL
  63
  64         /* Successful; return the syscall's value.  */
  65 L(pseudo_end):
  66         ret
  67
  68 PSEUDO_END (__socket)
  69
  70 #ifndef NO_WEAK_ALIAS
  71 weak_alias (__socket, socket)
  72 #endif