sysdeps/powerpc/powerpc32/fpu/s_round.S

   1 /* round function.  PowerPC32 version.
   2    Copyright (C) 2004, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 1 Franklin Street, Fifth Floor, Boston MA
  18    02110-1301 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <math_ldbl_opt.h>
  22
  23         .section        .rodata.cst8,"aM",@progbits,8
  24         .align  2
  25 .LC0:   /* 2**52 */
  26         .long 0x59800000
  27 .LC1:   /* 0.5 */
  28         .long 0x3f000000
  29
  30 /* double [fp1] round (double x [fp1])
  31    IEEE 1003.1 round function.  IEEE specifies "round to the nearest
  32    integer value, rounding halfway cases away from zero, regardless of
  33    the current rounding mode."  However PowerPC Architecture defines
  34    "Round to Nearest" as "Choose the best approximation. In case of a
  35    tie, choose the one that is even (least significant bit o).".
  36    So we can't use the PowerPC "Round to Nearest" mode. Instead we set
  37    "Round toward Zero" mode and round by adding +-0.5 before rounding
  38    to the integer value.  */
  39
  40         .section        ".text"
  41 ENTRY (__round)
  42         mffs    fp11            /* Save current FPU rounding mode.  */
  43 #ifdef SHARED
  44         mflr    r11
  45         cfi_register(lr,r11)
  46         bcl     20,31,1f
  47 1:      mflr    r9
  48         addis   r9,r9,.LC0-1b@ha
  49         addi    r9,r9,.LC0-1b@l
  50         mtlr    r11
  51         cfi_same_value (lr)
  52         lfs     fp13,0(r9)
  53 #else
  54         lis     r9,.LC0@ha
  55         lfs     fp13,.LC0@l(r9)
  56 #endif
  57         fabs    fp0,fp1
  58         fsub    fp12,fp13,fp13  /* generate 0.0  */
  59         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  60         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  61         bnllr-  cr7
  62         mtfsfi  7,1             /* Set rounding mode toward 0.  */
  63 #ifdef SHARED
  64         lfs     fp10,.LC1-.LC0(r9)
  65 #else
  66         lis     r9,.LC1@ha
  67         lfs     fp10,.LC1@l(r9)
  68 #endif
  69         ble-    cr6,.L4
  70         fadd    fp1,fp1,fp10    /* x+= 0.5;  */
  71         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  72         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  73         fabs    fp1,fp1         /* if (x == 0.0)  */
  74                                 /* x = 0.0; */
  75         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  76         blr
  77 .L4:
  78         fsub    fp9,fp1,fp10    /* x+= 0.5;  */
  79         bge-    cr6,.L9         /* if (x < 0.0)  */
  80         fsub    fp1,fp9,fp13    /* x-= TWO52;  */
  81         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  82         fnabs   fp1,fp1         /* if (x == 0.0)  */
  83                                 /* x = -0.0; */
  84 .L9:
  85         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  86         blr
  87         END (__round)
  88
  89 weak_alias (__round, round)
  90
  91 #ifdef NO_LONG_DOUBLE
  92 weak_alias (__round, roundl)
  93 strong_alias (__round, __roundl)
  94 #endif
  95 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_1)
  96 compat_symbol (libm, __round, roundl, GLIBC_2_1)
  97 #endif