sysdeps/powerpc/powerpc32/fpu/s_roundf.S

   1 /* roundf  function.  PowerPC32 version.
   2    Copyright (C) 2004, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 1 Franklin Street, Fifth Floor, Boston MA
  18    02110-1301 USA.  */
  19
  20 #include <sysdep.h>
  21
  22         .section        .rodata.cst8,"aM",@progbits,8
  23         .align  2
  24 .LC0:   /* 2**23 */
  25         .long 0x4b000000
  26 .LC1:   /* 0.5 */
  27         .long 0x3f000000
  28
  29 /* float [fp1] roundf  (float x [fp1])
  30    IEEE 1003.1 round function.  IEEE specifies "round to the nearest
  31    integer value, rounding halfway cases away from zero, regardless of
  32    the current rounding mode."  However PowerPC Architecture defines
  33    "Round to Nearest" as "Choose the best approximation. In case of a
  34    tie, choose the one that is even (least significant bit o).".
  35    So we can't use the PowerPC "Round to Nearest" mode. Instead we set
  36    "Round toward Zero" mode and round by adding +-0.5 before rounding
  37    to the integer value.  */
  38
  39         .section        ".text"
  40 ENTRY (__roundf )
  41         mffs    fp11            /* Save current FPU rounding mode.  */
  42 #ifdef SHARED
  43         mflr    r11
  44         cfi_register(lr,r11)
  45         bcl     20,31,1f
  46 1:      mflr    r9
  47         addis   r9,r9,.LC0-1b@ha
  48         addi    r9,r9,.LC0-1b@l
  49         mtlr    r11
  50         cfi_same_value (lr)
  51         lfs     fp13,0(r9)
  52 #else
  53         lis     r9,.LC0@ha
  54         lfs     fp13,.LC0@l(r9)
  55 #endif
  56         fabs    fp0,fp1
  57         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  58         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  59         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  60         bnllr-  cr7
  61         mtfsfi  7,1             /* Set rounding mode toward 0.  */
  62 #ifdef SHARED
  63         lfs     fp10,.LC1-.LC0(r9)
  64 #else
  65         lis     r9,.LC1@ha
  66         lfs     fp10,.LC1@l(r9)
  67 #endif
  68         ble-    cr6,.L4
  69         fadds   fp1,fp1,fp10    /* x+= 0.5;  */
  70         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  71         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  72         fabs    fp1,fp1         /* if (x == 0.0)  */
  73                                 /* x = 0.0; */
  74         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  75         blr
  76 .L4:
  77         fsubs   fp9,fp1,fp10    /* x+= 0.5;  */
  78         bge-    cr6,.L9         /* if (x < 0.0)  */
  79         fsubs   fp1,fp9,fp13    /* x-= TWO23;  */
  80         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  81         fnabs   fp1,fp1         /* if (x == 0.0)  */
  82                                 /* x = -0.0; */
  83 .L9:
  84         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  85         blr
  86         END (__roundf)
  87
  88 weak_alias (__roundf, roundf)
  89