criss cross rename failure workaround
[git/dscho.git] / configure.ac
blob8bb0f44b489e0e963c70e88d04e5878dd78012d5
1 #                                               -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
4 AC_PREREQ(2.59)
5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
7 AC_CONFIG_SRCDIR([git.c])
9 config_file=config.mak.autogen
10 config_append=config.mak.append
11 config_in=config.mak.in
13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
16 ## Definitions of macros
17 # GIT_CONF_APPEND_LINE(LINE)
18 # --------------------------
19 # Append LINE to file ${config_append}
20 AC_DEFUN([GIT_CONF_APPEND_LINE],
21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
23 # GIT_ARG_SET_PATH(PROGRAM)
24 # -------------------------
25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
26 # Optional second argument allows setting NO_PROGRAM=YesPlease if
27 # --without-PROGRAM version used.
28 AC_DEFUN([GIT_ARG_SET_PATH],
29 [AC_ARG_WITH([$1],
30  [AS_HELP_STRING([--with-$1=PATH],
31                  [provide PATH to $1])],
32  [GIT_CONF_APPEND_PATH($1,$2)],[])
33 ])# GIT_ARG_SET_PATH
35 # GIT_CONF_APPEND_PATH(PROGRAM)
36 # ------------------------------
37 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
38 # Used by GIT_ARG_SET_PATH(PROGRAM)
39 # Optional second argument allows setting NO_PROGRAM=YesPlease if
40 # --without-PROGRAM is used.
41 AC_DEFUN([GIT_CONF_APPEND_PATH],
42 [PROGRAM=m4_toupper($1); \
43 if test "$withval" = "no"; then \
44         if test -n "$2"; then \
45                 m4_toupper($1)_PATH=$withval; \
46                 AC_MSG_NOTICE([Disabling use of ${PROGRAM}]); \
47                 GIT_CONF_APPEND_LINE(NO_${PROGRAM}=YesPlease); \
48                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=); \
49         else \
50                 AC_MSG_ERROR([You cannot use git without $1]); \
51         fi; \
52 else \
53         if test "$withval" = "yes"; then \
54                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
55         else \
56                 m4_toupper($1)_PATH=$withval; \
57                 AC_MSG_NOTICE([Setting m4_toupper($1)_PATH to $withval]); \
58                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
59         fi; \
60 fi; \
61 ]) # GIT_CONF_APPEND_PATH
63 # GIT_PARSE_WITH(PACKAGE)
64 # -----------------------
65 # For use in AC_ARG_WITH action-if-found, for packages default ON.
66 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
67 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
68 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
69 AC_DEFUN([GIT_PARSE_WITH],
70 [PACKAGE=m4_toupper($1); \
71 if test "$withval" = "no"; then \
72         m4_toupper(NO_$1)=YesPlease; \
73 elif test "$withval" = "yes"; then \
74         m4_toupper(NO_$1)=; \
75 else \
76         m4_toupper(NO_$1)=; \
77         m4_toupper($1)DIR=$withval; \
78         AC_MSG_NOTICE([Setting m4_toupper($1)DIR to $withval]); \
79         GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
80 fi \
81 ])# GIT_PARSE_WITH
83 # GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
84 # ---------------------
85 # Set VAR to the value specied by --with-WITHNAME.
86 # No verification of arguments is performed, but warnings are issued
87 # if either 'yes' or 'no' is specified.
88 # HELP_TEXT is presented when --help is called.
89 # This is a direct way to allow setting variables in the Makefile.
90 AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
91 [AC_ARG_WITH([$1],
92  [AS_HELP_STRING([--with-$1=VALUE], $3)],
93  if test -n "$withval"; then \
94   if test "$withval" = "yes" -o "$withval" = "no"; then \
95     AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
96                      [a value for $1 ($2).  Maybe you do...?]); \
97   fi; \
98   \
99   AC_MSG_NOTICE([Setting $2 to $withval]); \
100   GIT_CONF_APPEND_LINE($2=$withval); \
101  fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
104 dnl GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
105 dnl -----------------------------------------
106 dnl Similar to AC_CHECK_FUNC, but on systems that do not generate
107 dnl warnings for missing prototypes (e.g. FreeBSD when compiling without
108 dnl -Wall), it does not work.  By looking for function definition in
109 dnl libraries, this problem can be worked around.
110 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
111   AC_SEARCH_LIBS([$1],,
112   [$2],[$3])
113 ],[$3])])
116 dnl GIT_STASH_FLAGS(BASEPATH_VAR)
117 dnl -----------------------------
118 dnl Allow for easy stashing of LDFLAGS and CPPFLAGS before running
119 dnl tests that may want to take user settings into account.
120 AC_DEFUN([GIT_STASH_FLAGS],[
121 if test -n "$1"; then
122    old_CPPFLAGS="$CPPFLAGS"
123    old_LDFLAGS="$LDFLAGS"
124    CPPFLAGS="-I$1/include $CPPFLAGS"
125    LDFLAGS="-L$1/$lib $LDFLAGS"
130 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
131 dnl -----------------------------
132 dnl Restore the stashed *FLAGS values.
133 AC_DEFUN([GIT_UNSTASH_FLAGS],[
134 if test -n "$1"; then
135    CPPFLAGS="$old_CPPFLAGS"
136    LDFLAGS="$old_LDFLAGS"
140 ## Site configuration related to programs (before tests)
141 ## --with-PACKAGE[=ARG] and --without-PACKAGE
143 # Set lib to alternative name of lib directory (e.g. lib64)
144 AC_ARG_WITH([lib],
145  [AS_HELP_STRING([--with-lib=ARG],
146                  [ARG specifies alternative name for lib directory])],
147  [if test "$withval" = "no" || test "$withval" = "yes"; then \
148         AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
149 else \
150         lib=$withval; \
151         AC_MSG_NOTICE([Setting lib to '$lib']); \
152         GIT_CONF_APPEND_LINE(lib=$withval); \
153 fi; \
154 ],[])
156 if test -z "$lib"; then
157    AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
158    lib=lib
161 AC_ARG_ENABLE([pthreads],
162  [AS_HELP_STRING([--enable-pthreads=FLAGS],
163   [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
164   [The default if FLAGS is not specified is to try first -pthread]
165   [and then -lpthread.]
166   [--without-pthreads will disable threading.])],
168 if test "x$enableval" = "xyes"; then
169    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
170 elif test "x$enableval" != "xno"; then
171    PTHREAD_CFLAGS=$enableval
172    AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
173 else
174    AC_MSG_NOTICE([POSIX Threads will be disabled.])
175    NO_PTHREADS=YesPlease
176    USER_NOPTHREAD=1
177 fi],
179    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
182 # Define option to enable JavaScript minification
183 AC_ARG_ENABLE([jsmin],
184 [AS_HELP_STRING([--enable-jsmin=PATH],
185   [PATH is the name of a JavaScript minifier or the absolute path to one.])],
187   JSMIN=$enableval;
188   AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
189   GIT_CONF_APPEND_LINE(JSMIN=$enableval);
192 # Define option to enable CSS minification
193 AC_ARG_ENABLE([cssmin],
194 [AS_HELP_STRING([--enable-cssmin=PATH],
195   [PATH is the name of a CSS minifier or the absolute path to one.])],
197   CSSMIN=$enableval;
198   AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
199   GIT_CONF_APPEND_LINE(CSSMIN=$enableval);
202 ## Site configuration (override autodetection)
203 ## --with-PACKAGE[=ARG] and --without-PACKAGE
204 AC_MSG_NOTICE([CHECKS for site configuration])
206 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
207 # tests.  These tests take up a significant amount of the total test time
208 # but are not needed unless you plan to talk to SVN repos.
210 # Define PPC_SHA1 environment variable when running make to make use of
211 # a bundled SHA1 routine optimized for PowerPC.
213 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
214 # This also implies BLK_SHA1.
216 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
217 # /foo/bar/include and /foo/bar/lib directories.
218 AC_ARG_WITH(openssl,
219 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
220 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
221 GIT_PARSE_WITH(openssl))
223 # Define USE_LIBPCRE if you have and want to use libpcre. git-grep will be
224 # able to use Perl-compatible regular expressions.
226 # Define LIBPCREDIR=/foo/bar if your libpcre header and library files are in
227 # /foo/bar/include and /foo/bar/lib directories.
229 AC_ARG_WITH(libpcre,
230 AS_HELP_STRING([--with-libpcre],[support Perl-compatible regexes (default is NO)])
231 AS_HELP_STRING([],           [ARG can be also prefix for libpcre library and headers]),
232 if test "$withval" = "no"; then \
233         USE_LIBPCRE=; \
234 elif test "$withval" = "yes"; then \
235         USE_LIBPCRE=YesPlease; \
236 else
237         USE_LIBPCRE=YesPlease; \
238         LIBPCREDIR=$withval; \
239         AC_MSG_NOTICE([Setting LIBPCREDIR to $withval]); \
240         GIT_CONF_APPEND_LINE(LIBPCREDIR=$withval); \
241 fi \
244 # Define NO_CURL if you do not have curl installed.  git-http-pull and
245 # git-http-push are not built, and you cannot use http:// and https://
246 # transports.
248 # Define CURLDIR=/foo/bar if your curl header and library files are in
249 # /foo/bar/include and /foo/bar/lib directories.
250 AC_ARG_WITH(curl,
251 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
252 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
253 GIT_PARSE_WITH(curl))
255 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
256 # not built, and you cannot push using http:// and https:// transports.
258 # Define EXPATDIR=/foo/bar if your expat header and library files are in
259 # /foo/bar/include and /foo/bar/lib directories.
260 AC_ARG_WITH(expat,
261 AS_HELP_STRING([--with-expat],
262 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
263 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
264 GIT_PARSE_WITH(expat))
266 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
267 # installed in /sw, but don't want GIT to link against any libraries
268 # installed there.  If defined you may specify your own (or Fink's)
269 # include directories and library directories by defining CFLAGS
270 # and LDFLAGS appropriately.
272 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
273 # have DarwinPorts installed in /opt/local, but don't want GIT to
274 # link against any libraries installed there.  If defined you may
275 # specify your own (or DarwinPort's) include directories and
276 # library directories by defining CFLAGS and LDFLAGS appropriately.
278 # Define NO_MMAP if you want to avoid mmap.
280 # Define NO_ICONV if your libc does not properly support iconv.
281 AC_ARG_WITH(iconv,
282 AS_HELP_STRING([--without-iconv],
283 [if your architecture doesn't properly support iconv])
284 AS_HELP_STRING([--with-iconv=PATH],
285 [PATH is prefix for libiconv library and headers])
286 AS_HELP_STRING([],
287 [used only if you need linking with libiconv]),
288 GIT_PARSE_WITH(iconv))
290 ## --enable-FEATURE[=ARG] and --disable-FEATURE
292 # Define USE_NSEC below if you want git to care about sub-second file mtimes
293 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
294 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
295 # randomly break unless your underlying filesystem supports those sub-second
296 # times (my ext3 doesn't).
298 # Define USE_STDEV below if you want git to care about the underlying device
299 # change being considered an inode change from the update-index perspective.
302 # Allow user to set ETC_GITCONFIG variable
303 GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
304                         Use VALUE instead of /etc/gitconfig as the
305                         global git configuration file.
306                         If VALUE is not fully qualified it will be interpreted
307                         as a path relative to the computed prefix at runtime.)
310 # Allow user to set ETC_GITATTRIBUTES variable
311 GIT_PARSE_WITH_SET_MAKE_VAR(gitattributes, ETC_GITATTRIBUTES,
312                         Use VALUE instead of /etc/gitattributes as the
313                         global git attributes file.
314                         If VALUE is not fully qualified it will be interpreted
315                         as a path relative to the computed prefix at runtime.)
318 # Allow user to set the default pager
319 GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
320                         Use VALUE as the fall-back pager instead of 'less'.
321                         This is used by things like 'git log' when the user
322                         does not specify a pager to use through alternate
323                         methods. eg: /usr/bin/pager)
325 # Allow user to set the default editor
326 GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
327                         Use VALUE as the fall-back editor instead of 'vi'.
328                         This is used by things like 'git commit' when the user
329                         does not specify a preferred editor through other
330                         methods. eg: /usr/bin/editor)
333 # Define SHELL_PATH to provide path to shell.
334 GIT_ARG_SET_PATH(shell)
336 # Define PERL_PATH to provide path to Perl.
337 GIT_ARG_SET_PATH(perl)
339 # Define PYTHON_PATH to provide path to Python.
340 GIT_ARG_SET_PATH(python, allow-without)
342 # Define ZLIB_PATH to provide path to zlib.
343 GIT_ARG_SET_PATH(zlib)
345 # Declare the with-tcltk/without-tcltk options.
346 AC_ARG_WITH(tcltk,
347 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
348 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
349 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
350 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
351 GIT_PARSE_WITH(tcltk))
355 ## Checks for programs.
356 AC_MSG_NOTICE([CHECKS for programs])
358 AC_PROG_CC([cc gcc])
359 AC_C_INLINE
360 case $ac_cv_c_inline in
361   inline | yes | no)    ;;
362   *)                    AC_SUBST([INLINE], [$ac_cv_c_inline]) ;;
363 esac
365 # which switch to pass runtime path to dynamic libraries to the linker
366 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
367    SAVE_LDFLAGS="${LDFLAGS}"
368    LDFLAGS="${SAVE_LDFLAGS} -R /"
369    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
370    LDFLAGS="${SAVE_LDFLAGS}"
372 if test "$git_cv_ld_dashr" = "yes"; then
373    AC_SUBST(CC_LD_DYNPATH, [-R])
374 else
375    AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
376       SAVE_LDFLAGS="${LDFLAGS}"
377       LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
378       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
379       LDFLAGS="${SAVE_LDFLAGS}"
380    ])
381    if test "$git_cv_ld_wl_rpath" = "yes"; then
382       AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
383    else
384       AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
385          SAVE_LDFLAGS="${LDFLAGS}"
386          LDFLAGS="${SAVE_LDFLAGS} -rpath /"
387          AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
388          LDFLAGS="${SAVE_LDFLAGS}"
389       ])
390       if test "$git_cv_ld_rpath" = "yes"; then
391          AC_SUBST(CC_LD_DYNPATH, [-rpath])
392       else
393          AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
394       fi
395    fi
397 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
398 AC_CHECK_TOOLS(AR, [gar ar], :)
399 AC_CHECK_PROGS(TAR, [gtar tar])
400 AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
401 # TCLTK_PATH will be set to some value if we want Tcl/Tk
402 # or will be empty otherwise.
403 if test -z "$NO_TCLTK"; then
404   if test "$with_tcltk" = ""; then
405   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
406     TCLTK_PATH=wish
407     AC_SUBST(TCLTK_PATH)
408   elif test "$with_tcltk" = "yes"; then
409   # Tcl/Tk check requested.
410     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
411   else
412     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
413     TCLTK_PATH="$with_tcltk"
414     AC_SUBST(TCLTK_PATH)
415   fi
417 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
418 if test -n "$ASCIIDOC"; then
419         AC_MSG_CHECKING([for asciidoc version])
420         asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
421         case "${asciidoc_version}" in
422         asciidoc' '7*)
423                 ASCIIDOC7=YesPlease
424                 AC_MSG_RESULT([${asciidoc_version} > 7])
425                 ;;
426         asciidoc' '8*)
427                 ASCIIDOC7=
428                 AC_MSG_RESULT([${asciidoc_version}])
429                 ;;
430         *)
431                 ASCIIDOC7=
432                 AC_MSG_RESULT([${asciidoc_version} (unknown)])
433                 ;;
434         esac
436 AC_SUBST(ASCIIDOC7)
439 ## Checks for libraries.
440 AC_MSG_NOTICE([CHECKS for libraries])
442 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
443 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
445 GIT_STASH_FLAGS($OPENSSLDIR)
447 AC_CHECK_LIB([crypto], [SHA1_Init],
448 [NEEDS_SSL_WITH_CRYPTO=],
449 [AC_CHECK_LIB([ssl], [SHA1_Init],
450  [NEEDS_SSL_WITH_CRYPTO=YesPlease],
451  [NEEDS_SSL_WITH_CRYPTO= NO_OPENSSL=YesPlease])])
453 GIT_UNSTASH_FLAGS($OPENSSLDIR)
455 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
456 AC_SUBST(NO_OPENSSL)
459 # Define USE_LIBPCRE if you have and want to use libpcre. git-grep will be
460 # able to use Perl-compatible regular expressions.
463 if test -n "$USE_LIBPCRE"; then
465 GIT_STASH_FLAGS($LIBPCREDIR)
467 AC_CHECK_LIB([pcre], [pcre_version],
468 [USE_LIBPCRE=YesPlease],
469 [USE_LIBPCRE=])
471 GIT_UNSTASH_FLAGS($LIBPCREDIR)
473 AC_SUBST(USE_LIBPCRE)
478 # Define NO_CURL if you do not have libcurl installed.  git-http-pull and
479 # git-http-push are not built, and you cannot use http:// and https://
480 # transports.
482 GIT_STASH_FLAGS($CURLDIR)
484 AC_CHECK_LIB([curl], [curl_global_init],
485 [NO_CURL=],
486 [NO_CURL=YesPlease])
488 GIT_UNSTASH_FLAGS($CURLDIR)
490 AC_SUBST(NO_CURL)
493 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
494 # not built, and you cannot push using http:// and https:// transports.
496 GIT_STASH_FLAGS($EXPATDIR)
498 AC_CHECK_LIB([expat], [XML_ParserCreate],
499 [NO_EXPAT=],
500 [NO_EXPAT=YesPlease])
502 GIT_UNSTASH_FLAGS($EXPATDIR)
504 AC_SUBST(NO_EXPAT)
507 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
508 # some Solaris installations).
509 # Define NO_ICONV if neither libc nor libiconv support iconv.
511 if test -z "$NO_ICONV"; then
513 GIT_STASH_FLAGS($ICONVDIR)
515 AC_DEFUN([ICONVTEST_SRC],
516 [AC_LANG_PROGRAM([#include <iconv.h>],
517  [iconv_open("", "");])])
519 if test -n "$ICONVDIR"; then
520    lib_order="-liconv -lc"
521 else
522    lib_order="-lc -liconv"
525 NO_ICONV=YesPlease
527 for l in $lib_order; do
528     if test "$l" = "-liconv"; then
529        NEEDS_LIBICONV=YesPlease
530     else
531        NEEDS_LIBICONV=
532     fi
534     old_LIBS="$LIBS"
535     LIBS="$LIBS $l"
536     AC_MSG_CHECKING([for iconv in $l])
537     AC_LINK_IFELSE([ICONVTEST_SRC],
538         [AC_MSG_RESULT([yes])
539         NO_ICONV=
540         break],
541         [AC_MSG_RESULT([no])])
542     LIBS="$old_LIBS"
543 done
545 #in case of break
546 LIBS="$old_LIBS"
548 GIT_UNSTASH_FLAGS($ICONVDIR)
550 AC_SUBST(NEEDS_LIBICONV)
551 AC_SUBST(NO_ICONV)
553 if test -n "$NO_ICONV"; then
554     NEEDS_LIBICONV=
560 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
562 GIT_STASH_FLAGS($ZLIB_PATH)
564 AC_DEFUN([ZLIBTEST_SRC], [
565 AC_LANG_PROGRAM([#include <zlib.h>],
566  [deflateBound(0, 0);])])
567 AC_MSG_CHECKING([for deflateBound in -lz])
568 old_LIBS="$LIBS"
569 LIBS="$LIBS -lz"
570 AC_LINK_IFELSE([ZLIBTEST_SRC],
571         [AC_MSG_RESULT([yes])],
572         [AC_MSG_RESULT([no])
573         NO_DEFLATE_BOUND=yes])
574 LIBS="$old_LIBS"
576 GIT_UNSTASH_FLAGS($ZLIB_PATH)
578 AC_SUBST(NO_DEFLATE_BOUND)
581 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
582 # Patrick Mauritz).
583 AC_CHECK_LIB([c], [socket],
584 [NEEDS_SOCKET=],
585 [NEEDS_SOCKET=YesPlease])
586 AC_SUBST(NEEDS_SOCKET)
587 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
590 # The next few tests will define NEEDS_RESOLV if linking with
591 # libresolv provides some of the functions we would normally get
592 # from libc.
593 NEEDS_RESOLV=
594 AC_SUBST(NEEDS_RESOLV)
596 # Define NO_INET_NTOP if linking with -lresolv is not enough.
597 # Solaris 2.7 in particular hos inet_ntop in -lresolv.
598 NO_INET_NTOP=
599 AC_SUBST(NO_INET_NTOP)
600 AC_CHECK_FUNC([inet_ntop],
601         [],
602     [AC_CHECK_LIB([resolv], [inet_ntop],
603             [NEEDS_RESOLV=YesPlease],
604         [NO_INET_NTOP=YesPlease])
607 # Define NO_INET_PTON if linking with -lresolv is not enough.
608 # Solaris 2.7 in particular hos inet_pton in -lresolv.
609 NO_INET_PTON=
610 AC_SUBST(NO_INET_PTON)
611 AC_CHECK_FUNC([inet_pton],
612         [],
613     [AC_CHECK_LIB([resolv], [inet_pton],
614             [NEEDS_RESOLV=YesPlease],
615         [NO_INET_PTON=YesPlease])
618 # Define NO_HSTRERROR if linking with -lresolv is not enough.
619 # Solaris 2.6 in particular has no hstrerror, even in -lresolv.
620 NO_HSTRERROR=
621 AC_CHECK_FUNC([hstrerror],
622         [],
623     [AC_CHECK_LIB([resolv], [hstrerror],
624             [NEEDS_RESOLV=YesPlease],
625         [NO_HSTRERROR=YesPlease])
627 AC_SUBST(NO_HSTRERROR)
629 # If any of the above tests determined that -lresolv is needed at
630 # build-time, also set it here for remaining configure-time checks.
631 test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
633 AC_CHECK_LIB([c], [basename],
634 [NEEDS_LIBGEN=],
635 [NEEDS_LIBGEN=YesPlease])
636 AC_SUBST(NEEDS_LIBGEN)
637 test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
639 AC_CHECK_LIB([c], [gettext],
640 [LIBC_CONTAINS_LIBINTL=YesPlease],
641 [LIBC_CONTAINS_LIBINTL=])
642 AC_SUBST(LIBC_CONTAINS_LIBINTL)
645 # Define NO_GETTEXT if you don't want Git output to be translated.
646 # A translated Git requires GNU libintl or another gettext implementation
647 AC_CHECK_HEADER([libintl.h],
648 [NO_GETTEXT=],
649 [NO_GETTEXT=YesPlease])
650 AC_SUBST(NO_GETTEXT)
652 if test -z "$NO_GETTEXT"; then
653     test -n "$LIBC_CONTAINS_LIBINTL" || LIBS="$LIBS -lintl"
656 ## Checks for header files.
657 AC_MSG_NOTICE([CHECKS for header files])
659 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
660 AC_CHECK_HEADER([sys/select.h],
661 [NO_SYS_SELECT_H=],
662 [NO_SYS_SELECT_H=UnfortunatelyYes])
663 AC_SUBST(NO_SYS_SELECT_H)
665 # Define NO_SYS_POLL_H if you don't have sys/poll.h
666 AC_CHECK_HEADER([sys/poll.h],
667 [NO_SYS_POLL_H=],
668 [NO_SYS_POLL_H=UnfortunatelyYes])
669 AC_SUBST(NO_SYS_POLL_H)
671 # Define NO_INTTYPES_H if you don't have inttypes.h
672 AC_CHECK_HEADER([inttypes.h],
673 [NO_INTTYPES_H=],
674 [NO_INTTYPES_H=UnfortunatelyYes])
675 AC_SUBST(NO_INTTYPES_H)
677 # Define OLD_ICONV if your library has an old iconv(), where the second
678 # (input buffer pointer) parameter is declared with type (const char **).
679 AC_DEFUN([OLDICONVTEST_SRC], [
680 AC_LANG_PROGRAM([[
681 #include <iconv.h>
683 extern size_t iconv(iconv_t cd,
684                     char **inbuf, size_t *inbytesleft,
685                     char **outbuf, size_t *outbytesleft);
686 ]], [])])
688 GIT_STASH_FLAGS($ICONVDIR)
690 AC_MSG_CHECKING([for old iconv()])
691 AC_COMPILE_IFELSE([OLDICONVTEST_SRC],
692         [AC_MSG_RESULT([no])],
693         [AC_MSG_RESULT([yes])
694         OLD_ICONV=UnfortunatelyYes])
696 GIT_UNSTASH_FLAGS($ICONVDIR)
698 AC_SUBST(OLD_ICONV)
700 ## Checks for typedefs, structures, and compiler characteristics.
701 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
703 TYPE_SOCKLEN_T
704 case $ac_cv_type_socklen_t in
705   yes)  ;;
706   *)    AC_SUBST([SOCKLEN_T], [$git_cv_socklen_t_equiv]) ;;
707 esac
709 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
710 AC_CHECK_MEMBER(struct dirent.d_ino,
711 [NO_D_INO_IN_DIRENT=],
712 [NO_D_INO_IN_DIRENT=YesPlease],
713 [#include <dirent.h>])
714 AC_SUBST(NO_D_INO_IN_DIRENT)
716 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
717 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
718 AC_CHECK_MEMBER(struct dirent.d_type,
719 [NO_D_TYPE_IN_DIRENT=],
720 [NO_D_TYPE_IN_DIRENT=YesPlease],
721 [#include <dirent.h>])
722 AC_SUBST(NO_D_TYPE_IN_DIRENT)
724 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
725 # sockaddr_storage.
726 AC_CHECK_TYPE(struct sockaddr_storage,
727 [NO_SOCKADDR_STORAGE=],
728 [NO_SOCKADDR_STORAGE=YesPlease],[
729 #include <sys/types.h>
730 #include <sys/socket.h>
732 AC_SUBST(NO_SOCKADDR_STORAGE)
734 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
735 AC_CHECK_TYPE([struct addrinfo],[
736  GIT_CHECK_FUNC([getaddrinfo],
737   [NO_IPV6=],
738   [NO_IPV6=YesPlease])
739 ],[NO_IPV6=YesPlease],[
740 #include <sys/types.h>
741 #include <sys/socket.h>
742 #include <netdb.h>
744 AC_SUBST(NO_IPV6)
746 # Define NO_REGEX if you have no or inferior regex support in your C library.
747 AC_CACHE_CHECK([whether the platform regex can handle null bytes],
748  [ac_cv_c_excellent_regex], [
749 AC_EGREP_CPP(yippeeyeswehaveit,
750         AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
751 #include <regex.h>
753 [#ifdef REG_STARTEND
754 yippeeyeswehaveit
755 #endif
757         [ac_cv_c_excellent_regex=yes],
758         [ac_cv_c_excellent_regex=no])
760 if test $ac_cv_c_excellent_regex = yes; then
761         NO_REGEX=
762 else
763         NO_REGEX=YesPlease
765 AC_SUBST(NO_REGEX)
767 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
768 # when attempting to read from an fopen'ed directory.
769 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
770  [ac_cv_fread_reads_directories],
772 AC_RUN_IFELSE(
773         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
774                 [[char c;
775                 FILE *f = fopen(".", "r");
776                 return f && fread(&c, 1, 1, f)]])],
777         [ac_cv_fread_reads_directories=no],
778         [ac_cv_fread_reads_directories=yes])
780 if test $ac_cv_fread_reads_directories = yes; then
781         FREAD_READS_DIRECTORIES=UnfortunatelyYes
782 else
783         FREAD_READS_DIRECTORIES=
785 AC_SUBST(FREAD_READS_DIRECTORIES)
787 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
788 # or vsnprintf() return -1 instead of number of characters which would
789 # have been written to the final string if enough space had been available.
790 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
791  [ac_cv_snprintf_returns_bogus],
793 AC_RUN_IFELSE(
794         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
795                 #include "stdarg.h"
797                 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
798                 {
799                   int ret;
800                   va_list ap;
801                   va_start(ap, format);
802                   ret = vsnprintf(str, maxsize, format, ap);
803                   va_end(ap);
804                   return ret;
805                 }],
806                 [[char buf[6];
807                   if (test_vsnprintf(buf, 3, "%s", "12345") != 5
808                       || strcmp(buf, "12")) return 1;
809                   if (snprintf(buf, 3, "%s", "12345") != 5
810                       || strcmp(buf, "12")) return 1]])],
811         [ac_cv_snprintf_returns_bogus=no],
812         [ac_cv_snprintf_returns_bogus=yes])
814 if test $ac_cv_snprintf_returns_bogus = yes; then
815         SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
816 else
817         SNPRINTF_RETURNS_BOGUS=
819 AC_SUBST(SNPRINTF_RETURNS_BOGUS)
822 ## Checks for library functions.
823 ## (in default C library and libraries checked by AC_CHECK_LIB)
824 AC_MSG_NOTICE([CHECKS for library functions])
826 # Define NO_LIBGEN_H if you don't have libgen.h.
827 AC_CHECK_HEADER([libgen.h],
828 [NO_LIBGEN_H=],
829 [NO_LIBGEN_H=YesPlease])
830 AC_SUBST(NO_LIBGEN_H)
832 # Define HAVE_PATHS_H if you have paths.h.
833 AC_CHECK_HEADER([paths.h],
834 [HAVE_PATHS_H=YesPlease],
835 [HAVE_PATHS_H=])
836 AC_SUBST(HAVE_PATHS_H)
838 # Define HAVE_LIBCHARSET_H if have libcharset.h
839 AC_CHECK_HEADER([libcharset.h],
840 [HAVE_LIBCHARSET_H=YesPlease],
841 [HAVE_LIBCHARSET_H=])
842 AC_SUBST(HAVE_LIBCHARSET_H)
843 # Define CHARSET_LIB if libiconv does not export the locale_charset symbol
844 # and libcharset does
845 CHARSET_LIB=
846 AC_CHECK_LIB([iconv], [locale_charset],
847        [],
848        [AC_CHECK_LIB([charset], [locale_charset],
849                      [CHARSET_LIB=-lcharset])
850        ]
852 AC_SUBST(CHARSET_LIB)
854 # Define NO_STRCASESTR if you don't have strcasestr.
855 GIT_CHECK_FUNC(strcasestr,
856 [NO_STRCASESTR=],
857 [NO_STRCASESTR=YesPlease])
858 AC_SUBST(NO_STRCASESTR)
860 # Define NO_STRTOK_R if you don't have strtok_r
861 GIT_CHECK_FUNC(strtok_r,
862 [NO_STRTOK_R=],
863 [NO_STRTOK_R=YesPlease])
864 AC_SUBST(NO_STRTOK_R)
866 # Define NO_FNMATCH if you don't have fnmatch
867 GIT_CHECK_FUNC(fnmatch,
868 [NO_FNMATCH=],
869 [NO_FNMATCH=YesPlease])
870 AC_SUBST(NO_FNMATCH)
872 # Define NO_FNMATCH_CASEFOLD if your fnmatch function doesn't have the
873 # FNM_CASEFOLD GNU extension.
874 AC_CACHE_CHECK([whether the fnmatch function supports the FNMATCH_CASEFOLD GNU extension],
875  [ac_cv_c_excellent_fnmatch], [
876 AC_EGREP_CPP(yippeeyeswehaveit,
877         AC_LANG_PROGRAM([
878 #include <fnmatch.h>
880 [#ifdef FNM_CASEFOLD
881 yippeeyeswehaveit
882 #endif
884         [ac_cv_c_excellent_fnmatch=yes],
885         [ac_cv_c_excellent_fnmatch=no])
887 if test $ac_cv_c_excellent_fnmatch = yes; then
888         NO_FNMATCH_CASEFOLD=
889 else
890         NO_FNMATCH_CASEFOLD=YesPlease
892 AC_SUBST(NO_FNMATCH_CASEFOLD)
894 # Define NO_MEMMEM if you don't have memmem.
895 GIT_CHECK_FUNC(memmem,
896 [NO_MEMMEM=],
897 [NO_MEMMEM=YesPlease])
898 AC_SUBST(NO_MEMMEM)
900 # Define NO_STRLCPY if you don't have strlcpy.
901 GIT_CHECK_FUNC(strlcpy,
902 [NO_STRLCPY=],
903 [NO_STRLCPY=YesPlease])
904 AC_SUBST(NO_STRLCPY)
906 # Define NO_UINTMAX_T if your platform does not have uintmax_t
907 AC_CHECK_TYPE(uintmax_t,
908 [NO_UINTMAX_T=],
909 [NO_UINTMAX_T=YesPlease],[
910 #include <inttypes.h>
912 AC_SUBST(NO_UINTMAX_T)
914 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
915 GIT_CHECK_FUNC(strtoumax,
916 [NO_STRTOUMAX=],
917 [NO_STRTOUMAX=YesPlease])
918 AC_SUBST(NO_STRTOUMAX)
920 # Define NO_SETENV if you don't have setenv in the C library.
921 GIT_CHECK_FUNC(setenv,
922 [NO_SETENV=],
923 [NO_SETENV=YesPlease])
924 AC_SUBST(NO_SETENV)
926 # Define NO_UNSETENV if you don't have unsetenv in the C library.
927 GIT_CHECK_FUNC(unsetenv,
928 [NO_UNSETENV=],
929 [NO_UNSETENV=YesPlease])
930 AC_SUBST(NO_UNSETENV)
932 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
933 GIT_CHECK_FUNC(mkdtemp,
934 [NO_MKDTEMP=],
935 [NO_MKDTEMP=YesPlease])
936 AC_SUBST(NO_MKDTEMP)
938 # Define NO_MKSTEMPS if you don't have mkstemps in the C library.
939 GIT_CHECK_FUNC(mkstemps,
940 [NO_MKSTEMPS=],
941 [NO_MKSTEMPS=YesPlease])
942 AC_SUBST(NO_MKSTEMPS)
944 # Define NO_INITGROUPS if you don't have initgroups in the C library.
945 GIT_CHECK_FUNC(initgroups,
946 [NO_INITGROUPS=],
947 [NO_INITGROUPS=YesPlease])
948 AC_SUBST(NO_INITGROUPS)
951 # Define NO_MMAP if you want to avoid mmap.
953 # Define NO_ICONV if your libc does not properly support iconv.
956 ## Other checks.
957 # Define USE_PIC if you need the main git objects to be built with -fPIC
958 # in order to build and link perl/Git.so.  x86-64 seems to need this.
960 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
961 # Enable it on Windows.  By default, symrefs are still used.
963 # Define NO_PTHREADS if we do not have pthreads.
965 # Define PTHREAD_LIBS to the linker flag used for Pthread support.
966 AC_DEFUN([PTHREADTEST_SRC], [
967 AC_LANG_PROGRAM([[
968 #include <pthread.h>
969 ]], [[
970         pthread_mutex_t test_mutex;
971         pthread_key_t test_key;
972         int retcode = 0;
973         retcode |= pthread_key_create(&test_key, (void *)0);
974         retcode |= pthread_mutex_init(&test_mutex,(void *)0);
975         retcode |= pthread_mutex_lock(&test_mutex);
976         retcode |= pthread_mutex_unlock(&test_mutex);
977         return retcode;
978 ]])])
980 dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
981 dnl   [[#include <pthread.h>]],
982 dnl   [[pthread_mutex_t test_mutex;]]
983 dnl )])
985 NO_PTHREADS=UnfortunatelyYes
986 PTHREAD_LIBS=
988 if test -n "$USER_NOPTHREAD"; then
989    AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
990 # handle these separately since PTHREAD_CFLAGS could be '-lpthreads
991 # -D_REENTRANT' or some such.
992 elif test -z "$PTHREAD_CFLAGS"; then
993   threads_found=no
994   for opt in -mt -pthread -lpthread; do
995      old_CFLAGS="$CFLAGS"
996      CFLAGS="$opt $CFLAGS"
997      AC_MSG_CHECKING([Checking for POSIX Threads with '$opt'])
998      AC_LINK_IFELSE([PTHREADTEST_SRC],
999         [AC_MSG_RESULT([yes])
1000                 NO_PTHREADS=
1001                 PTHREAD_LIBS="$opt"
1002                 PTHREAD_CFLAGS="$opt"
1003                 threads_found=yes
1004                 break
1005         ],
1006         [AC_MSG_RESULT([no])])
1007       CFLAGS="$old_CFLAGS"
1008   done
1009   if test $threads_found != yes; then
1010     AC_CHECK_LIB([pthread], [pthread_create],
1011         [PTHREAD_LIBS="-lpthread"],
1012         [NO_PTHREADS=UnfortunatelyYes])
1013   fi
1014 else
1015   old_CFLAGS="$CFLAGS"
1016   CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1017   AC_MSG_CHECKING([Checking for POSIX Threads with '$PTHREAD_CFLAGS'])
1018   AC_LINK_IFELSE([PTHREADTEST_SRC],
1019         [AC_MSG_RESULT([yes])
1020                 NO_PTHREADS=
1021                 PTHREAD_LIBS="$PTHREAD_CFLAGS"
1022         ],
1023         [AC_MSG_RESULT([no])])
1025   CFLAGS="$old_CFLAGS"
1028 CFLAGS="$old_CFLAGS"
1030 AC_SUBST(PTHREAD_CFLAGS)
1031 AC_SUBST(PTHREAD_LIBS)
1032 AC_SUBST(NO_PTHREADS)
1034 ## Output files
1035 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
1036 AC_OUTPUT
1039 ## Cleanup
1040 rm -f "${config_append}"