dir.h: move struct exclude declaration to top level
[git.git] / configure.ac
blob4b1ae7c3c9f5ff5080dc026a6eb835d579d29949
1 #                                               -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
4 ## Definitions of private macros.
6 # GIT_CONF_SUBST(VAL, VAR)
7 # ------------------------
8 # Cause the line "VAR=VAL" to be eventually appended to ${config_file}.
9 AC_DEFUN([GIT_CONF_SUBST],
10 [AC_REQUIRE([GIT_CONF_SUBST_INIT])
11 config_appended_defs="$config_appended_defs${newline}dnl
12 $1=m4_if([$#],[1],[${$1}],[$2])"])
14 # GIT_CONF_SUBST_INIT
15 # -------------------
16 # Prepare shell variables and autoconf machine required by later calls
17 # to GIT_CONF_SUBST.
18 AC_DEFUN([GIT_CONF_SUBST_INIT],
19     [config_appended_defs=; newline='
21     AC_CONFIG_COMMANDS([$config_file],
22                        [echo "$config_appended_defs" >> "$config_file"],
23                        [config_file=$config_file
24                         config_appended_defs="$config_appended_defs"])])
26 # GIT_ARG_SET_PATH(PROGRAM)
27 # -------------------------
28 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
29 # Optional second argument allows setting NO_PROGRAM=YesPlease if
30 # --without-PROGRAM version used.
31 AC_DEFUN([GIT_ARG_SET_PATH],
32     [AC_ARG_WITH([$1],
33         [AS_HELP_STRING([--with-$1=PATH],
34                         [provide PATH to $1])],
35         [GIT_CONF_APPEND_PATH([$1], [$2])],
36         [])])
38 # GIT_CONF_APPEND_PATH(PROGRAM)
39 # -----------------------------
40 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
41 # Used by GIT_ARG_SET_PATH(PROGRAM)
42 # Optional second argument allows setting NO_PROGRAM=YesPlease if
43 # --without-PROGRAM is used.
44 AC_DEFUN([GIT_CONF_APPEND_PATH],
45     [m4_pushdef([GIT_UC_PROGRAM], m4_toupper([$1]))dnl
46     if test "$withval" = "no"; then
47         if test -n "$2"; then
48                 GIT_UC_PROGRAM[]_PATH=$withval
49                 AC_MSG_NOTICE([Disabling use of GIT_UC_PROGRAM])
50                 GIT_CONF_SUBST([NO_]GIT_UC_PROGRAM, [YesPlease])
51                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [])
52         else
53                 AC_MSG_ERROR([You cannot use git without $1])
54         fi
55     else
56         if test "$withval" = "yes"; then
57                 AC_MSG_WARN([You should provide path for --with-$1=PATH])
58         else
59                 GIT_UC_PROGRAM[]_PATH=$withval
60                 AC_MSG_NOTICE([Setting GIT_UC_PROGRAM[]_PATH to $withval])
61                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [$withval])
62         fi
63     fi
64     m4_popdef([GIT_UC_PROGRAM])])
66 # GIT_PARSE_WITH(PACKAGE)
67 # -----------------------
68 # For use in AC_ARG_WITH action-if-found, for packages default ON.
69 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
70 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
71 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
72 AC_DEFUN([GIT_PARSE_WITH],
73     [m4_pushdef([GIT_UC_PACKAGE], m4_toupper([$1]))dnl
74     if test "$withval" = "no"; then
75         NO_[]GIT_UC_PACKAGE=YesPlease
76     elif test "$withval" = "yes"; then
77         NO_[]GIT_UC_PACKAGE=
78     else
79         NO_[]GIT_UC_PACKAGE=
80         GIT_UC_PACKAGE[]DIR=$withval
81         AC_MSG_NOTICE([Setting GIT_UC_PACKAGE[]DIR to $withval])
82         GIT_CONF_SUBST(GIT_UC_PACKAGE[DIR], [$withval])
83     fi
84     m4_popdef([GIT_UC_PACKAGE])])
86 # GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
87 # -----------------------------------------------------
88 # Set VAR to the value specied by --with-WITHNAME.
89 # No verification of arguments is performed, but warnings are issued
90 # if either 'yes' or 'no' is specified.
91 # HELP_TEXT is presented when --help is called.
92 # This is a direct way to allow setting variables in the Makefile.
93 AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
94 [AC_ARG_WITH([$1],
95  [AS_HELP_STRING([--with-$1=VALUE], $3)],
96  if test -n "$withval"; then
97   if test "$withval" = "yes" -o "$withval" = "no"; then
98     AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
99                      [a value for $1 ($2).  Maybe you do...?])
100   fi
101   AC_MSG_NOTICE([Setting $2 to $withval])
102   GIT_CONF_SUBST([$2], [$withval])
103  fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
106 # GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
107 # -----------------------------------------
108 # Similar to AC_CHECK_FUNC, but on systems that do not generate
109 # warnings for missing prototypes (e.g. FreeBSD when compiling without
110 # -Wall), it does not work.  By looking for function definition in
111 # libraries, this problem can be worked around.
112 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
113   AC_SEARCH_LIBS([$1],,
114   [$2],[$3])
115 ],[$3])])
118 # GIT_STASH_FLAGS(BASEPATH_VAR)
119 # -----------------------------
120 # Allow for easy stashing of LDFLAGS and CPPFLAGS before running
121 # tests that may want to take user settings into account.
122 AC_DEFUN([GIT_STASH_FLAGS],[
123 if test -n "$1"; then
124    old_CPPFLAGS="$CPPFLAGS"
125    old_LDFLAGS="$LDFLAGS"
126    CPPFLAGS="-I$1/include $CPPFLAGS"
127    LDFLAGS="-L$1/$lib $LDFLAGS"
132 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
133 dnl -----------------------------
134 dnl Restore the stashed *FLAGS values.
135 AC_DEFUN([GIT_UNSTASH_FLAGS],[
136 if test -n "$1"; then
137    CPPFLAGS="$old_CPPFLAGS"
138    LDFLAGS="$old_LDFLAGS"
142 ## Configure body starts here.
144 AC_PREREQ(2.59)
145 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
147 AC_CONFIG_SRCDIR([git.c])
149 config_file=config.mak.autogen
150 config_in=config.mak.in
152 GIT_CONF_SUBST([AUTOCONFIGURED], [YesPlease])
154 # Directories holding "saner" versions of common or POSIX binaries.
155 AC_ARG_WITH([sane-tool-path],
156   [AS_HELP_STRING(
157     [--with-sane-tool-path=DIR-1[[:DIR-2...:DIR-n]]],
158     [Directories to prepend to PATH in build system and generated scripts])],
159   [if test "$withval" = "no"; then
160     withval=''
161   else
162     AC_MSG_NOTICE([Setting SANE_TOOL_PATH to '$withval'])
163   fi
164   GIT_CONF_SUBST([SANE_TOOL_PATH], [$withval])],
165   [# If the "--with-sane-tool-path" option was not given, don't touch
166    # SANE_TOOL_PATH here, but let defaults in Makefile take care of it.
167    # This should minimize spurious differences in the behaviour of the
168    # Git build system when configure is used w.r.t. when it is not.
169    :])
171 ## Site configuration related to programs (before tests)
172 ## --with-PACKAGE[=ARG] and --without-PACKAGE
174 # Set lib to alternative name of lib directory (e.g. lib64)
175 AC_ARG_WITH([lib],
176  [AS_HELP_STRING([--with-lib=ARG],
177                  [ARG specifies alternative name for lib directory])],
178  [if test "$withval" = "no" || test "$withval" = "yes"; then
179         AC_MSG_WARN([You should provide name for --with-lib=ARG])
180   else
181         lib=$withval
182         AC_MSG_NOTICE([Setting lib to '$lib'])
183         GIT_CONF_SUBST([lib])
184   fi])
186 if test -z "$lib"; then
187    AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
188    lib=lib
191 AC_ARG_ENABLE([pthreads],
192  [AS_HELP_STRING([--enable-pthreads=FLAGS],
193   [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
194   [The default if FLAGS is not specified is to try first -pthread]
195   [and then -lpthread.]
196   [--disable-pthreads will disable threading.])],
198 if test "x$enableval" = "xyes"; then
199    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
200 elif test "x$enableval" != "xno"; then
201    PTHREAD_CFLAGS=$enableval
202    AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
203 else
204    AC_MSG_NOTICE([POSIX Threads will be disabled.])
205    NO_PTHREADS=YesPlease
206    USER_NOPTHREAD=1
207 fi],
209    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
212 # Define option to enable JavaScript minification
213 AC_ARG_ENABLE([jsmin],
214 [AS_HELP_STRING([--enable-jsmin=PATH],
215   [PATH is the name of a JavaScript minifier or the absolute path to one.])],
217   JSMIN=$enableval;
218   AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
219   GIT_CONF_SUBST([JSMIN])
222 # Define option to enable CSS minification
223 AC_ARG_ENABLE([cssmin],
224 [AS_HELP_STRING([--enable-cssmin=PATH],
225   [PATH is the name of a CSS minifier or the absolute path to one.])],
227   CSSMIN=$enableval;
228   AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
229   GIT_CONF_SUBST([CSSMIN])
232 ## Site configuration (override autodetection)
233 ## --with-PACKAGE[=ARG] and --without-PACKAGE
234 AC_MSG_NOTICE([CHECKS for site configuration])
236 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
237 # tests.  These tests take up a significant amount of the total test time
238 # but are not needed unless you plan to talk to SVN repos.
240 # Define PPC_SHA1 environment variable when running make to make use of
241 # a bundled SHA1 routine optimized for PowerPC.
243 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
244 # This also implies BLK_SHA1.
246 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
247 # /foo/bar/include and /foo/bar/lib directories.
248 AC_ARG_WITH(openssl,
249 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
250 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),
251 GIT_PARSE_WITH([openssl]))
253 # Define USE_LIBPCRE if you have and want to use libpcre. git-grep will be
254 # able to use Perl-compatible regular expressions.
256 # Define LIBPCREDIR=/foo/bar if your libpcre header and library files are in
257 # /foo/bar/include and /foo/bar/lib directories.
259 AC_ARG_WITH(libpcre,
260 AS_HELP_STRING([--with-libpcre],[support Perl-compatible regexes (default is NO)])
261 AS_HELP_STRING([],           [ARG can be also prefix for libpcre library and headers]),
262     if test "$withval" = "no"; then
263         USE_LIBPCRE=
264     elif test "$withval" = "yes"; then
265         USE_LIBPCRE=YesPlease
266     else
267         USE_LIBPCRE=YesPlease
268         LIBPCREDIR=$withval
269         AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
270         dnl USE_LIBPCRE can still be modified below, so don't substitute
271         dnl it yet.
272         GIT_CONF_SUBST([LIBPCREDIR])
273     fi)
275 # Define HAVE_ALLOCA_H if you have working alloca(3) defined in that header.
276 AC_FUNC_ALLOCA
277 case $ac_cv_working_alloca_h in
278     yes)    HAVE_ALLOCA_H=YesPlease;;
279     *)      HAVE_ALLOCA_H='';;
280 esac
281 GIT_CONF_SUBST([HAVE_ALLOCA_H])
283 # Define NO_CURL if you do not have curl installed.  git-http-pull and
284 # git-http-push are not built, and you cannot use http:// and https://
285 # transports.
287 # Define CURLDIR=/foo/bar if your curl header and library files are in
288 # /foo/bar/include and /foo/bar/lib directories.
289 AC_ARG_WITH(curl,
290 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
291 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
292 GIT_PARSE_WITH(curl))
294 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
295 # not built, and you cannot push using http:// and https:// transports.
297 # Define EXPATDIR=/foo/bar if your expat header and library files are in
298 # /foo/bar/include and /foo/bar/lib directories.
299 AC_ARG_WITH(expat,
300 AS_HELP_STRING([--with-expat],
301 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
302 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
303 GIT_PARSE_WITH(expat))
305 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
306 # installed in /sw, but don't want GIT to link against any libraries
307 # installed there.  If defined you may specify your own (or Fink's)
308 # include directories and library directories by defining CFLAGS
309 # and LDFLAGS appropriately.
311 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
312 # have DarwinPorts installed in /opt/local, but don't want GIT to
313 # link against any libraries installed there.  If defined you may
314 # specify your own (or DarwinPort's) include directories and
315 # library directories by defining CFLAGS and LDFLAGS appropriately.
317 # Define NO_MMAP if you want to avoid mmap.
319 # Define NO_ICONV if your libc does not properly support iconv.
320 AC_ARG_WITH(iconv,
321 AS_HELP_STRING([--without-iconv],
322 [if your architecture doesn't properly support iconv])
323 AS_HELP_STRING([--with-iconv=PATH],
324 [PATH is prefix for libiconv library and headers])
325 AS_HELP_STRING([],
326 [used only if you need linking with libiconv]),
327 GIT_PARSE_WITH(iconv))
329 ## --enable-FEATURE[=ARG] and --disable-FEATURE
331 # Define USE_NSEC below if you want git to care about sub-second file mtimes
332 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
333 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
334 # randomly break unless your underlying filesystem supports those sub-second
335 # times (my ext3 doesn't).
337 # Define USE_STDEV below if you want git to care about the underlying device
338 # change being considered an inode change from the update-index perspective.
341 # Allow user to set ETC_GITCONFIG variable
342 GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
343                         Use VALUE instead of /etc/gitconfig as the
344                         global git configuration file.
345                         If VALUE is not fully qualified it will be interpreted
346                         as a path relative to the computed prefix at runtime.)
349 # Allow user to set ETC_GITATTRIBUTES variable
350 GIT_PARSE_WITH_SET_MAKE_VAR(gitattributes, ETC_GITATTRIBUTES,
351                         Use VALUE instead of /etc/gitattributes as the
352                         global git attributes file.
353                         If VALUE is not fully qualified it will be interpreted
354                         as a path relative to the computed prefix at runtime.)
357 # Allow user to set the default pager
358 GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
359                         Use VALUE as the fall-back pager instead of 'less'.
360                         This is used by things like 'git log' when the user
361                         does not specify a pager to use through alternate
362                         methods. eg: /usr/bin/pager)
364 # Allow user to set the default editor
365 GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
366                         Use VALUE as the fall-back editor instead of 'vi'.
367                         This is used by things like 'git commit' when the user
368                         does not specify a preferred editor through other
369                         methods. eg: /usr/bin/editor)
372 # Define SHELL_PATH to provide path to shell.
373 GIT_ARG_SET_PATH(shell)
375 # Define PERL_PATH to provide path to Perl.
376 GIT_ARG_SET_PATH(perl)
378 # Define PYTHON_PATH to provide path to Python.
379 GIT_ARG_SET_PATH(python, allow-without)
381 # Define ZLIB_PATH to provide path to zlib.
382 GIT_ARG_SET_PATH(zlib)
384 # Declare the with-tcltk/without-tcltk options.
385 AC_ARG_WITH(tcltk,
386 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
387 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
388 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
389 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),
390 GIT_PARSE_WITH(tcltk))
394 ## Checks for programs.
395 AC_MSG_NOTICE([CHECKS for programs])
397 AC_PROG_CC([cc gcc])
398 AC_C_INLINE
399 case $ac_cv_c_inline in
400   inline | yes | no) INLINE='';;
401   *)                 INLINE=$ac_cv_c_inline ;;
402 esac
403 GIT_CONF_SUBST([INLINE])
405 # which switch to pass runtime path to dynamic libraries to the linker
406 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
407    SAVE_LDFLAGS="${LDFLAGS}"
408    LDFLAGS="${SAVE_LDFLAGS} -R /"
409    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
410    LDFLAGS="${SAVE_LDFLAGS}"
412 if test "$git_cv_ld_dashr" = "yes"; then
413    CC_LD_DYNPATH=-R
414 else
415    AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
416       SAVE_LDFLAGS="${LDFLAGS}"
417       LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
418       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
419       LDFLAGS="${SAVE_LDFLAGS}"
420    ])
421    if test "$git_cv_ld_wl_rpath" = "yes"; then
422       CC_LD_DYNPATH=-Wl,-rpath,
423    else
424       AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
425          SAVE_LDFLAGS="${LDFLAGS}"
426          LDFLAGS="${SAVE_LDFLAGS} -rpath /"
427          AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
428          LDFLAGS="${SAVE_LDFLAGS}"
429       ])
430       if test "$git_cv_ld_rpath" = "yes"; then
431          CC_LD_DYNPATH=-rpath
432       else
433          CC_LD_DYNPATH=
434          AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
435       fi
436    fi
438 GIT_CONF_SUBST([CC_LD_DYNPATH])
439 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
440 AC_CHECK_TOOLS(AR, [gar ar], :)
441 AC_CHECK_PROGS(TAR, [gtar tar])
442 AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
443 # TCLTK_PATH will be set to some value if we want Tcl/Tk
444 # or will be empty otherwise.
445 if test -n "$NO_TCLTK"; then
446   TCLTK_PATH=
447 else
448   if test "$with_tcltk" = ""; then
449   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
450     TCLTK_PATH=wish
451   elif test "$with_tcltk" = "yes"; then
452   # Tcl/Tk check requested.
453     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
454   else
455     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
456     TCLTK_PATH="$with_tcltk"
457   fi
459 GIT_CONF_SUBST([TCLTK_PATH])
460 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
461 if test -n "$ASCIIDOC"; then
462         AC_MSG_CHECKING([for asciidoc version])
463         asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
464         case "${asciidoc_version}" in
465         asciidoc' '8*)
466                 AC_MSG_RESULT([${asciidoc_version}])
467                 ;;
468         *)
469                 AC_MSG_RESULT([${asciidoc_version} (unknown)])
470                 ;;
471         esac
475 ## Checks for libraries.
476 AC_MSG_NOTICE([CHECKS for libraries])
478 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
479 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
481 GIT_STASH_FLAGS($OPENSSLDIR)
483 AC_CHECK_LIB([crypto], [SHA1_Init],
484 [NEEDS_SSL_WITH_CRYPTO=],
485 [AC_CHECK_LIB([ssl], [SHA1_Init],
486  [NEEDS_SSL_WITH_CRYPTO=YesPlease NO_OPENSSL=],
487  [NEEDS_SSL_WITH_CRYPTO=          NO_OPENSSL=YesPlease])])
489 GIT_UNSTASH_FLAGS($OPENSSLDIR)
491 GIT_CONF_SUBST([NEEDS_SSL_WITH_CRYPTO])
492 GIT_CONF_SUBST([NO_OPENSSL])
495 # Define USE_LIBPCRE if you have and want to use libpcre. git-grep will be
496 # able to use Perl-compatible regular expressions.
499 if test -n "$USE_LIBPCRE"; then
501 GIT_STASH_FLAGS($LIBPCREDIR)
503 AC_CHECK_LIB([pcre], [pcre_version],
504 [USE_LIBPCRE=YesPlease],
505 [USE_LIBPCRE=])
507 GIT_UNSTASH_FLAGS($LIBPCREDIR)
509 GIT_CONF_SUBST([USE_LIBPCRE])
514 # Define NO_CURL if you do not have libcurl installed.  git-http-pull and
515 # git-http-push are not built, and you cannot use http:// and https://
516 # transports.
518 GIT_STASH_FLAGS($CURLDIR)
520 AC_CHECK_LIB([curl], [curl_global_init],
521 [NO_CURL=],
522 [NO_CURL=YesPlease])
524 GIT_UNSTASH_FLAGS($CURLDIR)
526 GIT_CONF_SUBST([NO_CURL])
529 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
530 # not built, and you cannot push using http:// and https:// transports.
532 GIT_STASH_FLAGS($EXPATDIR)
534 AC_CHECK_LIB([expat], [XML_ParserCreate],
535 [NO_EXPAT=],
536 [NO_EXPAT=YesPlease])
538 GIT_UNSTASH_FLAGS($EXPATDIR)
540 GIT_CONF_SUBST([NO_EXPAT])
543 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
544 # some Solaris installations).
545 # Define NO_ICONV if neither libc nor libiconv support iconv.
547 if test -z "$NO_ICONV"; then
549 GIT_STASH_FLAGS($ICONVDIR)
551 AC_DEFUN([ICONVTEST_SRC],
552 [AC_LANG_PROGRAM([#include <iconv.h>],
553  [iconv_open("", "");])])
555 if test -n "$ICONVDIR"; then
556    lib_order="-liconv -lc"
557 else
558    lib_order="-lc -liconv"
561 NO_ICONV=YesPlease
563 for l in $lib_order; do
564     if test "$l" = "-liconv"; then
565        NEEDS_LIBICONV=YesPlease
566     else
567        NEEDS_LIBICONV=
568     fi
570     old_LIBS="$LIBS"
571     LIBS="$LIBS $l"
572     AC_MSG_CHECKING([for iconv in $l])
573     AC_LINK_IFELSE([ICONVTEST_SRC],
574         [AC_MSG_RESULT([yes])
575         NO_ICONV=
576         break],
577         [AC_MSG_RESULT([no])])
578     LIBS="$old_LIBS"
579 done
581 #in case of break
582 LIBS="$old_LIBS"
584 GIT_UNSTASH_FLAGS($ICONVDIR)
586 GIT_CONF_SUBST([NEEDS_LIBICONV])
587 GIT_CONF_SUBST([NO_ICONV])
589 if test -n "$NO_ICONV"; then
590     NEEDS_LIBICONV=
596 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
598 GIT_STASH_FLAGS($ZLIB_PATH)
600 AC_DEFUN([ZLIBTEST_SRC], [
601 AC_LANG_PROGRAM([#include <zlib.h>],
602  [deflateBound(0, 0);])])
603 AC_MSG_CHECKING([for deflateBound in -lz])
604 old_LIBS="$LIBS"
605 LIBS="$LIBS -lz"
606 AC_LINK_IFELSE([ZLIBTEST_SRC],
607         [AC_MSG_RESULT([yes])],
608         [AC_MSG_RESULT([no])
609         NO_DEFLATE_BOUND=yes])
610 LIBS="$old_LIBS"
612 GIT_UNSTASH_FLAGS($ZLIB_PATH)
614 GIT_CONF_SUBST([NO_DEFLATE_BOUND])
617 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
618 # Patrick Mauritz).
619 AC_CHECK_LIB([c], [socket],
620 [NEEDS_SOCKET=],
621 [NEEDS_SOCKET=YesPlease])
622 GIT_CONF_SUBST([NEEDS_SOCKET])
623 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
626 # The next few tests will define NEEDS_RESOLV if linking with
627 # libresolv provides some of the functions we would normally get
628 # from libc.
629 NEEDS_RESOLV=
631 # Define NO_INET_NTOP if linking with -lresolv is not enough.
632 # Solaris 2.7 in particular hos inet_ntop in -lresolv.
633 NO_INET_NTOP=
634 AC_CHECK_FUNC([inet_ntop],
635     [],
636     [AC_CHECK_LIB([resolv], [inet_ntop],
637         [NEEDS_RESOLV=YesPlease],
638         [NO_INET_NTOP=YesPlease])
640 GIT_CONF_SUBST([NO_INET_NTOP])
642 # Define NO_INET_PTON if linking with -lresolv is not enough.
643 # Solaris 2.7 in particular hos inet_pton in -lresolv.
644 NO_INET_PTON=
645 AC_CHECK_FUNC([inet_pton],
646     [],
647     [AC_CHECK_LIB([resolv], [inet_pton],
648         [NEEDS_RESOLV=YesPlease],
649         [NO_INET_PTON=YesPlease])
651 GIT_CONF_SUBST([NO_INET_PTON])
653 # Define NO_HSTRERROR if linking with -lresolv is not enough.
654 # Solaris 2.6 in particular has no hstrerror, even in -lresolv.
655 NO_HSTRERROR=
656 AC_CHECK_FUNC([hstrerror],
657     [],
658     [AC_CHECK_LIB([resolv], [hstrerror],
659         [NEEDS_RESOLV=YesPlease],
660         [NO_HSTRERROR=YesPlease])
662 GIT_CONF_SUBST([NO_HSTRERROR])
664 dnl This must go after all the possible places for its initialization,
665 dnl in the AC_CHECK_FUNC invocations above.
666 GIT_CONF_SUBST([NEEDS_RESOLV])
668 # If any of the above tests determined that -lresolv is needed at
669 # build-time, also set it here for remaining configure-time checks.
670 test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
672 AC_CHECK_LIB([c], [basename],
673 [NEEDS_LIBGEN=],
674 [NEEDS_LIBGEN=YesPlease])
675 GIT_CONF_SUBST([NEEDS_LIBGEN])
676 test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
678 AC_CHECK_LIB([c], [gettext],
679 [LIBC_CONTAINS_LIBINTL=YesPlease],
680 [LIBC_CONTAINS_LIBINTL=])
681 GIT_CONF_SUBST([LIBC_CONTAINS_LIBINTL])
684 # Define NO_GETTEXT if you don't want Git output to be translated.
685 # A translated Git requires GNU libintl or another gettext implementation
686 AC_CHECK_HEADER([libintl.h],
687 [NO_GETTEXT=],
688 [NO_GETTEXT=YesPlease])
689 GIT_CONF_SUBST([NO_GETTEXT])
691 if test -z "$NO_GETTEXT"; then
692     test -n "$LIBC_CONTAINS_LIBINTL" || LIBS="$LIBS -lintl"
695 ## Checks for header files.
696 AC_MSG_NOTICE([CHECKS for header files])
698 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
699 AC_CHECK_HEADER([sys/select.h],
700 [NO_SYS_SELECT_H=],
701 [NO_SYS_SELECT_H=UnfortunatelyYes])
702 GIT_CONF_SUBST([NO_SYS_SELECT_H])
704 # Define NO_SYS_POLL_H if you don't have sys/poll.h
705 AC_CHECK_HEADER([sys/poll.h],
706 [NO_SYS_POLL_H=],
707 [NO_SYS_POLL_H=UnfortunatelyYes])
708 GIT_CONF_SUBST([NO_SYS_POLL_H])
710 # Define NO_INTTYPES_H if you don't have inttypes.h
711 AC_CHECK_HEADER([inttypes.h],
712 [NO_INTTYPES_H=],
713 [NO_INTTYPES_H=UnfortunatelyYes])
714 GIT_CONF_SUBST([NO_INTTYPES_H])
716 # Define OLD_ICONV if your library has an old iconv(), where the second
717 # (input buffer pointer) parameter is declared with type (const char **).
718 AC_DEFUN([OLDICONVTEST_SRC], [
719 AC_LANG_PROGRAM([[
720 #include <iconv.h>
722 extern size_t iconv(iconv_t cd,
723                     char **inbuf, size_t *inbytesleft,
724                     char **outbuf, size_t *outbytesleft);
725 ]], [])])
727 GIT_STASH_FLAGS($ICONVDIR)
729 AC_MSG_CHECKING([for old iconv()])
730 AC_COMPILE_IFELSE([OLDICONVTEST_SRC],
731         [AC_MSG_RESULT([no])],
732         [AC_MSG_RESULT([yes])
733         OLD_ICONV=UnfortunatelyYes])
735 GIT_UNSTASH_FLAGS($ICONVDIR)
737 GIT_CONF_SUBST([OLD_ICONV])
739 ## Checks for typedefs, structures, and compiler characteristics.
740 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
742 TYPE_SOCKLEN_T
743 case $ac_cv_type_socklen_t in
744   yes)  SOCKLEN_T='';;
745   *)    SOCKLEN_T=$git_cv_socklen_t_equiv;;
746 esac
747 GIT_CONF_SUBST([SOCKLEN_T])
749 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
750 AC_CHECK_MEMBER(struct dirent.d_ino,
751 [NO_D_INO_IN_DIRENT=],
752 [NO_D_INO_IN_DIRENT=YesPlease],
753 [#include <dirent.h>])
754 GIT_CONF_SUBST([NO_D_INO_IN_DIRENT])
756 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
757 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
758 AC_CHECK_MEMBER(struct dirent.d_type,
759 [NO_D_TYPE_IN_DIRENT=],
760 [NO_D_TYPE_IN_DIRENT=YesPlease],
761 [#include <dirent.h>])
762 GIT_CONF_SUBST([NO_D_TYPE_IN_DIRENT])
764 # Define NO_GECOS_IN_PWENT if you don't have pw_gecos in struct passwd
765 # in the C library.
766 AC_CHECK_MEMBER(struct passwd.pw_gecos,
767 [NO_GECOS_IN_PWENT=],
768 [NO_GECOS_IN_PWENT=YesPlease],
769 [#include <pwd.h>])
770 GIT_CONF_SUBST([NO_GECOS_IN_PWENT])
772 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
773 # sockaddr_storage.
774 AC_CHECK_TYPE(struct sockaddr_storage,
775 [NO_SOCKADDR_STORAGE=],
776 [NO_SOCKADDR_STORAGE=YesPlease],[
777 #include <sys/types.h>
778 #include <sys/socket.h>
780 GIT_CONF_SUBST([NO_SOCKADDR_STORAGE])
782 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
783 AC_CHECK_TYPE([struct addrinfo],[
784  GIT_CHECK_FUNC([getaddrinfo],
785   [NO_IPV6=],
786   [NO_IPV6=YesPlease])
787 ],[NO_IPV6=YesPlease],[
788 #include <sys/types.h>
789 #include <sys/socket.h>
790 #include <netdb.h>
792 GIT_CONF_SUBST([NO_IPV6])
794 # Define NO_REGEX if you have no or inferior regex support in your C library.
795 AC_CACHE_CHECK([whether the platform regex can handle null bytes],
796  [ac_cv_c_excellent_regex], [
797 AC_EGREP_CPP(yippeeyeswehaveit,
798         AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
799 #include <regex.h>
801 [#ifdef REG_STARTEND
802 yippeeyeswehaveit
803 #endif
805         [ac_cv_c_excellent_regex=yes],
806         [ac_cv_c_excellent_regex=no])
808 if test $ac_cv_c_excellent_regex = yes; then
809         NO_REGEX=
810 else
811         NO_REGEX=YesPlease
813 GIT_CONF_SUBST([NO_REGEX])
815 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
816 # when attempting to read from an fopen'ed directory.
817 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
818  [ac_cv_fread_reads_directories],
820 AC_RUN_IFELSE(
821         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
822                 [[char c;
823                 FILE *f = fopen(".", "r");
824                 return f && fread(&c, 1, 1, f)]])],
825         [ac_cv_fread_reads_directories=no],
826         [ac_cv_fread_reads_directories=yes])
828 if test $ac_cv_fread_reads_directories = yes; then
829         FREAD_READS_DIRECTORIES=UnfortunatelyYes
830 else
831         FREAD_READS_DIRECTORIES=
833 GIT_CONF_SUBST([FREAD_READS_DIRECTORIES])
835 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
836 # or vsnprintf() return -1 instead of number of characters which would
837 # have been written to the final string if enough space had been available.
838 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
839  [ac_cv_snprintf_returns_bogus],
841 AC_RUN_IFELSE(
842         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
843                 #include "stdarg.h"
845                 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
846                 {
847                   int ret;
848                   va_list ap;
849                   va_start(ap, format);
850                   ret = vsnprintf(str, maxsize, format, ap);
851                   va_end(ap);
852                   return ret;
853                 }],
854                 [[char buf[6];
855                   if (test_vsnprintf(buf, 3, "%s", "12345") != 5
856                       || strcmp(buf, "12")) return 1;
857                   if (snprintf(buf, 3, "%s", "12345") != 5
858                       || strcmp(buf, "12")) return 1]])],
859         [ac_cv_snprintf_returns_bogus=no],
860         [ac_cv_snprintf_returns_bogus=yes])
862 if test $ac_cv_snprintf_returns_bogus = yes; then
863         SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
864 else
865         SNPRINTF_RETURNS_BOGUS=
867 GIT_CONF_SUBST([SNPRINTF_RETURNS_BOGUS])
870 ## Checks for library functions.
871 ## (in default C library and libraries checked by AC_CHECK_LIB)
872 AC_MSG_NOTICE([CHECKS for library functions])
874 # Define NO_LIBGEN_H if you don't have libgen.h.
875 AC_CHECK_HEADER([libgen.h],
876 [NO_LIBGEN_H=],
877 [NO_LIBGEN_H=YesPlease])
878 GIT_CONF_SUBST([NO_LIBGEN_H])
880 # Define HAVE_PATHS_H if you have paths.h.
881 AC_CHECK_HEADER([paths.h],
882 [HAVE_PATHS_H=YesPlease],
883 [HAVE_PATHS_H=])
884 GIT_CONF_SUBST([HAVE_PATHS_H])
886 # Define HAVE_LIBCHARSET_H if have libcharset.h
887 AC_CHECK_HEADER([libcharset.h],
888 [HAVE_LIBCHARSET_H=YesPlease],
889 [HAVE_LIBCHARSET_H=])
890 GIT_CONF_SUBST([HAVE_LIBCHARSET_H])
892 # Define HAVE_STRINGS_H if you have strings.h
893 AC_CHECK_HEADER([strings.h],
894 [HAVE_STRINGS_H=YesPlease],
895 [HAVE_STRINGS_H=])
896 GIT_CONF_SUBST([HAVE_STRINGS_H])
897 # Define CHARSET_LIB if libiconv does not export the locale_charset symbol
898 # and libcharset does
899 CHARSET_LIB=
900 AC_CHECK_LIB([iconv], [locale_charset],
901        [CHARSET_LIB=-liconv],
902        [AC_CHECK_LIB([charset], [locale_charset],
903                      [CHARSET_LIB=-lcharset])])
904 GIT_CONF_SUBST([CHARSET_LIB])
906 # Define NO_STRCASESTR if you don't have strcasestr.
907 GIT_CHECK_FUNC(strcasestr,
908 [NO_STRCASESTR=],
909 [NO_STRCASESTR=YesPlease])
910 GIT_CONF_SUBST([NO_STRCASESTR])
912 # Define NO_MEMMEM if you don't have memmem.
913 GIT_CHECK_FUNC(memmem,
914 [NO_MEMMEM=],
915 [NO_MEMMEM=YesPlease])
916 GIT_CONF_SUBST([NO_MEMMEM])
918 # Define NO_STRLCPY if you don't have strlcpy.
919 GIT_CHECK_FUNC(strlcpy,
920 [NO_STRLCPY=],
921 [NO_STRLCPY=YesPlease])
922 GIT_CONF_SUBST([NO_STRLCPY])
924 # Define NO_UINTMAX_T if your platform does not have uintmax_t
925 AC_CHECK_TYPE(uintmax_t,
926 [NO_UINTMAX_T=],
927 [NO_UINTMAX_T=YesPlease],[
928 #include <inttypes.h>
930 GIT_CONF_SUBST([NO_UINTMAX_T])
932 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
933 GIT_CHECK_FUNC(strtoumax,
934 [NO_STRTOUMAX=],
935 [NO_STRTOUMAX=YesPlease])
936 GIT_CONF_SUBST([NO_STRTOUMAX])
938 # Define NO_SETENV if you don't have setenv in the C library.
939 GIT_CHECK_FUNC(setenv,
940 [NO_SETENV=],
941 [NO_SETENV=YesPlease])
942 GIT_CONF_SUBST([NO_SETENV])
944 # Define NO_UNSETENV if you don't have unsetenv in the C library.
945 GIT_CHECK_FUNC(unsetenv,
946 [NO_UNSETENV=],
947 [NO_UNSETENV=YesPlease])
948 GIT_CONF_SUBST([NO_UNSETENV])
950 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
951 GIT_CHECK_FUNC(mkdtemp,
952 [NO_MKDTEMP=],
953 [NO_MKDTEMP=YesPlease])
954 GIT_CONF_SUBST([NO_MKDTEMP])
956 # Define NO_MKSTEMPS if you don't have mkstemps in the C library.
957 GIT_CHECK_FUNC(mkstemps,
958 [NO_MKSTEMPS=],
959 [NO_MKSTEMPS=YesPlease])
960 GIT_CONF_SUBST([NO_MKSTEMPS])
962 # Define NO_INITGROUPS if you don't have initgroups in the C library.
963 GIT_CHECK_FUNC(initgroups,
964 [NO_INITGROUPS=],
965 [NO_INITGROUPS=YesPlease])
966 GIT_CONF_SUBST([NO_INITGROUPS])
969 # Define NO_MMAP if you want to avoid mmap.
971 # Define NO_ICONV if your libc does not properly support iconv.
974 ## Other checks.
975 # Define USE_PIC if you need the main git objects to be built with -fPIC
976 # in order to build and link perl/Git.so.  x86-64 seems to need this.
978 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
979 # Enable it on Windows.  By default, symrefs are still used.
981 # Define NO_PTHREADS if we do not have pthreads.
983 # Define PTHREAD_LIBS to the linker flag used for Pthread support.
984 AC_DEFUN([PTHREADTEST_SRC], [
985 AC_LANG_PROGRAM([[
986 #include <pthread.h>
987 ]], [[
988         pthread_mutex_t test_mutex;
989         pthread_key_t test_key;
990         int retcode = 0;
991         retcode |= pthread_key_create(&test_key, (void *)0);
992         retcode |= pthread_mutex_init(&test_mutex,(void *)0);
993         retcode |= pthread_mutex_lock(&test_mutex);
994         retcode |= pthread_mutex_unlock(&test_mutex);
995         return retcode;
996 ]])])
998 dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
999 dnl   [[#include <pthread.h>]],
1000 dnl   [[pthread_mutex_t test_mutex;]]
1001 dnl )])
1003 NO_PTHREADS=UnfortunatelyYes
1004 PTHREAD_LIBS=
1006 if test -n "$USER_NOPTHREAD"; then
1007    AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
1008 # handle these separately since PTHREAD_CFLAGS could be '-lpthreads
1009 # -D_REENTRANT' or some such.
1010 elif test -z "$PTHREAD_CFLAGS"; then
1011   threads_found=no
1012   # Attempt to compile and link some code using pthreads to determine
1013   # required linker flags. The order is somewhat important here: We
1014   # first try it without any extra flags, to catch systems where
1015   # pthreads are part of the C library, then go on testing various other
1016   # flags. We do so to avoid false positives. For example, on Mac OS X
1017   # pthreads are part of the C library; moreover, the compiler allows us
1018   # to add "-mt" to the CFLAGS (although it will do nothing except
1019   # trigger a warning about an unused flag). Hence if we checked for
1020   # "-mt" before "" we would end up picking it. But unfortunately this
1021   # would then trigger compiler warnings on every single file we compile.
1022   for opt in "" -mt -pthread -lpthread; do
1023      old_CFLAGS="$CFLAGS"
1024      CFLAGS="$opt $CFLAGS"
1025      AC_MSG_CHECKING([for POSIX Threads with '$opt'])
1026      AC_LINK_IFELSE([PTHREADTEST_SRC],
1027         [AC_MSG_RESULT([yes])
1028                 NO_PTHREADS=
1029                 PTHREAD_LIBS="$opt"
1030                 PTHREAD_CFLAGS="$opt"
1031                 threads_found=yes
1032                 break
1033         ],
1034         [AC_MSG_RESULT([no])])
1035       CFLAGS="$old_CFLAGS"
1036   done
1037   if test $threads_found != yes; then
1038     AC_CHECK_LIB([pthread], [pthread_create],
1039         [PTHREAD_LIBS="-lpthread"],
1040         [NO_PTHREADS=UnfortunatelyYes])
1041   fi
1042 else
1043   old_CFLAGS="$CFLAGS"
1044   CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1045   AC_MSG_CHECKING([for POSIX Threads with '$PTHREAD_CFLAGS'])
1046   AC_LINK_IFELSE([PTHREADTEST_SRC],
1047         [AC_MSG_RESULT([yes])
1048                 NO_PTHREADS=
1049                 PTHREAD_LIBS="$PTHREAD_CFLAGS"
1050         ],
1051         [AC_MSG_RESULT([no])])
1053   CFLAGS="$old_CFLAGS"
1056 CFLAGS="$old_CFLAGS"
1058 GIT_CONF_SUBST([PTHREAD_CFLAGS])
1059 GIT_CONF_SUBST([PTHREAD_LIBS])
1060 GIT_CONF_SUBST([NO_PTHREADS])
1062 ## Output files
1063 AC_CONFIG_FILES(["${config_file}":"${config_in}"])
1064 AC_OUTPUT