sysdeps/ia64/fpu/e_exp10f.S

   1 .file "exp10f.s"
   2
   3
   4 // Copyright (c) 2000 - 2003, Intel Corporation
   5 // All rights reserved.
   6 //
   7 // Contributed 2000 by the Intel Numerics Group, Intel Corporation
   8 //
   9 // Redistribution and use in source and binary forms, with or without
  10 // modification, are permitted provided that the following conditions are
  11 // met:
  12 //
  13 // * Redistributions of source code must retain the above copyright
  14 // notice, this list of conditions and the following disclaimer.
  15 //
  16 // * Redistributions in binary form must reproduce the above copyright
  17 // notice, this list of conditions and the following disclaimer in the
  18 // documentation and/or other materials provided with the distribution.
  19 //
  20 // * The name of Intel Corporation may not be used to endorse or promote
  21 // products derived from this software without specific prior written
  22 // permission.
  23
  24 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  25 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  26 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  27 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
  28 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  30 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  31 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  32 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
  33 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  34 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  35 //
  36 // Intel Corporation is the author of this code, and requests that all
  37 // problem reports or change requests be submitted to it directly at
  38 // http: //www.intel.com/software/products/opensource/libraries/num.htm.
  39 //
  40 // History
  41 //==============================================================
  42 // 08/25/00 Initial version
  43 // 05/20/02 Cleaned up namespace and sf0 syntax
  44 // 09/06/02 Improved performance and accuracy; no inexact flags on exact cases
  45 // 01/29/03 Added missing } to bundle templates
  46 //
  47 // API
  48 //==============================================================
  49 // float exp10f(float)
  50 //
  51 // Overview of operation
  52 //==============================================================
  53 // Background
  54 //
  55 // Implementation
  56 //
  57 // Let x= (K + fh + fl + r)/log2(10), where
  58 // K is an integer, fh= 0.b1 b2 b3 b4 b5,
  59 // fl= 2^{-5}* 0.b6 b7 b8 b8 b10 (fh, fl >= 0),
  60 // and |r|<2^{-11}
  61 // Th is a table that stores 2^fh (32 entries) rounded to
  62 // double extended precision (only mantissa is stored)
  63 // Tl is a table that stores 2^fl (32 entries) rounded to
  64 // double extended precision (only mantissa is stored)
  65 //
  66 // 10^x is approximated as
  67 // 2^K * Th [ f ] * Tl [ f ] * (1+c1*r+c2*r^2)
  68
  69 // Note there are only 10 non-zero values that produce an exact result:
  70 //  1.0, 2.0, ... 10.0.
  71 // We test for these cases and use s1 to avoid setting the inexact flag.
  72
  73 // Special values
  74 //==============================================================
  75 // exp10(0)= 1
  76 // exp10(+inf)= inf
  77 // exp10(-inf)= 0
  78 //
  79
  80 // Registers used
  81 //==============================================================
  82 // r2-r3, r14-r40
  83 // f6-f15, f32-f51
  84 // p6-p9, p12
  85 //
  86
  87
  88 GR_TBL_START        = r2
  89 GR_LOG_TBL          = r3
  90
  91 GR_OF_LIMIT         = r14
  92 GR_UF_LIMIT         = r15
  93 GR_EXP_CORR         = r16
  94 GR_F_low            = r17
  95 GR_F_high           = r18
  96 GR_K                = r19
  97 GR_Flow_ADDR        = r20
  98
  99 GR_BIAS             = r21
 100 GR_Fh               = r22
 101 GR_Fh_ADDR          = r23
 102 GR_EXPMAX           = r24
 103
 104 GR_ROUNDVAL         = r26
 105 GR_MASK             = r27
 106 GR_KF0              = r28
 107 GR_MASK_low         = r29
 108 GR_COEFF_START      = r30
 109 GR_exact_limit      = r31
 110
 111 GR_SAVE_B0          = r33
 112 GR_SAVE_PFS         = r34
 113 GR_SAVE_GP          = r35
 114 GR_SAVE_SP          = r36
 115
 116 GR_Parameter_X      = r37
 117 GR_Parameter_Y      = r38
 118 GR_Parameter_RESULT = r39
 119 GR_Parameter_TAG    = r40
 120
 121
 122 FR_X                = f10
 123 FR_Y                = f1
 124 FR_RESULT           = f8
 125
 126
 127 FR_COEFF1           = f6
 128 FR_COEFF2           = f7
 129 FR_R                = f9
 130 FR_LOG2_10          = f10
 131
 132 FR_2P53             = f11
 133 FR_KF0              = f12
 134 FR_COEFF3           = f13
 135 FR_COEFF4           = f14
 136 FR_UF_LIMIT         = f15
 137
 138 FR_OF_LIMIT         = f32
 139 FR_DX_L210          = f33
 140 FR_ROUNDVAL         = f34
 141 FR_KF               = f35
 142
 143 FR_2_TO_K           = f36
 144 FR_T_low            = f37
 145 FR_T_high           = f38
 146
 147 FR_P12              = f41
 148 FR_T_low_K          = f42
 149 FR_T                = f44
 150 FR_P                = f45
 151
 152 FR_E                = f49
 153 FR_exact_limit      = f50
 154
 155 FR_int_x            = f51
 156
 157
 158 // Data tables
 159 //==============================================================
 160
 161 RODATA
 162
 163 .align 16
 164
 165 LOCAL_OBJECT_START(poly_coeffs)
 166
 167 data8 0xd49a784bcd1b8afe, 0x00003fcb // log2(10)*2^(10-63)
 168 data8 0xb17217f7d1cf79ab, 0x00004033 // C_1 * 2^53
 169 data8 0xf5fdeffc162c7541, 0x00004066 // C_2 * 2^106
 170 LOCAL_OBJECT_END(poly_coeffs)
 171
 172
 173 LOCAL_OBJECT_START(T_table)
 174
 175 // 2^{0.00000 b6 b7 b8 b9 b10}
 176 data8 0x8000000000000000, 0x8016302f17467628
 177 data8 0x802c6436d0e04f50, 0x80429c17d77c18ed
 178 data8 0x8058d7d2d5e5f6b0, 0x806f17687707a7af
 179 data8 0x80855ad965e88b83, 0x809ba2264dada76a
 180 data8 0x80b1ed4fd999ab6c, 0x80c83c56b50cf77f
 181 data8 0x80de8f3b8b85a0af, 0x80f4e5ff089f763e
 182 data8 0x810b40a1d81406d4, 0x81219f24a5baa59d
 183 data8 0x813801881d886f7b, 0x814e67cceb90502c
 184 data8 0x8164d1f3bc030773, 0x817b3ffd3b2f2e47
 185 data8 0x8191b1ea15813bfd, 0x81a827baf7838b78
 186 data8 0x81bea1708dde6055, 0x81d51f0b8557ec1c
 187 data8 0x81eba08c8ad4536f, 0x820225f44b55b33b
 188 data8 0x8218af4373fc25eb, 0x822f3c7ab205c89a
 189 data8 0x8245cd9ab2cec048, 0x825c62a423d13f0c
 190 data8 0x8272fb97b2a5894c, 0x828998760d01faf3
 191 data8 0x82a0393fe0bb0ca8, 0x82b6ddf5dbc35906
 192 //
 193 //
 194 // 2^{0.b1 b2 b3 b4 b5}
 195 data8 0x8000000000000000, 0x82cd8698ac2ba1d7
 196 data8 0x85aac367cc487b14, 0x88980e8092da8527
 197 data8 0x8b95c1e3ea8bd6e6, 0x8ea4398b45cd53c0
 198 data8 0x91c3d373ab11c336, 0x94f4efa8fef70961
 199 data8 0x9837f0518db8a96f, 0x9b8d39b9d54e5538
 200 data8 0x9ef5326091a111ad, 0xa27043030c496818
 201 data8 0xa5fed6a9b15138ea, 0xa9a15ab4ea7c0ef8
 202 data8 0xad583eea42a14ac6, 0xb123f581d2ac258f
 203 data8 0xb504f333f9de6484, 0xb8fbaf4762fb9ee9
 204 data8 0xbd08a39f580c36be, 0xc12c4cca66709456
 205 data8 0xc5672a115506dadd, 0xc9b9bd866e2f27a2
 206 data8 0xce248c151f8480e3, 0xd2a81d91f12ae45a
 207 data8 0xd744fccad69d6af4, 0xdbfbb797daf23755
 208 data8 0xe0ccdeec2a94e111, 0xe5b906e77c8348a8
 209 data8 0xeac0c6e7dd24392e, 0xefe4b99bdcdaf5cb
 210 data8 0xf5257d152486cc2c, 0xfa83b2db722a033a
 211 LOCAL_OBJECT_END(T_table)
 212
 213
 214
 215 .section .text
 216 GLOBAL_IEEE754_ENTRY(exp10f)
 217
 218
 219 {.mfi
 220        alloc r32= ar.pfs, 1, 4, 4, 0
 221        // will continue only for non-zero normal/denormal numbers
 222        fclass.nm.unc p12, p7= f8, 0x1b
 223        nop.i 0
 224 }
 225 {.mlx
 226        // GR_TBL_START= pointer to log2(10), C_1...C_4 followed by T_table
 227        addl GR_TBL_START= @ltoff(poly_coeffs), gp
 228        movl GR_ROUNDVAL= 0x3fc00000             // 1.5 (SP)
 229 }
 230 ;;
 231
 232 {.mfi
 233        ld8 GR_COEFF_START= [ GR_TBL_START ]     // Load pointer to coeff table
 234        fcmp.lt.s1 p6, p8= f8, f0                // X<0 ?
 235        nop.i 0
 236 }
 237 ;;
 238
 239 {.mlx
 240        nop.m 0
 241        movl GR_UF_LIMIT= 0xc2349e35             // (-2^7-22) / log2(10)
 242 }
 243 {.mlx
 244        setf.s FR_ROUNDVAL= GR_ROUNDVAL
 245        movl GR_OF_LIMIT= 0x421a209a             // Overflow threshold
 246 }
 247 ;;
 248
 249 {.mib
 250        ldfe FR_LOG2_10= [ GR_COEFF_START ], 16  // load log2(10)*2^(10-63)
 251        nop.i 0
 252  (p12) br.cond.spnt SPECIAL_exp10               // Branch if nan, inf, zero
 253 }
 254 ;;
 255
 256 {.mfi
 257        setf.s FR_OF_LIMIT= GR_OF_LIMIT           // Set overflow limit
 258        fma.s0 f8= f8, f1, f0                     // normalize x
 259        nop.i 0
 260 }
 261 ;;
 262
 263 {.mfi
 264        nop.m 0
 265  (p8)  fcvt.fx.s1 FR_int_x = f8                   // Convert x to integer
 266        nop.i 0
 267 }
 268 {.mfi
 269        setf.s FR_UF_LIMIT= GR_UF_LIMIT            // Set underflow limit
 270        fma.s1 FR_KF0= f8, FR_LOG2_10, FR_ROUNDVAL // y= (x*log2(10)*2^10 +
 271                                                   //    1.5*2^63) * 2^(-63)
 272        mov GR_EXP_CORR= 0xffff-126
 273 }
 274 ;;
 275
 276 {.mfi
 277        ldfe FR_COEFF1= [ GR_COEFF_START ], 16    // load C_1
 278        fms.s1 FR_KF= FR_KF0, f1, FR_ROUNDVAL     // (K+f)*2^(10-63)
 279        mov GR_MASK= 1023
 280 }
 281 ;;
 282
 283 {.mfi
 284        ldfe FR_COEFF2= [ GR_COEFF_START ], 16    // load C_2
 285        nop.f 0
 286        mov GR_MASK_low= 31
 287 }
 288 ;;
 289
 290 {.mlx
 291        getf.sig GR_KF0= FR_KF0                   // (K+f)*2^10= round_to_int(y)
 292  (p8)  movl GR_exact_limit= 0x41200000           // Largest x for exact result,
 293                                                  //  +10.0
 294 }
 295 ;;
 296
 297 {.mfi
 298        add GR_LOG_TBL= 256, GR_COEFF_START       // Pointer to high T_table
 299        fcmp.gt.s1 p12, p7= f8, FR_OF_LIMIT       // x>overflow threshold ?
 300        nop.i 0
 301 }
 302 ;;
 303
 304 {.mfi
 305  (p8)  setf.s FR_exact_limit = GR_exact_limit    // Largest x for exact result
 306  (p8)  fcvt.xf FR_int_x = FR_int_x               // Integral part of x
 307        shr GR_K= GR_KF0, 10                      // K
 308 }
 309 {.mfi
 310        and GR_F_high= GR_MASK, GR_KF0            // f_high*32
 311        fms.s1 FR_R= f8, FR_LOG2_10, FR_KF        // r*2^(-53)= [ x*log2(10)-
 312                                                  //           (K+f) ] *2^{10-63}
 313        and GR_F_low= GR_KF0, GR_MASK_low         // f_low
 314 }
 315 ;;
 316
 317 {.mmi
 318        shladd GR_Flow_ADDR= GR_F_low, 3, GR_COEFF_START // address of 2^{f_low}
 319        add GR_BIAS= GR_K, GR_EXP_CORR            // K= bias-2*63
 320        shr GR_Fh= GR_F_high, 5                   // f_high
 321 }
 322 ;;
 323
 324 {.mfi
 325        setf.exp FR_2_TO_K= GR_BIAS               // 2^{K-126}
 326  (p7)  fcmp.lt.s1 p12, p7= f8, FR_UF_LIMIT       // x<underflow threshold ?
 327        shladd GR_Fh_ADDR= GR_Fh, 3, GR_LOG_TBL   // address of 2^{f_high}
 328 }
 329 {.mfi
 330        ldf8 FR_T_low= [ GR_Flow_ADDR ]           // load T_low= 2^{f_low}
 331        nop.f 0
 332        nop.i 0
 333 }
 334 ;;
 335
 336 {.mfb
 337        ldf8 FR_T_high= [ GR_Fh_ADDR ]            // load T_high= 2^{f_high}
 338        nop.f 0
 339  (p12) br.cond.spnt OUT_RANGE_exp10
 340 }
 341 ;;
 342
 343 {.mfi
 344        nop.m 0
 345        fma.s1 FR_P12= FR_COEFF2, FR_R, FR_COEFF1 // P12= C_1+C_2*r
 346        cmp.eq p7,p9= r0,r0                       // Assume inexact result
 347 }
 348 ;;
 349
 350 {.mfi
 351        nop.m 0
 352  (p8)  fcmp.eq.s1 p9,p7= FR_int_x, f8            // Test x positive integer
 353        nop.i 0
 354 }
 355 {.mfi
 356        nop.m 0
 357        fma.s1 FR_T_low_K= FR_T_low, FR_2_TO_K, f0 // T= 2^{K-126}*T_low
 358        nop.i 0
 359 }
 360 ;;
 361
 362 {.mfi
 363        nop.m 0
 364        fma.s1 FR_P= FR_P12, FR_R, f0              // P= P12*r
 365        nop.i 0
 366 }
 367 ;;
 368
 369 // If x a positive integer, will it produce an exact result?
 370 //   p7 result will be inexact
 371 //   p9 result will be exact
 372 {.mfi
 373        nop.m 0
 374  (p9)  fcmp.le.s1 p9,p7= f8, FR_exact_limit       // Test x gives exact result
 375        nop.i 0
 376 }
 377 {.mfi
 378        nop.m 0
 379        fma.s1 FR_T= FR_T_low_K, FR_T_high, f0     // T= T*T_high
 380        nop.i 0
 381 }
 382 ;;
 383
 384 .pred.rel "mutex",p7,p9
 385 {.mfi
 386        nop.m 0
 387  (p7)  fma.s.s0 f8= FR_P, FR_T, FR_T              // result= T+T*P, inexact set
 388        nop.i 0
 389 }
 390 {.mfb
 391        nop.m 0
 392  (p9)  fma.s.s1 f8= FR_P, FR_T, FR_T              // result= T+T*P, exact use s1
 393        br.ret.sptk b0                             // return
 394 }
 395 ;;
 396
 397
 398 SPECIAL_exp10:
 399 {.mfi
 400        nop.m 0
 401        fclass.m p6, p0= f8, 0x22                  // x= -Infinity ?
 402        nop.i 0
 403 }
 404 ;;
 405
 406 {.mfi
 407        nop.m 0
 408        fclass.m p7, p0= f8, 0x21                  // x= +Infinity ?
 409        nop.i 0
 410 }
 411 ;;
 412
 413 {.mfi
 414        nop.m 0
 415        fclass.m p8, p0= f8, 0x7                   // x= +/-Zero ?
 416        nop.i 0
 417 }
 418 {.mfb
 419        nop.m 0
 420  (p6)  mov f8= f0                                 // exp10(-Infinity)= 0
 421  (p6)  br.ret.spnt b0
 422 }
 423 ;;
 424
 425 {.mfb
 426        nop.m 0
 427        nop.f 0
 428  (p7)  br.ret.spnt b0                             // exp10(+Infinity)= +Infinity
 429 }
 430 ;;
 431
 432 {.mfb
 433        nop.m 0
 434  (p8)  mov f8= f1                                 // exp10(+/-0)= 1
 435  (p8)  br.ret.spnt b0
 436 }
 437 ;;
 438
 439 {.mfb
 440        nop.m 0
 441        fma.s.s0 f8= f8, f1, f0                    // Remaining cases: NaNs
 442        br.ret.sptk b0
 443 }
 444 ;;
 445
 446
 447 OUT_RANGE_exp10:
 448
 449 // overflow: p8= 1
 450
 451 {.mii
 452  (p8)  mov GR_EXPMAX= 0x1fffe
 453        nop.i 0
 454        nop.i 0
 455 }
 456 ;;
 457
 458
 459 {.mmb
 460  (p8)  mov GR_Parameter_TAG= 167
 461  (p8)  setf.exp FR_R= GR_EXPMAX
 462        nop.b 999
 463 }
 464 ;;
 465
 466 {.mfi
 467        nop.m 999
 468  (p8)  fma.s.s0 f8= FR_R, FR_R, f0                // Create overflow
 469        nop.i 999
 470 }
 471 // underflow: p6= 1
 472 {.mii
 473        nop.m 0
 474  (p6)  mov GR_EXPMAX= 1
 475        nop.i 0
 476 }
 477 ;;
 478
 479 {.mmb
 480        nop.m 0
 481  (p6)  setf.exp FR_R= GR_EXPMAX
 482        nop.b 999
 483 }
 484 ;;
 485
 486 {.mfb
 487        nop.m 999
 488  (p6)  fma.s.s0 f8= FR_R, FR_R, f0                // Create underflow
 489  (p6)  br.ret.sptk b0                  // will not call libm_error for underflow
 490 }
 491 ;;
 492
 493 GLOBAL_IEEE754_END(exp10f)
 494 weak_alias (exp10f, pow10f)
 495
 496 LOCAL_LIBM_ENTRY(__libm_error_region)
 497
 498 .prologue
 499 {.mfi
 500        add GR_Parameter_Y= -32, sp                // Parameter 2 value
 501        nop.f 0
 502 .save ar.pfs, GR_SAVE_PFS
 503        mov GR_SAVE_PFS= ar.pfs                    // Save ar.pfs
 504 }
 505
 506 {.mfi
 507 .fframe 64
 508        add sp= -64, sp                            // Create new stack
 509        nop.f 0
 510        mov GR_SAVE_GP= gp                         // Save gp
 511 }
 512 ;;
 513
 514 {.mmi
 515        stfs [ GR_Parameter_Y ]= FR_Y, 16          // STORE Parameter 2 on stack
 516        add GR_Parameter_X= 16, sp                 // Parameter 1 address
 517 .save b0, GR_SAVE_B0
 518        mov GR_SAVE_B0= b0                         // Save b0
 519 }
 520 ;;
 521
 522 .body
 523 {.mib
 524        stfs [ GR_Parameter_X ]= FR_X              // STORE Parameter 1 on stack
 525        add GR_Parameter_RESULT= 0, GR_Parameter_Y // Parameter 3 address
 526        nop.b 0
 527 }
 528 {.mib
 529        stfs [ GR_Parameter_Y ]= FR_RESULT         // STORE Parameter 3 on stack
 530        add GR_Parameter_Y= -16, GR_Parameter_Y
 531        br.call.sptk b0= __libm_error_support#    // Call error handling function
 532 }
 533 ;;
 534
 535 {.mmi
 536        add GR_Parameter_RESULT= 48, sp
 537        nop.m 0
 538        nop.i 0
 539 }
 540 ;;
 541
 542 {.mmi
 543        ldfs f8= [ GR_Parameter_RESULT ]          // Get return result off stack
 544 .restore sp
 545        add sp= 64, sp                            // Restore stack pointer
 546        mov b0= GR_SAVE_B0                        // Restore return address
 547 }
 548 ;;
 549
 550 {.mib
 551        mov gp= GR_SAVE_GP                        // Restore gp
 552        mov ar.pfs= GR_SAVE_PFS                   // Restore ar.pfs
 553        br.ret.sptk b0                            // Return
 554 }
 555 ;;
 556
 557
 558 LOCAL_LIBM_END(__libm_error_region)
 559
 560 .type __libm_error_support#, @function
 561 .global __libm_error_support#