gitweb/gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 our $t0 = [ gettimeofday() ];
  24 our $number_of_git_cmds = 0;
  25
  26 BEGIN {
  27         CGI->compile() if $ENV{'MOD_PERL'};
  28 }
  29
  30 our $version = "++GIT_VERSION++";
  31
  32 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  33 sub evaluate_uri {
  34         our $cgi;
  35
  36         our $my_url = $cgi->url();
  37         our $my_uri = $cgi->url(-absolute => 1);
  38
  39         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  40         # needed and used only for URLs with nonempty PATH_INFO
  41         our $base_url = $my_url;
  42
  43         # When the script is used as DirectoryIndex, the URL does not contain the name
  44         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  45         # have to do it ourselves. We make $path_info global because it's also used
  46         # later on.
  47         #
  48         # Another issue with the script being the DirectoryIndex is that the resulting
  49         # $my_url data is not the full script URL: this is good, because we want
  50         # generated links to keep implying the script name if it wasn't explicitly
  51         # indicated in the URL we're handling, but it means that $my_url cannot be used
  52         # as base URL.
  53         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  54         # to build the base URL ourselves:
  55         our $path_info = $ENV{"PATH_INFO"};
  56         if ($path_info) {
  57                 if ($my_url =~ s,\Q$path_info\E$,, &&
  58                     $my_uri =~ s,\Q$path_info\E$,, &&
  59                     defined $ENV{'SCRIPT_NAME'}) {
  60                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  61                 }
  62         }
  63
  64         # target of the home link on top of all pages
  65         our $home_link = $my_uri || "/";
  66 }
  67
  68 # core git executable to use
  69 # this can just be "git" if your webserver has a sensible PATH
  70 our $GIT = "++GIT_BINDIR++/git";
  71
  72 # absolute fs-path which will be prepended to the project path
  73 #our $projectroot = "/pub/scm";
  74 our $projectroot = "++GITWEB_PROJECTROOT++";
  75
  76 # fs traversing limit for getting project list
  77 # the number is relative to the projectroot
  78 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  79
  80 # string of the home link on top of all pages
  81 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  82
  83 # name of your site or organization to appear in page titles
  84 # replace this with something more descriptive for clearer bookmarks
  85 our $site_name = "++GITWEB_SITENAME++"
  86                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  87
  88 # html snippet to include in the <head> section of each page
  89 our $site_html_head_string = "++GITWEB_SITE_HTML_HEAD_STRING++";
  90 # filename of html text to include at top of each page
  91 our $site_header = "++GITWEB_SITE_HEADER++";
  92 # html text to include at home page
  93 our $home_text = "++GITWEB_HOMETEXT++";
  94 # filename of html text to include at bottom of each page
  95 our $site_footer = "++GITWEB_SITE_FOOTER++";
  96
  97 # URI of stylesheets
  98 our @stylesheets = ("++GITWEB_CSS++");
  99 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 100 our $stylesheet = undef;
 101 # URI of GIT logo (72x27 size)
 102 our $logo = "++GITWEB_LOGO++";
 103 # URI of GIT favicon, assumed to be image/png type
 104 our $favicon = "++GITWEB_FAVICON++";
 105 # URI of gitweb.js (JavaScript code for gitweb)
 106 our $javascript = "++GITWEB_JS++";
 107
 108 # URI and label (title) of GIT logo link
 109 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 110 #our $logo_label = "git documentation";
 111 our $logo_url = "http://git-scm.com/";
 112 our $logo_label = "git homepage";
 113
 114 # source of projects list
 115 our $projects_list = "++GITWEB_LIST++";
 116
 117 # the width (in characters) of the projects list "Description" column
 118 our $projects_list_description_width = 25;
 119
 120 # group projects by category on the projects list
 121 # (enabled if this variable evaluates to true)
 122 our $projects_list_group_categories = 0;
 123
 124 # default category if none specified
 125 # (leave the empty string for no category)
 126 our $project_list_default_category = "";
 127
 128 # default order of projects list
 129 # valid values are none, project, descr, owner, and age
 130 our $default_projects_order = "project";
 131
 132 # show repository only if this file exists
 133 # (only effective if this variable evaluates to true)
 134 our $export_ok = "++GITWEB_EXPORT_OK++";
 135
 136 # show repository only if this subroutine returns true
 137 # when given the path to the project, for example:
 138 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 139 our $export_auth_hook = undef;
 140
 141 # only allow viewing of repositories also shown on the overview page
 142 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 143
 144 # list of git base URLs used for URL to where fetch project from,
 145 # i.e. full URL is "$git_base_url/$project"
 146 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 147
 148 # default blob_plain mimetype and default charset for text/plain blob
 149 our $default_blob_plain_mimetype = 'text/plain';
 150 our $default_text_plain_charset  = undef;
 151
 152 # file to use for guessing MIME types before trying /etc/mime.types
 153 # (relative to the current git repository)
 154 our $mimetypes_file = undef;
 155
 156 # assume this charset if line contains non-UTF-8 characters;
 157 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 158 # for which encoding all byte sequences are valid, for example
 159 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 160 # could be even 'utf-8' for the old behavior)
 161 our $fallback_encoding = 'latin1';
 162
 163 # rename detection options for git-diff and git-diff-tree
 164 # - default is '-M', with the cost proportional to
 165 #   (number of removed files) * (number of new files).
 166 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 167 #   (number of changed files + number of removed files) * (number of new files)
 168 # - even more costly is '-C', '--find-copies-harder' with cost
 169 #   (number of files in the original tree) * (number of new files)
 170 # - one might want to include '-B' option, e.g. '-B', '-M'
 171 our @diff_opts = ('-M'); # taken from git_commit
 172
 173 # Disables features that would allow repository owners to inject script into
 174 # the gitweb domain.
 175 our $prevent_xss = 0;
 176
 177 # Path to the highlight executable to use (must be the one from
 178 # http://www.andre-simon.de due to assumptions about parameters and output).
 179 # Useful if highlight is not installed on your webserver's PATH.
 180 # [Default: highlight]
 181 our $highlight_bin = "++HIGHLIGHT_BIN++";
 182
 183 # information about snapshot formats that gitweb is capable of serving
 184 our %known_snapshot_formats = (
 185         # name => {
 186         #       'display' => display name,
 187         #       'type' => mime type,
 188         #       'suffix' => filename suffix,
 189         #       'format' => --format for git-archive,
 190         #       'compressor' => [compressor command and arguments]
 191         #                       (array reference, optional)
 192         #       'disabled' => boolean (optional)}
 193         #
 194         'tgz' => {
 195                 'display' => 'tar.gz',
 196                 'type' => 'application/x-gzip',
 197                 'suffix' => '.tar.gz',
 198                 'format' => 'tar',
 199                 'compressor' => ['gzip', '-n']},
 200
 201         'tbz2' => {
 202                 'display' => 'tar.bz2',
 203                 'type' => 'application/x-bzip2',
 204                 'suffix' => '.tar.bz2',
 205                 'format' => 'tar',
 206                 'compressor' => ['bzip2']},
 207
 208         'txz' => {
 209                 'display' => 'tar.xz',
 210                 'type' => 'application/x-xz',
 211                 'suffix' => '.tar.xz',
 212                 'format' => 'tar',
 213                 'compressor' => ['xz'],
 214                 'disabled' => 1},
 215
 216         'zip' => {
 217                 'display' => 'zip',
 218                 'type' => 'application/x-zip',
 219                 'suffix' => '.zip',
 220                 'format' => 'zip'},
 221 );
 222
 223 # Aliases so we understand old gitweb.snapshot values in repository
 224 # configuration.
 225 our %known_snapshot_format_aliases = (
 226         'gzip'  => 'tgz',
 227         'bzip2' => 'tbz2',
 228         'xz'    => 'txz',
 229
 230         # backward compatibility: legacy gitweb config support
 231         'x-gzip' => undef, 'gz' => undef,
 232         'x-bzip2' => undef, 'bz2' => undef,
 233         'x-zip' => undef, '' => undef,
 234 );
 235
 236 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 237 # are changed, it may be appropriate to change these values too via
 238 # $GITWEB_CONFIG.
 239 our %avatar_size = (
 240         'default' => 16,
 241         'double'  => 32
 242 );
 243
 244 # Used to set the maximum load that we will still respond to gitweb queries.
 245 # If server load exceed this value then return "503 server busy" error.
 246 # If gitweb cannot determined server load, it is taken to be 0.
 247 # Leave it undefined (or set to 'undef') to turn off load checking.
 248 our $maxload = 300;
 249
 250 # configuration for 'highlight' (http://www.andre-simon.de/)
 251 # match by basename
 252 our %highlight_basename = (
 253         #'Program' => 'py',
 254         #'Library' => 'py',
 255         'SConstruct' => 'py', # SCons equivalent of Makefile
 256         'Makefile' => 'make',
 257 );
 258 # match by extension
 259 our %highlight_ext = (
 260         # main extensions, defining name of syntax;
 261         # see files in /usr/share/highlight/langDefs/ directory
 262         map { $_ => $_ }
 263                 qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl sql make),
 264         # alternate extensions, see /etc/highlight/filetypes.conf
 265         'h' => 'c',
 266         map { $_ => 'sh'  } qw(bash zsh ksh),
 267         map { $_ => 'cpp' } qw(cxx c++ cc),
 268         map { $_ => 'php' } qw(php3 php4 php5 phps),
 269         map { $_ => 'pl'  } qw(perl pm), # perhaps also 'cgi'
 270         map { $_ => 'make'} qw(mak mk),
 271         map { $_ => 'xml' } qw(xhtml html htm),
 272 );
 273
 274 # You define site-wide feature defaults here; override them with
 275 # $GITWEB_CONFIG as necessary.
 276 our %feature = (
 277         # feature => {
 278         #       'sub' => feature-sub (subroutine),
 279         #       'override' => allow-override (boolean),
 280         #       'default' => [ default options...] (array reference)}
 281         #
 282         # if feature is overridable (it means that allow-override has true value),
 283         # then feature-sub will be called with default options as parameters;
 284         # return value of feature-sub indicates if to enable specified feature
 285         #
 286         # if there is no 'sub' key (no feature-sub), then feature cannot be
 287         # overridden
 288         #
 289         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 290         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 291         # is enabled
 292
 293         # Enable the 'blame' blob view, showing the last commit that modified
 294         # each line in the file. This can be very CPU-intensive.
 295
 296         # To enable system wide have in $GITWEB_CONFIG
 297         # $feature{'blame'}{'default'} = [1];
 298         # To have project specific config enable override in $GITWEB_CONFIG
 299         # $feature{'blame'}{'override'} = 1;
 300         # and in project config gitweb.blame = 0|1;
 301         'blame' => {
 302                 'sub' => sub { feature_bool('blame', @_) },
 303                 'override' => 0,
 304                 'default' => [0]},
 305
 306         # Enable the 'snapshot' link, providing a compressed archive of any
 307         # tree. This can potentially generate high traffic if you have large
 308         # project.
 309
 310         # Value is a list of formats defined in %known_snapshot_formats that
 311         # you wish to offer.
 312         # To disable system wide have in $GITWEB_CONFIG
 313         # $feature{'snapshot'}{'default'} = [];
 314         # To have project specific config enable override in $GITWEB_CONFIG
 315         # $feature{'snapshot'}{'override'} = 1;
 316         # and in project config, a comma-separated list of formats or "none"
 317         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 318         'snapshot' => {
 319                 'sub' => \&feature_snapshot,
 320                 'override' => 0,
 321                 'default' => ['tgz']},
 322
 323         # Enable text search, which will list the commits which match author,
 324         # committer or commit text to a given string.  Enabled by default.
 325         # Project specific override is not supported.
 326         #
 327         # Note that this controls all search features, which means that if
 328         # it is disabled, then 'grep' and 'pickaxe' search would also be
 329         # disabled.
 330         'search' => {
 331                 'override' => 0,
 332                 'default' => [1]},
 333
 334         # Enable grep search, which will list the files in currently selected
 335         # tree containing the given string. Enabled by default. This can be
 336         # potentially CPU-intensive, of course.
 337         # Note that you need to have 'search' feature enabled too.
 338
 339         # To enable system wide have in $GITWEB_CONFIG
 340         # $feature{'grep'}{'default'} = [1];
 341         # To have project specific config enable override in $GITWEB_CONFIG
 342         # $feature{'grep'}{'override'} = 1;
 343         # and in project config gitweb.grep = 0|1;
 344         'grep' => {
 345                 'sub' => sub { feature_bool('grep', @_) },
 346                 'override' => 0,
 347                 'default' => [1]},
 348
 349         # Enable the pickaxe search, which will list the commits that modified
 350         # a given string in a file. This can be practical and quite faster
 351         # alternative to 'blame', but still potentially CPU-intensive.
 352         # Note that you need to have 'search' feature enabled too.
 353
 354         # To enable system wide have in $GITWEB_CONFIG
 355         # $feature{'pickaxe'}{'default'} = [1];
 356         # To have project specific config enable override in $GITWEB_CONFIG
 357         # $feature{'pickaxe'}{'override'} = 1;
 358         # and in project config gitweb.pickaxe = 0|1;
 359         'pickaxe' => {
 360                 'sub' => sub { feature_bool('pickaxe', @_) },
 361                 'override' => 0,
 362                 'default' => [1]},
 363
 364         # Enable showing size of blobs in a 'tree' view, in a separate
 365         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 366
 367         # To disable system wide have in $GITWEB_CONFIG
 368         # $feature{'show-sizes'}{'default'} = [0];
 369         # To have project specific config enable override in $GITWEB_CONFIG
 370         # $feature{'show-sizes'}{'override'} = 1;
 371         # and in project config gitweb.showsizes = 0|1;
 372         'show-sizes' => {
 373                 'sub' => sub { feature_bool('showsizes', @_) },
 374                 'override' => 0,
 375                 'default' => [1]},
 376
 377         # Make gitweb use an alternative format of the URLs which can be
 378         # more readable and natural-looking: project name is embedded
 379         # directly in the path and the query string contains other
 380         # auxiliary information. All gitweb installations recognize
 381         # URL in either format; this configures in which formats gitweb
 382         # generates links.
 383
 384         # To enable system wide have in $GITWEB_CONFIG
 385         # $feature{'pathinfo'}{'default'} = [1];
 386         # Project specific override is not supported.
 387
 388         # Note that you will need to change the default location of CSS,
 389         # favicon, logo and possibly other files to an absolute URL. Also,
 390         # if gitweb.cgi serves as your indexfile, you will need to force
 391         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 392         'pathinfo' => {
 393                 'override' => 0,
 394                 'default' => [0]},
 395
 396         # Make gitweb consider projects in project root subdirectories
 397         # to be forks of existing projects. Given project $projname.git,
 398         # projects matching $projname/*.git will not be shown in the main
 399         # projects list, instead a '+' mark will be added to $projname
 400         # there and a 'forks' view will be enabled for the project, listing
 401         # all the forks. If project list is taken from a file, forks have
 402         # to be listed after the main project.
 403
 404         # To enable system wide have in $GITWEB_CONFIG
 405         # $feature{'forks'}{'default'} = [1];
 406         # Project specific override is not supported.
 407         'forks' => {
 408                 'override' => 0,
 409                 'default' => [0]},
 410
 411         # Insert custom links to the action bar of all project pages.
 412         # This enables you mainly to link to third-party scripts integrating
 413         # into gitweb; e.g. git-browser for graphical history representation
 414         # or custom web-based repository administration interface.
 415
 416         # The 'default' value consists of a list of triplets in the form
 417         # (label, link, position) where position is the label after which
 418         # to insert the link and link is a format string where %n expands
 419         # to the project name, %f to the project path within the filesystem,
 420         # %h to the current hash (h gitweb parameter) and %b to the current
 421         # hash base (hb gitweb parameter); %% expands to %.
 422
 423         # To enable system wide have in $GITWEB_CONFIG e.g.
 424         # $feature{'actions'}{'default'} = [('graphiclog',
 425         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 426         # Project specific override is not supported.
 427         'actions' => {
 428                 'override' => 0,
 429                 'default' => []},
 430
 431         # Allow gitweb scan project content tags of project repository,
 432         # and display the popular Web 2.0-ish "tag cloud" near the projects
 433         # list.  Note that this is something COMPLETELY different from the
 434         # normal Git tags.
 435
 436         # gitweb by itself can show existing tags, but it does not handle
 437         # tagging itself; you need to do it externally, outside gitweb.
 438         # The format is described in git_get_project_ctags() subroutine.
 439         # You may want to install the HTML::TagCloud Perl module to get
 440         # a pretty tag cloud instead of just a list of tags.
 441
 442         # To enable system wide have in $GITWEB_CONFIG
 443         # $feature{'ctags'}{'default'} = [1];
 444         # Project specific override is not supported.
 445
 446         # In the future whether ctags editing is enabled might depend
 447         # on the value, but using 1 should always mean no editing of ctags.
 448         'ctags' => {
 449                 'override' => 0,
 450                 'default' => [0]},
 451
 452         # The maximum number of patches in a patchset generated in patch
 453         # view. Set this to 0 or undef to disable patch view, or to a
 454         # negative number to remove any limit.
 455
 456         # To disable system wide have in $GITWEB_CONFIG
 457         # $feature{'patches'}{'default'} = [0];
 458         # To have project specific config enable override in $GITWEB_CONFIG
 459         # $feature{'patches'}{'override'} = 1;
 460         # and in project config gitweb.patches = 0|n;
 461         # where n is the maximum number of patches allowed in a patchset.
 462         'patches' => {
 463                 'sub' => \&feature_patches,
 464                 'override' => 0,
 465                 'default' => [16]},
 466
 467         # Avatar support. When this feature is enabled, views such as
 468         # shortlog or commit will display an avatar associated with
 469         # the email of the committer(s) and/or author(s).
 470
 471         # Currently available providers are gravatar and picon.
 472         # If an unknown provider is specified, the feature is disabled.
 473
 474         # Gravatar depends on Digest::MD5.
 475         # Picon currently relies on the indiana.edu database.
 476
 477         # To enable system wide have in $GITWEB_CONFIG
 478         # $feature{'avatar'}{'default'} = ['<provider>'];
 479         # where <provider> is either gravatar or picon.
 480         # To have project specific config enable override in $GITWEB_CONFIG
 481         # $feature{'avatar'}{'override'} = 1;
 482         # and in project config gitweb.avatar = <provider>;
 483         'avatar' => {
 484                 'sub' => \&feature_avatar,
 485                 'override' => 0,
 486                 'default' => ['']},
 487
 488         # Enable displaying how much time and how many git commands
 489         # it took to generate and display page.  Disabled by default.
 490         # Project specific override is not supported.
 491         'timed' => {
 492                 'override' => 0,
 493                 'default' => [0]},
 494
 495         # Enable turning some links into links to actions which require
 496         # JavaScript to run (like 'blame_incremental').  Not enabled by
 497         # default.  Project specific override is currently not supported.
 498         'javascript-actions' => {
 499                 'override' => 0,
 500                 'default' => [0]},
 501
 502         # Enable and configure ability to change common timezone for dates
 503         # in gitweb output via JavaScript.  Enabled by default.
 504         # Project specific override is not supported.
 505         'javascript-timezone' => {
 506                 'override' => 0,
 507                 'default' => [
 508                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 509                                      # or undef to turn off this feature
 510                         'gitweb_tz', # name of cookie where to store selected timezone
 511                         'datetime',  # CSS class used to mark up dates for manipulation
 512                 ]},
 513
 514         # Syntax highlighting support. This is based on Daniel Svensson's
 515         # and Sham Chukoury's work in gitweb-xmms2.git.
 516         # It requires the 'highlight' program present in $PATH,
 517         # and therefore is disabled by default.
 518
 519         # To enable system wide have in $GITWEB_CONFIG
 520         # $feature{'highlight'}{'default'} = [1];
 521
 522         'highlight' => {
 523                 'sub' => sub { feature_bool('highlight', @_) },
 524                 'override' => 0,
 525                 'default' => [0]},
 526
 527         # Enable displaying of remote heads in the heads list
 528
 529         # To enable system wide have in $GITWEB_CONFIG
 530         # $feature{'remote_heads'}{'default'} = [1];
 531         # To have project specific config enable override in $GITWEB_CONFIG
 532         # $feature{'remote_heads'}{'override'} = 1;
 533         # and in project config gitweb.remote_heads = 0|1;
 534         'remote_heads' => {
 535                 'sub' => sub { feature_bool('remote_heads', @_) },
 536                 'override' => 0,
 537                 'default' => [0]},
 538 );
 539
 540 sub gitweb_get_feature {
 541         my ($name) = @_;
 542         return unless exists $feature{$name};
 543         my ($sub, $override, @defaults) = (
 544                 $feature{$name}{'sub'},
 545                 $feature{$name}{'override'},
 546                 @{$feature{$name}{'default'}});
 547         # project specific override is possible only if we have project
 548         our $git_dir; # global variable, declared later
 549         if (!$override || !defined $git_dir) {
 550                 return @defaults;
 551         }
 552         if (!defined $sub) {
 553                 warn "feature $name is not overridable";
 554                 return @defaults;
 555         }
 556         return $sub->(@defaults);
 557 }
 558
 559 # A wrapper to check if a given feature is enabled.
 560 # With this, you can say
 561 #
 562 #   my $bool_feat = gitweb_check_feature('bool_feat');
 563 #   gitweb_check_feature('bool_feat') or somecode;
 564 #
 565 # instead of
 566 #
 567 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 568 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 569 #
 570 sub gitweb_check_feature {
 571         return (gitweb_get_feature(@_))[0];
 572 }
 573
 574
 575 sub feature_bool {
 576         my $key = shift;
 577         my ($val) = git_get_project_config($key, '--bool');
 578
 579         if (!defined $val) {
 580                 return ($_[0]);
 581         } elsif ($val eq 'true') {
 582                 return (1);
 583         } elsif ($val eq 'false') {
 584                 return (0);
 585         }
 586 }
 587
 588 sub feature_snapshot {
 589         my (@fmts) = @_;
 590
 591         my ($val) = git_get_project_config('snapshot');
 592
 593         if ($val) {
 594                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 595         }
 596
 597         return @fmts;
 598 }
 599
 600 sub feature_patches {
 601         my @val = (git_get_project_config('patches', '--int'));
 602
 603         if (@val) {
 604                 return @val;
 605         }
 606
 607         return ($_[0]);
 608 }
 609
 610 sub feature_avatar {
 611         my @val = (git_get_project_config('avatar'));
 612
 613         return @val ? @val : @_;
 614 }
 615
 616 # checking HEAD file with -e is fragile if the repository was
 617 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 618 # and then pruned.
 619 sub check_head_link {
 620         my ($dir) = @_;
 621         my $headfile = "$dir/HEAD";
 622         return ((-e $headfile) ||
 623                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 624 }
 625
 626 sub check_export_ok {
 627         my ($dir) = @_;
 628         return (check_head_link($dir) &&
 629                 (!$export_ok || -e "$dir/$export_ok") &&
 630                 (!$export_auth_hook || $export_auth_hook->($dir)));
 631 }
 632
 633 # process alternate names for backward compatibility
 634 # filter out unsupported (unknown) snapshot formats
 635 sub filter_snapshot_fmts {
 636         my @fmts = @_;
 637
 638         @fmts = map {
 639                 exists $known_snapshot_format_aliases{$_} ?
 640                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 641         @fmts = grep {
 642                 exists $known_snapshot_formats{$_} &&
 643                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 644 }
 645
 646 # If it is set to code reference, it is code that it is to be run once per
 647 # request, allowing updating configurations that change with each request,
 648 # while running other code in config file only once.
 649 #
 650 # Otherwise, if it is false then gitweb would process config file only once;
 651 # if it is true then gitweb config would be run for each request.
 652 our $per_request_config = 1;
 653
 654 # read and parse gitweb config file given by its parameter.
 655 # returns true on success, false on recoverable error, allowing
 656 # to chain this subroutine, using first file that exists.
 657 # dies on errors during parsing config file, as it is unrecoverable.
 658 sub read_config_file {
 659         my $filename = shift;
 660         return unless defined $filename;
 661         # die if there are errors parsing config file
 662         if (-e $filename) {
 663                 do $filename;
 664                 die $@ if $@;
 665                 return 1;
 666         }
 667         return;
 668 }
 669
 670 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 671 sub evaluate_gitweb_config {
 672         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 673         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 674         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
 675
 676         # Protect agains duplications of file names, to not read config twice.
 677         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 678         # there possibility of duplication of filename there doesn't matter.
 679         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 680         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 681
 682         # Common system-wide settings for convenience.
 683         # Those settings can be ovverriden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 684         read_config_file($GITWEB_CONFIG_COMMON);
 685
 686         # Use first config file that exists.  This means use the per-instance
 687         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 688         read_config_file($GITWEB_CONFIG) and return;
 689         read_config_file($GITWEB_CONFIG_SYSTEM);
 690 }
 691
 692 # Get loadavg of system, to compare against $maxload.
 693 # Currently it requires '/proc/loadavg' present to get loadavg;
 694 # if it is not present it returns 0, which means no load checking.
 695 sub get_loadavg {
 696         if( -e '/proc/loadavg' ){
 697                 open my $fd, '<', '/proc/loadavg'
 698                         or return 0;
 699                 my @load = split(/\s+/, scalar <$fd>);
 700                 close $fd;
 701
 702                 # The first three columns measure CPU and IO utilization of the last one,
 703                 # five, and 10 minute periods.  The fourth column shows the number of
 704                 # currently running processes and the total number of processes in the m/n
 705                 # format.  The last column displays the last process ID used.
 706                 return $load[0] || 0;
 707         }
 708         # additional checks for load average should go here for things that don't export
 709         # /proc/loadavg
 710
 711         return 0;
 712 }
 713
 714 # version of the core git binary
 715 our $git_version;
 716 sub evaluate_git_version {
 717         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 718         $number_of_git_cmds++;
 719 }
 720
 721 sub check_loadavg {
 722         if (defined $maxload && get_loadavg() > $maxload) {
 723                 die_error(503, "The load average on the server is too high");
 724         }
 725 }
 726
 727 # ======================================================================
 728 # input validation and dispatch
 729
 730 # input parameters can be collected from a variety of sources (presently, CGI
 731 # and PATH_INFO), so we define an %input_params hash that collects them all
 732 # together during validation: this allows subsequent uses (e.g. href()) to be
 733 # agnostic of the parameter origin
 734
 735 our %input_params = ();
 736
 737 # input parameters are stored with the long parameter name as key. This will
 738 # also be used in the href subroutine to convert parameters to their CGI
 739 # equivalent, and since the href() usage is the most frequent one, we store
 740 # the name -> CGI key mapping here, instead of the reverse.
 741 #
 742 # XXX: Warning: If you touch this, check the search form for updating,
 743 # too.
 744
 745 our @cgi_param_mapping = (
 746         project => "p",
 747         action => "a",
 748         file_name => "f",
 749         file_parent => "fp",
 750         hash => "h",
 751         hash_parent => "hp",
 752         hash_base => "hb",
 753         hash_parent_base => "hpb",
 754         page => "pg",
 755         order => "o",
 756         searchtext => "s",
 757         searchtype => "st",
 758         snapshot_format => "sf",
 759         extra_options => "opt",
 760         search_use_regexp => "sr",
 761         ctag => "by_tag",
 762         diff_style => "ds",
 763         # this must be last entry (for manipulation from JavaScript)
 764         javascript => "js"
 765 );
 766 our %cgi_param_mapping = @cgi_param_mapping;
 767
 768 # we will also need to know the possible actions, for validation
 769 our %actions = (
 770         "blame" => \&git_blame,
 771         "blame_incremental" => \&git_blame_incremental,
 772         "blame_data" => \&git_blame_data,
 773         "blobdiff" => \&git_blobdiff,
 774         "blobdiff_plain" => \&git_blobdiff_plain,
 775         "blob" => \&git_blob,
 776         "blob_plain" => \&git_blob_plain,
 777         "commitdiff" => \&git_commitdiff,
 778         "commitdiff_plain" => \&git_commitdiff_plain,
 779         "commit" => \&git_commit,
 780         "forks" => \&git_forks,
 781         "heads" => \&git_heads,
 782         "history" => \&git_history,
 783         "log" => \&git_log,
 784         "patch" => \&git_patch,
 785         "patches" => \&git_patches,
 786         "remotes" => \&git_remotes,
 787         "rss" => \&git_rss,
 788         "atom" => \&git_atom,
 789         "search" => \&git_search,
 790         "search_help" => \&git_search_help,
 791         "shortlog" => \&git_shortlog,
 792         "summary" => \&git_summary,
 793         "tag" => \&git_tag,
 794         "tags" => \&git_tags,
 795         "tree" => \&git_tree,
 796         "snapshot" => \&git_snapshot,
 797         "object" => \&git_object,
 798         # those below don't need $project
 799         "opml" => \&git_opml,
 800         "project_list" => \&git_project_list,
 801         "project_index" => \&git_project_index,
 802 );
 803
 804 # finally, we have the hash of allowed extra_options for the commands that
 805 # allow them
 806 our %allowed_options = (
 807         "--no-merges" => [ qw(rss atom log shortlog history) ],
 808 );
 809
 810 # fill %input_params with the CGI parameters. All values except for 'opt'
 811 # should be single values, but opt can be an array. We should probably
 812 # build an array of parameters that can be multi-valued, but since for the time
 813 # being it's only this one, we just single it out
 814 sub evaluate_query_params {
 815         our $cgi;
 816
 817         while (my ($name, $symbol) = each %cgi_param_mapping) {
 818                 if ($symbol eq 'opt') {
 819                         $input_params{$name} = [ $cgi->param($symbol) ];
 820                 } else {
 821                         $input_params{$name} = $cgi->param($symbol);
 822                 }
 823         }
 824 }
 825
 826 # now read PATH_INFO and update the parameter list for missing parameters
 827 sub evaluate_path_info {
 828         return if defined $input_params{'project'};
 829         return if !$path_info;
 830         $path_info =~ s,^/+,,;
 831         return if !$path_info;
 832
 833         # find which part of PATH_INFO is project
 834         my $project = $path_info;
 835         $project =~ s,/+$,,;
 836         while ($project && !check_head_link("$projectroot/$project")) {
 837                 $project =~ s,/*[^/]*$,,;
 838         }
 839         return unless $project;
 840         $input_params{'project'} = $project;
 841
 842         # do not change any parameters if an action is given using the query string
 843         return if $input_params{'action'};
 844         $path_info =~ s,^\Q$project\E/*,,;
 845
 846         # next, check if we have an action
 847         my $action = $path_info;
 848         $action =~ s,/.*$,,;
 849         if (exists $actions{$action}) {
 850                 $path_info =~ s,^$action/*,,;
 851                 $input_params{'action'} = $action;
 852         }
 853
 854         # list of actions that want hash_base instead of hash, but can have no
 855         # pathname (f) parameter
 856         my @wants_base = (
 857                 'tree',
 858                 'history',
 859         );
 860
 861         # we want to catch, among others
 862         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 863         my ($parentrefname, $parentpathname, $refname, $pathname) =
 864                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 865
 866         # first, analyze the 'current' part
 867         if (defined $pathname) {
 868                 # we got "branch:filename" or "branch:dir/"
 869                 # we could use git_get_type(branch:pathname), but:
 870                 # - it needs $git_dir
 871                 # - it does a git() call
 872                 # - the convention of terminating directories with a slash
 873                 #   makes it superfluous
 874                 # - embedding the action in the PATH_INFO would make it even
 875                 #   more superfluous
 876                 $pathname =~ s,^/+,,;
 877                 if (!$pathname || substr($pathname, -1) eq "/") {
 878                         $input_params{'action'} ||= "tree";
 879                         $pathname =~ s,/$,,;
 880                 } else {
 881                         # the default action depends on whether we had parent info
 882                         # or not
 883                         if ($parentrefname) {
 884                                 $input_params{'action'} ||= "blobdiff_plain";
 885                         } else {
 886                                 $input_params{'action'} ||= "blob_plain";
 887                         }
 888                 }
 889                 $input_params{'hash_base'} ||= $refname;
 890                 $input_params{'file_name'} ||= $pathname;
 891         } elsif (defined $refname) {
 892                 # we got "branch". In this case we have to choose if we have to
 893                 # set hash or hash_base.
 894                 #
 895                 # Most of the actions without a pathname only want hash to be
 896                 # set, except for the ones specified in @wants_base that want
 897                 # hash_base instead. It should also be noted that hand-crafted
 898                 # links having 'history' as an action and no pathname or hash
 899                 # set will fail, but that happens regardless of PATH_INFO.
 900                 if (defined $parentrefname) {
 901                         # if there is parent let the default be 'shortlog' action
 902                         # (for http://git.example.com/repo.git/A..B links); if there
 903                         # is no parent, dispatch will detect type of object and set
 904                         # action appropriately if required (if action is not set)
 905                         $input_params{'action'} ||= "shortlog";
 906                 }
 907                 if ($input_params{'action'} &&
 908                     grep { $_ eq $input_params{'action'} } @wants_base) {
 909                         $input_params{'hash_base'} ||= $refname;
 910                 } else {
 911                         $input_params{'hash'} ||= $refname;
 912                 }
 913         }
 914
 915         # next, handle the 'parent' part, if present
 916         if (defined $parentrefname) {
 917                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 918                 # someproject/blobdiff/oldrev..newrev:/filename
 919                 if ($parentpathname) {
 920                         $parentpathname =~ s,^/+,,;
 921                         $parentpathname =~ s,/$,,;
 922                         $input_params{'file_parent'} ||= $parentpathname;
 923                 } else {
 924                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 925                 }
 926                 # we assume that hash_parent_base is wanted if a path was specified,
 927                 # or if the action wants hash_base instead of hash
 928                 if (defined $input_params{'file_parent'} ||
 929                         grep { $_ eq $input_params{'action'} } @wants_base) {
 930                         $input_params{'hash_parent_base'} ||= $parentrefname;
 931                 } else {
 932                         $input_params{'hash_parent'} ||= $parentrefname;
 933                 }
 934         }
 935
 936         # for the snapshot action, we allow URLs in the form
 937         # $project/snapshot/$hash.ext
 938         # where .ext determines the snapshot and gets removed from the
 939         # passed $refname to provide the $hash.
 940         #
 941         # To be able to tell that $refname includes the format extension, we
 942         # require the following two conditions to be satisfied:
 943         # - the hash input parameter MUST have been set from the $refname part
 944         #   of the URL (i.e. they must be equal)
 945         # - the snapshot format MUST NOT have been defined already (e.g. from
 946         #   CGI parameter sf)
 947         # It's also useless to try any matching unless $refname has a dot,
 948         # so we check for that too
 949         if (defined $input_params{'action'} &&
 950                 $input_params{'action'} eq 'snapshot' &&
 951                 defined $refname && index($refname, '.') != -1 &&
 952                 $refname eq $input_params{'hash'} &&
 953                 !defined $input_params{'snapshot_format'}) {
 954                 # We loop over the known snapshot formats, checking for
 955                 # extensions. Allowed extensions are both the defined suffix
 956                 # (which includes the initial dot already) and the snapshot
 957                 # format key itself, with a prepended dot
 958                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 959                         my $hash = $refname;
 960                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 961                                 next;
 962                         }
 963                         my $sfx = $1;
 964                         # a valid suffix was found, so set the snapshot format
 965                         # and reset the hash parameter
 966                         $input_params{'snapshot_format'} = $fmt;
 967                         $input_params{'hash'} = $hash;
 968                         # we also set the format suffix to the one requested
 969                         # in the URL: this way a request for e.g. .tgz returns
 970                         # a .tgz instead of a .tar.gz
 971                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 972                         last;
 973                 }
 974         }
 975 }
 976
 977 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 978      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 979      $searchtext, $search_regexp);
 980 sub evaluate_and_validate_params {
 981         our $action = $input_params{'action'};
 982         if (defined $action) {
 983                 if (!validate_action($action)) {
 984                         die_error(400, "Invalid action parameter");
 985                 }
 986         }
 987
 988         # parameters which are pathnames
 989         our $project = $input_params{'project'};
 990         if (defined $project) {
 991                 if (!validate_project($project)) {
 992                         undef $project;
 993                         die_error(404, "No such project");
 994                 }
 995         }
 996
 997         our $file_name = $input_params{'file_name'};
 998         if (defined $file_name) {
 999                 if (!validate_pathname($file_name)) {
1000                         die_error(400, "Invalid file parameter");
1001                 }
1002         }
1003
1004         our $file_parent = $input_params{'file_parent'};
1005         if (defined $file_parent) {
1006                 if (!validate_pathname($file_parent)) {
1007                         die_error(400, "Invalid file parent parameter");
1008                 }
1009         }
1010
1011         # parameters which are refnames
1012         our $hash = $input_params{'hash'};
1013         if (defined $hash) {
1014                 if (!validate_refname($hash)) {
1015                         die_error(400, "Invalid hash parameter");
1016                 }
1017         }
1018
1019         our $hash_parent = $input_params{'hash_parent'};
1020         if (defined $hash_parent) {
1021                 if (!validate_refname($hash_parent)) {
1022                         die_error(400, "Invalid hash parent parameter");
1023                 }
1024         }
1025
1026         our $hash_base = $input_params{'hash_base'};
1027         if (defined $hash_base) {
1028                 if (!validate_refname($hash_base)) {
1029                         die_error(400, "Invalid hash base parameter");
1030                 }
1031         }
1032
1033         our @extra_options = @{$input_params{'extra_options'}};
1034         # @extra_options is always defined, since it can only be (currently) set from
1035         # CGI, and $cgi->param() returns the empty array in array context if the param
1036         # is not set
1037         foreach my $opt (@extra_options) {
1038                 if (not exists $allowed_options{$opt}) {
1039                         die_error(400, "Invalid option parameter");
1040                 }
1041                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1042                         die_error(400, "Invalid option parameter for this action");
1043                 }
1044         }
1045
1046         our $hash_parent_base = $input_params{'hash_parent_base'};
1047         if (defined $hash_parent_base) {
1048                 if (!validate_refname($hash_parent_base)) {
1049                         die_error(400, "Invalid hash parent base parameter");
1050                 }
1051         }
1052
1053         # other parameters
1054         our $page = $input_params{'page'};
1055         if (defined $page) {
1056                 if ($page =~ m/[^0-9]/) {
1057                         die_error(400, "Invalid page parameter");
1058                 }
1059         }
1060
1061         our $searchtype = $input_params{'searchtype'};
1062         if (defined $searchtype) {
1063                 if ($searchtype =~ m/[^a-z]/) {
1064                         die_error(400, "Invalid searchtype parameter");
1065                 }
1066         }
1067
1068         our $search_use_regexp = $input_params{'search_use_regexp'};
1069
1070         our $searchtext = $input_params{'searchtext'};
1071         our $search_regexp;
1072         if (defined $searchtext) {
1073                 if (length($searchtext) < 2) {
1074                         die_error(403, "At least two characters are required for search parameter");
1075                 }
1076                 $search_regexp = $search_use_regexp ? $searchtext : quotemeta $searchtext;
1077         }
1078 }
1079
1080 # path to the current git repository
1081 our $git_dir;
1082 sub evaluate_git_dir {
1083         our $git_dir = "$projectroot/$project" if $project;
1084 }
1085
1086 our (@snapshot_fmts, $git_avatar);
1087 sub configure_gitweb_features {
1088         # list of supported snapshot formats
1089         our @snapshot_fmts = gitweb_get_feature('snapshot');
1090         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1091
1092         # check that the avatar feature is set to a known provider name,
1093         # and for each provider check if the dependencies are satisfied.
1094         # if the provider name is invalid or the dependencies are not met,
1095         # reset $git_avatar to the empty string.
1096         our ($git_avatar) = gitweb_get_feature('avatar');
1097         if ($git_avatar eq 'gravatar') {
1098                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1099         } elsif ($git_avatar eq 'picon') {
1100                 # no dependencies
1101         } else {
1102                 $git_avatar = '';
1103         }
1104 }
1105
1106 # custom error handler: 'die <message>' is Internal Server Error
1107 sub handle_errors_html {
1108         my $msg = shift; # it is already HTML escaped
1109
1110         # to avoid infinite loop where error occurs in die_error,
1111         # change handler to default handler, disabling handle_errors_html
1112         set_message("Error occured when inside die_error:\n$msg");
1113
1114         # you cannot jump out of die_error when called as error handler;
1115         # the subroutine set via CGI::Carp::set_message is called _after_
1116         # HTTP headers are already written, so it cannot write them itself
1117         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1118 }
1119 set_message(\&handle_errors_html);
1120
1121 # dispatch
1122 sub dispatch {
1123         if (!defined $action) {
1124                 if (defined $hash) {
1125                         $action = git_get_type($hash);
1126                         $action or die_error(404, "Object does not exist");
1127                 } elsif (defined $hash_base && defined $file_name) {
1128                         $action = git_get_type("$hash_base:$file_name");
1129                         $action or die_error(404, "File or directory does not exist");
1130                 } elsif (defined $project) {
1131                         $action = 'summary';
1132                 } else {
1133                         $action = 'project_list';
1134                 }
1135         }
1136         if (!defined($actions{$action})) {
1137                 die_error(400, "Unknown action");
1138         }
1139         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1140             !$project) {
1141                 die_error(400, "Project needed");
1142         }
1143         $actions{$action}->();
1144 }
1145
1146 sub reset_timer {
1147         our $t0 = [ gettimeofday() ]
1148                 if defined $t0;
1149         our $number_of_git_cmds = 0;
1150 }
1151
1152 our $first_request = 1;
1153 sub run_request {
1154         reset_timer();
1155
1156         evaluate_uri();
1157         if ($first_request) {
1158                 evaluate_gitweb_config();
1159                 evaluate_git_version();
1160         }
1161         if ($per_request_config) {
1162                 if (ref($per_request_config) eq 'CODE') {
1163                         $per_request_config->();
1164                 } elsif (!$first_request) {
1165                         evaluate_gitweb_config();
1166                 }
1167         }
1168         check_loadavg();
1169
1170         # $projectroot and $projects_list might be set in gitweb config file
1171         $projects_list ||= $projectroot;
1172
1173         evaluate_query_params();
1174         evaluate_path_info();
1175         evaluate_and_validate_params();
1176         evaluate_git_dir();
1177
1178         configure_gitweb_features();
1179
1180         dispatch();
1181 }
1182
1183 our $is_last_request = sub { 1 };
1184 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1185 our $CGI = 'CGI';
1186 our $cgi;
1187 sub configure_as_fcgi {
1188         require CGI::Fast;
1189         our $CGI = 'CGI::Fast';
1190
1191         my $request_number = 0;
1192         # let each child service 100 requests
1193         our $is_last_request = sub { ++$request_number > 100 };
1194 }
1195 sub evaluate_argv {
1196         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1197         configure_as_fcgi()
1198                 if $script_name =~ /\.fcgi$/;
1199
1200         return unless (@ARGV);
1201
1202         require Getopt::Long;
1203         Getopt::Long::GetOptions(
1204                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1205                 'nproc|n=i' => sub {
1206                         my ($arg, $val) = @_;
1207                         return unless eval { require FCGI::ProcManager; 1; };
1208                         my $proc_manager = FCGI::ProcManager->new({
1209                                 n_processes => $val,
1210                         });
1211                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1212                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1213                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1214                 },
1215         );
1216 }
1217
1218 sub run {
1219         evaluate_argv();
1220
1221         $first_request = 1;
1222         $pre_listen_hook->()
1223                 if $pre_listen_hook;
1224
1225  REQUEST:
1226         while ($cgi = $CGI->new()) {
1227                 $pre_dispatch_hook->()
1228                         if $pre_dispatch_hook;
1229
1230                 run_request();
1231
1232                 $post_dispatch_hook->()
1233                         if $post_dispatch_hook;
1234                 $first_request = 0;
1235
1236                 last REQUEST if ($is_last_request->());
1237         }
1238
1239  DONE_GITWEB:
1240         1;
1241 }
1242
1243 run();
1244
1245 if (defined caller) {
1246         # wrapped in a subroutine processing requests,
1247         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1248         return;
1249 } else {
1250         # pure CGI script, serving single request
1251         exit;
1252 }
1253
1254 ## ======================================================================
1255 ## action links
1256
1257 # possible values of extra options
1258 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1259 # -replay => 1      - start from a current view (replay with modifications)
1260 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1261 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1262 sub href {
1263         my %params = @_;
1264         # default is to use -absolute url() i.e. $my_uri
1265         my $href = $params{-full} ? $my_url : $my_uri;
1266
1267         # implicit -replay, must be first of implicit params
1268         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1269
1270         $params{'project'} = $project unless exists $params{'project'};
1271
1272         if ($params{-replay}) {
1273                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1274                         if (!exists $params{$name}) {
1275                                 $params{$name} = $input_params{$name};
1276                         }
1277                 }
1278         }
1279
1280         my $use_pathinfo = gitweb_check_feature('pathinfo');
1281         if (defined $params{'project'} &&
1282             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1283                 # try to put as many parameters as possible in PATH_INFO:
1284                 #   - project name
1285                 #   - action
1286                 #   - hash_parent or hash_parent_base:/file_parent
1287                 #   - hash or hash_base:/filename
1288                 #   - the snapshot_format as an appropriate suffix
1289
1290                 # When the script is the root DirectoryIndex for the domain,
1291                 # $href here would be something like http://gitweb.example.com/
1292                 # Thus, we strip any trailing / from $href, to spare us double
1293                 # slashes in the final URL
1294                 $href =~ s,/$,,;
1295
1296                 # Then add the project name, if present
1297                 $href .= "/".esc_path_info($params{'project'});
1298                 delete $params{'project'};
1299
1300                 # since we destructively absorb parameters, we keep this
1301                 # boolean that remembers if we're handling a snapshot
1302                 my $is_snapshot = $params{'action'} eq 'snapshot';
1303
1304                 # Summary just uses the project path URL, any other action is
1305                 # added to the URL
1306                 if (defined $params{'action'}) {
1307                         $href .= "/".esc_path_info($params{'action'})
1308                                 unless $params{'action'} eq 'summary';
1309                         delete $params{'action'};
1310                 }
1311
1312                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1313                 # stripping nonexistent or useless pieces
1314                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1315                         || $params{'hash_parent'} || $params{'hash'});
1316                 if (defined $params{'hash_base'}) {
1317                         if (defined $params{'hash_parent_base'}) {
1318                                 $href .= esc_path_info($params{'hash_parent_base'});
1319                                 # skip the file_parent if it's the same as the file_name
1320                                 if (defined $params{'file_parent'}) {
1321                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1322                                                 delete $params{'file_parent'};
1323                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1324                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1325                                                 delete $params{'file_parent'};
1326                                         }
1327                                 }
1328                                 $href .= "..";
1329                                 delete $params{'hash_parent'};
1330                                 delete $params{'hash_parent_base'};
1331                         } elsif (defined $params{'hash_parent'}) {
1332                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1333                                 delete $params{'hash_parent'};
1334                         }
1335
1336                         $href .= esc_path_info($params{'hash_base'});
1337                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1338                                 $href .= ":/".esc_path_info($params{'file_name'});
1339                                 delete $params{'file_name'};
1340                         }
1341                         delete $params{'hash'};
1342                         delete $params{'hash_base'};
1343                 } elsif (defined $params{'hash'}) {
1344                         $href .= esc_path_info($params{'hash'});
1345                         delete $params{'hash'};
1346                 }
1347
1348                 # If the action was a snapshot, we can absorb the
1349                 # snapshot_format parameter too
1350                 if ($is_snapshot) {
1351                         my $fmt = $params{'snapshot_format'};
1352                         # snapshot_format should always be defined when href()
1353                         # is called, but just in case some code forgets, we
1354                         # fall back to the default
1355                         $fmt ||= $snapshot_fmts[0];
1356                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1357                         delete $params{'snapshot_format'};
1358                 }
1359         }
1360
1361         # now encode the parameters explicitly
1362         my @result = ();
1363         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1364                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1365                 if (defined $params{$name}) {
1366                         if (ref($params{$name}) eq "ARRAY") {
1367                                 foreach my $par (@{$params{$name}}) {
1368                                         push @result, $symbol . "=" . esc_param($par);
1369                                 }
1370                         } else {
1371                                 push @result, $symbol . "=" . esc_param($params{$name});
1372                         }
1373                 }
1374         }
1375         $href .= "?" . join(';', @result) if scalar @result;
1376
1377         # final transformation: trailing spaces must be escaped (URI-encoded)
1378         $href =~ s/(\s+)$/CGI::escape($1)/e;
1379
1380         if ($params{-anchor}) {
1381                 $href .= "#".esc_param($params{-anchor});
1382         }
1383
1384         return $href;
1385 }
1386
1387
1388 ## ======================================================================
1389 ## validation, quoting/unquoting and escaping
1390
1391 sub validate_action {
1392         my $input = shift || return undef;
1393         return undef unless exists $actions{$input};
1394         return $input;
1395 }
1396
1397 sub validate_project {
1398         my $input = shift || return undef;
1399         if (!validate_pathname($input) ||
1400                 !(-d "$projectroot/$input") ||
1401                 !check_export_ok("$projectroot/$input") ||
1402                 ($strict_export && !project_in_list($input))) {
1403                 return undef;
1404         } else {
1405                 return $input;
1406         }
1407 }
1408
1409 sub validate_pathname {
1410         my $input = shift || return undef;
1411
1412         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1413         # at the beginning, at the end, and between slashes.
1414         # also this catches doubled slashes
1415         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1416                 return undef;
1417         }
1418         # no null characters
1419         if ($input =~ m!\0!) {
1420                 return undef;
1421         }
1422         return $input;
1423 }
1424
1425 sub validate_refname {
1426         my $input = shift || return undef;
1427
1428         # textual hashes are O.K.
1429         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1430                 return $input;
1431         }
1432         # it must be correct pathname
1433         $input = validate_pathname($input)
1434                 or return undef;
1435         # restrictions on ref name according to git-check-ref-format
1436         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1437                 return undef;
1438         }
1439         return $input;
1440 }
1441
1442 # decode sequences of octets in utf8 into Perl's internal form,
1443 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1444 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1445 sub to_utf8 {
1446         my $str = shift;
1447         return undef unless defined $str;
1448
1449         if (utf8::is_utf8($str) || utf8::decode($str)) {
1450                 return $str;
1451         } else {
1452                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1453         }
1454 }
1455
1456 # quote unsafe chars, but keep the slash, even when it's not
1457 # correct, but quoted slashes look too horrible in bookmarks
1458 sub esc_param {
1459         my $str = shift;
1460         return undef unless defined $str;
1461         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1462         $str =~ s/ /\+/g;
1463         return $str;
1464 }
1465
1466 # the quoting rules for path_info fragment are slightly different
1467 sub esc_path_info {
1468         my $str = shift;
1469         return undef unless defined $str;
1470
1471         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1472         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1473
1474         return $str;
1475 }
1476
1477 # quote unsafe chars in whole URL, so some characters cannot be quoted
1478 sub esc_url {
1479         my $str = shift;
1480         return undef unless defined $str;
1481         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1482         $str =~ s/ /\+/g;
1483         return $str;
1484 }
1485
1486 # quote unsafe characters in HTML attributes
1487 sub esc_attr {
1488
1489         # for XHTML conformance escaping '"' to '&quot;' is not enough
1490         return esc_html(@_);
1491 }
1492
1493 # replace invalid utf8 character with SUBSTITUTION sequence
1494 sub esc_html {
1495         my $str = shift;
1496         my %opts = @_;
1497
1498         return undef unless defined $str;
1499
1500         $str = to_utf8($str);
1501         $str = $cgi->escapeHTML($str);
1502         if ($opts{'-nbsp'}) {
1503                 $str =~ s/ /&nbsp;/g;
1504         }
1505         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1506         return $str;
1507 }
1508
1509 # quote control characters and escape filename to HTML
1510 sub esc_path {
1511         my $str = shift;
1512         my %opts = @_;
1513
1514         return undef unless defined $str;
1515
1516         $str = to_utf8($str);
1517         $str = $cgi->escapeHTML($str);
1518         if ($opts{'-nbsp'}) {
1519                 $str =~ s/ /&nbsp;/g;
1520         }
1521         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1522         return $str;
1523 }
1524
1525 # Sanitize for use in XHTML + application/xml+xhtm (valid XML 1.0)
1526 sub sanitize {
1527         my $str = shift;
1528
1529         return undef unless defined $str;
1530
1531         $str = to_utf8($str);
1532         $str =~ s|([[:cntrl:]])|($1 =~ /[\t\n\r]/ ? $1 : quot_cec($1))|eg;
1533         return $str;
1534 }
1535
1536 # Make control characters "printable", using character escape codes (CEC)
1537 sub quot_cec {
1538         my $cntrl = shift;
1539         my %opts = @_;
1540         my %es = ( # character escape codes, aka escape sequences
1541                 "\t" => '\t',   # tab            (HT)
1542                 "\n" => '\n',   # line feed      (LF)
1543                 "\r" => '\r',   # carrige return (CR)
1544                 "\f" => '\f',   # form feed      (FF)
1545                 "\b" => '\b',   # backspace      (BS)
1546                 "\a" => '\a',   # alarm (bell)   (BEL)
1547                 "\e" => '\e',   # escape         (ESC)
1548                 "\013" => '\v', # vertical tab   (VT)
1549                 "\000" => '\0', # nul character  (NUL)
1550         );
1551         my $chr = ( (exists $es{$cntrl})
1552                     ? $es{$cntrl}
1553                     : sprintf('\%2x', ord($cntrl)) );
1554         if ($opts{-nohtml}) {
1555                 return $chr;
1556         } else {
1557                 return "<span class=\"cntrl\">$chr</span>";
1558         }
1559 }
1560
1561 # Alternatively use unicode control pictures codepoints,
1562 # Unicode "printable representation" (PR)
1563 sub quot_upr {
1564         my $cntrl = shift;
1565         my %opts = @_;
1566
1567         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1568         if ($opts{-nohtml}) {
1569                 return $chr;
1570         } else {
1571                 return "<span class=\"cntrl\">$chr</span>";
1572         }
1573 }
1574
1575 # git may return quoted and escaped filenames
1576 sub unquote {
1577         my $str = shift;
1578
1579         sub unq {
1580                 my $seq = shift;
1581                 my %es = ( # character escape codes, aka escape sequences
1582                         't' => "\t",   # tab            (HT, TAB)
1583                         'n' => "\n",   # newline        (NL)
1584                         'r' => "\r",   # return         (CR)
1585                         'f' => "\f",   # form feed      (FF)
1586                         'b' => "\b",   # backspace      (BS)
1587                         'a' => "\a",   # alarm (bell)   (BEL)
1588                         'e' => "\e",   # escape         (ESC)
1589                         'v' => "\013", # vertical tab   (VT)
1590                 );
1591
1592                 if ($seq =~ m/^[0-7]{1,3}$/) {
1593                         # octal char sequence
1594                         return chr(oct($seq));
1595                 } elsif (exists $es{$seq}) {
1596                         # C escape sequence, aka character escape code
1597                         return $es{$seq};
1598                 }
1599                 # quoted ordinary character
1600                 return $seq;
1601         }
1602
1603         if ($str =~ m/^"(.*)"$/) {
1604                 # needs unquoting
1605                 $str = $1;
1606                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1607         }
1608         return $str;
1609 }
1610
1611 # escape tabs (convert tabs to spaces)
1612 sub untabify {
1613         my $line = shift;
1614
1615         while ((my $pos = index($line, "\t")) != -1) {
1616                 if (my $count = (8 - ($pos % 8))) {
1617                         my $spaces = ' ' x $count;
1618                         $line =~ s/\t/$spaces/;
1619                 }
1620         }
1621
1622         return $line;
1623 }
1624
1625 sub project_in_list {
1626         my $project = shift;
1627         my @list = git_get_projects_list();
1628         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1629 }
1630
1631 ## ----------------------------------------------------------------------
1632 ## HTML aware string manipulation
1633
1634 # Try to chop given string on a word boundary between position
1635 # $len and $len+$add_len. If there is no word boundary there,
1636 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1637 # (marking chopped part) would be longer than given string.
1638 sub chop_str {
1639         my $str = shift;
1640         my $len = shift;
1641         my $add_len = shift || 10;
1642         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1643
1644         # Make sure perl knows it is utf8 encoded so we don't
1645         # cut in the middle of a utf8 multibyte char.
1646         $str = to_utf8($str);
1647
1648         # allow only $len chars, but don't cut a word if it would fit in $add_len
1649         # if it doesn't fit, cut it if it's still longer than the dots we would add
1650         # remove chopped character entities entirely
1651
1652         # when chopping in the middle, distribute $len into left and right part
1653         # return early if chopping wouldn't make string shorter
1654         if ($where eq 'center') {
1655                 return $str if ($len + 5 >= length($str)); # filler is length 5
1656                 $len = int($len/2);
1657         } else {
1658                 return $str if ($len + 4 >= length($str)); # filler is length 4
1659         }
1660
1661         # regexps: ending and beginning with word part up to $add_len
1662         my $endre = qr/.{$len}\w{0,$add_len}/;
1663         my $begre = qr/\w{0,$add_len}.{$len}/;
1664
1665         if ($where eq 'left') {
1666                 $str =~ m/^(.*?)($begre)$/;
1667                 my ($lead, $body) = ($1, $2);
1668                 if (length($lead) > 4) {
1669                         $lead = " ...";
1670                 }
1671                 return "$lead$body";
1672
1673         } elsif ($where eq 'center') {
1674                 $str =~ m/^($endre)(.*)$/;
1675                 my ($left, $str)  = ($1, $2);
1676                 $str =~ m/^(.*?)($begre)$/;
1677                 my ($mid, $right) = ($1, $2);
1678                 if (length($mid) > 5) {
1679                         $mid = " ... ";
1680                 }
1681                 return "$left$mid$right";
1682
1683         } else {
1684                 $str =~ m/^($endre)(.*)$/;
1685                 my $body = $1;
1686                 my $tail = $2;
1687                 if (length($tail) > 4) {
1688                         $tail = "... ";
1689                 }
1690                 return "$body$tail";
1691         }
1692 }
1693
1694 # takes the same arguments as chop_str, but also wraps a <span> around the
1695 # result with a title attribute if it does get chopped. Additionally, the
1696 # string is HTML-escaped.
1697 sub chop_and_escape_str {
1698         my ($str) = @_;
1699
1700         my $chopped = chop_str(@_);
1701         $str = to_utf8($str);
1702         if ($chopped eq $str) {
1703                 return esc_html($chopped);
1704         } else {
1705                 $str =~ s/[[:cntrl:]]/?/g;
1706                 return $cgi->span({-title=>$str}, esc_html($chopped));
1707         }
1708 }
1709
1710 ## ----------------------------------------------------------------------
1711 ## functions returning short strings
1712
1713 # CSS class for given age value (in seconds)
1714 sub age_class {
1715         my $age = shift;
1716
1717         if (!defined $age) {
1718                 return "noage";
1719         } elsif ($age < 60*60*2) {
1720                 return "age0";
1721         } elsif ($age < 60*60*24*2) {
1722                 return "age1";
1723         } else {
1724                 return "age2";
1725         }
1726 }
1727
1728 # convert age in seconds to "nn units ago" string
1729 sub age_string {
1730         my $age = shift;
1731         my $age_str;
1732
1733         if ($age > 60*60*24*365*2) {
1734                 $age_str = (int $age/60/60/24/365);
1735                 $age_str .= " years ago";
1736         } elsif ($age > 60*60*24*(365/12)*2) {
1737                 $age_str = int $age/60/60/24/(365/12);
1738                 $age_str .= " months ago";
1739         } elsif ($age > 60*60*24*7*2) {
1740                 $age_str = int $age/60/60/24/7;
1741                 $age_str .= " weeks ago";
1742         } elsif ($age > 60*60*24*2) {
1743                 $age_str = int $age/60/60/24;
1744                 $age_str .= " days ago";
1745         } elsif ($age > 60*60*2) {
1746                 $age_str = int $age/60/60;
1747                 $age_str .= " hours ago";
1748         } elsif ($age > 60*2) {
1749                 $age_str = int $age/60;
1750                 $age_str .= " min ago";
1751         } elsif ($age > 2) {
1752                 $age_str = int $age;
1753                 $age_str .= " sec ago";
1754         } else {
1755                 $age_str .= " right now";
1756         }
1757         return $age_str;
1758 }
1759
1760 use constant {
1761         S_IFINVALID => 0030000,
1762         S_IFGITLINK => 0160000,
1763 };
1764
1765 # submodule/subproject, a commit object reference
1766 sub S_ISGITLINK {
1767         my $mode = shift;
1768
1769         return (($mode & S_IFMT) == S_IFGITLINK)
1770 }
1771
1772 # convert file mode in octal to symbolic file mode string
1773 sub mode_str {
1774         my $mode = oct shift;
1775
1776         if (S_ISGITLINK($mode)) {
1777                 return 'm---------';
1778         } elsif (S_ISDIR($mode & S_IFMT)) {
1779                 return 'drwxr-xr-x';
1780         } elsif (S_ISLNK($mode)) {
1781                 return 'lrwxrwxrwx';
1782         } elsif (S_ISREG($mode)) {
1783                 # git cares only about the executable bit
1784                 if ($mode & S_IXUSR) {
1785                         return '-rwxr-xr-x';
1786                 } else {
1787                         return '-rw-r--r--';
1788                 };
1789         } else {
1790                 return '----------';
1791         }
1792 }
1793
1794 # convert file mode in octal to file type string
1795 sub file_type {
1796         my $mode = shift;
1797
1798         if ($mode !~ m/^[0-7]+$/) {
1799                 return $mode;
1800         } else {
1801                 $mode = oct $mode;
1802         }
1803
1804         if (S_ISGITLINK($mode)) {
1805                 return "submodule";
1806         } elsif (S_ISDIR($mode & S_IFMT)) {
1807                 return "directory";
1808         } elsif (S_ISLNK($mode)) {
1809                 return "symlink";
1810         } elsif (S_ISREG($mode)) {
1811                 return "file";
1812         } else {
1813                 return "unknown";
1814         }
1815 }
1816
1817 # convert file mode in octal to file type description string
1818 sub file_type_long {
1819         my $mode = shift;
1820
1821         if ($mode !~ m/^[0-7]+$/) {
1822                 return $mode;
1823         } else {
1824                 $mode = oct $mode;
1825         }
1826
1827         if (S_ISGITLINK($mode)) {
1828                 return "submodule";
1829         } elsif (S_ISDIR($mode & S_IFMT)) {
1830                 return "directory";
1831         } elsif (S_ISLNK($mode)) {
1832                 return "symlink";
1833         } elsif (S_ISREG($mode)) {
1834                 if ($mode & S_IXUSR) {
1835                         return "executable";
1836                 } else {
1837                         return "file";
1838                 };
1839         } else {
1840                 return "unknown";
1841         }
1842 }
1843
1844
1845 ## ----------------------------------------------------------------------
1846 ## functions returning short HTML fragments, or transforming HTML fragments
1847 ## which don't belong to other sections
1848
1849 # format line of commit message.
1850 sub format_log_line_html {
1851         my $line = shift;
1852
1853         $line = esc_html($line, -nbsp=>1);
1854         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1855                 $cgi->a({-href => href(action=>"object", hash=>$1),
1856                                         -class => "text"}, $1);
1857         }eg;
1858
1859         return $line;
1860 }
1861
1862 # format marker of refs pointing to given object
1863
1864 # the destination action is chosen based on object type and current context:
1865 # - for annotated tags, we choose the tag view unless it's the current view
1866 #   already, in which case we go to shortlog view
1867 # - for other refs, we keep the current view if we're in history, shortlog or
1868 #   log view, and select shortlog otherwise
1869 sub format_ref_marker {
1870         my ($refs, $id) = @_;
1871         my $markers = '';
1872
1873         if (defined $refs->{$id}) {
1874                 foreach my $ref (@{$refs->{$id}}) {
1875                         # this code exploits the fact that non-lightweight tags are the
1876                         # only indirect objects, and that they are the only objects for which
1877                         # we want to use tag instead of shortlog as action
1878                         my ($type, $name) = qw();
1879                         my $indirect = ($ref =~ s/\^\{\}$//);
1880                         # e.g. tags/v2.6.11 or heads/next
1881                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
1882                                 $type = $1;
1883                                 $name = $2;
1884                         } else {
1885                                 $type = "ref";
1886                                 $name = $ref;
1887                         }
1888
1889                         my $class = $type;
1890                         $class .= " indirect" if $indirect;
1891
1892                         my $dest_action = "shortlog";
1893
1894                         if ($indirect) {
1895                                 $dest_action = "tag" unless $action eq "tag";
1896                         } elsif ($action =~ /^(history|(short)?log)$/) {
1897                                 $dest_action = $action;
1898                         }
1899
1900                         my $dest = "";
1901                         $dest .= "refs/" unless $ref =~ m!^refs/!;
1902                         $dest .= $ref;
1903
1904                         my $link = $cgi->a({
1905                                 -href => href(
1906                                         action=>$dest_action,
1907                                         hash=>$dest
1908                                 )}, $name);
1909
1910                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
1911                                 $link . "</span>";
1912                 }
1913         }
1914
1915         if ($markers) {
1916                 return ' <span class="refs">'. $markers . '</span>';
1917         } else {
1918                 return "";
1919         }
1920 }
1921
1922 # format, perhaps shortened and with markers, title line
1923 sub format_subject_html {
1924         my ($long, $short, $href, $extra) = @_;
1925         $extra = '' unless defined($extra);
1926
1927         if (length($short) < length($long)) {
1928                 $long =~ s/[[:cntrl:]]/?/g;
1929                 return $cgi->a({-href => $href, -class => "list subject",
1930                                 -title => to_utf8($long)},
1931                        esc_html($short)) . $extra;
1932         } else {
1933                 return $cgi->a({-href => $href, -class => "list subject"},
1934                        esc_html($long)) . $extra;
1935         }
1936 }
1937
1938 # Rather than recomputing the url for an email multiple times, we cache it
1939 # after the first hit. This gives a visible benefit in views where the avatar
1940 # for the same email is used repeatedly (e.g. shortlog).
1941 # The cache is shared by all avatar engines (currently gravatar only), which
1942 # are free to use it as preferred. Since only one avatar engine is used for any
1943 # given page, there's no risk for cache conflicts.
1944 our %avatar_cache = ();
1945
1946 # Compute the picon url for a given email, by using the picon search service over at
1947 # http://www.cs.indiana.edu/picons/search.html
1948 sub picon_url {
1949         my $email = lc shift;
1950         if (!$avatar_cache{$email}) {
1951                 my ($user, $domain) = split('@', $email);
1952                 $avatar_cache{$email} =
1953                         "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
1954                         "$domain/$user/" .
1955                         "users+domains+unknown/up/single";
1956         }
1957         return $avatar_cache{$email};
1958 }
1959
1960 # Compute the gravatar url for a given email, if it's not in the cache already.
1961 # Gravatar stores only the part of the URL before the size, since that's the
1962 # one computationally more expensive. This also allows reuse of the cache for
1963 # different sizes (for this particular engine).
1964 sub gravatar_url {
1965         my $email = lc shift;
1966         my $size = shift;
1967         $avatar_cache{$email} ||=
1968                 "http://www.gravatar.com/avatar/" .
1969                         Digest::MD5::md5_hex($email) . "?s=";
1970         return $avatar_cache{$email} . $size;
1971 }
1972
1973 # Insert an avatar for the given $email at the given $size if the feature
1974 # is enabled.
1975 sub git_get_avatar {
1976         my ($email, %opts) = @_;
1977         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
1978         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
1979         $opts{-size} ||= 'default';
1980         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
1981         my $url = "";
1982         if ($git_avatar eq 'gravatar') {
1983                 $url = gravatar_url($email, $size);
1984         } elsif ($git_avatar eq 'picon') {
1985                 $url = picon_url($email);
1986         }
1987         # Other providers can be added by extending the if chain, defining $url
1988         # as needed. If no variant puts something in $url, we assume avatars
1989         # are completely disabled/unavailable.
1990         if ($url) {
1991                 return $pre_white .
1992                        "<img width=\"$size\" " .
1993                             "class=\"avatar\" " .
1994                             "src=\"".esc_url($url)."\" " .
1995                             "alt=\"\" " .
1996                        "/>" . $post_white;
1997         } else {
1998                 return "";
1999         }
2000 }
2001
2002 sub format_search_author {
2003         my ($author, $searchtype, $displaytext) = @_;
2004         my $have_search = gitweb_check_feature('search');
2005
2006         if ($have_search) {
2007                 my $performed = "";
2008                 if ($searchtype eq 'author') {
2009                         $performed = "authored";
2010                 } elsif ($searchtype eq 'committer') {
2011                         $performed = "committed";
2012                 }
2013
2014                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2015                                 searchtext=>$author,
2016                                 searchtype=>$searchtype), class=>"list",
2017                                 title=>"Search for commits $performed by $author"},
2018                                 $displaytext);
2019
2020         } else {
2021                 return $displaytext;
2022         }
2023 }
2024
2025 # format the author name of the given commit with the given tag
2026 # the author name is chopped and escaped according to the other
2027 # optional parameters (see chop_str).
2028 sub format_author_html {
2029         my $tag = shift;
2030         my $co = shift;
2031         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2032         return "<$tag class=\"author\">" .
2033                format_search_author($co->{'author_name'}, "author",
2034                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2035                        $author) .
2036                "</$tag>";
2037 }
2038
2039 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2040 sub format_git_diff_header_line {
2041         my $line = shift;
2042         my $diffinfo = shift;
2043         my ($from, $to) = @_;
2044
2045         if ($diffinfo->{'nparents'}) {
2046                 # combined diff
2047                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2048                 if ($to->{'href'}) {
2049                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2050                                          esc_path($to->{'file'}));
2051                 } else { # file was deleted (no href)
2052                         $line .= esc_path($to->{'file'});
2053                 }
2054         } else {
2055                 # "ordinary" diff
2056                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2057                 if ($from->{'href'}) {
2058                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2059                                          'a/' . esc_path($from->{'file'}));
2060                 } else { # file was added (no href)
2061                         $line .= 'a/' . esc_path($from->{'file'});
2062                 }
2063                 $line .= ' ';
2064                 if ($to->{'href'}) {
2065                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2066                                          'b/' . esc_path($to->{'file'}));
2067                 } else { # file was deleted
2068                         $line .= 'b/' . esc_path($to->{'file'});
2069                 }
2070         }
2071
2072         return "<div class=\"diff header\">$line</div>\n";
2073 }
2074
2075 # format extended diff header line, before patch itself
2076 sub format_extended_diff_header_line {
2077         my $line = shift;
2078         my $diffinfo = shift;
2079         my ($from, $to) = @_;
2080
2081         # match <path>
2082         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2083                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2084                                        esc_path($from->{'file'}));
2085         }
2086         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2087                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2088                                  esc_path($to->{'file'}));
2089         }
2090         # match single <mode>
2091         if ($line =~ m/\s(\d{6})$/) {
2092                 $line .= '<span class="info"> (' .
2093                          file_type_long($1) .
2094                          ')</span>';
2095         }
2096         # match <hash>
2097         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2098                 # can match only for combined diff
2099                 $line = 'index ';
2100                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2101                         if ($from->{'href'}[$i]) {
2102                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2103                                                   -class=>"hash"},
2104                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2105                         } else {
2106                                 $line .= '0' x 7;
2107                         }
2108                         # separator
2109                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2110                 }
2111                 $line .= '..';
2112                 if ($to->{'href'}) {
2113                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2114                                          substr($diffinfo->{'to_id'},0,7));
2115                 } else {
2116                         $line .= '0' x 7;
2117                 }
2118
2119         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2120                 # can match only for ordinary diff
2121                 my ($from_link, $to_link);
2122                 if ($from->{'href'}) {
2123                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2124                                              substr($diffinfo->{'from_id'},0,7));
2125                 } else {
2126                         $from_link = '0' x 7;
2127                 }
2128                 if ($to->{'href'}) {
2129                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2130                                            substr($diffinfo->{'to_id'},0,7));
2131                 } else {
2132                         $to_link = '0' x 7;
2133                 }
2134                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2135                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2136         }
2137
2138         return $line . "<br/>\n";
2139 }
2140
2141 # format from-file/to-file diff header
2142 sub format_diff_from_to_header {
2143         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2144         my $line;
2145         my $result = '';
2146
2147         $line = $from_line;
2148         #assert($line =~ m/^---/) if DEBUG;
2149         # no extra formatting for "^--- /dev/null"
2150         if (! $diffinfo->{'nparents'}) {
2151                 # ordinary (single parent) diff
2152                 if ($line =~ m!^--- "?a/!) {
2153                         if ($from->{'href'}) {
2154                                 $line = '--- a/' .
2155                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2156                                                 esc_path($from->{'file'}));
2157                         } else {
2158                                 $line = '--- a/' .
2159                                         esc_path($from->{'file'});
2160                         }
2161                 }
2162                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2163
2164         } else {
2165                 # combined diff (merge commit)
2166                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2167                         if ($from->{'href'}[$i]) {
2168                                 $line = '--- ' .
2169                                         $cgi->a({-href=>href(action=>"blobdiff",
2170                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2171                                                              hash_parent_base=>$parents[$i],
2172                                                              file_parent=>$from->{'file'}[$i],
2173                                                              hash=>$diffinfo->{'to_id'},
2174                                                              hash_base=>$hash,
2175                                                              file_name=>$to->{'file'}),
2176                                                  -class=>"path",
2177                                                  -title=>"diff" . ($i+1)},
2178                                                 $i+1) .
2179                                         '/' .
2180                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2181                                                 esc_path($from->{'file'}[$i]));
2182                         } else {
2183                                 $line = '--- /dev/null';
2184                         }
2185                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2186                 }
2187         }
2188
2189         $line = $to_line;
2190         #assert($line =~ m/^\+\+\+/) if DEBUG;
2191         # no extra formatting for "^+++ /dev/null"
2192         if ($line =~ m!^\+\+\+ "?b/!) {
2193                 if ($to->{'href'}) {
2194                         $line = '+++ b/' .
2195                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2196                                         esc_path($to->{'file'}));
2197                 } else {
2198                         $line = '+++ b/' .
2199                                 esc_path($to->{'file'});
2200                 }
2201         }
2202         $result .= qq!<div class="diff to_file">$line</div>\n!;
2203
2204         return $result;
2205 }
2206
2207 # create note for patch simplified by combined diff
2208 sub format_diff_cc_simplified {
2209         my ($diffinfo, @parents) = @_;
2210         my $result = '';
2211
2212         $result .= "<div class=\"diff header\">" .
2213                    "diff --cc ";
2214         if (!is_deleted($diffinfo)) {
2215                 $result .= $cgi->a({-href => href(action=>"blob",
2216                                                   hash_base=>$hash,
2217                                                   hash=>$diffinfo->{'to_id'},
2218                                                   file_name=>$diffinfo->{'to_file'}),
2219                                     -class => "path"},
2220                                    esc_path($diffinfo->{'to_file'}));
2221         } else {
2222                 $result .= esc_path($diffinfo->{'to_file'});
2223         }
2224         $result .= "</div>\n" . # class="diff header"
2225                    "<div class=\"diff nodifferences\">" .
2226                    "Simple merge" .
2227                    "</div>\n"; # class="diff nodifferences"
2228
2229         return $result;
2230 }
2231
2232 sub diff_line_class {
2233         my ($line, $from, $to) = @_;
2234
2235         # ordinary diff
2236         my $num_sign = 1;
2237         # combined diff
2238         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2239                 $num_sign = scalar @{$from->{'href'}};
2240         }
2241
2242         my @diff_line_classifier = (
2243                 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2244                 { regexp => qr/^\\/,               class => "incomplete"  },
2245                 { regexp => qr/^ {$num_sign}/,     class => "ctx" },
2246                 # classifier for context must come before classifier add/rem,
2247                 # or we would have to use more complicated regexp, for example
2248                 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2249                 { regexp => qr/^[+ ]{$num_sign}/,   class => "add" },
2250                 { regexp => qr/^[- ]{$num_sign}/,   class => "rem" },
2251         );
2252         for my $clsfy (@diff_line_classifier) {
2253                 return $clsfy->{'class'}
2254                         if ($line =~ $clsfy->{'regexp'});
2255         }
2256
2257         # fallback
2258         return "";
2259 }
2260
2261 # assumes that $from and $to are defined and correctly filled,
2262 # and that $line holds a line of chunk header for unified diff
2263 sub format_unidiff_chunk_header {
2264         my ($line, $from, $to) = @_;
2265
2266         my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2267                 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2268
2269         $from_lines = 0 unless defined $from_lines;
2270         $to_lines   = 0 unless defined $to_lines;
2271
2272         if ($from->{'href'}) {
2273                 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2274                                      -class=>"list"}, $from_text);
2275         }
2276         if ($to->{'href'}) {
2277                 $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2278                                      -class=>"list"}, $to_text);
2279         }
2280         $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2281                 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2282         return $line;
2283 }
2284
2285 # assumes that $from and $to are defined and correctly filled,
2286 # and that $line holds a line of chunk header for combined diff
2287 sub format_cc_diff_chunk_header {
2288         my ($line, $from, $to) = @_;
2289
2290         my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2291         my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2292
2293         @from_text = split(' ', $ranges);
2294         for (my $i = 0; $i < @from_text; ++$i) {
2295                 ($from_start[$i], $from_nlines[$i]) =
2296                         (split(',', substr($from_text[$i], 1)), 0);
2297         }
2298
2299         $to_text   = pop @from_text;
2300         $to_start  = pop @from_start;
2301         $to_nlines = pop @from_nlines;
2302
2303         $line = "<span class=\"chunk_info\">$prefix ";
2304         for (my $i = 0; $i < @from_text; ++$i) {
2305                 if ($from->{'href'}[$i]) {
2306                         $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2307                                           -class=>"list"}, $from_text[$i]);
2308                 } else {
2309                         $line .= $from_text[$i];
2310                 }
2311                 $line .= " ";
2312         }
2313         if ($to->{'href'}) {
2314                 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2315                                   -class=>"list"}, $to_text);
2316         } else {
2317                 $line .= $to_text;
2318         }
2319         $line .= " $prefix</span>" .
2320                  "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2321         return $line;
2322 }
2323
2324 # process patch (diff) line (not to be used for diff headers),
2325 # returning class and HTML-formatted (but not wrapped) line
2326 sub process_diff_line {
2327         my $line = shift;
2328         my ($from, $to) = @_;
2329
2330         my $diff_class = diff_line_class($line, $from, $to);
2331
2332         chomp $line;
2333         $line = untabify($line);
2334
2335         if ($from && $to && $line =~ m/^\@{2} /) {
2336                 $line = format_unidiff_chunk_header($line, $from, $to);
2337                 return $diff_class, $line;
2338
2339         } elsif ($from && $to && $line =~ m/^\@{3}/) {
2340                 $line = format_cc_diff_chunk_header($line, $from, $to);
2341                 return $diff_class, $line;
2342
2343         }
2344         return $diff_class, esc_html($line, -nbsp=>1);
2345 }
2346
2347 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2348 # linked.  Pass the hash of the tree/commit to snapshot.
2349 sub format_snapshot_links {
2350         my ($hash) = @_;
2351         my $num_fmts = @snapshot_fmts;
2352         if ($num_fmts > 1) {
2353                 # A parenthesized list of links bearing format names.
2354                 # e.g. "snapshot (_tar.gz_ _zip_)"
2355                 return "snapshot (" . join(' ', map
2356                         $cgi->a({
2357                                 -href => href(
2358                                         action=>"snapshot",
2359                                         hash=>$hash,
2360                                         snapshot_format=>$_
2361                                 )
2362                         }, $known_snapshot_formats{$_}{'display'})
2363                 , @snapshot_fmts) . ")";
2364         } elsif ($num_fmts == 1) {
2365                 # A single "snapshot" link whose tooltip bears the format name.
2366                 # i.e. "_snapshot_"
2367                 my ($fmt) = @snapshot_fmts;
2368                 return
2369                         $cgi->a({
2370                                 -href => href(
2371                                         action=>"snapshot",
2372                                         hash=>$hash,
2373                                         snapshot_format=>$fmt
2374                                 ),
2375                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2376                         }, "snapshot");
2377         } else { # $num_fmts == 0
2378                 return undef;
2379         }
2380 }
2381
2382 ## ......................................................................
2383 ## functions returning values to be passed, perhaps after some
2384 ## transformation, to other functions; e.g. returning arguments to href()
2385
2386 # returns hash to be passed to href to generate gitweb URL
2387 # in -title key it returns description of link
2388 sub get_feed_info {
2389         my $format = shift || 'Atom';
2390         my %res = (action => lc($format));
2391
2392         # feed links are possible only for project views
2393         return unless (defined $project);
2394         # some views should link to OPML, or to generic project feed,
2395         # or don't have specific feed yet (so they should use generic)
2396         return if (!$action || $action =~ /^(?:tags|heads|forks|tag|search)$/x);
2397
2398         my $branch;
2399         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2400         # from tag links; this also makes possible to detect branch links
2401         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2402             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2403                 $branch = $1;
2404         }
2405         # find log type for feed description (title)
2406         my $type = 'log';
2407         if (defined $file_name) {
2408                 $type  = "history of $file_name";
2409                 $type .= "/" if ($action eq 'tree');
2410                 $type .= " on '$branch'" if (defined $branch);
2411         } else {
2412                 $type = "log of $branch" if (defined $branch);
2413         }
2414
2415         $res{-title} = $type;
2416         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2417         $res{'file_name'} = $file_name;
2418
2419         return %res;
2420 }
2421
2422 ## ----------------------------------------------------------------------
2423 ## git utility subroutines, invoking git commands
2424
2425 # returns path to the core git executable and the --git-dir parameter as list
2426 sub git_cmd {
2427         $number_of_git_cmds++;
2428         return $GIT, '--git-dir='.$git_dir;
2429 }
2430
2431 # quote the given arguments for passing them to the shell
2432 # quote_command("command", "arg 1", "arg with ' and ! characters")
2433 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2434 # Try to avoid using this function wherever possible.
2435 sub quote_command {
2436         return join(' ',
2437                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2438 }
2439
2440 # get HEAD ref of given project as hash
2441 sub git_get_head_hash {
2442         return git_get_full_hash(shift, 'HEAD');
2443 }
2444
2445 sub git_get_full_hash {
2446         return git_get_hash(@_);
2447 }
2448
2449 sub git_get_short_hash {
2450         return git_get_hash(@_, '--short=7');
2451 }
2452
2453 sub git_get_hash {
2454         my ($project, $hash, @options) = @_;
2455         my $o_git_dir = $git_dir;
2456         my $retval = undef;
2457         $git_dir = "$projectroot/$project";
2458         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2459             '--verify', '-q', @options, $hash) {
2460                 $retval = <$fd>;
2461                 chomp $retval if defined $retval;
2462                 close $fd;
2463         }
2464         if (defined $o_git_dir) {
2465                 $git_dir = $o_git_dir;
2466         }
2467         return $retval;
2468 }
2469
2470 # get type of given object
2471 sub git_get_type {
2472         my $hash = shift;
2473
2474         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2475         my $type = <$fd>;
2476         close $fd or return;
2477         chomp $type;
2478         return $type;
2479 }
2480
2481 # repository configuration
2482 our $config_file = '';
2483 our %config;
2484
2485 # store multiple values for single key as anonymous array reference
2486 # single values stored directly in the hash, not as [ <value> ]
2487 sub hash_set_multi {
2488         my ($hash, $key, $value) = @_;
2489
2490         if (!exists $hash->{$key}) {
2491                 $hash->{$key} = $value;
2492         } elsif (!ref $hash->{$key}) {
2493                 $hash->{$key} = [ $hash->{$key}, $value ];
2494         } else {
2495                 push @{$hash->{$key}}, $value;
2496         }
2497 }
2498
2499 # return hash of git project configuration
2500 # optionally limited to some section, e.g. 'gitweb'
2501 sub git_parse_project_config {
2502         my $section_regexp = shift;
2503         my %config;
2504
2505         local $/ = "\0";
2506
2507         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2508                 or return;
2509
2510         while (my $keyval = <$fh>) {
2511                 chomp $keyval;
2512                 my ($key, $value) = split(/\n/, $keyval, 2);
2513
2514                 hash_set_multi(\%config, $key, $value)
2515                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2516         }
2517         close $fh;
2518
2519         return %config;
2520 }
2521
2522 # convert config value to boolean: 'true' or 'false'
2523 # no value, number > 0, 'true' and 'yes' values are true
2524 # rest of values are treated as false (never as error)
2525 sub config_to_bool {
2526         my $val = shift;
2527
2528         return 1 if !defined $val;             # section.key
2529
2530         # strip leading and trailing whitespace
2531         $val =~ s/^\s+//;
2532         $val =~ s/\s+$//;
2533
2534         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2535                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2536 }
2537
2538 # convert config value to simple decimal number
2539 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2540 # to be multiplied by 1024, 1048576, or 1073741824
2541 sub config_to_int {
2542         my $val = shift;
2543
2544         # strip leading and trailing whitespace
2545         $val =~ s/^\s+//;
2546         $val =~ s/\s+$//;
2547
2548         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2549                 $unit = lc($unit);
2550                 # unknown unit is treated as 1
2551                 return $num * ($unit eq 'g' ? 1073741824 :
2552                                $unit eq 'm' ?    1048576 :
2553                                $unit eq 'k' ?       1024 : 1);
2554         }
2555         return $val;
2556 }
2557
2558 # convert config value to array reference, if needed
2559 sub config_to_multi {
2560         my $val = shift;
2561
2562         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2563 }
2564
2565 sub git_get_project_config {
2566         my ($key, $type) = @_;
2567
2568         return unless defined $git_dir;
2569
2570         # key sanity check
2571         return unless ($key);
2572         # only subsection, if exists, is case sensitive,
2573         # and not lowercased by 'git config -z -l'
2574         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2575                 $key = join(".", lc($hi), $mi, lc($lo));
2576         } else {
2577                 $key = lc($key);
2578         }
2579         $key =~ s/^gitweb\.//;
2580         return if ($key =~ m/\W/);
2581
2582         # type sanity check
2583         if (defined $type) {
2584                 $type =~ s/^--//;
2585                 $type = undef
2586                         unless ($type eq 'bool' || $type eq 'int');
2587         }
2588
2589         # get config
2590         if (!defined $config_file ||
2591             $config_file ne "$git_dir/config") {
2592                 %config = git_parse_project_config('gitweb');
2593                 $config_file = "$git_dir/config";
2594         }
2595
2596         # check if config variable (key) exists
2597         return unless exists $config{"gitweb.$key"};
2598
2599         # ensure given type
2600         if (!defined $type) {
2601                 return $config{"gitweb.$key"};
2602         } elsif ($type eq 'bool') {
2603                 # backward compatibility: 'git config --bool' returns true/false
2604                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2605         } elsif ($type eq 'int') {
2606                 return config_to_int($config{"gitweb.$key"});
2607         }
2608         return $config{"gitweb.$key"};
2609 }
2610
2611 # get hash of given path at given ref
2612 sub git_get_hash_by_path {
2613         my $base = shift;
2614         my $path = shift || return undef;
2615         my $type = shift;
2616
2617         $path =~ s,/+$,,;
2618
2619         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2620                 or die_error(500, "Open git-ls-tree failed");
2621         my $line = <$fd>;
2622         close $fd or return undef;
2623
2624         if (!defined $line) {
2625                 # there is no tree or hash given by $path at $base
2626                 return undef;
2627         }
2628
2629         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2630         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2631         if (defined $type && $type ne $2) {
2632                 # type doesn't match
2633                 return undef;
2634         }
2635         return $3;
2636 }
2637
2638 # get path of entry with given hash at given tree-ish (ref)
2639 # used to get 'from' filename for combined diff (merge commit) for renames
2640 sub git_get_path_by_hash {
2641         my $base = shift || return;
2642         my $hash = shift || return;
2643
2644         local $/ = "\0";
2645
2646         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2647                 or return undef;
2648         while (my $line = <$fd>) {
2649                 chomp $line;
2650
2651                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2652                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2653                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2654                         close $fd;
2655                         return $1;
2656                 }
2657         }
2658         close $fd;
2659         return undef;
2660 }
2661
2662 ## ......................................................................
2663 ## git utility functions, directly accessing git repository
2664
2665 # get the value of config variable either from file named as the variable
2666 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2667 # configuration variable in the repository config file.
2668 sub git_get_file_or_project_config {
2669         my ($path, $name) = @_;
2670
2671         $git_dir = "$projectroot/$path";
2672         open my $fd, '<', "$git_dir/$name"
2673                 or return git_get_project_config($name);
2674         my $conf = <$fd>;
2675         close $fd;
2676         if (defined $conf) {
2677                 chomp $conf;
2678         }
2679         return $conf;
2680 }
2681
2682 sub git_get_project_description {
2683         my $path = shift;
2684         return git_get_file_or_project_config($path, 'description');
2685 }
2686
2687 sub git_get_project_category {
2688         my $path = shift;
2689         return git_get_file_or_project_config($path, 'category');
2690 }
2691
2692
2693 # supported formats:
2694 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2695 #   - if its contents is a number, use it as tag weight,
2696 #   - otherwise add a tag with weight 1
2697 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2698 #   the same value multiple times increases tag weight
2699 # * `gitweb.ctag' multi-valued repo config variable
2700 sub git_get_project_ctags {
2701         my $project = shift;
2702         my $ctags = {};
2703
2704         $git_dir = "$projectroot/$project";
2705         if (opendir my $dh, "$git_dir/ctags") {
2706                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2707                 foreach my $tagfile (@files) {
2708                         open my $ct, '<', $tagfile
2709                                 or next;
2710                         my $val = <$ct>;
2711                         chomp $val if $val;
2712                         close $ct;
2713
2714                         (my $ctag = $tagfile) =~ s#.*/##;
2715                         if ($val =~ /^\d+$/) {
2716                                 $ctags->{$ctag} = $val;
2717                         } else {
2718                                 $ctags->{$ctag} = 1;
2719                         }
2720                 }
2721                 closedir $dh;
2722
2723         } elsif (open my $fh, '<', "$git_dir/ctags") {
2724                 while (my $line = <$fh>) {
2725                         chomp $line;
2726                         $ctags->{$line}++ if $line;
2727                 }
2728                 close $fh;
2729
2730         } else {
2731                 my $taglist = config_to_multi(git_get_project_config('ctag'));
2732                 foreach my $tag (@$taglist) {
2733                         $ctags->{$tag}++;
2734                 }
2735         }
2736
2737         return $ctags;
2738 }
2739
2740 # return hash, where keys are content tags ('ctags'),
2741 # and values are sum of weights of given tag in every project
2742 sub git_gather_all_ctags {
2743         my $projects = shift;
2744         my $ctags = {};
2745
2746         foreach my $p (@$projects) {
2747                 foreach my $ct (keys %{$p->{'ctags'}}) {
2748                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
2749                 }
2750         }
2751
2752         return $ctags;
2753 }
2754
2755 sub git_populate_project_tagcloud {
2756         my $ctags = shift;
2757
2758         # First, merge different-cased tags; tags vote on casing
2759         my %ctags_lc;
2760         foreach (keys %$ctags) {
2761                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2762                 if (not $ctags_lc{lc $_}->{topcount}
2763                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2764                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2765                         $ctags_lc{lc $_}->{topname} = $_;
2766                 }
2767         }
2768
2769         my $cloud;
2770         my $matched = $cgi->param('by_tag');
2771         if (eval { require HTML::TagCloud; 1; }) {
2772                 $cloud = HTML::TagCloud->new;
2773                 foreach my $ctag (sort keys %ctags_lc) {
2774                         # Pad the title with spaces so that the cloud looks
2775                         # less crammed.
2776                         my $title = esc_html($ctags_lc{$ctag}->{topname});
2777                         $title =~ s/ /&nbsp;/g;
2778                         $title =~ s/^/&nbsp;/g;
2779                         $title =~ s/$/&nbsp;/g;
2780                         if (defined $matched && $matched eq $ctag) {
2781                                 $title = qq(<span class="match">$title</span>);
2782                         }
2783                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
2784                                     $ctags_lc{$ctag}->{count});
2785                 }
2786         } else {
2787                 $cloud = {};
2788                 foreach my $ctag (keys %ctags_lc) {
2789                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
2790                         if (defined $matched && $matched eq $ctag) {
2791                                 $title = qq(<span class="match">$title</span>);
2792                         }
2793                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
2794                         $cloud->{$ctag}{ctag} =
2795                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
2796                 }
2797         }
2798         return $cloud;
2799 }
2800
2801 sub git_show_project_tagcloud {
2802         my ($cloud, $count) = @_;
2803         if (ref $cloud eq 'HTML::TagCloud') {
2804                 return $cloud->html_and_css($count);
2805         } else {
2806                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
2807                 return
2808                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
2809                         join (', ', map {
2810                                 $cloud->{$_}->{'ctag'}
2811                         } splice(@tags, 0, $count)) .
2812                         '</div>';
2813         }
2814 }
2815
2816 sub git_get_project_url_list {
2817         my $path = shift;
2818
2819         $git_dir = "$projectroot/$path";
2820         open my $fd, '<', "$git_dir/cloneurl"
2821                 or return wantarray ?
2822                 @{ config_to_multi(git_get_project_config('url')) } :
2823                    config_to_multi(git_get_project_config('url'));
2824         my @git_project_url_list = map { chomp; $_ } <$fd>;
2825         close $fd;
2826
2827         return wantarray ? @git_project_url_list : \@git_project_url_list;
2828 }
2829
2830 sub git_get_projects_list {
2831         my $filter = shift || '';
2832         my @list;
2833
2834         $filter =~ s/\.git$//;
2835
2836         if (-d $projects_list) {
2837                 # search in directory
2838                 my $dir = $projects_list;
2839                 # remove the trailing "/"
2840                 $dir =~ s!/+$!!;
2841                 my $pfxlen = length("$dir");
2842                 my $pfxdepth = ($dir =~ tr!/!!);
2843                 # when filtering, search only given subdirectory
2844                 if ($filter) {
2845                         $dir .= "/$filter";
2846                         $dir =~ s!/+$!!;
2847                 }
2848
2849                 File::Find::find({
2850                         follow_fast => 1, # follow symbolic links
2851                         follow_skip => 2, # ignore duplicates
2852                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2853                         wanted => sub {
2854                                 # global variables
2855                                 our $project_maxdepth;
2856                                 our $projectroot;
2857                                 # skip project-list toplevel, if we get it.
2858                                 return if (m!^[/.]$!);
2859                                 # only directories can be git repositories
2860                                 return unless (-d $_);
2861                                 # don't traverse too deep (Find is super slow on os x)
2862                                 # $project_maxdepth excludes depth of $projectroot
2863                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2864                                         $File::Find::prune = 1;
2865                                         return;
2866                                 }
2867
2868                                 my $path = substr($File::Find::name, $pfxlen + 1);
2869                                 # we check related file in $projectroot
2870                                 if (check_export_ok("$projectroot/$path")) {
2871                                         push @list, { path => $path };
2872                                         $File::Find::prune = 1;
2873                                 }
2874                         },
2875                 }, "$dir");
2876
2877         } elsif (-f $projects_list) {
2878                 # read from file(url-encoded):
2879                 # 'git%2Fgit.git Linus+Torvalds'
2880                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2881                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2882                 open my $fd, '<', $projects_list or return;
2883         PROJECT:
2884                 while (my $line = <$fd>) {
2885                         chomp $line;
2886                         my ($path, $owner) = split ' ', $line;
2887                         $path = unescape($path);
2888                         $owner = unescape($owner);
2889                         if (!defined $path) {
2890                                 next;
2891                         }
2892                         # if $filter is rpovided, check if $path begins with $filter
2893                         if ($filter && $path !~ m!^\Q$filter\E/!) {
2894                                 next;
2895                         }
2896                         if (check_export_ok("$projectroot/$path")) {
2897                                 my $pr = {
2898                                         path => $path,
2899                                         owner => to_utf8($owner),
2900                                 };
2901                                 push @list, $pr;
2902                         }
2903                 }
2904                 close $fd;
2905         }
2906         return @list;
2907 }
2908
2909 # written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
2910 # as side effects it sets 'forks' field to list of forks for forked projects
2911 sub filter_forks_from_projects_list {
2912         my $projects = shift;
2913
2914         my %trie; # prefix tree of directories (path components)
2915         # generate trie out of those directories that might contain forks
2916         foreach my $pr (@$projects) {
2917                 my $path = $pr->{'path'};
2918                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
2919                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
2920                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
2921                 next unless (-d "$projectroot/$path"); # containing directory exists
2922                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
2923
2924                 # add to trie
2925                 my @dirs = split('/', $path);
2926                 # walk the trie, until either runs out of components or out of trie
2927                 my $ref = \%trie;
2928                 while (scalar @dirs &&
2929                        exists($ref->{$dirs[0]})) {
2930                         $ref = $ref->{shift @dirs};
2931                 }
2932                 # create rest of trie structure from rest of components
2933                 foreach my $dir (@dirs) {
2934                         $ref = $ref->{$dir} = {};
2935                 }
2936                 # create end marker, store $pr as a data
2937                 $ref->{''} = $pr if (!exists $ref->{''});
2938         }
2939
2940         # filter out forks, by finding shortest prefix match for paths
2941         my @filtered;
2942  PROJECT:
2943         foreach my $pr (@$projects) {
2944                 # trie lookup
2945                 my $ref = \%trie;
2946         DIR:
2947                 foreach my $dir (split('/', $pr->{'path'})) {
2948                         if (exists $ref->{''}) {
2949                                 # found [shortest] prefix, is a fork - skip it
2950                                 push @{$ref->{''}{'forks'}}, $pr;
2951                                 next PROJECT;
2952                         }
2953                         if (!exists $ref->{$dir}) {
2954                                 # not in trie, cannot have prefix, not a fork
2955                                 push @filtered, $pr;
2956                                 next PROJECT;
2957                         }
2958                         # If the dir is there, we just walk one step down the trie.
2959                         $ref = $ref->{$dir};
2960                 }
2961                 # we ran out of trie
2962                 # (shouldn't happen: it's either no match, or end marker)
2963                 push @filtered, $pr;
2964         }
2965
2966         return @filtered;
2967 }
2968
2969 # note: fill_project_list_info must be run first,
2970 # for 'descr_long' and 'ctags' to be filled
2971 sub search_projects_list {
2972         my ($projlist, %opts) = @_;
2973         my $tagfilter  = $opts{'tagfilter'};
2974         my $searchtext = $opts{'searchtext'};
2975
2976         return @$projlist
2977                 unless ($tagfilter || $searchtext);
2978
2979         my @projects;
2980  PROJECT:
2981         foreach my $pr (@$projlist) {
2982
2983                 if ($tagfilter) {
2984                         next unless ref($pr->{'ctags'}) eq 'HASH';
2985                         next unless
2986                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
2987                 }
2988
2989                 if ($searchtext) {
2990                         next unless
2991                                 $pr->{'path'} =~ /$searchtext/ ||
2992                                 $pr->{'descr_long'} =~ /$searchtext/;
2993                 }
2994
2995                 push @projects, $pr;
2996         }
2997
2998         return @projects;
2999 }
3000
3001 our $gitweb_project_owner = undef;
3002 sub git_get_project_list_from_file {
3003
3004         return if (defined $gitweb_project_owner);
3005
3006         $gitweb_project_owner = {};
3007         # read from file (url-encoded):
3008         # 'git%2Fgit.git Linus+Torvalds'
3009         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3010         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3011         if (-f $projects_list) {
3012                 open(my $fd, '<', $projects_list);
3013                 while (my $line = <$fd>) {
3014                         chomp $line;
3015                         my ($pr, $ow) = split ' ', $line;
3016                         $pr = unescape($pr);
3017                         $ow = unescape($ow);
3018                         $gitweb_project_owner->{$pr} = to_utf8($ow);
3019                 }
3020                 close $fd;
3021         }
3022 }
3023
3024 sub git_get_project_owner {
3025         my $project = shift;
3026         my $owner;
3027
3028         return undef unless $project;
3029         $git_dir = "$projectroot/$project";
3030
3031         if (!defined $gitweb_project_owner) {
3032                 git_get_project_list_from_file();
3033         }
3034
3035         if (exists $gitweb_project_owner->{$project}) {
3036                 $owner = $gitweb_project_owner->{$project};
3037         }
3038         if (!defined $owner){
3039                 $owner = git_get_project_config('owner');
3040         }
3041         if (!defined $owner) {
3042                 $owner = get_file_owner("$git_dir");
3043         }
3044
3045         return $owner;
3046 }
3047
3048 sub git_get_last_activity {
3049         my ($path) = @_;
3050         my $fd;
3051
3052         $git_dir = "$projectroot/$path";
3053         open($fd, "-|", git_cmd(), 'for-each-ref',
3054              '--format=%(committer)',
3055              '--sort=-committerdate',
3056              '--count=1',
3057              'refs/heads') or return;
3058         my $most_recent = <$fd>;
3059         close $fd or return;
3060         if (defined $most_recent &&
3061             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3062                 my $timestamp = $1;
3063                 my $age = time - $timestamp;
3064                 return ($age, age_string($age));
3065         }
3066         return (undef, undef);
3067 }
3068
3069 # Implementation note: when a single remote is wanted, we cannot use 'git
3070 # remote show -n' because that command always work (assuming it's a remote URL
3071 # if it's not defined), and we cannot use 'git remote show' because that would
3072 # try to make a network roundtrip. So the only way to find if that particular
3073 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3074 # and when we find what we want.
3075 sub git_get_remotes_list {
3076         my $wanted = shift;
3077         my %remotes = ();
3078
3079         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3080         return unless $fd;
3081         while (my $remote = <$fd>) {
3082                 chomp $remote;
3083                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3084                 next if $wanted and not $remote eq $wanted;
3085                 my ($url, $key) = ($1, $2);
3086
3087                 $remotes{$remote} ||= { 'heads' => () };
3088                 $remotes{$remote}{$key} = $url;
3089         }
3090         close $fd or return;
3091         return wantarray ? %remotes : \%remotes;
3092 }
3093
3094 # Takes a hash of remotes as first parameter and fills it by adding the
3095 # available remote heads for each of the indicated remotes.
3096 sub fill_remote_heads {
3097         my $remotes = shift;
3098         my @heads = map { "remotes/$_" } keys %$remotes;
3099         my @remoteheads = git_get_heads_list(undef, @heads);
3100         foreach my $remote (keys %$remotes) {
3101                 $remotes->{$remote}{'heads'} = [ grep {
3102                         $_->{'name'} =~ s!^$remote/!!
3103                         } @remoteheads ];
3104         }
3105 }
3106
3107 sub git_get_references {
3108         my $type = shift || "";
3109         my %refs;
3110         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3111         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3112         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3113                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3114                 or return;
3115
3116         while (my $line = <$fd>) {
3117                 chomp $line;
3118                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3119                         if (defined $refs{$1}) {
3120                                 push @{$refs{$1}}, $2;
3121                         } else {
3122                                 $refs{$1} = [ $2 ];
3123                         }
3124                 }
3125         }
3126         close $fd or return;
3127         return \%refs;
3128 }
3129
3130 sub git_get_rev_name_tags {
3131         my $hash = shift || return undef;
3132
3133         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3134                 or return;
3135         my $name_rev = <$fd>;
3136         close $fd;
3137
3138         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3139                 return $1;
3140         } else {
3141                 # catches also '$hash undefined' output
3142                 return undef;
3143         }
3144 }
3145
3146 ## ----------------------------------------------------------------------
3147 ## parse to hash functions
3148
3149 sub parse_date {
3150         my $epoch = shift;
3151         my $tz = shift || "-0000";
3152
3153         my %date;
3154         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3155         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3156         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3157         $date{'hour'} = $hour;
3158         $date{'minute'} = $min;
3159         $date{'mday'} = $mday;
3160         $date{'day'} = $days[$wday];
3161         $date{'month'} = $months[$mon];
3162         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3163                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3164         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3165                              $mday, $months[$mon], $hour ,$min;
3166         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3167                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3168
3169         my ($tz_sign, $tz_hour, $tz_min) =
3170                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3171         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3172         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3173         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3174         $date{'hour_local'} = $hour;
3175         $date{'minute_local'} = $min;
3176         $date{'tz_local'} = $tz;
3177         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3178                                   1900+$year, $mon+1, $mday,
3179                                   $hour, $min, $sec, $tz);
3180         return %date;
3181 }
3182
3183 sub parse_tag {
3184         my $tag_id = shift;
3185         my %tag;
3186         my @comment;
3187
3188         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3189         $tag{'id'} = $tag_id;
3190         while (my $line = <$fd>) {
3191                 chomp $line;
3192                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3193                         $tag{'object'} = $1;
3194                 } elsif ($line =~ m/^type (.+)$/) {
3195                         $tag{'type'} = $1;
3196                 } elsif ($line =~ m/^tag (.+)$/) {
3197                         $tag{'name'} = $1;
3198                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3199                         $tag{'author'} = $1;
3200                         $tag{'author_epoch'} = $2;
3201                         $tag{'author_tz'} = $3;
3202                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3203                                 $tag{'author_name'}  = $1;
3204                                 $tag{'author_email'} = $2;
3205                         } else {
3206                                 $tag{'author_name'} = $tag{'author'};
3207                         }
3208                 } elsif ($line =~ m/--BEGIN/) {
3209                         push @comment, $line;
3210                         last;
3211                 } elsif ($line eq "") {
3212                         last;
3213                 }
3214         }
3215         push @comment, <$fd>;
3216         $tag{'comment'} = \@comment;
3217         close $fd or return;
3218         if (!defined $tag{'name'}) {
3219                 return
3220         };
3221         return %tag
3222 }
3223
3224 sub parse_commit_text {
3225         my ($commit_text, $withparents) = @_;
3226         my @commit_lines = split '\n', $commit_text;
3227         my %co;
3228
3229         pop @commit_lines; # Remove '\0'
3230
3231         if (! @commit_lines) {
3232                 return;
3233         }
3234
3235         my $header = shift @commit_lines;
3236         if ($header !~ m/^[0-9a-fA-F]{40}/) {
3237                 return;
3238         }
3239         ($co{'id'}, my @parents) = split ' ', $header;
3240         while (my $line = shift @commit_lines) {
3241                 last if $line eq "\n";
3242                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3243                         $co{'tree'} = $1;
3244                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3245                         push @parents, $1;
3246                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3247                         $co{'author'} = to_utf8($1);
3248                         $co{'author_epoch'} = $2;
3249                         $co{'author_tz'} = $3;
3250                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3251                                 $co{'author_name'}  = $1;
3252                                 $co{'author_email'} = $2;
3253                         } else {
3254                                 $co{'author_name'} = $co{'author'};
3255                         }
3256                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3257                         $co{'committer'} = to_utf8($1);
3258                         $co{'committer_epoch'} = $2;
3259                         $co{'committer_tz'} = $3;
3260                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3261                                 $co{'committer_name'}  = $1;
3262                                 $co{'committer_email'} = $2;
3263                         } else {
3264                                 $co{'committer_name'} = $co{'committer'};
3265                         }
3266                 }
3267         }
3268         if (!defined $co{'tree'}) {
3269                 return;
3270         };
3271         $co{'parents'} = \@parents;
3272         $co{'parent'} = $parents[0];
3273
3274         foreach my $title (@commit_lines) {
3275                 $title =~ s/^    //;
3276                 if ($title ne "") {
3277                         $co{'title'} = chop_str($title, 80, 5);
3278                         # remove leading stuff of merges to make the interesting part visible
3279                         if (length($title) > 50) {
3280                                 $title =~ s/^Automatic //;
3281                                 $title =~ s/^merge (of|with) /Merge ... /i;
3282                                 if (length($title) > 50) {
3283                                         $title =~ s/(http|rsync):\/\///;
3284                                 }
3285                                 if (length($title) > 50) {
3286                                         $title =~ s/(master|www|rsync)\.//;
3287                                 }
3288                                 if (length($title) > 50) {
3289                                         $title =~ s/kernel.org:?//;
3290                                 }
3291                                 if (length($title) > 50) {
3292                                         $title =~ s/\/pub\/scm//;
3293                                 }
3294                         }
3295                         $co{'title_short'} = chop_str($title, 50, 5);
3296                         last;
3297                 }
3298         }
3299         if (! defined $co{'title'} || $co{'title'} eq "") {
3300                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3301         }
3302         # remove added spaces
3303         foreach my $line (@commit_lines) {
3304                 $line =~ s/^    //;
3305         }
3306         $co{'comment'} = \@commit_lines;
3307
3308         my $age = time - $co{'committer_epoch'};
3309         $co{'age'} = $age;
3310         $co{'age_string'} = age_string($age);
3311         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3312         if ($age > 60*60*24*7*2) {
3313                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3314                 $co{'age_string_age'} = $co{'age_string'};
3315         } else {
3316                 $co{'age_string_date'} = $co{'age_string'};
3317                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3318         }
3319         return %co;
3320 }
3321
3322 sub parse_commit {
3323         my ($commit_id) = @_;
3324         my %co;
3325
3326         local $/ = "\0";
3327
3328         open my $fd, "-|", git_cmd(), "rev-list",
3329                 "--parents",
3330                 "--header",
3331                 "--max-count=1",
3332                 $commit_id,
3333                 "--",
3334                 or die_error(500, "Open git-rev-list failed");
3335         %co = parse_commit_text(<$fd>, 1);
3336         close $fd;
3337
3338         return %co;
3339 }
3340
3341 sub parse_commits {
3342         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3343         my @cos;
3344
3345         $maxcount ||= 1;
3346         $skip ||= 0;
3347
3348         local $/ = "\0";
3349
3350         open my $fd, "-|", git_cmd(), "rev-list",
3351                 "--header",
3352                 @args,
3353                 ("--max-count=" . $maxcount),
3354                 ("--skip=" . $skip),
3355                 @extra_options,
3356                 $commit_id,
3357                 "--",
3358                 ($filename ? ($filename) : ())
3359                 or die_error(500, "Open git-rev-list failed");
3360         while (my $line = <$fd>) {
3361                 my %co = parse_commit_text($line);
3362                 push @cos, \%co;
3363         }
3364         close $fd;
3365
3366         return wantarray ? @cos : \@cos;
3367 }
3368
3369 # parse line of git-diff-tree "raw" output
3370 sub parse_difftree_raw_line {
3371         my $line = shift;
3372         my %res;
3373
3374         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3375         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3376         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3377                 $res{'from_mode'} = $1;
3378                 $res{'to_mode'} = $2;
3379                 $res{'from_id'} = $3;
3380                 $res{'to_id'} = $4;
3381                 $res{'status'} = $5;
3382                 $res{'similarity'} = $6;
3383                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3384                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3385                 } else {
3386                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3387                 }
3388         }
3389         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3390         # combined diff (for merge commit)
3391         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3392                 $res{'nparents'}  = length($1);
3393                 $res{'from_mode'} = [ split(' ', $2) ];
3394                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3395                 $res{'from_id'} = [ split(' ', $3) ];
3396                 $res{'to_id'} = pop @{$res{'from_id'}};
3397                 $res{'status'} = [ split('', $4) ];
3398                 $res{'to_file'} = unquote($5);
3399         }
3400         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3401         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3402                 $res{'commit'} = $1;
3403         }
3404
3405         return wantarray ? %res : \%res;
3406 }
3407
3408 # wrapper: return parsed line of git-diff-tree "raw" output
3409 # (the argument might be raw line, or parsed info)
3410 sub parsed_difftree_line {
3411         my $line_or_ref = shift;
3412
3413         if (ref($line_or_ref) eq "HASH") {
3414                 # pre-parsed (or generated by hand)
3415                 return $line_or_ref;
3416         } else {
3417                 return parse_difftree_raw_line($line_or_ref);
3418         }
3419 }
3420
3421 # parse line of git-ls-tree output
3422 sub parse_ls_tree_line {
3423         my $line = shift;
3424         my %opts = @_;
3425         my %res;
3426
3427         if ($opts{'-l'}) {
3428                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3429                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3430
3431                 $res{'mode'} = $1;
3432                 $res{'type'} = $2;
3433                 $res{'hash'} = $3;
3434                 $res{'size'} = $4;
3435                 if ($opts{'-z'}) {
3436                         $res{'name'} = $5;
3437                 } else {
3438                         $res{'name'} = unquote($5);
3439                 }
3440         } else {
3441                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3442                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3443
3444                 $res{'mode'} = $1;
3445                 $res{'type'} = $2;
3446                 $res{'hash'} = $3;
3447                 if ($opts{'-z'}) {
3448                         $res{'name'} = $4;
3449                 } else {
3450                         $res{'name'} = unquote($4);
3451                 }
3452         }
3453
3454         return wantarray ? %res : \%res;
3455 }
3456
3457 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3458 sub parse_from_to_diffinfo {
3459         my ($diffinfo, $from, $to, @parents) = @_;
3460
3461         if ($diffinfo->{'nparents'}) {
3462                 # combined diff
3463                 $from->{'file'} = [];
3464                 $from->{'href'} = [];
3465                 fill_from_file_info($diffinfo, @parents)
3466                         unless exists $diffinfo->{'from_file'};
3467                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3468                         $from->{'file'}[$i] =
3469                                 defined $diffinfo->{'from_file'}[$i] ?
3470                                         $diffinfo->{'from_file'}[$i] :
3471                                         $diffinfo->{'to_file'};
3472                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3473                                 $from->{'href'}[$i] = href(action=>"blob",
3474                                                            hash_base=>$parents[$i],
3475                                                            hash=>$diffinfo->{'from_id'}[$i],
3476                                                            file_name=>$from->{'file'}[$i]);
3477                         } else {
3478                                 $from->{'href'}[$i] = undef;
3479                         }
3480                 }
3481         } else {
3482                 # ordinary (not combined) diff
3483                 $from->{'file'} = $diffinfo->{'from_file'};
3484                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3485                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3486                                                hash=>$diffinfo->{'from_id'},
3487                                                file_name=>$from->{'file'});
3488                 } else {
3489                         delete $from->{'href'};
3490                 }
3491         }
3492
3493         $to->{'file'} = $diffinfo->{'to_file'};
3494         if (!is_deleted($diffinfo)) { # file exists in result
3495                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3496                                      hash=>$diffinfo->{'to_id'},
3497                                      file_name=>$to->{'file'});
3498         } else {
3499                 delete $to->{'href'};
3500         }
3501 }
3502
3503 ## ......................................................................
3504 ## parse to array of hashes functions
3505
3506 sub git_get_heads_list {
3507         my ($limit, @classes) = @_;
3508         @classes = ('heads') unless @classes;
3509         my @patterns = map { "refs/$_" } @classes;
3510         my @headslist;
3511
3512         open my $fd, '-|', git_cmd(), 'for-each-ref',
3513                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3514                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3515                 @patterns
3516                 or return;
3517         while (my $line = <$fd>) {
3518                 my %ref_item;
3519
3520                 chomp $line;
3521                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3522                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3523                 my ($committer, $epoch, $tz) =
3524                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3525                 $ref_item{'fullname'}  = $name;
3526                 $name =~ s!^refs/(?:head|remote)s/!!;
3527
3528                 $ref_item{'name'}  = $name;
3529                 $ref_item{'id'}    = $hash;
3530                 $ref_item{'title'} = $title || '(no commit message)';
3531                 $ref_item{'epoch'} = $epoch;
3532                 if ($epoch) {
3533                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3534                 } else {
3535                         $ref_item{'age'} = "unknown";
3536                 }
3537
3538                 push @headslist, \%ref_item;
3539         }
3540         close $fd;
3541
3542         return wantarray ? @headslist : \@headslist;
3543 }
3544
3545 sub git_get_tags_list {
3546         my $limit = shift;
3547         my @tagslist;
3548
3549         open my $fd, '-|', git_cmd(), 'for-each-ref',
3550                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3551                 '--format=%(objectname) %(objecttype) %(refname) '.
3552                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3553                 'refs/tags'
3554                 or return;
3555         while (my $line = <$fd>) {
3556                 my %ref_item;
3557
3558                 chomp $line;
3559                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3560                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3561                 my ($creator, $epoch, $tz) =
3562                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3563                 $ref_item{'fullname'} = $name;
3564                 $name =~ s!^refs/tags/!!;
3565
3566                 $ref_item{'type'} = $type;
3567                 $ref_item{'id'} = $id;
3568                 $ref_item{'name'} = $name;
3569                 if ($type eq "tag") {
3570                         $ref_item{'subject'} = $title;
3571                         $ref_item{'reftype'} = $reftype;
3572                         $ref_item{'refid'}   = $refid;
3573                 } else {
3574                         $ref_item{'reftype'} = $type;
3575                         $ref_item{'refid'}   = $id;
3576                 }
3577
3578                 if ($type eq "tag" || $type eq "commit") {
3579                         $ref_item{'epoch'} = $epoch;
3580                         if ($epoch) {
3581                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3582                         } else {
3583                                 $ref_item{'age'} = "unknown";
3584                         }
3585                 }
3586
3587                 push @tagslist, \%ref_item;
3588         }
3589         close $fd;
3590
3591         return wantarray ? @tagslist : \@tagslist;
3592 }
3593
3594 ## ----------------------------------------------------------------------
3595 ## filesystem-related functions
3596
3597 sub get_file_owner {
3598         my $path = shift;
3599
3600         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3601         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3602         if (!defined $gcos) {
3603                 return undef;
3604         }
3605         my $owner = $gcos;
3606         $owner =~ s/[,;].*$//;
3607         return to_utf8($owner);
3608 }
3609
3610 # assume that file exists
3611 sub insert_file {
3612         my $filename = shift;
3613
3614         open my $fd, '<', $filename;
3615         print map { to_utf8($_) } <$fd>;
3616         close $fd;
3617 }
3618
3619 ## ......................................................................
3620 ## mimetype related functions
3621
3622 sub mimetype_guess_file {
3623         my $filename = shift;
3624         my $mimemap = shift;
3625         -r $mimemap or return undef;
3626
3627         my %mimemap;
3628         open(my $mh, '<', $mimemap) or return undef;
3629         while (<$mh>) {
3630                 next if m/^#/; # skip comments
3631                 my ($mimetype, @exts) = split(/\s+/);
3632                 foreach my $ext (@exts) {
3633                         $mimemap{$ext} = $mimetype;
3634                 }
3635         }
3636         close($mh);
3637
3638         $filename =~ /\.([^.]*)$/;
3639         return $mimemap{$1};
3640 }
3641
3642 sub mimetype_guess {
3643         my $filename = shift;
3644         my $mime;
3645         $filename =~ /\./ or return undef;
3646
3647         if ($mimetypes_file) {
3648                 my $file = $mimetypes_file;
3649                 if ($file !~ m!^/!) { # if it is relative path
3650                         # it is relative to project
3651                         $file = "$projectroot/$project/$file";
3652                 }
3653                 $mime = mimetype_guess_file($filename, $file);
3654         }
3655         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3656         return $mime;
3657 }
3658
3659 sub blob_mimetype {
3660         my $fd = shift;
3661         my $filename = shift;
3662
3663         if ($filename) {
3664                 my $mime = mimetype_guess($filename);
3665                 $mime and return $mime;
3666         }
3667
3668         # just in case
3669         return $default_blob_plain_mimetype unless $fd;
3670
3671         if (-T $fd) {
3672                 return 'text/plain';
3673         } elsif (! $filename) {
3674                 return 'application/octet-stream';
3675         } elsif ($filename =~ m/\.png$/i) {
3676                 return 'image/png';
3677         } elsif ($filename =~ m/\.gif$/i) {
3678                 return 'image/gif';
3679         } elsif ($filename =~ m/\.jpe?g$/i) {
3680                 return 'image/jpeg';
3681         } else {
3682                 return 'application/octet-stream';
3683         }
3684 }
3685
3686 sub blob_contenttype {
3687         my ($fd, $file_name, $type) = @_;
3688
3689         $type ||= blob_mimetype($fd, $file_name);
3690         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3691                 $type .= "; charset=$default_text_plain_charset";
3692         }
3693
3694         return $type;
3695 }
3696
3697 # guess file syntax for syntax highlighting; return undef if no highlighting
3698 # the name of syntax can (in the future) depend on syntax highlighter used
3699 sub guess_file_syntax {
3700         my ($highlight, $mimetype, $file_name) = @_;
3701         return undef unless ($highlight && defined $file_name);
3702         my $basename = basename($file_name, '.in');
3703         return $highlight_basename{$basename}
3704                 if exists $highlight_basename{$basename};
3705
3706         $basename =~ /\.([^.]*)$/;
3707         my $ext = $1 or return undef;
3708         return $highlight_ext{$ext}
3709                 if exists $highlight_ext{$ext};
3710
3711         return undef;
3712 }
3713
3714 # run highlighter and return FD of its output,
3715 # or return original FD if no highlighting
3716 sub run_highlighter {
3717         my ($fd, $highlight, $syntax) = @_;
3718         return $fd unless ($highlight && defined $syntax);
3719
3720         close $fd;
3721         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3722                   quote_command($highlight_bin).
3723                   " --replace-tabs=8 --fragment --syntax $syntax |"
3724                 or die_error(500, "Couldn't open file or run syntax highlighter");
3725         return $fd;
3726 }
3727
3728 ## ======================================================================
3729 ## functions printing HTML: header, footer, error page
3730
3731 sub get_page_title {
3732         my $title = to_utf8($site_name);
3733
3734         return $title unless (defined $project);
3735         $title .= " - " . to_utf8($project);
3736
3737         return $title unless (defined $action);
3738         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3739
3740         return $title unless (defined $file_name);
3741         $title .= " - " . esc_path($file_name);
3742         if ($action eq "tree" && $file_name !~ m|/$|) {
3743                 $title .= "/";
3744         }
3745
3746         return $title;
3747 }
3748
3749 sub get_content_type_html {
3750         # require explicit support from the UA if we are to send the page as
3751         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3752         # we have to do this because MSIE sometimes globs '*/*', pretending to
3753         # support xhtml+xml but choking when it gets what it asked for.
3754         if (defined $cgi->http('HTTP_ACCEPT') &&
3755             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3756             $cgi->Accept('application/xhtml+xml') != 0) {
3757                 return 'application/xhtml+xml';
3758         } else {
3759                 return 'text/html';
3760         }
3761 }
3762
3763 sub print_feed_meta {
3764         if (defined $project) {
3765                 my %href_params = get_feed_info();
3766                 if (!exists $href_params{'-title'}) {
3767                         $href_params{'-title'} = 'log';
3768                 }
3769
3770                 foreach my $format (qw(RSS Atom)) {
3771                         my $type = lc($format);
3772                         my %link_attr = (
3773                                 '-rel' => 'alternate',
3774                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
3775                                 '-type' => "application/$type+xml"
3776                         );
3777
3778                         $href_params{'action'} = $type;
3779                         $link_attr{'-href'} = href(%href_params);
3780                         print "<link ".
3781                               "rel=\"$link_attr{'-rel'}\" ".
3782                               "title=\"$link_attr{'-title'}\" ".
3783                               "href=\"$link_attr{'-href'}\" ".
3784                               "type=\"$link_attr{'-type'}\" ".
3785                               "/>\n";
3786
3787                         $href_params{'extra_options'} = '--no-merges';
3788                         $link_attr{'-href'} = href(%href_params);
3789                         $link_attr{'-title'} .= ' (no merges)';
3790                         print "<link ".
3791                               "rel=\"$link_attr{'-rel'}\" ".
3792                               "title=\"$link_attr{'-title'}\" ".
3793                               "href=\"$link_attr{'-href'}\" ".
3794                               "type=\"$link_attr{'-type'}\" ".
3795                               "/>\n";
3796                 }
3797
3798         } else {
3799                 printf('<link rel="alternate" title="%s projects list" '.
3800                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3801                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
3802                 printf('<link rel="alternate" title="%s projects feeds" '.
3803                        'href="%s" type="text/x-opml" />'."\n",
3804                        esc_attr($site_name), href(project=>undef, action=>"opml"));
3805         }
3806 }
3807
3808 sub print_header_links {
3809         my $status = shift;
3810
3811         # print out each stylesheet that exist, providing backwards capability
3812         # for those people who defined $stylesheet in a config file
3813         if (defined $stylesheet) {
3814                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3815         } else {
3816                 foreach my $stylesheet (@stylesheets) {
3817                         next unless $stylesheet;
3818                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3819                 }
3820         }
3821         print_feed_meta()
3822                 if ($status eq '200 OK');
3823         if (defined $favicon) {
3824                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
3825         }
3826 }
3827
3828 sub print_nav_breadcrumbs {
3829         my %opts = @_;
3830
3831         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3832         if (defined $project) {
3833                 print $cgi->a({-href => href(action=>"summary")}, esc_html($project));
3834                 if (defined $action) {
3835                         my $action_print = $action ;
3836                         if (defined $opts{-action_extra}) {
3837                                 $action_print = $cgi->a({-href => href(action=>$action)},
3838                                         $action);
3839                         }
3840                         print " / $action_print";
3841                 }
3842                 if (defined $opts{-action_extra}) {
3843                         print " / $opts{-action_extra}";
3844                 }
3845                 print "\n";
3846         }
3847 }
3848
3849 sub print_search_form {
3850         if (!defined $searchtext) {
3851                 $searchtext = "";
3852         }
3853         my $search_hash;
3854         if (defined $hash_base) {
3855                 $search_hash = $hash_base;
3856         } elsif (defined $hash) {
3857                 $search_hash = $hash;
3858         } else {
3859                 $search_hash = "HEAD";
3860         }
3861         my $action = $my_uri;
3862         my $use_pathinfo = gitweb_check_feature('pathinfo');
3863         if ($use_pathinfo) {
3864                 $action .= "/".esc_url($project);
3865         }
3866         print $cgi->startform(-method => "get", -action => $action) .
3867               "<div class=\"search\">\n" .
3868               (!$use_pathinfo &&
3869               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
3870               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
3871               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
3872               $cgi->popup_menu(-name => 'st', -default => 'commit',
3873                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
3874               $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
3875               " search:\n",
3876               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
3877               "<span title=\"Extended regular expression\">" .
3878               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
3879                              -checked => $search_use_regexp) .
3880               "</span>" .
3881               "</div>" .
3882               $cgi->end_form() . "\n";
3883 }
3884
3885 sub git_header_html {
3886         my $status = shift || "200 OK";
3887         my $expires = shift;
3888         my %opts = @_;
3889
3890         my $title = get_page_title();
3891         my $content_type = get_content_type_html();
3892         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
3893                            -status=> $status, -expires => $expires)
3894                 unless ($opts{'-no_http_header'});
3895         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
3896         print <<EOF;
3897 <?xml version="1.0" encoding="utf-8"?>
3898 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
3899 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
3900 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
3901 <!-- git core binaries version $git_version -->
3902 <head>
3903 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
3904 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
3905 <meta name="robots" content="index, nofollow"/>
3906 <title>$title</title>
3907 EOF
3908         # the stylesheet, favicon etc urls won't work correctly with path_info
3909         # unless we set the appropriate base URL
3910         if ($ENV{'PATH_INFO'}) {
3911                 print "<base href=\"".esc_url($base_url)."\" />\n";
3912         }
3913         print_header_links($status);
3914
3915         if (defined $site_html_head_string) {
3916                 print to_utf8($site_html_head_string);
3917         }
3918
3919         print "</head>\n" .
3920               "<body>\n";
3921
3922         if (defined $site_header && -f $site_header) {
3923                 insert_file($site_header);
3924         }
3925
3926         print "<div class=\"page_header\">\n";
3927         if (defined $logo) {
3928                 print $cgi->a({-href => esc_url($logo_url),
3929                                -title => $logo_label},
3930                               $cgi->img({-src => esc_url($logo),
3931                                          -width => 72, -height => 27,
3932                                          -alt => "git",
3933                                          -class => "logo"}));
3934         }
3935         print_nav_breadcrumbs(%opts);
3936         print "</div>\n";
3937
3938         my $have_search = gitweb_check_feature('search');
3939         if (defined $project && $have_search) {
3940                 print_search_form();
3941         }
3942 }
3943
3944 sub git_footer_html {
3945         my $feed_class = 'rss_logo';
3946
3947         print "<div class=\"page_footer\">\n";
3948         if (defined $project) {
3949                 my $descr = git_get_project_description($project);
3950                 if (defined $descr) {
3951                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
3952                 }
3953
3954                 my %href_params = get_feed_info();
3955                 if (!%href_params) {
3956                         $feed_class .= ' generic';
3957                 }
3958                 $href_params{'-title'} ||= 'log';
3959
3960                 foreach my $format (qw(RSS Atom)) {
3961                         $href_params{'action'} = lc($format);
3962                         print $cgi->a({-href => href(%href_params),
3963                                       -title => "$href_params{'-title'} $format feed",
3964                                       -class => $feed_class}, $format)."\n";
3965                 }
3966
3967         } else {
3968                 print $cgi->a({-href => href(project=>undef, action=>"opml"),
3969                               -class => $feed_class}, "OPML") . " ";
3970                 print $cgi->a({-href => href(project=>undef, action=>"project_index"),
3971                               -class => $feed_class}, "TXT") . "\n";
3972         }
3973         print "</div>\n"; # class="page_footer"
3974
3975         if (defined $t0 && gitweb_check_feature('timed')) {
3976                 print "<div id=\"generating_info\">\n";
3977                 print 'This page took '.
3978                       '<span id="generating_time" class="time_span">'.
3979                       tv_interval($t0, [ gettimeofday() ]).
3980                       ' seconds </span>'.
3981                       ' and '.
3982                       '<span id="generating_cmd">'.
3983                       $number_of_git_cmds.
3984                       '</span> git commands '.
3985                       " to generate.\n";
3986                 print "</div>\n"; # class="page_footer"
3987         }
3988
3989         if (defined $site_footer && -f $site_footer) {
3990                 insert_file($site_footer);
3991         }
3992
3993         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
3994         if (defined $action &&
3995             $action eq 'blame_incremental') {
3996                 print qq!<script type="text/javascript">\n!.
3997                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
3998                       qq!           "!. href() .qq!");\n!.
3999                       qq!</script>\n!;
4000         } else {
4001                 my ($jstimezone, $tz_cookie, $datetime_class) =
4002                         gitweb_get_feature('javascript-timezone');
4003
4004                 print qq!<script type="text/javascript">\n!.
4005                       qq!window.onload = function () {\n!;
4006                 if (gitweb_check_feature('javascript-actions')) {
4007                         print qq!       fixLinks();\n!;
4008                 }
4009                 if ($jstimezone && $tz_cookie && $datetime_class) {
4010                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
4011                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
4012                 }
4013                 print qq!};\n!.
4014                       qq!</script>\n!;
4015         }
4016
4017         print "</body>\n" .
4018               "</html>";
4019 }
4020
4021 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
4022 # Example: die_error(404, 'Hash not found')
4023 # By convention, use the following status codes (as defined in RFC 2616):
4024 # 400: Invalid or missing CGI parameters, or
4025 #      requested object exists but has wrong type.
4026 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
4027 #      this server or project.
4028 # 404: Requested object/revision/project doesn't exist.
4029 # 500: The server isn't configured properly, or
4030 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4031 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4032 # 503: The server is currently unavailable (because it is overloaded,
4033 #      or down for maintenance).  Generally, this is a temporary state.
4034 sub die_error {
4035         my $status = shift || 500;
4036         my $error = esc_html(shift) || "Internal Server Error";
4037         my $extra = shift;
4038         my %opts = @_;
4039
4040         my %http_responses = (
4041                 400 => '400 Bad Request',
4042                 403 => '403 Forbidden',
4043                 404 => '404 Not Found',
4044                 500 => '500 Internal Server Error',
4045                 503 => '503 Service Unavailable',
4046         );
4047         git_header_html($http_responses{$status}, undef, %opts);
4048         print <<EOF;
4049 <div class="page_body">
4050 <br /><br />
4051 $status - $error
4052 <br />
4053 EOF
4054         if (defined $extra) {
4055                 print "<hr />\n" .
4056                       "$extra\n";
4057         }
4058         print "</div>\n";
4059
4060         git_footer_html();
4061         goto DONE_GITWEB
4062                 unless ($opts{'-error_handler'});
4063 }
4064
4065 ## ----------------------------------------------------------------------
4066 ## functions printing or outputting HTML: navigation
4067
4068 sub git_print_page_nav {
4069         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4070         $extra = '' if !defined $extra; # pager or formats
4071
4072         my @navs = qw(summary shortlog log commit commitdiff tree);
4073         if ($suppress) {
4074                 @navs = grep { $_ ne $suppress } @navs;
4075         }
4076
4077         my %arg = map { $_ => {action=>$_} } @navs;
4078         if (defined $head) {
4079                 for (qw(commit commitdiff)) {
4080                         $arg{$_}{'hash'} = $head;
4081                 }
4082                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4083                         for (qw(shortlog log)) {
4084                                 $arg{$_}{'hash'} = $head;
4085                         }
4086                 }
4087         }
4088
4089         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4090         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4091
4092         my @actions = gitweb_get_feature('actions');
4093         my %repl = (
4094                 '%' => '%',
4095                 'n' => $project,         # project name
4096                 'f' => $git_dir,         # project path within filesystem
4097                 'h' => $treehead || '',  # current hash ('h' parameter)
4098                 'b' => $treebase || '',  # hash base ('hb' parameter)
4099         );
4100         while (@actions) {
4101                 my ($label, $link, $pos) = splice(@actions,0,3);
4102                 # insert
4103                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4104                 # munch munch
4105                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4106                 $arg{$label}{'_href'} = $link;
4107         }
4108
4109         print "<div class=\"page_nav\">\n" .
4110                 (join " | ",
4111                  map { $_ eq $current ?
4112                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4113                  } @navs);
4114         print "<br/>\n$extra<br/>\n" .
4115               "</div>\n";
4116 }
4117
4118 # returns a submenu for the nagivation of the refs views (tags, heads,
4119 # remotes) with the current view disabled and the remotes view only
4120 # available if the feature is enabled
4121 sub format_ref_views {
4122         my ($current) = @_;
4123         my @ref_views = qw{tags heads};
4124         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4125         return join " | ", map {
4126                 $_ eq $current ? $_ :
4127                 $cgi->a({-href => href(action=>$_)}, $_)
4128         } @ref_views
4129 }
4130
4131 sub format_paging_nav {
4132         my ($action, $page, $has_next_link) = @_;
4133         my $paging_nav;
4134
4135
4136         if ($page > 0) {
4137                 $paging_nav .=
4138                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4139                         " &sdot; " .
4140                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4141                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4142         } else {
4143                 $paging_nav .= "first &sdot; prev";
4144         }
4145
4146         if ($has_next_link) {
4147                 $paging_nav .= " &sdot; " .
4148                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4149                                  -accesskey => "n", -title => "Alt-n"}, "next");
4150         } else {
4151                 $paging_nav .= " &sdot; next";
4152         }
4153
4154         return $paging_nav;
4155 }
4156
4157 ## ......................................................................
4158 ## functions printing or outputting HTML: div
4159
4160 sub git_print_header_div {
4161         my ($action, $title, $hash, $hash_base) = @_;
4162         my %args = ();
4163
4164         $args{'action'} = $action;
4165         $args{'hash'} = $hash if $hash;
4166         $args{'hash_base'} = $hash_base if $hash_base;
4167
4168         print "<div class=\"header\">\n" .
4169               $cgi->a({-href => href(%args), -class => "title"},
4170               $title ? $title : $action) .
4171               "\n</div>\n";
4172 }
4173
4174 sub format_repo_url {
4175         my ($name, $url) = @_;
4176         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4177 }
4178
4179 # Group output by placing it in a DIV element and adding a header.
4180 # Options for start_div() can be provided by passing a hash reference as the
4181 # first parameter to the function.
4182 # Options to git_print_header_div() can be provided by passing an array
4183 # reference. This must follow the options to start_div if they are present.
4184 # The content can be a scalar, which is output as-is, a scalar reference, which
4185 # is output after html escaping, an IO handle passed either as *handle or
4186 # *handle{IO}, or a function reference. In the latter case all following
4187 # parameters will be taken as argument to the content function call.
4188 sub git_print_section {
4189         my ($div_args, $header_args, $content);
4190         my $arg = shift;
4191         if (ref($arg) eq 'HASH') {
4192                 $div_args = $arg;
4193                 $arg = shift;
4194         }
4195         if (ref($arg) eq 'ARRAY') {
4196                 $header_args = $arg;
4197                 $arg = shift;
4198         }
4199         $content = $arg;
4200
4201         print $cgi->start_div($div_args);
4202         git_print_header_div(@$header_args);
4203
4204         if (ref($content) eq 'CODE') {
4205                 $content->(@_);
4206         } elsif (ref($content) eq 'SCALAR') {
4207                 print esc_html($$content);
4208         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4209                 print <$content>;
4210         } elsif (!ref($content) && defined($content)) {
4211                 print $content;
4212         }
4213
4214         print $cgi->end_div;
4215 }
4216
4217 sub format_timestamp_html {
4218         my $date = shift;
4219         my $strtime = $date->{'rfc2822'};
4220
4221         my (undef, undef, $datetime_class) =
4222                 gitweb_get_feature('javascript-timezone');
4223         if ($datetime_class) {
4224                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4225         }
4226
4227         my $localtime_format = '(%02d:%02d %s)';
4228         if ($date->{'hour_local'} < 6) {
4229                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4230         }
4231         $strtime .= ' ' .
4232                     sprintf($localtime_format,
4233                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4234
4235         return $strtime;
4236 }
4237
4238 # Outputs the author name and date in long form
4239 sub git_print_authorship {
4240         my $co = shift;
4241         my %opts = @_;
4242         my $tag = $opts{-tag} || 'div';
4243         my $author = $co->{'author_name'};
4244
4245         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4246         print "<$tag class=\"author_date\">" .
4247               format_search_author($author, "author", esc_html($author)) .
4248               " [".format_timestamp_html(\%ad)."]".
4249               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4250               "</$tag>\n";
4251 }
4252
4253 # Outputs table rows containing the full author or committer information,
4254 # in the format expected for 'commit' view (& similar).
4255 # Parameters are a commit hash reference, followed by the list of people
4256 # to output information for. If the list is empty it defaults to both
4257 # author and committer.
4258 sub git_print_authorship_rows {
4259         my $co = shift;
4260         # too bad we can't use @people = @_ || ('author', 'committer')
4261         my @people = @_;
4262         @people = ('author', 'committer') unless @people;
4263         foreach my $who (@people) {
4264                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4265                 print "<tr><td>$who</td><td>" .
4266                       format_search_author($co->{"${who}_name"}, $who,
4267                                            esc_html($co->{"${who}_name"})) . " " .
4268                       format_search_author($co->{"${who}_email"}, $who,
4269                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4270                       "</td><td rowspan=\"2\">" .
4271                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4272                       "</td></tr>\n" .
4273                       "<tr>" .
4274                       "<td></td><td>" .
4275                       format_timestamp_html(\%wd) .
4276                       "</td>" .
4277                       "</tr>\n";
4278         }
4279 }
4280
4281 sub git_print_page_path {
4282         my $name = shift;
4283         my $type = shift;
4284         my $hb = shift;
4285
4286
4287         print "<div class=\"page_path\">";
4288         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4289                       -title => 'tree root'}, to_utf8("[$project]"));
4290         print " / ";
4291         if (defined $name) {
4292                 my @dirname = split '/', $name;
4293                 my $basename = pop @dirname;
4294                 my $fullname = '';
4295
4296                 foreach my $dir (@dirname) {
4297                         $fullname .= ($fullname ? '/' : '') . $dir;
4298                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4299                                                      hash_base=>$hb),
4300                                       -title => $fullname}, esc_path($dir));
4301                         print " / ";
4302                 }
4303                 if (defined $type && $type eq 'blob') {
4304                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4305                                                      hash_base=>$hb),
4306                                       -title => $name}, esc_path($basename));
4307                         print '&nbsp;&nbsp;&nbsp;&nbsp;
4308 <a id="lineNoToggle" href="#" onclick="toggleLineNumbers();"></a>
4309 <script>
4310 function toggleLineNumbers() {
4311         e = document.getElementById("lineNoStyle");
4312         e2 = document.getElementById("lineNoToggle");
4313         if (e2.innerHTML == "[Hide line numbers]") {
4314                 e.innerHTML = ".linenr { display:none; }";
4315                 e2.innerHTML = "[Show line numbers]";
4316         }
4317         else {
4318                 e.innerHTML = "";
4319                 e2.innerHTML = "[Hide line numbers]";
4320         }
4321 }
4322 var style = document.createElement("style");
4323 style.setAttribute("id", "lineNoStyle");
4324 document.getElementsByTagName("head")[0].appendChild(style);
4325 toggleLineNumbers();
4326 </script>
4327 ';
4328                 } elsif (defined $type && $type eq 'tree') {
4329                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4330                                                      hash_base=>$hb),
4331                                       -title => $name}, esc_path($basename));
4332                         print " / ";
4333                 } else {
4334                         print esc_path($basename);
4335                 }
4336         }
4337         print "<br/></div>\n";
4338 }
4339
4340 sub git_print_log {
4341         my $log = shift;
4342         my %opts = @_;
4343
4344         if ($opts{'-remove_title'}) {
4345                 # remove title, i.e. first line of log
4346                 shift @$log;
4347         }
4348         # remove leading empty lines
4349         while (defined $log->[0] && $log->[0] eq "") {
4350                 shift @$log;
4351         }
4352
4353         # print log
4354         my $signoff = 0;
4355         my $empty = 0;
4356         foreach my $line (@$log) {
4357                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
4358                         $signoff = 1;
4359                         $empty = 0;
4360                         if (! $opts{'-remove_signoff'}) {
4361                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4362                                 next;
4363                         } else {
4364                                 # remove signoff lines
4365                                 next;
4366                         }
4367                 } else {
4368                         $signoff = 0;
4369                 }
4370
4371                 # print only one empty line
4372                 # do not print empty line after signoff
4373                 if ($line eq "") {
4374                         next if ($empty || $signoff);
4375                         $empty = 1;
4376                 } else {
4377                         $empty = 0;
4378                 }
4379
4380                 print format_log_line_html($line) . "<br/>\n";
4381         }
4382
4383         if ($opts{'-final_empty_line'}) {
4384                 # end with single empty line
4385                 print "<br/>\n" unless $empty;
4386         }
4387 }
4388
4389 # return link target (what link points to)
4390 sub git_get_link_target {
4391         my $hash = shift;
4392         my $link_target;
4393
4394         # read link
4395         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4396                 or return;
4397         {
4398                 local $/ = undef;
4399                 $link_target = <$fd>;
4400         }
4401         close $fd
4402                 or return;
4403
4404         return $link_target;
4405 }
4406
4407 # given link target, and the directory (basedir) the link is in,
4408 # return target of link relative to top directory (top tree);
4409 # return undef if it is not possible (including absolute links).
4410 sub normalize_link_target {
4411         my ($link_target, $basedir) = @_;
4412
4413         # absolute symlinks (beginning with '/') cannot be normalized
4414         return if (substr($link_target, 0, 1) eq '/');
4415
4416         # normalize link target to path from top (root) tree (dir)
4417         my $path;
4418         if ($basedir) {
4419                 $path = $basedir . '/' . $link_target;
4420         } else {
4421                 # we are in top (root) tree (dir)
4422                 $path = $link_target;
4423         }
4424
4425         # remove //, /./, and /../
4426         my @path_parts;
4427         foreach my $part (split('/', $path)) {
4428                 # discard '.' and ''
4429                 next if (!$part || $part eq '.');
4430                 # handle '..'
4431                 if ($part eq '..') {
4432                         if (@path_parts) {
4433                                 pop @path_parts;
4434                         } else {
4435                                 # link leads outside repository (outside top dir)
4436                                 return;
4437                         }
4438                 } else {
4439                         push @path_parts, $part;
4440                 }
4441         }
4442         $path = join('/', @path_parts);
4443
4444         return $path;
4445 }
4446
4447 # print tree entry (row of git_tree), but without encompassing <tr> element
4448 sub git_print_tree_entry {
4449         my ($t, $basedir, $hash_base, $have_blame) = @_;
4450
4451         my %base_key = ();
4452         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4453
4454         # The format of a table row is: mode list link.  Where mode is
4455         # the mode of the entry, list is the name of the entry, an href,
4456         # and link is the action links of the entry.
4457
4458         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4459         if (exists $t->{'size'}) {
4460                 print "<td class=\"size\">$t->{'size'}</td>\n";
4461         }
4462         if ($t->{'type'} eq "blob") {
4463                 print "<td class=\"list\">" .
4464                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4465                                                file_name=>"$basedir$t->{'name'}", %base_key),
4466                                 -class => "list"}, esc_path($t->{'name'}));
4467                 if (S_ISLNK(oct $t->{'mode'})) {
4468                         my $link_target = git_get_link_target($t->{'hash'});
4469                         if ($link_target) {
4470                                 my $norm_target = normalize_link_target($link_target, $basedir);
4471                                 if (defined $norm_target) {
4472                                         print " -> " .
4473                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4474                                                                      file_name=>$norm_target),
4475                                                        -title => $norm_target}, esc_path($link_target));
4476                                 } else {
4477                                         print " -> " . esc_path($link_target);
4478                                 }
4479                         }
4480                 }
4481                 print "</td>\n";
4482                 print "<td class=\"link\">";
4483                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4484                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4485                               "blob");
4486                 if ($have_blame) {
4487                         print " | " .
4488                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4489                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4490                                       "blame");
4491                 }
4492                 if (defined $hash_base) {
4493                         print " | " .
4494                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4495                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4496                                       "history");
4497                 }
4498                 print " | " .
4499                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4500                                                file_name=>"$basedir$t->{'name'}")},
4501                                 "raw");
4502                 print "</td>\n";
4503
4504         } elsif ($t->{'type'} eq "tree") {
4505                 print "<td class=\"list\">";
4506                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4507                                              file_name=>"$basedir$t->{'name'}",
4508                                              %base_key)},
4509                               esc_path($t->{'name'}));
4510                 print "</td>\n";
4511                 print "<td class=\"link\">";
4512                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4513                                              file_name=>"$basedir$t->{'name'}",
4514                                              %base_key)},
4515                               "tree");
4516                 if (defined $hash_base) {
4517                         print " | " .
4518                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4519                                                      file_name=>"$basedir$t->{'name'}")},
4520                                       "history");
4521                 }
4522                 print "</td>\n";
4523         } else {
4524                 # unknown object: we can only present history for it
4525                 # (this includes 'commit' object, i.e. submodule support)
4526                 print "<td class=\"list\">" .
4527                       esc_path($t->{'name'}) .
4528                       "</td>\n";
4529                 print "<td class=\"link\">";
4530                 if (defined $hash_base) {
4531                         print $cgi->a({-href => href(action=>"history",
4532                                                      hash_base=>$hash_base,
4533                                                      file_name=>"$basedir$t->{'name'}")},
4534                                       "history");
4535                 }
4536                 print "</td>\n";
4537         }
4538 }
4539
4540 ## ......................................................................
4541 ## functions printing large fragments of HTML
4542
4543 # get pre-image filenames for merge (combined) diff
4544 sub fill_from_file_info {
4545         my ($diff, @parents) = @_;
4546
4547         $diff->{'from_file'} = [ ];
4548         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4549         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4550                 if ($diff->{'status'}[$i] eq 'R' ||
4551                     $diff->{'status'}[$i] eq 'C') {
4552                         $diff->{'from_file'}[$i] =
4553                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4554                 }
4555         }
4556
4557         return $diff;
4558 }
4559
4560 # is current raw difftree line of file deletion
4561 sub is_deleted {
4562         my $diffinfo = shift;
4563
4564         return $diffinfo->{'to_id'} eq ('0' x 40);
4565 }
4566
4567 # does patch correspond to [previous] difftree raw line
4568 # $diffinfo  - hashref of parsed raw diff format
4569 # $patchinfo - hashref of parsed patch diff format
4570 #              (the same keys as in $diffinfo)
4571 sub is_patch_split {
4572         my ($diffinfo, $patchinfo) = @_;
4573
4574         return defined $diffinfo && defined $patchinfo
4575                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4576 }
4577
4578
4579 sub git_difftree_body {
4580         my ($difftree, $hash, @parents) = @_;
4581         my ($parent) = $parents[0];
4582         my $have_blame = gitweb_check_feature('blame');
4583         print "<div class=\"list_head\">\n";
4584         if ($#{$difftree} > 10) {
4585                 print(($#{$difftree} + 1) . " files changed:\n");
4586         }
4587         print "</div>\n";
4588
4589         print "<table class=\"" .
4590               (@parents > 1 ? "combined " : "") .
4591               "diff_tree\">\n";
4592
4593         # header only for combined diff in 'commitdiff' view
4594         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4595         if ($has_header) {
4596                 # table header
4597                 print "<thead><tr>\n" .
4598                        "<th></th><th></th>\n"; # filename, patchN link
4599                 for (my $i = 0; $i < @parents; $i++) {
4600                         my $par = $parents[$i];
4601                         print "<th>" .
4602                               $cgi->a({-href => href(action=>"commitdiff",
4603                                                      hash=>$hash, hash_parent=>$par),
4604                                        -title => 'commitdiff to parent number ' .
4605                                                   ($i+1) . ': ' . substr($par,0,7)},
4606                                       $i+1) .
4607                               "&nbsp;</th>\n";
4608                 }
4609                 print "</tr></thead>\n<tbody>\n";
4610         }
4611
4612         my $alternate = 1;
4613         my $patchno = 0;
4614         foreach my $line (@{$difftree}) {
4615                 my $diff = parsed_difftree_line($line);
4616
4617                 if ($alternate) {
4618                         print "<tr class=\"dark\">\n";
4619                 } else {
4620                         print "<tr class=\"light\">\n";
4621                 }
4622                 $alternate ^= 1;
4623
4624                 if (exists $diff->{'nparents'}) { # combined diff
4625
4626                         fill_from_file_info($diff, @parents)
4627                                 unless exists $diff->{'from_file'};
4628
4629                         if (!is_deleted($diff)) {
4630                                 # file exists in the result (child) commit
4631                                 print "<td>" .
4632                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4633                                                              file_name=>$diff->{'to_file'},
4634                                                              hash_base=>$hash),
4635                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4636                                       "</td>\n";
4637                         } else {
4638                                 print "<td>" .
4639                                       esc_path($diff->{'to_file'}) .
4640                                       "</td>\n";
4641                         }
4642
4643                         if ($action eq 'commitdiff') {
4644                                 # link to patch
4645                                 $patchno++;
4646                                 print "<td class=\"link\">" .
4647                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4648                                               "patch") .
4649                                       " | " .
4650                                       "</td>\n";
4651                         }
4652
4653                         my $has_history = 0;
4654                         my $not_deleted = 0;
4655                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4656                                 my $hash_parent = $parents[$i];
4657                                 my $from_hash = $diff->{'from_id'}[$i];
4658                                 my $from_path = $diff->{'from_file'}[$i];
4659                                 my $status = $diff->{'status'}[$i];
4660
4661                                 $has_history ||= ($status ne 'A');
4662                                 $not_deleted ||= ($status ne 'D');
4663
4664                                 if ($status eq 'A') {
4665                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4666                                 } elsif ($status eq 'D') {
4667                                         print "<td class=\"link\">" .
4668                                               $cgi->a({-href => href(action=>"blob",
4669                                                                      hash_base=>$hash,
4670                                                                      hash=>$from_hash,
4671                                                                      file_name=>$from_path)},
4672                                                       "blob" . ($i+1)) .
4673                                               " | </td>\n";
4674                                 } else {
4675                                         if ($diff->{'to_id'} eq $from_hash) {
4676                                                 print "<td class=\"link nochange\">";
4677                                         } else {
4678                                                 print "<td class=\"link\">";
4679                                         }
4680                                         print $cgi->a({-href => href(action=>"blobdiff",
4681                                                                      hash=>$diff->{'to_id'},
4682                                                                      hash_parent=>$from_hash,
4683                                                                      hash_base=>$hash,
4684                                                                      hash_parent_base=>$hash_parent,
4685                                                                      file_name=>$diff->{'to_file'},
4686                                                                      file_parent=>$from_path)},
4687                                                       "diff" . ($i+1)) .
4688                                               " | </td>\n";
4689                                 }
4690                         }
4691
4692                         print "<td class=\"link\">";
4693                         if ($not_deleted) {
4694                                 print $cgi->a({-href => href(action=>"blob",
4695                                                              hash=>$diff->{'to_id'},
4696                                                              file_name=>$diff->{'to_file'},
4697                                                              hash_base=>$hash)},
4698                                               "blob");
4699                                 print " | " if ($has_history);
4700                         }
4701                         if ($has_history) {
4702                                 print $cgi->a({-href => href(action=>"history",
4703                                                              file_name=>$diff->{'to_file'},
4704                                                              hash_base=>$hash)},
4705                                               "history");
4706                         }
4707                         print "</td>\n";
4708
4709                         print "</tr>\n";
4710                         next; # instead of 'else' clause, to avoid extra indent
4711                 }
4712                 # else ordinary diff
4713
4714                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4715                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4716                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4717                         $to_mode_oct = oct $diff->{'to_mode'};
4718                         if (S_ISREG($to_mode_oct)) { # only for regular file
4719                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4720                         }
4721                         $to_file_type = file_type($diff->{'to_mode'});
4722                 }
4723                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4724                         $from_mode_oct = oct $diff->{'from_mode'};
4725                         if (S_ISREG($from_mode_oct)) { # only for regular file
4726                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4727                         }
4728                         $from_file_type = file_type($diff->{'from_mode'});
4729                 }
4730
4731                 if ($diff->{'status'} eq "A") { # created
4732                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4733                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4734                         $mode_chng   .= "]</span>";
4735                         print "<td>";
4736                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4737                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4738                                       -class => "list"}, esc_path($diff->{'file'}));
4739                         print "</td>\n";
4740                         print "<td>$mode_chng</td>\n";
4741                         print "<td class=\"link\">";
4742                         if ($action eq 'commitdiff') {
4743                                 # link to patch
4744                                 $patchno++;
4745                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4746                                               "patch") .
4747                                       " | ";
4748                         }
4749                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4750                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4751                                       "blob");
4752                         print "</td>\n";
4753
4754                 } elsif ($diff->{'status'} eq "D") { # deleted
4755                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4756                         print "<td>";
4757                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4758                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4759                                        -class => "list"}, esc_path($diff->{'file'}));
4760                         print "</td>\n";
4761                         print "<td>$mode_chng</td>\n";
4762                         print "<td class=\"link\">";
4763                         if ($action eq 'commitdiff') {
4764                                 # link to patch
4765                                 $patchno++;
4766                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4767                                               "patch") .
4768                                       " | ";
4769                         }
4770                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4771                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4772                                       "blob") . " | ";
4773                         if ($have_blame) {
4774                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4775                                                              file_name=>$diff->{'file'})},
4776                                               "blame") . " | ";
4777                         }
4778                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4779                                                      file_name=>$diff->{'file'})},
4780                                       "history");
4781                         print "</td>\n";
4782
4783                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4784                         my $mode_chnge = "";
4785                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4786                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4787                                 if ($from_file_type ne $to_file_type) {
4788                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4789                                 }
4790                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4791                                         if ($from_mode_str && $to_mode_str) {
4792                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4793                                         } elsif ($to_mode_str) {
4794                                                 $mode_chnge .= " mode: $to_mode_str";
4795                                         }
4796                                 }
4797                                 $mode_chnge .= "]</span>\n";
4798                         }
4799                         print "<td>";
4800                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4801                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4802                                       -class => "list"}, esc_path($diff->{'file'}));
4803                         print "</td>\n";
4804                         print "<td>$mode_chnge</td>\n";
4805                         print "<td class=\"link\">";
4806                         if ($action eq 'commitdiff') {
4807                                 # link to patch
4808                                 $patchno++;
4809                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4810                                               "patch") .
4811                                       " | ";
4812                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4813                                 # "commit" view and modified file (not onlu mode changed)
4814                                 print $cgi->a({-href => href(action=>"blobdiff",
4815                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4816                                                              hash_base=>$hash, hash_parent_base=>$parent,
4817                                                              file_name=>$diff->{'file'})},
4818                                               "diff") .
4819                                       " | ";
4820                         }
4821                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4822                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4823                                        "blob") . " | ";
4824                         if ($have_blame) {
4825                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4826                                                              file_name=>$diff->{'file'})},
4827                                               "blame") . " | ";
4828                         }
4829                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4830                                                      file_name=>$diff->{'file'})},
4831                                       "history");
4832                         print "</td>\n";
4833
4834                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4835                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4836                         my $nstatus = $status_name{$diff->{'status'}};
4837                         my $mode_chng = "";
4838                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4839                                 # mode also for directories, so we cannot use $to_mode_str
4840                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4841                         }
4842                         print "<td>" .
4843                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4844                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4845                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4846                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4847                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4848                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4849                                       -class => "list"}, esc_path($diff->{'from_file'})) .
4850                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
4851                               "<td class=\"link\">";
4852                         if ($action eq 'commitdiff') {
4853                                 # link to patch
4854                                 $patchno++;
4855                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4856                                               "patch") .
4857                                       " | ";
4858                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4859                                 # "commit" view and modified file (not only pure rename or copy)
4860                                 print $cgi->a({-href => href(action=>"blobdiff",
4861                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4862                                                              hash_base=>$hash, hash_parent_base=>$parent,
4863                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
4864                                               "diff") .
4865                                       " | ";
4866                         }
4867                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4868                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
4869                                       "blob") . " | ";
4870                         if ($have_blame) {
4871                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4872                                                              file_name=>$diff->{'to_file'})},
4873                                               "blame") . " | ";
4874                         }
4875                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4876                                                     file_name=>$diff->{'to_file'})},
4877                                       "history");
4878                         print "</td>\n";
4879
4880                 } # we should not encounter Unmerged (U) or Unknown (X) status
4881                 print "</tr>\n";
4882         }
4883         print "</tbody>" if $has_header;
4884         print "</table>\n";
4885 }
4886
4887 sub print_sidebyside_diff_chunk {
4888         my @chunk = @_;
4889         my (@ctx, @rem, @add);
4890
4891         return unless @chunk;
4892
4893         # incomplete last line might be among removed or added lines,
4894         # or both, or among context lines: find which
4895         for (my $i = 1; $i < @chunk; $i++) {
4896                 if ($chunk[$i][0] eq 'incomplete') {
4897                         $chunk[$i][0] = $chunk[$i-1][0];
4898                 }
4899         }
4900
4901         # guardian
4902         push @chunk, ["", ""];
4903
4904         foreach my $line_info (@chunk) {
4905                 my ($class, $line) = @$line_info;
4906
4907                 # print chunk headers
4908                 if ($class && $class eq 'chunk_header') {
4909                         print $line;
4910                         next;
4911                 }
4912
4913                 ## print from accumulator when type of class of lines change
4914                 # empty contents block on start rem/add block, or end of chunk
4915                 if (@ctx && (!$class || $class eq 'rem' || $class eq 'add')) {
4916                         print join '',
4917                                 '<div class="chunk_block ctx">',
4918                                         '<div class="old">',
4919                                         @ctx,
4920                                         '</div>',
4921                                         '<div class="new">',
4922                                         @ctx,
4923                                         '</div>',
4924                                 '</div>';
4925                         @ctx = ();
4926                 }
4927                 # empty add/rem block on start context block, or end of chunk
4928                 if ((@rem || @add) && (!$class || $class eq 'ctx')) {
4929                         if (!@add) {
4930                                 # pure removal
4931                                 print join '',
4932                                         '<div class="chunk_block rem">',
4933                                                 '<div class="old">',
4934                                                 @rem,
4935                                                 '</div>',
4936                                         '</div>';
4937                         } elsif (!@rem) {
4938                                 # pure addition
4939                                 print join '',
4940                                         '<div class="chunk_block add">',
4941                                                 '<div class="new">',
4942                                                 @add,
4943                                                 '</div>',
4944                                         '</div>';
4945                         } else {
4946                                 # assume that it is change
4947                                 print join '',
4948                                         '<div class="chunk_block chg">',
4949                                                 '<div class="old">',
4950                                                 @rem,
4951                                                 '</div>',
4952                                                 '<div class="new">',
4953                                                 @add,
4954                                                 '</div>',
4955                                         '</div>';
4956                         }
4957                         @rem = @add = ();
4958                 }
4959
4960                 ## adding lines to accumulator
4961                 # guardian value
4962                 last unless $line;
4963                 # rem, add or change
4964                 if ($class eq 'rem') {
4965                         push @rem, $line;
4966                 } elsif ($class eq 'add') {
4967                         push @add, $line;
4968                 }
4969                 # context line
4970                 if ($class eq 'ctx') {
4971                         push @ctx, $line;
4972                 }
4973         }
4974 }
4975
4976 sub git_patchset_body {
4977         my ($fd, $diff_style, $difftree, $hash, @hash_parents) = @_;
4978         my ($hash_parent) = $hash_parents[0];
4979
4980         my $is_combined = (@hash_parents > 1);
4981         my $patch_idx = 0;
4982         my $patch_number = 0;
4983         my $patch_line;
4984         my $diffinfo;
4985         my $to_name;
4986         my (%from, %to);
4987         my @chunk; # for side-by-side diff
4988
4989         print "<div class=\"patchset\">\n";
4990
4991         # skip to first patch
4992         while ($patch_line = <$fd>) {
4993                 chomp $patch_line;
4994
4995                 last if ($patch_line =~ m/^diff /);
4996         }
4997
4998  PATCH:
4999         while ($patch_line) {
5000
5001                 # parse "git diff" header line
5002                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
5003                         # $1 is from_name, which we do not use
5004                         $to_name = unquote($2);
5005                         $to_name =~ s!^b/!!;
5006                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
5007                         # $1 is 'cc' or 'combined', which we do not use
5008                         $to_name = unquote($2);
5009                 } else {
5010                         $to_name = undef;
5011                 }
5012
5013                 # check if current patch belong to current raw line
5014                 # and parse raw git-diff line if needed
5015                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
5016                         # this is continuation of a split patch
5017                         print "<div class=\"patch cont\">\n";
5018                 } else {
5019                         # advance raw git-diff output if needed
5020                         $patch_idx++ if defined $diffinfo;
5021
5022                         # read and prepare patch information
5023                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5024
5025                         # compact combined diff output can have some patches skipped
5026                         # find which patch (using pathname of result) we are at now;
5027                         if ($is_combined) {
5028                                 while ($to_name ne $diffinfo->{'to_file'}) {
5029                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5030                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
5031                                               "</div>\n";  # class="patch"
5032
5033                                         $patch_idx++;
5034                                         $patch_number++;
5035
5036                                         last if $patch_idx > $#$difftree;
5037                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5038                                 }
5039                         }
5040
5041                         # modifies %from, %to hashes
5042                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
5043
5044                         # this is first patch for raw difftree line with $patch_idx index
5045                         # we index @$difftree array from 0, but number patches from 1
5046                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
5047                 }
5048
5049                 # git diff header
5050                 #assert($patch_line =~ m/^diff /) if DEBUG;
5051                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
5052                 $patch_number++;
5053                 # print "git diff" header
5054                 print format_git_diff_header_line($patch_line, $diffinfo,
5055                                                   \%from, \%to);
5056
5057                 # print extended diff header
5058                 print "<div class=\"diff extended_header\">\n";
5059         EXTENDED_HEADER:
5060                 while ($patch_line = <$fd>) {
5061                         chomp $patch_line;
5062
5063                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
5064
5065                         print format_extended_diff_header_line($patch_line, $diffinfo,
5066                                                                \%from, \%to);
5067                 }
5068                 print "</div>\n"; # class="diff extended_header"
5069
5070                 # from-file/to-file diff header
5071                 if (! $patch_line) {
5072                         print "</div>\n"; # class="patch"
5073                         last PATCH;
5074                 }
5075                 next PATCH if ($patch_line =~ m/^diff /);
5076                 #assert($patch_line =~ m/^---/) if DEBUG;
5077
5078                 my $last_patch_line = $patch_line;
5079                 $patch_line = <$fd>;
5080                 chomp $patch_line;
5081                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
5082
5083                 print format_diff_from_to_header($last_patch_line, $patch_line,
5084                                                  $diffinfo, \%from, \%to,
5085                                                  @hash_parents);
5086
5087                 # the patch itself
5088         LINE:
5089                 while ($patch_line = <$fd>) {
5090                         chomp $patch_line;
5091
5092                         next PATCH if ($patch_line =~ m/^diff /);
5093
5094                         my ($class, $line) = process_diff_line($patch_line, \%from, \%to);
5095                         my $diff_classes = "diff";
5096                         $diff_classes .= " $class" if ($class);
5097                         $line = "<div class=\"$diff_classes\">$line</div>\n";
5098
5099                         if ($diff_style eq 'sidebyside' && !$is_combined) {
5100                                 if ($class eq 'chunk_header') {
5101                                         print_sidebyside_diff_chunk(@chunk);
5102                                         @chunk = ( [ $class, $line ] );
5103                                 } else {
5104                                         push @chunk, [ $class, $line ];
5105                                 }
5106                         } else {
5107                                 # default 'inline' style and unknown styles
5108                                 print $line;
5109                         }
5110                 }
5111
5112         } continue {
5113                 if (@chunk) {
5114                         print_sidebyside_diff_chunk(@chunk);
5115                         @chunk = ();
5116                 }
5117                 print "</div>\n"; # class="patch"
5118         }
5119
5120         # for compact combined (--cc) format, with chunk and patch simplification
5121         # the patchset might be empty, but there might be unprocessed raw lines
5122         for (++$patch_idx if $patch_number > 0;
5123              $patch_idx < @$difftree;
5124              ++$patch_idx) {
5125                 # read and prepare patch information
5126                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5127
5128                 # generate anchor for "patch" links in difftree / whatchanged part
5129                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5130                       format_diff_cc_simplified($diffinfo, @hash_parents) .
5131                       "</div>\n";  # class="patch"
5132
5133                 $patch_number++;
5134         }
5135
5136         if ($patch_number == 0) {
5137                 if (@hash_parents > 1) {
5138                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
5139                 } else {
5140                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
5141                 }
5142         }
5143
5144         print "</div>\n"; # class="patchset"
5145 }
5146
5147 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
5148
5149 # fills project list info (age, description, owner, category, forks)
5150 # for each project in the list, removing invalid projects from
5151 # returned list
5152 # NOTE: modifies $projlist, but does not remove entries from it
5153 sub fill_project_list_info {
5154         my $projlist = shift;
5155         my @projects;
5156
5157         my $show_ctags = gitweb_check_feature('ctags');
5158  PROJECT:
5159         foreach my $pr (@$projlist) {
5160                 my (@activity) = git_get_last_activity($pr->{'path'});
5161                 unless (@activity) {
5162                         next PROJECT;
5163                 }
5164                 ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5165                 if (!defined $pr->{'descr'}) {
5166                         my $descr = git_get_project_description($pr->{'path'}) || "";
5167                         $descr = to_utf8($descr);
5168                         $pr->{'descr_long'} = $descr;
5169                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5170                 }
5171                 if (!defined $pr->{'owner'}) {
5172                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5173                 }
5174                 if ($show_ctags) {
5175                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5176                 }
5177                 if ($projects_list_group_categories && !defined $pr->{'category'}) {
5178                         my $cat = git_get_project_category($pr->{'path'}) ||
5179                                                            $project_list_default_category;
5180                         $pr->{'category'} = to_utf8($cat);
5181                 }
5182
5183                 push @projects, $pr;
5184         }
5185
5186         return @projects;
5187 }
5188
5189 sub sort_projects_list {
5190         my ($projlist, $order) = @_;
5191         my @projects;
5192
5193         my %order_info = (
5194                 project => { key => 'path', type => 'str' },
5195                 descr => { key => 'descr_long', type => 'str' },
5196                 owner => { key => 'owner', type => 'str' },
5197                 age => { key => 'age', type => 'num' }
5198         );
5199         my $oi = $order_info{$order};
5200         return @$projlist unless defined $oi;
5201         if ($oi->{'type'} eq 'str') {
5202                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @$projlist;
5203         } else {
5204                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @$projlist;
5205         }
5206
5207         return @projects;
5208 }
5209
5210 # returns a hash of categories, containing the list of project
5211 # belonging to each category
5212 sub build_projlist_by_category {
5213         my ($projlist, $from, $to) = @_;
5214         my %categories;
5215
5216         $from = 0 unless defined $from;
5217         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5218
5219         for (my $i = $from; $i <= $to; $i++) {
5220                 my $pr = $projlist->[$i];
5221                 push @{$categories{ $pr->{'category'} }}, $pr;
5222         }
5223
5224         return wantarray ? %categories : \%categories;
5225 }
5226
5227 # print 'sort by' <th> element, generating 'sort by $name' replay link
5228 # if that order is not selected
5229 sub print_sort_th {
5230         print format_sort_th(@_);
5231 }
5232
5233 sub format_sort_th {
5234         my ($name, $order, $header) = @_;
5235         my $sort_th = "";
5236         $header ||= ucfirst($name);
5237
5238         if ($order eq $name) {
5239                 $sort_th .= "<th>$header</th>\n";
5240         } else {
5241                 $sort_th .= "<th>" .
5242                             $cgi->a({-href => href(-replay=>1, order=>$name),
5243                                      -class => "header"}, $header) .
5244                             "</th>\n";
5245         }
5246
5247         return $sort_th;
5248 }
5249
5250 sub git_project_list_rows {
5251         my ($projlist, $from, $to, $check_forks) = @_;
5252
5253         $from = 0 unless defined $from;
5254         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5255
5256         my $alternate = 1;
5257         for (my $i = $from; $i <= $to; $i++) {
5258                 my $pr = $projlist->[$i];
5259
5260                 if ($alternate) {
5261                         print "<tr class=\"dark\">\n";
5262                 } else {
5263                         print "<tr class=\"light\">\n";
5264                 }
5265                 $alternate ^= 1;
5266
5267                 if ($check_forks) {
5268                         print "<td>";
5269                         if ($pr->{'forks'}) {
5270                                 my $nforks = scalar @{$pr->{'forks'}};
5271                                 if ($nforks > 0) {
5272                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5273                                                        -title => "$nforks forks"}, "+");
5274                                 } else {
5275                                         print $cgi->span({-title => "$nforks forks"}, "+");
5276                                 }
5277                         }
5278                         print "</td>\n";
5279                 }
5280                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5281                                         -class => "list"}, esc_html($pr->{'path'})) . "</td>\n" .
5282                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5283                                         -class => "list", -title => $pr->{'descr_long'}},
5284                                         esc_html($pr->{'descr'})) . "</td>\n" .
5285                       "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5286                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5287                       (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n" .
5288                       "<td class=\"link\">" .
5289                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5290                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5291                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5292                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5293                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5294                       "</td>\n" .
5295                       "</tr>\n";
5296         }
5297 }
5298
5299 sub git_project_list_body {
5300         # actually uses global variable $project
5301         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5302         my @projects = @$projlist;
5303
5304         my $check_forks = gitweb_check_feature('forks');
5305         my $show_ctags  = gitweb_check_feature('ctags');
5306         my $tagfilter = $show_ctags ? $cgi->param('by_tag') : undef;
5307         $check_forks = undef
5308                 if ($tagfilter || $searchtext);
5309
5310         # filtering out forks before filling info allows to do less work
5311         @projects = filter_forks_from_projects_list(\@projects)
5312                 if ($check_forks);
5313         @projects = fill_project_list_info(\@projects);
5314         # searching projects require filling to be run before it
5315         @projects = search_projects_list(\@projects,
5316                                          'searchtext' => $searchtext,
5317                                          'tagfilter'  => $tagfilter)
5318                 if ($tagfilter || $searchtext);
5319
5320         $order ||= $default_projects_order;
5321         $from = 0 unless defined $from;
5322         $to = $#projects if (!defined $to || $#projects < $to);
5323
5324         # short circuit
5325         if ($from > $to) {
5326                 print "<center>\n".
5327                       "<b>No such projects found</b><br />\n".
5328                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5329                       "</center>\n<br />\n";
5330                 return;
5331         }
5332
5333         @projects = sort_projects_list(\@projects, $order);
5334
5335         if ($show_ctags) {
5336                 my $ctags = git_gather_all_ctags(\@projects);
5337                 my $cloud = git_populate_project_tagcloud($ctags);
5338                 print git_show_project_tagcloud($cloud, 64);
5339         }
5340
5341         print "<table class=\"project_list\">\n";
5342         unless ($no_header) {
5343                 print "<tr>\n";
5344                 if ($check_forks) {
5345                         print "<th></th>\n";
5346                 }
5347                 print_sort_th('project', $order, 'Project');
5348                 print_sort_th('descr', $order, 'Description');
5349                 print_sort_th('owner', $order, 'Owner');
5350                 print_sort_th('age', $order, 'Last Change');
5351                 print "<th></th>\n" . # for links
5352                       "</tr>\n";
5353         }
5354
5355         if ($projects_list_group_categories) {
5356                 # only display categories with projects in the $from-$to window
5357                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5358                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5359                 foreach my $cat (sort keys %categories) {
5360                         unless ($cat eq "") {
5361                                 print "<tr>\n";
5362                                 if ($check_forks) {
5363                                         print "<td></td>\n";
5364                                 }
5365                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5366                                 print "</tr>\n";
5367                         }
5368
5369                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5370                 }
5371         } else {
5372                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5373         }
5374
5375         if (defined $extra) {
5376                 print "<tr>\n";
5377                 if ($check_forks) {
5378                         print "<td></td>\n";
5379                 }
5380                 print "<td colspan=\"5\">$extra</td>\n" .
5381                       "</tr>\n";
5382         }
5383         print "</table>\n";
5384 }
5385
5386 sub git_log_body {
5387         # uses global variable $project
5388         my ($commitlist, $from, $to, $refs, $extra) = @_;
5389
5390         $from = 0 unless defined $from;
5391         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5392
5393         for (my $i = 0; $i <= $to; $i++) {
5394                 my %co = %{$commitlist->[$i]};
5395                 next if !%co;
5396                 my $commit = $co{'id'};
5397                 my $ref = format_ref_marker($refs, $commit);
5398                 git_print_header_div('commit',
5399                                "<span class=\"age\">$co{'age_string'}</span>" .
5400                                esc_html($co{'title'}) . $ref,
5401                                $commit);
5402                 print "<div class=\"title_text\">\n" .
5403                       "<div class=\"log_link\">\n" .
5404                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5405                       " | " .
5406                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5407                       " | " .
5408                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5409                       "<br/>\n" .
5410                       "</div>\n";
5411                       git_print_authorship(\%co, -tag => 'span');
5412                       print "<br/>\n</div>\n";
5413
5414                 print "<div class=\"log_body\">\n";
5415                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5416                 print "</div>\n";
5417         }
5418         if ($extra) {
5419                 print "<div class=\"page_nav\">\n";
5420                 print "$extra\n";
5421                 print "</div>\n";
5422         }
5423 }
5424
5425 sub git_shortlog_body {
5426         # uses global variable $project
5427         my ($commitlist, $from, $to, $refs, $extra) = @_;
5428
5429         $from = 0 unless defined $from;
5430         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5431
5432         print "<table class=\"shortlog\">\n";
5433         my $alternate = 1;
5434         for (my $i = $from; $i <= $to; $i++) {
5435                 my %co = %{$commitlist->[$i]};
5436                 my $commit = $co{'id'};
5437                 my $ref = format_ref_marker($refs, $commit);
5438                 if ($alternate) {
5439                         print "<tr class=\"dark\">\n";
5440                 } else {
5441                         print "<tr class=\"light\">\n";
5442                 }
5443                 $alternate ^= 1;
5444                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5445                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5446                       format_author_html('td', \%co, 10) . "<td>";
5447                 print format_subject_html($co{'title'}, $co{'title_short'},
5448                                           href(action=>"commit", hash=>$commit), $ref);
5449                 print "</td>\n" .
5450                       "<td class=\"link\">" .
5451                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5452                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5453                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5454                 my $snapshot_links = format_snapshot_links($commit);
5455                 if (defined $snapshot_links) {
5456                         print " | " . $snapshot_links;
5457                 }
5458                 print "</td>\n" .
5459                       "</tr>\n";
5460         }
5461         if (defined $extra) {
5462                 print "<tr>\n" .
5463                       "<td colspan=\"4\">$extra</td>\n" .
5464                       "</tr>\n";
5465         }
5466         print "</table>\n";
5467 }
5468
5469 sub git_history_body {
5470         # Warning: assumes constant type (blob or tree) during history
5471         my ($commitlist, $from, $to, $refs, $extra,
5472             $file_name, $file_hash, $ftype) = @_;
5473
5474         $from = 0 unless defined $from;
5475         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5476
5477         print "<table class=\"history\">\n";
5478         my $alternate = 1;
5479         for (my $i = $from; $i <= $to; $i++) {
5480                 my %co = %{$commitlist->[$i]};
5481                 if (!%co) {
5482                         next;
5483                 }
5484                 my $commit = $co{'id'};
5485
5486                 my $ref = format_ref_marker($refs, $commit);
5487
5488                 if ($alternate) {
5489                         print "<tr class=\"dark\">\n";
5490                 } else {
5491                         print "<tr class=\"light\">\n";
5492                 }
5493                 $alternate ^= 1;
5494                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5495         # shortlog:   format_author_html('td', \%co, 10)
5496                       format_author_html('td', \%co, 15, 3) . "<td>";
5497                 # originally git_history used chop_str($co{'title'}, 50)
5498                 print format_subject_html($co{'title'}, $co{'title_short'},
5499                                           href(action=>"commit", hash=>$commit), $ref);
5500                 print "</td>\n" .
5501                       "<td class=\"link\">" .
5502                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5503                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5504
5505                 if ($ftype eq 'blob') {
5506                         my $blob_current = $file_hash;
5507                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5508                         if (defined $blob_current && defined $blob_parent &&
5509                                         $blob_current ne $blob_parent) {
5510                                 print " | " .
5511                                         $cgi->a({-href => href(action=>"blobdiff",
5512                                                                hash=>$blob_current, hash_parent=>$blob_parent,
5513                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
5514                                                                file_name=>$file_name)},
5515                                                 "diff to current");
5516                         }
5517                 }
5518                 print "</td>\n" .
5519                       "</tr>\n";
5520         }
5521         if (defined $extra) {
5522                 print "<tr>\n" .
5523                       "<td colspan=\"4\">$extra</td>\n" .
5524                       "</tr>\n";
5525         }
5526         print "</table>\n";
5527 }
5528
5529 sub git_tags_body {
5530         # uses global variable $project
5531         my ($taglist, $from, $to, $extra) = @_;
5532         $from = 0 unless defined $from;
5533         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
5534
5535         print "<table class=\"tags\">\n";
5536         my $alternate = 1;
5537         for (my $i = $from; $i <= $to; $i++) {
5538                 my $entry = $taglist->[$i];
5539                 my %tag = %$entry;
5540                 my $comment = $tag{'subject'};
5541                 my $comment_short;
5542                 if (defined $comment) {
5543                         $comment_short = chop_str($comment, 30, 5);
5544                 }
5545                 if ($alternate) {
5546                         print "<tr class=\"dark\">\n";
5547                 } else {
5548                         print "<tr class=\"light\">\n";
5549                 }
5550                 $alternate ^= 1;
5551                 if (defined $tag{'age'}) {
5552                         print "<td><i>$tag{'age'}</i></td>\n";
5553                 } else {
5554                         print "<td></td>\n";
5555                 }
5556                 print "<td>" .
5557                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
5558                                -class => "list name"}, esc_html($tag{'name'})) .
5559                       "</td>\n" .
5560                       "<td>";
5561                 if (defined $comment) {
5562                         print format_subject_html($comment, $comment_short,
5563                                                   href(action=>"tag", hash=>$tag{'id'}));
5564                 }
5565                 print "</td>\n" .
5566                       "<td class=\"selflink\">";
5567                 if ($tag{'type'} eq "tag") {
5568                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
5569                 } else {
5570                         print "&nbsp;";
5571                 }
5572                 print "</td>\n" .
5573                       "<td class=\"link\">" . " | " .
5574                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
5575                 if ($tag{'reftype'} eq "commit") {
5576                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
5577                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
5578                 } elsif ($tag{'reftype'} eq "blob") {
5579                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
5580                 }
5581                 print "</td>\n" .
5582                       "</tr>";
5583         }
5584         if (defined $extra) {
5585                 print "<tr>\n" .
5586                       "<td colspan=\"5\">$extra</td>\n" .
5587                       "</tr>\n";
5588         }
5589         print "</table>\n";
5590 }
5591
5592 sub git_heads_body {
5593         # uses global variable $project
5594         my ($headlist, $head, $from, $to, $extra) = @_;
5595         $from = 0 unless defined $from;
5596         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
5597
5598         print "<table class=\"heads\">\n";
5599         my $alternate = 1;
5600         for (my $i = $from; $i <= $to; $i++) {
5601                 my $entry = $headlist->[$i];
5602                 my %ref = %$entry;
5603                 my $curr = $ref{'id'} eq $head;
5604                 if ($alternate) {
5605                         print "<tr class=\"dark\">\n";
5606                 } else {
5607                         print "<tr class=\"light\">\n";
5608                 }
5609                 $alternate ^= 1;
5610                 print "<td><i>$ref{'age'}</i></td>\n" .
5611                       ($curr ? "<td class=\"current_head\">" : "<td>") .
5612                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
5613                                -class => "list name"},esc_html($ref{'name'})) .
5614                       "</td>\n" .
5615                       "<td class=\"link\">" .
5616                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
5617                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
5618                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
5619                       "</td>\n" .
5620                       "</tr>";
5621         }
5622         if (defined $extra) {
5623                 print "<tr>\n" .
5624                       "<td colspan=\"3\">$extra</td>\n" .
5625                       "</tr>\n";
5626         }
5627         print "</table>\n";
5628 }
5629
5630 # Display a single remote block
5631 sub git_remote_block {
5632         my ($remote, $rdata, $limit, $head) = @_;
5633
5634         my $heads = $rdata->{'heads'};
5635         my $fetch = $rdata->{'fetch'};
5636         my $push = $rdata->{'push'};
5637
5638         my $urls_table = "<table class=\"projects_list\">\n" ;
5639
5640         if (defined $fetch) {
5641                 if ($fetch eq $push) {
5642                         $urls_table .= format_repo_url("URL", $fetch);
5643                 } else {
5644                         $urls_table .= format_repo_url("Fetch URL", $fetch);
5645                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
5646                 }
5647         } elsif (defined $push) {
5648                 $urls_table .= format_repo_url("Push URL", $push);
5649         } else {
5650                 $urls_table .= format_repo_url("", "No remote URL");
5651         }
5652
5653         $urls_table .= "</table>\n";
5654
5655         my $dots;
5656         if (defined $limit && $limit < @$heads) {
5657                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
5658         }
5659
5660         print $urls_table;
5661         git_heads_body($heads, $head, 0, $limit, $dots);
5662 }
5663
5664 # Display a list of remote names with the respective fetch and push URLs
5665 sub git_remotes_list {
5666         my ($remotedata, $limit) = @_;
5667         print "<table class=\"heads\">\n";
5668         my $alternate = 1;
5669         my @remotes = sort keys %$remotedata;
5670
5671         my $limited = $limit && $limit < @remotes;
5672
5673         $#remotes = $limit - 1 if $limited;
5674
5675         while (my $remote = shift @remotes) {
5676                 my $rdata = $remotedata->{$remote};
5677                 my $fetch = $rdata->{'fetch'};
5678                 my $push = $rdata->{'push'};
5679                 if ($alternate) {
5680                         print "<tr class=\"dark\">\n";
5681                 } else {
5682                         print "<tr class=\"light\">\n";
5683                 }
5684                 $alternate ^= 1;
5685                 print "<td>" .
5686                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
5687                                -class=> "list name"},esc_html($remote)) .
5688                       "</td>";
5689                 print "<td class=\"link\">" .
5690                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
5691                       " | " .
5692                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
5693                       "</td>";
5694
5695                 print "</tr>\n";
5696         }
5697
5698         if ($limited) {
5699                 print "<tr>\n" .
5700                       "<td colspan=\"3\">" .
5701                       $cgi->a({-href => href(action=>"remotes")}, "...") .
5702                       "</td>\n" . "</tr>\n";
5703         }
5704
5705         print "</table>";
5706 }
5707
5708 # Display remote heads grouped by remote, unless there are too many
5709 # remotes, in which case we only display the remote names
5710 sub git_remotes_body {
5711         my ($remotedata, $limit, $head) = @_;
5712         if ($limit and $limit < keys %$remotedata) {
5713                 git_remotes_list($remotedata, $limit);
5714         } else {
5715                 fill_remote_heads($remotedata);
5716                 while (my ($remote, $rdata) = each %$remotedata) {
5717                         git_print_section({-class=>"remote", -id=>$remote},
5718                                 ["remotes", $remote, $remote], sub {
5719                                         git_remote_block($remote, $rdata, $limit, $head);
5720                                 });
5721                 }
5722         }
5723 }
5724
5725 sub git_search_message {
5726         my %co = @_;
5727
5728         my $greptype;
5729         if ($searchtype eq 'commit') {
5730                 $greptype = "--grep=";
5731         } elsif ($searchtype eq 'author') {
5732                 $greptype = "--author=";
5733         } elsif ($searchtype eq 'committer') {
5734                 $greptype = "--committer=";
5735         }
5736         $greptype .= $searchtext;
5737         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
5738                                        $greptype, '--regexp-ignore-case',
5739                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
5740
5741         my $paging_nav = '';
5742         if ($page > 0) {
5743                 $paging_nav .=
5744                         $cgi->a({-href => href(-replay=>1, page=>undef)},
5745                                 "first") .
5746                         " &sdot; " .
5747                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
5748                                  -accesskey => "p", -title => "Alt-p"}, "prev");
5749         } else {
5750                 $paging_nav .= "first &sdot; prev";
5751         }
5752         my $next_link = '';
5753         if ($#commitlist >= 100) {
5754                 $next_link =
5755                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
5756                                  -accesskey => "n", -title => "Alt-n"}, "next");
5757                 $paging_nav .= " &sdot; $next_link";
5758         } else {
5759                 $paging_nav .= " &sdot; next";
5760         }
5761
5762         git_header_html();
5763
5764         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
5765         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5766         if ($page == 0 && !@commitlist) {
5767                 print "<p>No match.</p>\n";
5768         } else {
5769                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
5770         }
5771
5772         git_footer_html();
5773 }
5774
5775 sub git_search_changes {
5776         my %co = @_;
5777
5778         local $/ = "\n";
5779         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
5780                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
5781                 ($search_use_regexp ? '--pickaxe-regex' : ())
5782                         or die_error(500, "Open git-log failed");
5783
5784         git_header_html();
5785
5786         git_print_page_nav('','', $hash,$co{'tree'},$hash);
5787         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5788
5789         print "<table class=\"pickaxe search\">\n";
5790         my $alternate = 1;
5791         undef %co;
5792         my @files;
5793         while (my $line = <$fd>) {
5794                 chomp $line;
5795                 next unless $line;
5796
5797                 my %set = parse_difftree_raw_line($line);
5798                 if (defined $set{'commit'}) {
5799                         # finish previous commit
5800                         if (%co) {
5801                                 print "</td>\n" .
5802                                       "<td class=\"link\">" .
5803                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
5804                                               "commit") .
5805                                       " | " .
5806                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
5807                                                              hash_base=>$co{'id'})},
5808                                               "tree") .
5809                                       "</td>\n" .
5810                                       "</tr>\n";
5811                         }
5812
5813                         if ($alternate) {
5814                                 print "<tr class=\"dark\">\n";
5815                         } else {
5816                                 print "<tr class=\"light\">\n";
5817                         }
5818                         $alternate ^= 1;
5819                         %co = parse_commit($set{'commit'});
5820                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
5821                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5822                               "<td><i>$author</i></td>\n" .
5823                               "<td>" .
5824                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
5825                                       -class => "list subject"},
5826                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
5827                 } elsif (defined $set{'to_id'}) {
5828                         next if ($set{'to_id'} =~ m/^0{40}$/);
5829
5830                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
5831                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
5832                                       -class => "list"},
5833                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
5834                               "<br/>\n";
5835                 }
5836         }
5837         close $fd;
5838
5839         # finish last commit (warning: repetition!)
5840         if (%co) {
5841                 print "</td>\n" .
5842                       "<td class=\"link\">" .
5843                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
5844                               "commit") .
5845                       " | " .
5846                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
5847                                              hash_base=>$co{'id'})},
5848                               "tree") .
5849                       "</td>\n" .
5850                       "</tr>\n";
5851         }
5852
5853         print "</table>\n";
5854
5855         git_footer_html();
5856 }
5857
5858 sub git_search_files {
5859         my %co = @_;
5860
5861         local $/ = "\n";
5862         open my $fd, "-|", git_cmd(), 'grep', '-n', '-z',
5863                 $search_use_regexp ? ('-E', '-i') : '-F',
5864                 $searchtext, $co{'tree'}
5865                         or die_error(500, "Open git-grep failed");
5866
5867         git_header_html();
5868
5869         git_print_page_nav('','', $hash,$co{'tree'},$hash);
5870         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5871
5872         print "<table class=\"grep_search\">\n";
5873         my $alternate = 1;
5874         my $matches = 0;
5875         my $lastfile = '';
5876         while (my $line = <$fd>) {
5877                 chomp $line;
5878                 my ($file, $file_href, $lno, $ltext, $binary);
5879                 last if ($matches++ > 1000);
5880                 if ($line =~ /^Binary file (.+) matches$/) {
5881                         $file = $1;
5882                         $binary = 1;
5883                 } else {
5884                         ($file, $lno, $ltext) = split(/\0/, $line, 3);
5885                         $file =~ s/^$co{'tree'}://;
5886                 }
5887                 if ($file ne $lastfile) {
5888                         $lastfile and print "</td></tr>\n";
5889                         if ($alternate++) {
5890                                 print "<tr class=\"dark\">\n";
5891                         } else {
5892                                 print "<tr class=\"light\">\n";
5893                         }
5894                         $file_href = href(action=>"blob", hash_base=>$co{'id'},
5895                                           file_name=>$file);
5896                         print "<td class=\"list\">".
5897                                 $cgi->a({-href => $file_href, -class => "list"}, esc_path($file));
5898                         print "</td><td>\n";
5899                         $lastfile = $file;
5900                 }
5901                 if ($binary) {
5902                         print "<div class=\"binary\">Binary file</div>\n";
5903                 } else {
5904                         $ltext = untabify($ltext);
5905                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
5906                                 $ltext = esc_html($1, -nbsp=>1);
5907                                 $ltext .= '<span class="match">';
5908                                 $ltext .= esc_html($2, -nbsp=>1);
5909                                 $ltext .= '</span>';
5910                                 $ltext .= esc_html($3, -nbsp=>1);
5911                         } else {
5912                                 $ltext = esc_html($ltext, -nbsp=>1);
5913                         }
5914                         print "<div class=\"pre\">" .
5915                                 $cgi->a({-href => $file_href.'#l'.$lno,
5916                                         -class => "linenr"}, sprintf('%4i', $lno)) .
5917                                 ' ' .  $ltext . "</div>\n";
5918                 }
5919         }
5920         if ($lastfile) {
5921                 print "</td></tr>\n";
5922                 if ($matches > 1000) {
5923                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
5924                 }
5925         } else {
5926                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
5927         }
5928         close $fd;
5929
5930         print "</table>\n";
5931
5932         git_footer_html();
5933 }
5934
5935 sub git_search_grep_body {
5936         my ($commitlist, $from, $to, $extra) = @_;
5937         $from = 0 unless defined $from;
5938         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5939
5940         print "<table class=\"commit_search\">\n";
5941         my $alternate = 1;
5942         for (my $i = $from; $i <= $to; $i++) {
5943                 my %co = %{$commitlist->[$i]};
5944                 if (!%co) {
5945                         next;
5946                 }
5947                 my $commit = $co{'id'};
5948                 if ($alternate) {
5949                         print "<tr class=\"dark\">\n";
5950                 } else {
5951                         print "<tr class=\"light\">\n";
5952                 }
5953                 $alternate ^= 1;
5954                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5955                       format_author_html('td', \%co, 15, 5) .
5956                       "<td>" .
5957                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
5958                                -class => "list subject"},
5959                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
5960                 my $comment = $co{'comment'};
5961                 foreach my $line (@$comment) {
5962                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
5963                                 my ($lead, $match, $trail) = ($1, $2, $3);
5964                                 $match = chop_str($match, 70, 5, 'center');
5965                                 my $contextlen = int((80 - length($match))/2);
5966                                 $contextlen = 30 if ($contextlen > 30);
5967                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
5968                                 $trail = chop_str($trail, $contextlen, 10, 'right');
5969
5970                                 $lead  = esc_html($lead);
5971                                 $match = esc_html($match);
5972                                 $trail = esc_html($trail);
5973
5974                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
5975                         }
5976                 }
5977                 print "</td>\n" .
5978                       "<td class=\"link\">" .
5979                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
5980                       " | " .
5981                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
5982                       " | " .
5983                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
5984                 print "</td>\n" .
5985                       "</tr>\n";
5986         }
5987         if (defined $extra) {
5988                 print "<tr>\n" .
5989                       "<td colspan=\"3\">$extra</td>\n" .
5990                       "</tr>\n";
5991         }
5992         print "</table>\n";
5993 }
5994
5995 ## ======================================================================
5996 ## ======================================================================
5997 ## actions
5998
5999 sub git_project_list {
6000         my $order = $input_params{'order'};
6001         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6002                 die_error(400, "Unknown order parameter");
6003         }
6004
6005         my @list = git_get_projects_list();
6006         if (!@list) {
6007                 die_error(404, "No projects found");
6008         }
6009
6010         git_header_html();
6011         if (defined $home_text && -f $home_text) {
6012                 print "<div class=\"index_include\">\n";
6013                 insert_file($home_text);
6014                 print "</div>\n";
6015         }
6016         print $cgi->startform(-method => "get") .
6017               "<p class=\"projsearch\">Search:\n" .
6018               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
6019               "</p>" .
6020               $cgi->end_form() . "\n";
6021         git_project_list_body(\@list, $order);
6022         git_footer_html();
6023 }
6024
6025 sub git_forks {
6026         my $order = $input_params{'order'};
6027         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6028                 die_error(400, "Unknown order parameter");
6029         }
6030
6031         my @list = git_get_projects_list($project);
6032         if (!@list) {
6033                 die_error(404, "No forks found");
6034         }
6035
6036         git_header_html();
6037         git_print_page_nav('','');
6038         git_print_header_div('summary', "$project forks");
6039         git_project_list_body(\@list, $order);
6040         git_footer_html();
6041 }
6042
6043 sub git_project_index {
6044         my @projects = git_get_projects_list();
6045         if (!@projects) {
6046                 die_error(404, "No projects found");
6047         }
6048
6049         print $cgi->header(
6050                 -type => 'text/plain',
6051                 -charset => 'utf-8',
6052                 -content_disposition => 'inline; filename="index.aux"');
6053
6054         foreach my $pr (@projects) {
6055                 if (!exists $pr->{'owner'}) {
6056                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
6057                 }
6058
6059                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
6060                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
6061                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6062                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6063                 $path  =~ s/ /\+/g;
6064                 $owner =~ s/ /\+/g;
6065
6066                 print "$path $owner\n";
6067         }
6068 }
6069
6070 sub git_summary {
6071         my $descr = git_get_project_description($project) || "none";
6072         my %co = parse_commit("HEAD");
6073         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
6074         my $head = $co{'id'};
6075         my $remote_heads = gitweb_check_feature('remote_heads');
6076
6077         my $owner = git_get_project_owner($project);
6078
6079         my $refs = git_get_references();
6080         # These get_*_list functions return one more to allow us to see if
6081         # there are more ...
6082         my @taglist  = git_get_tags_list(16);
6083         my @headlist = git_get_heads_list(16);
6084         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
6085         my @forklist;
6086         my $check_forks = gitweb_check_feature('forks');
6087
6088         if ($check_forks) {
6089                 # find forks of a project
6090                 @forklist = git_get_projects_list($project);
6091                 # filter out forks of forks
6092                 @forklist = filter_forks_from_projects_list(\@forklist)
6093                         if (@forklist);
6094         }
6095
6096         git_header_html();
6097         git_print_page_nav('summary','', $head);
6098
6099         print "<div class=\"title\">&nbsp;</div>\n";
6100         print "<table class=\"projects_list\">\n" .
6101               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
6102               "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
6103         if (defined $cd{'rfc2822'}) {
6104                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
6105                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
6106         }
6107
6108         # use per project git URL list in $projectroot/$project/cloneurl
6109         # or make project git URL from git base URL and project name
6110         my $url_tag = "URL";
6111         my @url_list = git_get_project_url_list($project);
6112         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
6113         foreach my $git_url (@url_list) {
6114                 next unless $git_url;
6115                 print format_repo_url($url_tag, $git_url);
6116                 $url_tag = "";
6117         }
6118
6119         # Tag cloud
6120         my $show_ctags = gitweb_check_feature('ctags');
6121         if ($show_ctags) {
6122                 my $ctags = git_get_project_ctags($project);
6123                 if (%$ctags) {
6124                         # without ability to add tags, don't show if there are none
6125                         my $cloud = git_populate_project_tagcloud($ctags);
6126                         print "<tr id=\"metadata_ctags\">" .
6127                               "<td>content tags</td>" .
6128                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
6129                               "</tr>\n";
6130                 }
6131         }
6132
6133         print "</table>\n";
6134
6135         # If XSS prevention is on, we don't include README.html.
6136         # TODO: Allow a readme in some safe format.
6137         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
6138                 print "<div class=\"title\">readme</div>\n" .
6139                       "<div class=\"readme\">\n";
6140                 insert_file("$projectroot/$project/README.html");
6141                 print "\n</div>\n"; # class="readme"
6142         }
6143
6144         # we need to request one more than 16 (0..15) to check if
6145         # those 16 are all
6146         my @commitlist = $head ? parse_commits($head, 17) : ();
6147         if (@commitlist) {
6148                 git_print_header_div('shortlog');
6149                 git_shortlog_body(\@commitlist, 0, 15, $refs,
6150                                   $#commitlist <=  15 ? undef :
6151                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
6152         }
6153
6154         if (@taglist) {
6155                 git_print_header_div('tags');
6156                 git_tags_body(\@taglist, 0, 15,
6157                               $#taglist <=  15 ? undef :
6158                               $cgi->a({-href => href(action=>"tags")}, "..."));
6159         }
6160
6161         if (@headlist) {
6162                 git_print_header_div('heads');
6163                 git_heads_body(\@headlist, $head, 0, 15,
6164                                $#headlist <= 15 ? undef :
6165                                $cgi->a({-href => href(action=>"heads")}, "..."));
6166         }
6167
6168         if (%remotedata) {
6169                 git_print_header_div('remotes');
6170                 git_remotes_body(\%remotedata, 15, $head);
6171         }
6172
6173         if (@forklist) {
6174                 git_print_header_div('forks');
6175                 git_project_list_body(\@forklist, 'age', 0, 15,
6176                                       $#forklist <= 15 ? undef :
6177                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6178                                       'no_header');
6179         }
6180
6181         git_footer_html();
6182 }
6183
6184 sub git_tag {
6185         my %tag = parse_tag($hash);
6186
6187         if (! %tag) {
6188                 die_error(404, "Unknown tag object");
6189         }
6190
6191         my $head = git_get_head_hash($project);
6192         git_header_html();
6193         git_print_page_nav('','', $head,undef,$head);
6194         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6195         print "<div class=\"title_text\">\n" .
6196               "<table class=\"object_header\">\n" .
6197               "<tr>\n" .
6198               "<td>object</td>\n" .
6199               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6200                                $tag{'object'}) . "</td>\n" .
6201               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6202                                               $tag{'type'}) . "</td>\n" .
6203               "</tr>\n";
6204         if (defined($tag{'author'})) {
6205                 git_print_authorship_rows(\%tag, 'author');
6206         }
6207         print "</table>\n\n" .
6208               "</div>\n";
6209         print "<div class=\"page_body\">";
6210         my $comment = $tag{'comment'};
6211         foreach my $line (@$comment) {
6212                 chomp $line;
6213                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6214         }
6215         print "</div>\n";
6216         git_footer_html();
6217 }
6218
6219 sub git_blame_common {
6220         my $format = shift || 'porcelain';
6221         if ($format eq 'porcelain' && $cgi->param('js')) {
6222                 $format = 'incremental';
6223                 $action = 'blame_incremental'; # for page title etc
6224         }
6225
6226         # permissions
6227         gitweb_check_feature('blame')
6228                 or die_error(403, "Blame view not allowed");
6229
6230         # error checking
6231         die_error(400, "No file name given") unless $file_name;
6232         $hash_base ||= git_get_head_hash($project);
6233         die_error(404, "Couldn't find base commit") unless $hash_base;
6234         my %co = parse_commit($hash_base)
6235                 or die_error(404, "Commit not found");
6236         my $ftype = "blob";
6237         if (!defined $hash) {
6238                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6239                         or die_error(404, "Error looking up file");
6240         } else {
6241                 $ftype = git_get_type($hash);
6242                 if ($ftype !~ "blob") {
6243                         die_error(400, "Object is not a blob");
6244                 }
6245         }
6246
6247         my $fd;
6248         if ($format eq 'incremental') {
6249                 # get file contents (as base)
6250                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6251                         or die_error(500, "Open git-cat-file failed");
6252         } elsif ($format eq 'data') {
6253                 # run git-blame --incremental
6254                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6255                         $hash_base, "--", $file_name
6256                         or die_error(500, "Open git-blame --incremental failed");
6257         } else {
6258                 # run git-blame --porcelain
6259                 open $fd, "-|", git_cmd(), "blame", '-p',
6260                         $hash_base, '--', $file_name
6261                         or die_error(500, "Open git-blame --porcelain failed");
6262         }
6263
6264         # incremental blame data returns early
6265         if ($format eq 'data') {
6266                 print $cgi->header(
6267                         -type=>"text/plain", -charset => "utf-8",
6268                         -status=> "200 OK");
6269                 local $| = 1; # output autoflush
6270                 while (my $line = <$fd>) {
6271                         print to_utf8($line);
6272                 }
6273                 close $fd
6274                         or print "ERROR $!\n";
6275
6276                 print 'END';
6277                 if (defined $t0 && gitweb_check_feature('timed')) {
6278                         print ' '.
6279                               tv_interval($t0, [ gettimeofday() ]).
6280                               ' '.$number_of_git_cmds;
6281                 }
6282                 print "\n";
6283
6284                 return;
6285         }
6286
6287         # page header
6288         git_header_html();
6289         my $formats_nav =
6290                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6291                         "blob") .
6292                 " | ";
6293         if ($format eq 'incremental') {
6294                 $formats_nav .=
6295                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6296                                 "blame") . " (non-incremental)";
6297         } else {
6298                 $formats_nav .=
6299                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6300                                 "blame") . " (incremental)";
6301         }
6302         $formats_nav .=
6303                 " | " .
6304                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6305                         "history") .
6306                 " | " .
6307                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6308                         "HEAD");
6309         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6310         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6311         git_print_page_path($file_name, $ftype, $hash_base);
6312
6313         # page body
6314         if ($format eq 'incremental') {
6315                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6316                       "This page requires JavaScript to run.\n Use ".
6317                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6318                               'this page').
6319                       " instead.\n".
6320                       "</b></center></div>\n</noscript>\n";
6321
6322                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6323         }
6324
6325         print qq!<div class="page_body">\n!;
6326         print qq!<div id="progress_info">... / ...</div>\n!
6327                 if ($format eq 'incremental');
6328         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6329               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6330               qq!<thead>\n!.
6331               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6332               qq!</thead>\n!.
6333               qq!<tbody>\n!;
6334
6335         my @rev_color = qw(light dark);
6336         my $num_colors = scalar(@rev_color);
6337         my $current_color = 0;
6338
6339         if ($format eq 'incremental') {
6340                 my $color_class = $rev_color[$current_color];
6341
6342                 #contents of a file
6343                 my $linenr = 0;
6344         LINE:
6345                 while (my $line = <$fd>) {
6346                         chomp $line;
6347                         $linenr++;
6348
6349                         print qq!<tr id="l$linenr" class="$color_class">!.
6350                               qq!<td class="sha1"><a href=""> </a></td>!.
6351                               qq!<td class="linenr">!.
6352                               qq!<a class="linenr" href="">$linenr</a></td>!;
6353                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6354                         print qq!</tr>\n!;
6355                 }
6356
6357         } else { # porcelain, i.e. ordinary blame
6358                 my %metainfo = (); # saves information about commits
6359
6360                 # blame data
6361         LINE:
6362                 while (my $line = <$fd>) {
6363                         chomp $line;
6364                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6365                         # no <lines in group> for subsequent lines in group of lines
6366                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6367                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
6368                         if (!exists $metainfo{$full_rev}) {
6369                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6370                         }
6371                         my $meta = $metainfo{$full_rev};
6372                         my $data;
6373                         while ($data = <$fd>) {
6374                                 chomp $data;
6375                                 last if ($data =~ s/^\t//); # contents of line
6376                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6377                                         $meta->{$1} = $2 unless exists $meta->{$1};
6378                                 }
6379                                 if ($data =~ /^previous /) {
6380                                         $meta->{'nprevious'}++;
6381                                 }
6382                         }
6383                         my $short_rev = substr($full_rev, 0, 8);
6384                         my $author = $meta->{'author'};
6385                         my %date =
6386                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6387                         my $date = $date{'iso-tz'};
6388                         if ($group_size) {
6389                                 $current_color = ($current_color + 1) % $num_colors;
6390                         }
6391                         my $tr_class = $rev_color[$current_color];
6392                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6393                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6394                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6395                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6396                         if ($group_size) {
6397                                 print "<td class=\"sha1\"";
6398                                 print " title=\"". esc_html($author) . ", $date\"";
6399                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6400                                 print ">";
6401                                 print $cgi->a({-href => href(action=>"commit",
6402                                                              hash=>$full_rev,
6403                                                              file_name=>$file_name)},
6404                                               esc_html($short_rev));
6405                                 if ($group_size >= 2) {
6406                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6407                                         if (@author_initials) {
6408                                                 print "<br />" .
6409                                                       esc_html(join('', @author_initials));
6410                                                 #           or join('.', ...)
6411                                         }
6412                                 }
6413                                 print "</td>\n";
6414                         }
6415                         # 'previous' <sha1 of parent commit> <filename at commit>
6416                         if (exists $meta->{'previous'} &&
6417                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
6418                                 $meta->{'parent'} = $1;
6419                                 $meta->{'file_parent'} = unquote($2);
6420                         }
6421                         my $linenr_commit =
6422                                 exists($meta->{'parent'}) ?
6423                                 $meta->{'parent'} : $full_rev;
6424                         my $linenr_filename =
6425                                 exists($meta->{'file_parent'}) ?
6426                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6427                         my $blamed = href(action => 'blame',
6428                                           file_name => $linenr_filename,
6429                                           hash_base => $linenr_commit);
6430                         print "<td class=\"linenr\">";
6431                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6432                                         -class => "linenr" },
6433                                       esc_html($lineno));
6434                         print "</td>";
6435                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6436                         print "</tr>\n";
6437                 } # end while
6438
6439         }
6440
6441         # footer
6442         print "</tbody>\n".
6443               "</table>\n"; # class="blame"
6444         print "</div>\n";   # class="blame_body"
6445         close $fd
6446                 or print "Reading blob failed\n";
6447
6448         git_footer_html();
6449 }
6450
6451 sub git_blame {
6452         git_blame_common();
6453 }
6454
6455 sub git_blame_incremental {
6456         git_blame_common('incremental');
6457 }
6458
6459 sub git_blame_data {
6460         git_blame_common('data');
6461 }
6462
6463 sub git_tags {
6464         my $head = git_get_head_hash($project);
6465         git_header_html();
6466         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6467         git_print_header_div('summary', $project);
6468
6469         my @tagslist = git_get_tags_list();
6470         if (@tagslist) {
6471                 git_tags_body(\@tagslist);
6472         }
6473         git_footer_html();
6474 }
6475
6476 sub git_heads {
6477         my $head = git_get_head_hash($project);
6478         git_header_html();
6479         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6480         git_print_header_div('summary', $project);
6481
6482         my @headslist = git_get_heads_list();
6483         if (@headslist) {
6484                 git_heads_body(\@headslist, $head);
6485         }
6486         git_footer_html();
6487 }
6488
6489 # used both for single remote view and for list of all the remotes
6490 sub git_remotes {
6491         gitweb_check_feature('remote_heads')
6492                 or die_error(403, "Remote heads view is disabled");
6493
6494         my $head = git_get_head_hash($project);
6495         my $remote = $input_params{'hash'};
6496
6497         my $remotedata = git_get_remotes_list($remote);
6498         die_error(500, "Unable to get remote information") unless defined $remotedata;
6499
6500         unless (%$remotedata) {
6501                 die_error(404, defined $remote ?
6502                         "Remote $remote not found" :
6503                         "No remotes found");
6504         }
6505
6506         git_header_html(undef, undef, -action_extra => $remote);
6507         git_print_page_nav('', '',  $head, undef, $head,
6508                 format_ref_views($remote ? '' : 'remotes'));
6509
6510         fill_remote_heads($remotedata);
6511         if (defined $remote) {
6512                 git_print_header_div('remotes', "$remote remote for $project");
6513                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
6514         } else {
6515                 git_print_header_div('summary', "$project remotes");
6516                 git_remotes_body($remotedata, undef, $head);
6517         }
6518
6519         git_footer_html();
6520 }
6521
6522 sub git_blob_plain {
6523         my $type = shift;
6524         my $expires;
6525
6526         if (!defined $hash) {
6527                 if (defined $file_name) {
6528                         my $base = $hash_base || git_get_head_hash($project);
6529                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6530                                 or die_error(404, "Cannot find file");
6531                 } else {
6532                         die_error(400, "No file name defined");
6533                 }
6534         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6535                 # blobs defined by non-textual hash id's can be cached
6536                 $expires = "+1d";
6537         }
6538
6539         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6540                 or die_error(500, "Open git-cat-file blob '$hash' failed");
6541
6542         # content-type (can include charset)
6543         $type = blob_contenttype($fd, $file_name, $type);
6544
6545         # "save as" filename, even when no $file_name is given
6546         my $save_as = "$hash";
6547         if (defined $file_name) {
6548                 $save_as = $file_name;
6549         } elsif ($type =~ m/^text\//) {
6550                 $save_as .= '.txt';
6551         }
6552
6553         # With XSS prevention on, blobs of all types except a few known safe
6554         # ones are served with "Content-Disposition: attachment" to make sure
6555         # they don't run in our security domain.  For certain image types,
6556         # blob view writes an <img> tag referring to blob_plain view, and we
6557         # want to be sure not to break that by serving the image as an
6558         # attachment (though Firefox 3 doesn't seem to care).
6559         my $sandbox = $prevent_xss &&
6560                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
6561
6562         # serve text/* as text/plain
6563         if ($prevent_xss &&
6564             ($type =~ m!^text/[a-z]+\b(.*)$! ||
6565              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
6566                 my $rest = $1;
6567                 $rest = defined $rest ? $rest : '';
6568                 $type = "text/plain$rest";
6569         }
6570
6571         print $cgi->header(
6572                 -type => $type,
6573                 -expires => $expires,
6574                 -content_disposition =>
6575                         ($sandbox ? 'attachment' : 'inline')
6576                         . '; filename="' . $save_as . '"');
6577         local $/ = undef;
6578         binmode STDOUT, ':raw';
6579         print <$fd>;
6580         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6581         close $fd;
6582 }
6583
6584 sub git_blob {
6585         my $expires;
6586
6587         if (!defined $hash) {
6588                 if (defined $file_name) {
6589                         my $base = $hash_base || git_get_head_hash($project);
6590                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6591                                 or die_error(404, "Cannot find file");
6592                 } else {
6593                         die_error(400, "No file name defined");
6594                 }
6595         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6596                 # blobs defined by non-textual hash id's can be cached
6597                 $expires = "+1d";
6598         }
6599
6600         my $have_blame = gitweb_check_feature('blame');
6601         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6602                 or die_error(500, "Couldn't cat $file_name, $hash");
6603         my $mimetype = blob_mimetype($fd, $file_name);
6604         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
6605         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
6606                 close $fd;
6607                 return git_blob_plain($mimetype);
6608         }
6609         # we can have blame only for text/* mimetype
6610         $have_blame &&= ($mimetype =~ m!^text/!);
6611
6612         my $highlight = gitweb_check_feature('highlight');
6613         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
6614         $fd = run_highlighter($fd, $highlight, $syntax)
6615                 if $syntax;
6616
6617         git_header_html(undef, $expires);
6618         my $formats_nav = '';
6619         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6620                 if (defined $file_name) {
6621                         if ($have_blame) {
6622                                 $formats_nav .=
6623                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
6624                                                 "blame") .
6625                                         " | ";
6626                         }
6627                         $formats_nav .=
6628                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6629                                         "history") .
6630                                 " | " .
6631                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6632                                         "raw") .
6633                                 " | " .
6634                                 $cgi->a({-href => href(action=>"blob",
6635                                                        hash_base=>"HEAD", file_name=>$file_name)},
6636                                         "HEAD");
6637                 } else {
6638                         $formats_nav .=
6639                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6640                                         "raw");
6641                 }
6642                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6643                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6644         } else {
6645                 print "<div class=\"page_nav\">\n" .
6646                       "<br/><br/></div>\n" .
6647                       "<div class=\"title\">".esc_html($hash)."</div>\n";
6648         }
6649         git_print_page_path($file_name, "blob", $hash_base);
6650         print "<div class=\"page_body\">\n";
6651         if ($mimetype =~ m!^image/!) {
6652                 print qq!<img type="!.esc_attr($mimetype).qq!"!;
6653                 if ($file_name) {
6654                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
6655                 }
6656                 print qq! src="! .
6657                       href(action=>"blob_plain", hash=>$hash,
6658                            hash_base=>$hash_base, file_name=>$file_name) .
6659                       qq!" />\n!;
6660         } else {
6661                 my $nr;
6662                 while (my $line = <$fd>) {
6663                         chomp $line;
6664                         $nr++;
6665                         $line = untabify($line);
6666                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
6667                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
6668                                $syntax ? sanitize($line) : esc_html($line, -nbsp=>1);
6669                 }
6670         }
6671         close $fd
6672                 or print "Reading blob failed.\n";
6673         print "</div>";
6674         git_footer_html();
6675 }
6676
6677 sub git_tree {
6678         if (!defined $hash_base) {
6679                 $hash_base = "HEAD";
6680         }
6681         if (!defined $hash) {
6682                 if (defined $file_name) {
6683                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
6684                 } else {
6685                         $hash = $hash_base;
6686                 }
6687         }
6688         die_error(404, "No such tree") unless defined($hash);
6689
6690         my $show_sizes = gitweb_check_feature('show-sizes');
6691         my $have_blame = gitweb_check_feature('blame');
6692
6693         my @entries = ();
6694         {
6695                 local $/ = "\0";
6696                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
6697                         ($show_sizes ? '-l' : ()), @extra_options, $hash
6698                         or die_error(500, "Open git-ls-tree failed");
6699                 @entries = map { chomp; $_ } <$fd>;
6700                 close $fd
6701                         or die_error(404, "Reading tree failed");
6702         }
6703
6704         my $refs = git_get_references();
6705         my $ref = format_ref_marker($refs, $hash_base);
6706         git_header_html();
6707         my $basedir = '';
6708         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6709                 my @views_nav = ();
6710                 if (defined $file_name) {
6711                         push @views_nav,
6712                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6713                                         "history"),
6714                                 $cgi->a({-href => href(action=>"tree",
6715                                                        hash_base=>"HEAD", file_name=>$file_name)},
6716                                         "HEAD"),
6717                 }
6718                 my $snapshot_links = format_snapshot_links($hash);
6719                 if (defined $snapshot_links) {
6720                         # FIXME: Should be available when we have no hash base as well.
6721                         push @views_nav, $snapshot_links;
6722                 }
6723                 git_print_page_nav('tree','', $hash_base, undef, undef,
6724                                    join(' | ', @views_nav));
6725                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
6726         } else {
6727                 undef $hash_base;
6728                 print "<div class=\"page_nav\">\n";
6729                 print "<br/><br/></div>\n";
6730                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
6731         }
6732         if (defined $file_name) {
6733                 $basedir = $file_name;
6734                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
6735                         $basedir .= '/';
6736                 }
6737                 git_print_page_path($file_name, 'tree', $hash_base);
6738         }
6739         print "<div class=\"page_body\">\n";
6740         print "<table class=\"tree\">\n";
6741         my $alternate = 1;
6742         # '..' (top directory) link if possible
6743         if (defined $hash_base &&
6744             defined $file_name && $file_name =~ m![^/]+$!) {
6745                 if ($alternate) {
6746                         print "<tr class=\"dark\">\n";
6747                 } else {
6748                         print "<tr class=\"light\">\n";
6749                 }
6750                 $alternate ^= 1;
6751
6752                 my $up = $file_name;
6753                 $up =~ s!/?[^/]+$!!;
6754                 undef $up unless $up;
6755                 # based on git_print_tree_entry
6756                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
6757                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
6758                 print '<td class="list">';
6759                 print $cgi->a({-href => href(action=>"tree",
6760                                              hash_base=>$hash_base,
6761                                              file_name=>$up)},
6762                               "..");
6763                 print "</td>\n";
6764                 print "<td class=\"link\"></td>\n";
6765
6766                 print "</tr>\n";
6767         }
6768         foreach my $line (@entries) {
6769                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
6770
6771                 if ($alternate) {
6772                         print "<tr class=\"dark\">\n";
6773                 } else {
6774                         print "<tr class=\"light\">\n";
6775                 }
6776                 $alternate ^= 1;
6777
6778                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
6779
6780                 print "</tr>\n";
6781         }
6782         print "</table>\n" .
6783               "</div>";
6784         git_footer_html();
6785 }
6786
6787 sub snapshot_name {
6788         my ($project, $hash) = @_;
6789
6790         # path/to/project.git  -> project
6791         # path/to/project/.git -> project
6792         my $name = to_utf8($project);
6793         $name =~ s,([^/])/*\.git$,$1,;
6794         $name = basename($name);
6795         # sanitize name
6796         $name =~ s/[[:cntrl:]]/?/g;
6797
6798         my $ver = $hash;
6799         if ($hash =~ /^[0-9a-fA-F]+$/) {
6800                 # shorten SHA-1 hash
6801                 my $full_hash = git_get_full_hash($project, $hash);
6802                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
6803                         $ver = git_get_short_hash($project, $hash);
6804                 }
6805         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
6806                 # tags don't need shortened SHA-1 hash
6807                 $ver = $1;
6808         } else {
6809                 # branches and other need shortened SHA-1 hash
6810                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
6811                         $ver = $1;
6812                 }
6813                 $ver .= '-' . git_get_short_hash($project, $hash);
6814         }
6815         # in case of hierarchical branch names
6816         $ver =~ s!/!.!g;
6817
6818         # name = project-version_string
6819         $name = "$name-$ver";
6820
6821         return wantarray ? ($name, $name) : $name;
6822 }
6823
6824 sub git_snapshot {
6825         my $format = $input_params{'snapshot_format'};
6826         if (!@snapshot_fmts) {
6827                 die_error(403, "Snapshots not allowed");
6828         }
6829         # default to first supported snapshot format
6830         $format ||= $snapshot_fmts[0];
6831         if ($format !~ m/^[a-z0-9]+$/) {
6832                 die_error(400, "Invalid snapshot format parameter");
6833         } elsif (!exists($known_snapshot_formats{$format})) {
6834                 die_error(400, "Unknown snapshot format");
6835         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
6836                 die_error(403, "Snapshot format not allowed");
6837         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
6838                 die_error(403, "Unsupported snapshot format");
6839         }
6840
6841         my $type = git_get_type("$hash^{}");
6842         if (!$type) {
6843                 die_error(404, 'Object does not exist');
6844         }  elsif ($type eq 'blob') {
6845                 die_error(400, 'Object is not a tree-ish');
6846         }
6847
6848         my ($name, $prefix) = snapshot_name($project, $hash);
6849         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
6850         my $cmd = quote_command(
6851                 git_cmd(), 'archive',
6852                 "--format=$known_snapshot_formats{$format}{'format'}",
6853                 "--prefix=$prefix/", $hash);
6854         if (exists $known_snapshot_formats{$format}{'compressor'}) {
6855                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
6856         }
6857
6858         $filename =~ s/(["\\])/\\$1/g;
6859         print $cgi->header(
6860                 -type => $known_snapshot_formats{$format}{'type'},
6861                 -content_disposition => 'inline; filename="' . $filename . '"',
6862                 -status => '200 OK');
6863
6864         open my $fd, "-|", $cmd
6865                 or die_error(500, "Execute git-archive failed");
6866         binmode STDOUT, ':raw';
6867         print <$fd>;
6868         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6869         close $fd;
6870 }
6871
6872 sub git_log_generic {
6873         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
6874
6875         my $head = git_get_head_hash($project);
6876         if (!defined $base) {
6877                 $base = $head;
6878         }
6879         if (!defined $page) {
6880                 $page = 0;
6881         }
6882         my $refs = git_get_references();
6883
6884         my $commit_hash = $base;
6885         if (defined $parent) {
6886                 $commit_hash = "$parent..$base";
6887         }
6888         my @commitlist =
6889                 parse_commits($commit_hash, 101, (100 * $page),
6890                               defined $file_name ? ($file_name, "--full-history") : ());
6891
6892         my $ftype;
6893         if (!defined $file_hash && defined $file_name) {
6894                 # some commits could have deleted file in question,
6895                 # and not have it in tree, but one of them has to have it
6896                 for (my $i = 0; $i < @commitlist; $i++) {
6897                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
6898                         last if defined $file_hash;
6899                 }
6900         }
6901         if (defined $file_hash) {
6902                 $ftype = git_get_type($file_hash);
6903         }
6904         if (defined $file_name && !defined $ftype) {
6905                 die_error(500, "Unknown type of object");
6906         }
6907         my %co;
6908         if (defined $file_name) {
6909                 %co = parse_commit($base)
6910                         or die_error(404, "Unknown commit object");
6911         }
6912
6913
6914         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
6915         my $next_link = '';
6916         if ($#commitlist >= 100) {
6917                 $next_link =
6918                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
6919                                  -accesskey => "n", -title => "Alt-n"}, "next");
6920         }
6921         my $patch_max = gitweb_get_feature('patches');
6922         if ($patch_max && !defined $file_name) {
6923                 if ($patch_max < 0 || @commitlist <= $patch_max) {
6924                         $paging_nav .= " &sdot; " .
6925                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
6926                                         "patches");
6927                 }
6928         }
6929
6930         git_header_html();
6931         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
6932         if (defined $file_name) {
6933                 git_print_header_div('commit', esc_html($co{'title'}), $base);
6934         } else {
6935                 git_print_header_div('summary', $project)
6936         }
6937         git_print_page_path($file_name, $ftype, $hash_base)
6938                 if (defined $file_name);
6939
6940         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
6941                      $file_name, $file_hash, $ftype);
6942
6943         git_footer_html();
6944 }
6945
6946 sub git_log {
6947         git_log_generic('log', \&git_log_body,
6948                         $hash, $hash_parent);
6949 }
6950
6951 sub git_commit {
6952         $hash ||= $hash_base || "HEAD";
6953         my %co = parse_commit($hash)
6954             or die_error(404, "Unknown commit object");
6955
6956         my $parent  = $co{'parent'};
6957         my $parents = $co{'parents'}; # listref
6958
6959         # we need to prepare $formats_nav before any parameter munging
6960         my $formats_nav;
6961         if (!defined $parent) {
6962                 # --root commitdiff
6963                 $formats_nav .= '(initial)';
6964         } elsif (@$parents == 1) {
6965                 # single parent commit
6966                 $formats_nav .=
6967                         '(parent: ' .
6968                         $cgi->a({-href => href(action=>"commit",
6969                                                hash=>$parent)},
6970                                 esc_html(substr($parent, 0, 7))) .
6971                         ')';
6972         } else {
6973                 # merge commit
6974                 $formats_nav .=
6975                         '(merge: ' .
6976                         join(' ', map {
6977                                 $cgi->a({-href => href(action=>"commit",
6978                                                        hash=>$_)},
6979                                         esc_html(substr($_, 0, 7)));
6980                         } @$parents ) .
6981                         ')';
6982         }
6983         if (gitweb_check_feature('patches') && @$parents <= 1) {
6984                 $formats_nav .= " | " .
6985                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
6986                                 "patch");
6987         }
6988
6989         if (!defined $parent) {
6990                 $parent = "--root";
6991         }
6992         my @difftree;
6993         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
6994                 @diff_opts,
6995                 (@$parents <= 1 ? $parent : '-c'),
6996                 $hash, "--"
6997                 or die_error(500, "Open git-diff-tree failed");
6998         @difftree = map { chomp; $_ } <$fd>;
6999         close $fd or die_error(404, "Reading git-diff-tree failed");
7000
7001         # non-textual hash id's can be cached
7002         my $expires;
7003         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7004                 $expires = "+1d";
7005         }
7006         my $refs = git_get_references();
7007         my $ref = format_ref_marker($refs, $co{'id'});
7008
7009         git_header_html(undef, $expires);
7010         git_print_page_nav('commit', '',
7011                            $hash, $co{'tree'}, $hash,
7012                            $formats_nav);
7013
7014         if (defined $co{'parent'}) {
7015                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
7016         } else {
7017                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
7018         }
7019         print "<div class=\"title_text\">\n" .
7020               "<table class=\"object_header\">\n";
7021         git_print_authorship_rows(\%co);
7022         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
7023         print "<tr>" .
7024               "<td>tree</td>" .
7025               "<td class=\"sha1\">" .
7026               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
7027                        class => "list"}, $co{'tree'}) .
7028               "</td>" .
7029               "<td class=\"link\">" .
7030               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
7031                       "tree");
7032         my $snapshot_links = format_snapshot_links($hash);
7033         if (defined $snapshot_links) {
7034                 print " | " . $snapshot_links;
7035         }
7036         print "</td>" .
7037               "</tr>\n";
7038
7039         foreach my $par (@$parents) {
7040                 print "<tr>" .
7041                       "<td>parent</td>" .
7042                       "<td class=\"sha1\">" .
7043                       $cgi->a({-href => href(action=>"commit", hash=>$par),
7044                                class => "list"}, $par) .
7045                       "</td>" .
7046                       "<td class=\"link\">" .
7047                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
7048                       " | " .
7049                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
7050                       "</td>" .
7051                       "</tr>\n";
7052         }
7053         print "</table>".
7054               "</div>\n";
7055
7056         print "<div class=\"page_body\">\n";
7057         git_print_log($co{'comment'});
7058         print "</div>\n";
7059
7060         git_difftree_body(\@difftree, $hash, @$parents);
7061
7062         git_footer_html();
7063 }
7064
7065 sub git_object {
7066         # object is defined by:
7067         # - hash or hash_base alone
7068         # - hash_base and file_name
7069         my $type;
7070
7071         # - hash or hash_base alone
7072         if ($hash || ($hash_base && !defined $file_name)) {
7073                 my $object_id = $hash || $hash_base;
7074
7075                 open my $fd, "-|", quote_command(
7076                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
7077                         or die_error(404, "Object does not exist");
7078                 $type = <$fd>;
7079                 chomp $type;
7080                 close $fd
7081                         or die_error(404, "Object does not exist");
7082
7083         # - hash_base and file_name
7084         } elsif ($hash_base && defined $file_name) {
7085                 $file_name =~ s,/+$,,;
7086
7087                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
7088                         or die_error(404, "Base object does not exist");
7089
7090                 # here errors should not hapen
7091                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
7092                         or die_error(500, "Open git-ls-tree failed");
7093                 my $line = <$fd>;
7094                 close $fd;
7095
7096                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
7097                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
7098                         die_error(404, "File or directory for given base does not exist");
7099                 }
7100                 $type = $2;
7101                 $hash = $3;
7102         } else {
7103                 die_error(400, "Not enough information to find object");
7104         }
7105
7106         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
7107                                           hash=>$hash, hash_base=>$hash_base,
7108                                           file_name=>$file_name),
7109                              -status => '302 Found');
7110 }
7111
7112 sub git_blobdiff {
7113         my $format = shift || 'html';
7114         my $diff_style = $input_params{'diff_style'} || 'inline';
7115
7116         my $fd;
7117         my @difftree;
7118         my %diffinfo;
7119         my $expires;
7120
7121         # preparing $fd and %diffinfo for git_patchset_body
7122         # new style URI
7123         if (defined $hash_base && defined $hash_parent_base) {
7124                 if (defined $file_name) {
7125                         # read raw output
7126                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7127                                 $hash_parent_base, $hash_base,
7128                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
7129                                 or die_error(500, "Open git-diff-tree failed");
7130                         @difftree = map { chomp; $_ } <$fd>;
7131                         close $fd
7132                                 or die_error(404, "Reading git-diff-tree failed");
7133                         @difftree
7134                                 or die_error(404, "Blob diff not found");
7135
7136                 } elsif (defined $hash &&
7137                          $hash =~ /[0-9a-fA-F]{40}/) {
7138                         # try to find filename from $hash
7139
7140                         # read filtered raw output
7141                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7142                                 $hash_parent_base, $hash_base, "--"
7143                                 or die_error(500, "Open git-diff-tree failed");
7144                         @difftree =
7145                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
7146                                 # $hash == to_id
7147                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
7148                                 map { chomp; $_ } <$fd>;
7149                         close $fd
7150                                 or die_error(404, "Reading git-diff-tree failed");
7151                         @difftree
7152                                 or die_error(404, "Blob diff not found");
7153
7154                 } else {
7155                         die_error(400, "Missing one of the blob diff parameters");
7156                 }
7157
7158                 if (@difftree > 1) {
7159                         die_error(400, "Ambiguous blob diff specification");
7160                 }
7161
7162                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7163                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7164                 $file_name   ||= $diffinfo{'to_file'};
7165
7166                 $hash_parent ||= $diffinfo{'from_id'};
7167                 $hash        ||= $diffinfo{'to_id'};
7168
7169                 # non-textual hash id's can be cached
7170                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
7171                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
7172                         $expires = '+1d';
7173                 }
7174
7175                 # open patch output
7176                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7177                         '-p', ($format eq 'html' ? "--full-index" : ()),
7178                         $hash_parent_base, $hash_base,
7179                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7180                         or die_error(500, "Open git-diff-tree failed");
7181         }
7182
7183         # old/legacy style URI -- not generated anymore since 1.4.3.
7184         if (!%diffinfo) {
7185                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7186         }
7187
7188         # header
7189         if ($format eq 'html') {
7190                 my $formats_nav =
7191                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7192                                 "raw");
7193                 $formats_nav .= diff_style_nav($diff_style);
7194                 git_header_html(undef, $expires);
7195                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7196                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7197                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7198                 } else {
7199                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7200                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7201                 }
7202                 if (defined $file_name) {
7203                         git_print_page_path($file_name, "blob", $hash_base);
7204                 } else {
7205                         print "<div class=\"page_path\"></div>\n";
7206                 }
7207
7208         } elsif ($format eq 'plain') {
7209                 print $cgi->header(
7210                         -type => 'text/plain',
7211                         -charset => 'utf-8',
7212                         -expires => $expires,
7213                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7214
7215                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7216
7217         } else {
7218                 die_error(400, "Unknown blobdiff format");
7219         }
7220
7221         # patch
7222         if ($format eq 'html') {
7223                 print "<div class=\"page_body\">\n";
7224
7225                 git_patchset_body($fd, $diff_style,
7226                                   [ \%diffinfo ], $hash_base, $hash_parent_base);
7227                 close $fd;
7228
7229                 print "</div>\n"; # class="page_body"
7230                 git_footer_html();
7231
7232         } else {
7233                 while (my $line = <$fd>) {
7234                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7235                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7236
7237                         print $line;
7238
7239                         last if $line =~ m!^\+\+\+!;
7240                 }
7241                 local $/ = undef;
7242                 print <$fd>;
7243                 close $fd;
7244         }
7245 }
7246
7247 sub git_blobdiff_plain {
7248         git_blobdiff('plain');
7249 }
7250
7251 # assumes that it is added as later part of already existing navigation,
7252 # so it returns "| foo | bar" rather than just "foo | bar"
7253 sub diff_style_nav {
7254         my ($diff_style, $is_combined) = @_;
7255         $diff_style ||= 'inline';
7256
7257         return "" if ($is_combined);
7258
7259         my @styles = (inline => 'inline', 'sidebyside' => 'side by side');
7260         my %styles = @styles;
7261         @styles =
7262                 @styles[ map { $_ * 2 } 0..$#styles/2 ];
7263
7264         return join '',
7265                 map { " | ".$_ }
7266                 map {
7267                         $_ eq $diff_style ? $styles{$_} :
7268                         $cgi->a({-href => href(-replay=>1, diff_style => $_)}, $styles{$_})
7269                 } @styles;
7270 }
7271
7272 sub git_commitdiff {
7273         my %params = @_;
7274         my $format = $params{-format} || 'html';
7275         my $diff_style = $input_params{'diff_style'} || 'inline';
7276
7277         my ($patch_max) = gitweb_get_feature('patches');
7278         if ($format eq 'patch') {
7279                 die_error(403, "Patch view not allowed") unless $patch_max;
7280         }
7281
7282         $hash ||= $hash_base || "HEAD";
7283         my %co = parse_commit($hash)
7284             or die_error(404, "Unknown commit object");
7285
7286         # choose format for commitdiff for merge
7287         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7288                 $hash_parent = '--cc';
7289         }
7290         # we need to prepare $formats_nav before almost any parameter munging
7291         my $formats_nav;
7292         if ($format eq 'html') {
7293                 $formats_nav =
7294                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7295                                 "raw");
7296                 if ($patch_max && @{$co{'parents'}} <= 1) {
7297                         $formats_nav .= " | " .
7298                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7299                                         "patch");
7300                 }
7301                 $formats_nav .= diff_style_nav($diff_style, @{$co{'parents'}} > 1);
7302
7303                 if (defined $hash_parent &&
7304                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7305                         # commitdiff with two commits given
7306                         my $hash_parent_short = $hash_parent;
7307                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
7308                                 $hash_parent_short = substr($hash_parent, 0, 7);
7309                         }
7310                         $formats_nav .=
7311                                 ' (from';
7312                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7313                                 if ($co{'parents'}[$i] eq $hash_parent) {
7314                                         $formats_nav .= ' parent ' . ($i+1);
7315                                         last;
7316                                 }
7317                         }
7318                         $formats_nav .= ': ' .
7319                                 $cgi->a({-href => href(-replay=>1,
7320                                                        hash=>$hash_parent, hash_base=>undef)},
7321                                         esc_html($hash_parent_short)) .
7322                                 ')';
7323                 } elsif (!$co{'parent'}) {
7324                         # --root commitdiff
7325                         $formats_nav .= ' (initial)';
7326                 } elsif (scalar @{$co{'parents'}} == 1) {
7327                         # single parent commit
7328                         $formats_nav .=
7329                                 ' (parent: ' .
7330                                 $cgi->a({-href => href(-replay=>1,
7331                                                        hash=>$co{'parent'}, hash_base=>undef)},
7332                                         esc_html(substr($co{'parent'}, 0, 7))) .
7333                                 ')';
7334                 } else {
7335                         # merge commit
7336                         if ($hash_parent eq '--cc') {
7337                                 $formats_nav .= ' | ' .
7338                                         $cgi->a({-href => href(-replay=>1,
7339                                                                hash=>$hash, hash_parent=>'-c')},
7340                                                 'combined');
7341                         } else { # $hash_parent eq '-c'
7342                                 $formats_nav .= ' | ' .
7343                                         $cgi->a({-href => href(-replay=>1,
7344                                                                hash=>$hash, hash_parent=>'--cc')},
7345                                                 'compact');
7346                         }
7347                         $formats_nav .=
7348                                 ' (merge: ' .
7349                                 join(' ', map {
7350                                         $cgi->a({-href => href(-replay=>1,
7351                                                                hash=>$_, hash_base=>undef)},
7352                                                 esc_html(substr($_, 0, 7)));
7353                                 } @{$co{'parents'}} ) .
7354                                 ')';
7355                 }
7356         }
7357
7358         my $hash_parent_param = $hash_parent;
7359         if (!defined $hash_parent_param) {
7360                 # --cc for multiple parents, --root for parentless
7361                 $hash_parent_param =
7362                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7363         }
7364
7365         # read commitdiff
7366         my $fd;
7367         my @difftree;
7368         if ($format eq 'html') {
7369                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7370                         "--no-commit-id", "--patch-with-raw", "--full-index",
7371                         $hash_parent_param, $hash, "--"
7372                         or die_error(500, "Open git-diff-tree failed");
7373
7374                 while (my $line = <$fd>) {
7375                         chomp $line;
7376                         # empty line ends raw part of diff-tree output
7377                         last unless $line;
7378                         push @difftree, scalar parse_difftree_raw_line($line);
7379                 }
7380
7381         } elsif ($format eq 'plain') {
7382                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7383                         '-p', $hash_parent_param, $hash, "--"
7384                         or die_error(500, "Open git-diff-tree failed");
7385         } elsif ($format eq 'patch') {
7386                 # For commit ranges, we limit the output to the number of
7387                 # patches specified in the 'patches' feature.
7388                 # For single commits, we limit the output to a single patch,
7389                 # diverging from the git-format-patch default.
7390                 my @commit_spec = ();
7391                 if ($hash_parent) {
7392                         if ($patch_max > 0) {
7393                                 push @commit_spec, "-$patch_max";
7394                         }
7395                         push @commit_spec, '-n', "$hash_parent..$hash";
7396                 } else {
7397                         if ($params{-single}) {
7398                                 push @commit_spec, '-1';
7399                         } else {
7400                                 if ($patch_max > 0) {
7401                                         push @commit_spec, "-$patch_max";
7402                                 }
7403                                 push @commit_spec, "-n";
7404                         }
7405                         push @commit_spec, '--root', $hash;
7406                 }
7407                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7408                         '--encoding=utf8', '--stdout', @commit_spec
7409                         or die_error(500, "Open git-format-patch failed");
7410         } else {
7411                 die_error(400, "Unknown commitdiff format");
7412         }
7413
7414         # non-textual hash id's can be cached
7415         my $expires;
7416         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7417                 $expires = "+1d";
7418         }
7419
7420         # write commit message
7421         if ($format eq 'html') {
7422                 my $refs = git_get_references();
7423                 my $ref = format_ref_marker($refs, $co{'id'});
7424
7425                 git_header_html(undef, $expires);
7426                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
7427                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
7428                 print "<div class=\"title_text\">\n" .
7429                       "<table class=\"object_header\">\n";
7430                 git_print_authorship_rows(\%co);
7431                 print "</table>".
7432                       "</div>\n";
7433                 print "<div class=\"page_body\">\n";
7434                 if (@{$co{'comment'}} > 1) {
7435                         print "<div class=\"log\">\n";
7436                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
7437                         print "</div>\n"; # class="log"
7438                 }
7439
7440         } elsif ($format eq 'plain') {
7441                 my $refs = git_get_references("tags");
7442                 my $tagname = git_get_rev_name_tags($hash);
7443                 my $filename = basename($project) . "-$hash.patch";
7444
7445                 print $cgi->header(
7446                         -type => 'text/plain',
7447                         -charset => 'utf-8',
7448                         -expires => $expires,
7449                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7450                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
7451                 print "From: " . to_utf8($co{'author'}) . "\n";
7452                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
7453                 print "Subject: " . to_utf8($co{'title'}) . "\n";
7454
7455                 print "X-Git-Tag: $tagname\n" if $tagname;
7456                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7457
7458                 foreach my $line (@{$co{'comment'}}) {
7459                         print to_utf8($line) . "\n";
7460                 }
7461                 print "---\n\n";
7462         } elsif ($format eq 'patch') {
7463                 my $filename = basename($project) . "-$hash.patch";
7464
7465                 print $cgi->header(
7466                         -type => 'text/plain',
7467                         -charset => 'utf-8',
7468                         -expires => $expires,
7469                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7470         }
7471
7472         # write patch
7473         if ($format eq 'html') {
7474                 my $use_parents = !defined $hash_parent ||
7475                         $hash_parent eq '-c' || $hash_parent eq '--cc';
7476                 git_difftree_body(\@difftree, $hash,
7477                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7478                 print "<br/>\n";
7479
7480                 git_patchset_body($fd, $diff_style,
7481                                   \@difftree, $hash,
7482                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7483                 close $fd;
7484                 print "</div>\n"; # class="page_body"
7485                 git_footer_html();
7486
7487         } elsif ($format eq 'plain') {
7488                 local $/ = undef;
7489                 print <$fd>;
7490                 close $fd
7491                         or print "Reading git-diff-tree failed\n";
7492         } elsif ($format eq 'patch') {
7493                 local $/ = undef;
7494                 print <$fd>;
7495                 close $fd
7496                         or print "Reading git-format-patch failed\n";
7497         }
7498 }
7499
7500 sub git_commitdiff_plain {
7501         git_commitdiff(-format => 'plain');
7502 }
7503
7504 # format-patch-style patches
7505 sub git_patch {
7506         git_commitdiff(-format => 'patch', -single => 1);
7507 }
7508
7509 sub git_patches {
7510         git_commitdiff(-format => 'patch');
7511 }
7512
7513 sub git_history {
7514         git_log_generic('history', \&git_history_body,
7515                         $hash_base, $hash_parent_base,
7516                         $file_name, $hash);
7517 }
7518
7519 sub git_search {
7520         $searchtype ||= 'commit';
7521
7522         # check if appropriate features are enabled
7523         gitweb_check_feature('search')
7524                 or die_error(403, "Search is disabled");
7525         if ($searchtype eq 'pickaxe') {
7526                 # pickaxe may take all resources of your box and run for several minutes
7527                 # with every query - so decide by yourself how public you make this feature
7528                 gitweb_check_feature('pickaxe')
7529                         or die_error(403, "Pickaxe search is disabled");
7530         }
7531         if ($searchtype eq 'grep') {
7532                 # grep search might be potentially CPU-intensive, too
7533                 gitweb_check_feature('grep')
7534                         or die_error(403, "Grep search is disabled");
7535         }
7536
7537         if (!defined $searchtext) {
7538                 die_error(400, "Text field is empty");
7539         }
7540         if (!defined $hash) {
7541                 $hash = git_get_head_hash($project);
7542         }
7543         my %co = parse_commit($hash);
7544         if (!%co) {
7545                 die_error(404, "Unknown commit object");
7546         }
7547         if (!defined $page) {
7548                 $page = 0;
7549         }
7550
7551         if ($searchtype eq 'commit' ||
7552             $searchtype eq 'author' ||
7553             $searchtype eq 'committer') {
7554                 git_search_message(%co);
7555         } elsif ($searchtype eq 'pickaxe') {
7556                 git_search_changes(%co);
7557         } elsif ($searchtype eq 'grep') {
7558                 git_search_files(%co);
7559         } else {
7560                 die_error(400, "Unknown search type");
7561         }
7562 }
7563
7564 sub git_search_help {
7565         git_header_html();
7566         git_print_page_nav('','', $hash,$hash,$hash);
7567         print <<EOT;
7568 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
7569 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
7570 the pattern entered is recognized as the POSIX extended
7571 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
7572 insensitive).</p>
7573 <dl>
7574 <dt><b>commit</b></dt>
7575 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
7576 EOT
7577         my $have_grep = gitweb_check_feature('grep');
7578         if ($have_grep) {
7579                 print <<EOT;
7580 <dt><b>grep</b></dt>
7581 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
7582     a different one) are searched for the given pattern. On large trees, this search can take
7583 a while and put some strain on the server, so please use it with some consideration. Note that
7584 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
7585 case-sensitive.</dd>
7586 EOT
7587         }
7588         print <<EOT;
7589 <dt><b>author</b></dt>
7590 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
7591 <dt><b>committer</b></dt>
7592 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
7593 EOT
7594         my $have_pickaxe = gitweb_check_feature('pickaxe');
7595         if ($have_pickaxe) {
7596                 print <<EOT;
7597 <dt><b>pickaxe</b></dt>
7598 <dd>All commits that caused the string to appear or disappear from any file (changes that
7599 added, removed or "modified" the string) will be listed. This search can take a while and
7600 takes a lot of strain on the server, so please use it wisely. Note that since you may be
7601 interested even in changes just changing the case as well, this search is case sensitive.</dd>
7602 EOT
7603         }
7604         print "</dl>\n";
7605         git_footer_html();
7606 }
7607
7608 sub git_shortlog {
7609         git_log_generic('shortlog', \&git_shortlog_body,
7610                         $hash, $hash_parent);
7611 }
7612
7613 ## ......................................................................
7614 ## feeds (RSS, Atom; OPML)
7615
7616 sub git_feed {
7617         my $format = shift || 'atom';
7618         my $have_blame = gitweb_check_feature('blame');
7619
7620         # Atom: http://www.atomenabled.org/developers/syndication/
7621         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
7622         if ($format ne 'rss' && $format ne 'atom') {
7623                 die_error(400, "Unknown web feed format");
7624         }
7625
7626         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
7627         my $head = $hash || 'HEAD';
7628         my @commitlist = parse_commits($head, 150, 0, $file_name);
7629
7630         my %latest_commit;
7631         my %latest_date;
7632         my $content_type = "application/$format+xml";
7633         if (defined $cgi->http('HTTP_ACCEPT') &&
7634                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
7635                 # browser (feed reader) prefers text/xml
7636                 $content_type = 'text/xml';
7637         }
7638         if (defined($commitlist[0])) {
7639                 %latest_commit = %{$commitlist[0]};
7640                 my $latest_epoch = $latest_commit{'committer_epoch'};
7641                 %latest_date   = parse_date($latest_epoch, $latest_commit{'comitter_tz'});
7642                 my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7643                 if (defined $if_modified) {
7644                         my $since;
7645                         if (eval { require HTTP::Date; 1; }) {
7646                                 $since = HTTP::Date::str2time($if_modified);
7647                         } elsif (eval { require Time::ParseDate; 1; }) {
7648                                 $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7649                         }
7650                         if (defined $since && $latest_epoch <= $since) {
7651                                 print $cgi->header(
7652                                         -type => $content_type,
7653                                         -charset => 'utf-8',
7654                                         -last_modified => $latest_date{'rfc2822'},
7655                                         -status => '304 Not Modified');
7656                                 return;
7657                         }
7658                 }
7659                 print $cgi->header(
7660                         -type => $content_type,
7661                         -charset => 'utf-8',
7662                         -last_modified => $latest_date{'rfc2822'});
7663         } else {
7664                 print $cgi->header(
7665                         -type => $content_type,
7666                         -charset => 'utf-8');
7667         }
7668
7669         # Optimization: skip generating the body if client asks only
7670         # for Last-Modified date.
7671         return if ($cgi->request_method() eq 'HEAD');
7672
7673         # header variables
7674         my $title = "$site_name - $project/$action";
7675         my $feed_type = 'log';
7676         if (defined $hash) {
7677                 $title .= " - '$hash'";
7678                 $feed_type = 'branch log';
7679                 if (defined $file_name) {
7680                         $title .= " :: $file_name";
7681                         $feed_type = 'history';
7682                 }
7683         } elsif (defined $file_name) {
7684                 $title .= " - $file_name";
7685                 $feed_type = 'history';
7686         }
7687         $title .= " $feed_type";
7688         my $descr = git_get_project_description($project);
7689         if (defined $descr) {
7690                 $descr = esc_html($descr);
7691         } else {
7692                 $descr = "$project " .
7693                          ($format eq 'rss' ? 'RSS' : 'Atom') .
7694                          " feed";
7695         }
7696         my $owner = git_get_project_owner($project);
7697         $owner = esc_html($owner);
7698
7699         #header
7700         my $alt_url;
7701         if (defined $file_name) {
7702                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
7703         } elsif (defined $hash) {
7704                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
7705         } else {
7706                 $alt_url = href(-full=>1, action=>"summary");
7707         }
7708         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
7709         if ($format eq 'rss') {
7710                 print <<XML;
7711 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
7712 <channel>
7713 XML
7714                 print "<title>$title</title>\n" .
7715                       "<link>$alt_url</link>\n" .
7716                       "<description>$descr</description>\n" .
7717                       "<language>en</language>\n" .
7718                       # project owner is responsible for 'editorial' content
7719                       "<managingEditor>$owner</managingEditor>\n";
7720                 if (defined $logo || defined $favicon) {
7721                         # prefer the logo to the favicon, since RSS
7722                         # doesn't allow both
7723                         my $img = esc_url($logo || $favicon);
7724                         print "<image>\n" .
7725                               "<url>$img</url>\n" .
7726                               "<title>$title</title>\n" .
7727                               "<link>$alt_url</link>\n" .
7728                               "</image>\n";
7729                 }
7730                 if (%latest_date) {
7731                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
7732                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
7733                 }
7734                 print "<generator>gitweb v.$version/$git_version</generator>\n";
7735         } elsif ($format eq 'atom') {
7736                 print <<XML;
7737 <feed xmlns="http://www.w3.org/2005/Atom">
7738 XML
7739                 print "<title>$title</title>\n" .
7740                       "<subtitle>$descr</subtitle>\n" .
7741                       '<link rel="alternate" type="text/html" href="' .
7742                       $alt_url . '" />' . "\n" .
7743                       '<link rel="self" type="' . $content_type . '" href="' .
7744                       $cgi->self_url() . '" />' . "\n" .
7745                       "<id>" . href(-full=>1) . "</id>\n" .
7746                       # use project owner for feed author
7747                       "<author><name>$owner</name></author>\n";
7748                 if (defined $favicon) {
7749                         print "<icon>" . esc_url($favicon) . "</icon>\n";
7750                 }
7751                 if (defined $logo) {
7752                         # not twice as wide as tall: 72 x 27 pixels
7753                         print "<logo>" . esc_url($logo) . "</logo>\n";
7754                 }
7755                 if (! %latest_date) {
7756                         # dummy date to keep the feed valid until commits trickle in:
7757                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
7758                 } else {
7759                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
7760                 }
7761                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
7762         }
7763
7764         # contents
7765         for (my $i = 0; $i <= $#commitlist; $i++) {
7766                 my %co = %{$commitlist[$i]};
7767                 my $commit = $co{'id'};
7768                 # we read 150, we always show 30 and the ones more recent than 48 hours
7769                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
7770                         last;
7771                 }
7772                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
7773
7774                 # get list of changed files
7775                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7776                         $co{'parent'} || "--root",
7777                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
7778                         or next;
7779                 my @difftree = map { chomp; $_ } <$fd>;
7780                 close $fd
7781                         or next;
7782
7783                 # print element (entry, item)
7784                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
7785                 if ($format eq 'rss') {
7786                         print "<item>\n" .
7787                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
7788                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
7789                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
7790                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
7791                               "<link>$co_url</link>\n" .
7792                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
7793                               "<content:encoded>" .
7794                               "<![CDATA[\n";
7795                 } elsif ($format eq 'atom') {
7796                         print "<entry>\n" .
7797                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
7798                               "<updated>$cd{'iso-8601'}</updated>\n" .
7799                               "<author>\n" .
7800                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
7801                         if ($co{'author_email'}) {
7802                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
7803                         }
7804                         print "</author>\n" .
7805                               # use committer for contributor
7806                               "<contributor>\n" .
7807                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
7808                         if ($co{'committer_email'}) {
7809                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
7810                         }
7811                         print "</contributor>\n" .
7812                               "<published>$cd{'iso-8601'}</published>\n" .
7813                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
7814                               "<id>$co_url</id>\n" .
7815                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
7816                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
7817                 }
7818                 my $comment = $co{'comment'};
7819                 print "<pre>\n";
7820                 foreach my $line (@$comment) {
7821                         $line = esc_html($line);
7822                         print "$line\n";
7823                 }
7824                 print "</pre><ul>\n";
7825                 foreach my $difftree_line (@difftree) {
7826                         my %difftree = parse_difftree_raw_line($difftree_line);
7827                         next if !$difftree{'from_id'};
7828
7829                         my $file = $difftree{'file'} || $difftree{'to_file'};
7830
7831                         print "<li>" .
7832                               "[" .
7833                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
7834                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
7835                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
7836                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
7837                                       -title => "diff"}, 'D');
7838                         if ($have_blame) {
7839                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
7840                                                              file_name=>$file, hash_base=>$commit),
7841                                               -title => "blame"}, 'B');
7842                         }
7843                         # if this is not a feed of a file history
7844                         if (!defined $file_name || $file_name ne $file) {
7845                                 print $cgi->a({-href => href(-full=>1, action=>"history",
7846                                                              file_name=>$file, hash=>$commit),
7847                                               -title => "history"}, 'H');
7848                         }
7849                         $file = esc_path($file);
7850                         print "] ".
7851                               "$file</li>\n";
7852                 }
7853                 if ($format eq 'rss') {
7854                         print "</ul>]]>\n" .
7855                               "</content:encoded>\n" .
7856                               "</item>\n";
7857                 } elsif ($format eq 'atom') {
7858                         print "</ul>\n</div>\n" .
7859                               "</content>\n" .
7860                               "</entry>\n";
7861                 }
7862         }
7863
7864         # end of feed
7865         if ($format eq 'rss') {
7866                 print "</channel>\n</rss>\n";
7867         } elsif ($format eq 'atom') {
7868                 print "</feed>\n";
7869         }
7870 }
7871
7872 sub git_rss {
7873         git_feed('rss');
7874 }
7875
7876 sub git_atom {
7877         git_feed('atom');
7878 }
7879
7880 sub git_opml {
7881         my @list = git_get_projects_list();
7882         if (!@list) {
7883                 die_error(404, "No projects found");
7884         }
7885
7886         print $cgi->header(
7887                 -type => 'text/xml',
7888                 -charset => 'utf-8',
7889                 -content_disposition => 'inline; filename="opml.xml"');
7890
7891         my $title = esc_html($site_name);
7892         print <<XML;
7893 <?xml version="1.0" encoding="utf-8"?>
7894 <opml version="1.0">
7895 <head>
7896   <title>$title OPML Export</title>
7897 </head>
7898 <body>
7899 <outline text="git RSS feeds">
7900 XML
7901
7902         foreach my $pr (@list) {
7903                 my %proj = %$pr;
7904                 my $head = git_get_head_hash($proj{'path'});
7905                 if (!defined $head) {
7906                         next;
7907                 }
7908                 $git_dir = "$projectroot/$proj{'path'}";
7909                 my %co = parse_commit($head);
7910                 if (!%co) {
7911                         next;
7912                 }
7913
7914                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
7915                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
7916                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
7917                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
7918         }
7919         print <<XML;
7920 </outline>
7921 </body>
7922 </opml>
7923 XML
7924 }