git-multimail: update to release 1.2.0
[git.git] / git-difftool.perl
blob7df7c8a9a7c889fbf5f0b2d6e67be66bf6fea6b1
1 #!/usr/bin/perl
2 # Copyright (c) 2009, 2010 David Aguilar
3 # Copyright (c) 2012 Tim Henigan
5 # This is a wrapper around the GIT_EXTERNAL_DIFF-compatible
6 # git-difftool--helper script.
8 # This script exports GIT_EXTERNAL_DIFF and GIT_PAGER for use by git.
9 # The GIT_DIFF* variables are exported for use by git-difftool--helper.
11 # Any arguments that are unknown to this script are forwarded to 'git diff'.
13 use 5.008;
14 use strict;
15 use warnings;
16 use Error qw(:try);
17 use File::Basename qw(dirname);
18 use File::Copy;
19 use File::Find;
20 use File::stat;
21 use File::Path qw(mkpath rmtree);
22 use File::Temp qw(tempdir);
23 use Getopt::Long qw(:config pass_through);
24 use Git;
26 sub usage
28 my $exitcode = shift;
29 print << 'USAGE';
30 usage: git difftool [-t|--tool=<tool>] [--tool-help]
31 [-x|--extcmd=<cmd>]
32 [-g|--gui] [--no-gui]
33 [--prompt] [-y|--no-prompt]
34 [-d|--dir-diff]
35 ['git diff' options]
36 USAGE
37 exit($exitcode);
40 sub find_worktree
42 # Git->repository->wc_path() does not honor changes to the working
43 # tree location made by $ENV{GIT_WORK_TREE} or the 'core.worktree'
44 # config variable.
45 return Git::command_oneline('rev-parse', '--show-toplevel');
48 sub print_tool_help
50 # See the comment at the bottom of file_diff() for the reason behind
51 # using system() followed by exit() instead of exec().
52 my $rc = system(qw(git mergetool --tool-help=diff));
53 exit($rc | ($rc >> 8));
56 sub exit_cleanup
58 my ($tmpdir, $status) = @_;
59 my $errno = $!;
60 rmtree($tmpdir);
61 if ($status and $errno) {
62 my ($package, $file, $line) = caller();
63 warn "$file line $line: $errno\n";
65 exit($status | ($status >> 8));
68 sub use_wt_file
70 my ($repo, $workdir, $file, $sha1) = @_;
71 my $null_sha1 = '0' x 40;
73 if (! -e "$workdir/$file") {
74 # If the file doesn't exist in the working tree, we cannot
75 # use it.
76 return (0, $null_sha1);
79 my $wt_sha1 = $repo->command_oneline('hash-object', "$workdir/$file");
80 my $use = ($sha1 eq $null_sha1) || ($sha1 eq $wt_sha1);
81 return ($use, $wt_sha1);
84 sub changed_files
86 my ($repo_path, $index, $worktree) = @_;
87 $ENV{GIT_INDEX_FILE} = $index;
88 $ENV{GIT_WORK_TREE} = $worktree;
89 my $must_unset_git_dir = 0;
90 if (not defined($ENV{GIT_DIR})) {
91 $must_unset_git_dir = 1;
92 $ENV{GIT_DIR} = $repo_path;
95 my @refreshargs = qw/update-index --really-refresh -q --unmerged/;
96 my @gitargs = qw/diff-files --name-only -z/;
97 try {
98 Git::command_oneline(@refreshargs);
99 } catch Git::Error::Command with {};
101 my $line = Git::command_oneline(@gitargs);
102 my @files;
103 if (defined $line) {
104 @files = split('\0', $line);
105 } else {
106 @files = ();
109 delete($ENV{GIT_INDEX_FILE});
110 delete($ENV{GIT_WORK_TREE});
111 delete($ENV{GIT_DIR}) if ($must_unset_git_dir);
113 return map { $_ => 1 } @files;
116 sub setup_dir_diff
118 my ($repo, $workdir, $symlinks) = @_;
120 # Run the diff; exit immediately if no diff found
121 # 'Repository' and 'WorkingCopy' must be explicitly set to insure that
122 # if $GIT_DIR and $GIT_WORK_TREE are set in ENV, they are actually used
123 # by Git->repository->command*.
124 my $repo_path = $repo->repo_path();
125 my %repo_args = (Repository => $repo_path, WorkingCopy => $workdir);
126 my $diffrepo = Git->repository(%repo_args);
128 my @gitargs = ('diff', '--raw', '--no-abbrev', '-z', @ARGV);
129 my $diffrtn = $diffrepo->command_oneline(@gitargs);
130 exit(0) unless defined($diffrtn);
132 # Build index info for left and right sides of the diff
133 my $submodule_mode = '160000';
134 my $symlink_mode = '120000';
135 my $null_mode = '0' x 6;
136 my $null_sha1 = '0' x 40;
137 my $lindex = '';
138 my $rindex = '';
139 my $wtindex = '';
140 my %submodule;
141 my %symlink;
142 my @working_tree = ();
143 my @rawdiff = split('\0', $diffrtn);
145 my $i = 0;
146 while ($i < $#rawdiff) {
147 if ($rawdiff[$i] =~ /^::/) {
148 warn << 'EOF';
149 Combined diff formats ('-c' and '--cc') are not supported in
150 directory diff mode ('-d' and '--dir-diff').
152 exit(1);
155 my ($lmode, $rmode, $lsha1, $rsha1, $status) =
156 split(' ', substr($rawdiff[$i], 1));
157 my $src_path = $rawdiff[$i + 1];
158 my $dst_path;
160 if ($status =~ /^[CR]/) {
161 $dst_path = $rawdiff[$i + 2];
162 $i += 3;
163 } else {
164 $dst_path = $src_path;
165 $i += 2;
168 if ($lmode eq $submodule_mode or $rmode eq $submodule_mode) {
169 $submodule{$src_path}{left} = $lsha1;
170 if ($lsha1 ne $rsha1) {
171 $submodule{$dst_path}{right} = $rsha1;
172 } else {
173 $submodule{$dst_path}{right} = "$rsha1-dirty";
175 next;
178 if ($lmode eq $symlink_mode) {
179 $symlink{$src_path}{left} =
180 $diffrepo->command_oneline('show', "$lsha1");
183 if ($rmode eq $symlink_mode) {
184 $symlink{$dst_path}{right} =
185 $diffrepo->command_oneline('show', "$rsha1");
188 if ($lmode ne $null_mode and $status !~ /^C/) {
189 $lindex .= "$lmode $lsha1\t$src_path\0";
192 if ($rmode ne $null_mode) {
193 my ($use, $wt_sha1) = use_wt_file($repo, $workdir,
194 $dst_path, $rsha1);
195 if ($use) {
196 push @working_tree, $dst_path;
197 $wtindex .= "$rmode $wt_sha1\t$dst_path\0";
198 } else {
199 $rindex .= "$rmode $rsha1\t$dst_path\0";
204 # Setup temp directories
205 my $tmpdir = tempdir('git-difftool.XXXXX', CLEANUP => 0, TMPDIR => 1);
206 my $ldir = "$tmpdir/left";
207 my $rdir = "$tmpdir/right";
208 mkpath($ldir) or exit_cleanup($tmpdir, 1);
209 mkpath($rdir) or exit_cleanup($tmpdir, 1);
211 # If $GIT_DIR is not set prior to calling 'git update-index' and
212 # 'git checkout-index', then those commands will fail if difftool
213 # is called from a directory other than the repo root.
214 my $must_unset_git_dir = 0;
215 if (not defined($ENV{GIT_DIR})) {
216 $must_unset_git_dir = 1;
217 $ENV{GIT_DIR} = $repo_path;
220 # Populate the left and right directories based on each index file
221 my ($inpipe, $ctx);
222 $ENV{GIT_INDEX_FILE} = "$tmpdir/lindex";
223 ($inpipe, $ctx) =
224 $repo->command_input_pipe(qw(update-index -z --index-info));
225 print($inpipe $lindex);
226 $repo->command_close_pipe($inpipe, $ctx);
228 my $rc = system('git', 'checkout-index', '--all', "--prefix=$ldir/");
229 exit_cleanup($tmpdir, $rc) if $rc != 0;
231 $ENV{GIT_INDEX_FILE} = "$tmpdir/rindex";
232 ($inpipe, $ctx) =
233 $repo->command_input_pipe(qw(update-index -z --index-info));
234 print($inpipe $rindex);
235 $repo->command_close_pipe($inpipe, $ctx);
237 $rc = system('git', 'checkout-index', '--all', "--prefix=$rdir/");
238 exit_cleanup($tmpdir, $rc) if $rc != 0;
240 $ENV{GIT_INDEX_FILE} = "$tmpdir/wtindex";
241 ($inpipe, $ctx) =
242 $repo->command_input_pipe(qw(update-index --info-only -z --index-info));
243 print($inpipe $wtindex);
244 $repo->command_close_pipe($inpipe, $ctx);
246 # If $GIT_DIR was explicitly set just for the update/checkout
247 # commands, then it should be unset before continuing.
248 delete($ENV{GIT_DIR}) if ($must_unset_git_dir);
249 delete($ENV{GIT_INDEX_FILE});
251 # Changes in the working tree need special treatment since they are
252 # not part of the index. Remove any trailing slash from $workdir
253 # before starting to avoid double slashes in symlink targets.
254 $workdir =~ s|/$||;
255 for my $file (@working_tree) {
256 my $dir = dirname($file);
257 unless (-d "$rdir/$dir") {
258 mkpath("$rdir/$dir") or
259 exit_cleanup($tmpdir, 1);
261 if ($symlinks) {
262 symlink("$workdir/$file", "$rdir/$file") or
263 exit_cleanup($tmpdir, 1);
264 } else {
265 copy("$workdir/$file", "$rdir/$file") or
266 exit_cleanup($tmpdir, 1);
268 my $mode = stat("$workdir/$file")->mode;
269 chmod($mode, "$rdir/$file") or
270 exit_cleanup($tmpdir, 1);
274 # Changes to submodules require special treatment. This loop writes a
275 # temporary file to both the left and right directories to show the
276 # change in the recorded SHA1 for the submodule.
277 for my $path (keys %submodule) {
278 my $ok;
279 if (defined($submodule{$path}{left})) {
280 $ok = write_to_file("$ldir/$path",
281 "Subproject commit $submodule{$path}{left}");
283 if (defined($submodule{$path}{right})) {
284 $ok = write_to_file("$rdir/$path",
285 "Subproject commit $submodule{$path}{right}");
287 exit_cleanup($tmpdir, 1) if not $ok;
290 # Symbolic links require special treatment. The standard "git diff"
291 # shows only the link itself, not the contents of the link target.
292 # This loop replicates that behavior.
293 for my $path (keys %symlink) {
294 my $ok;
295 if (defined($symlink{$path}{left})) {
296 $ok = write_to_file("$ldir/$path",
297 $symlink{$path}{left});
299 if (defined($symlink{$path}{right})) {
300 $ok = write_to_file("$rdir/$path",
301 $symlink{$path}{right});
303 exit_cleanup($tmpdir, 1) if not $ok;
306 return ($ldir, $rdir, $tmpdir, @working_tree);
309 sub write_to_file
311 my $path = shift;
312 my $value = shift;
314 # Make sure the path to the file exists
315 my $dir = dirname($path);
316 unless (-d "$dir") {
317 mkpath("$dir") or return 0;
320 # If the file already exists in that location, delete it. This
321 # is required in the case of symbolic links.
322 unlink($path);
324 open(my $fh, '>', $path) or return 0;
325 print($fh $value);
326 close($fh);
328 return 1;
331 sub main
333 # parse command-line options. all unrecognized options and arguments
334 # are passed through to the 'git diff' command.
335 my %opts = (
336 difftool_cmd => undef,
337 dirdiff => undef,
338 extcmd => undef,
339 gui => undef,
340 help => undef,
341 prompt => undef,
342 symlinks => $^O ne 'cygwin' &&
343 $^O ne 'MSWin32' && $^O ne 'msys',
344 tool_help => undef,
345 trust_exit_code => undef,
347 GetOptions('g|gui!' => \$opts{gui},
348 'd|dir-diff' => \$opts{dirdiff},
349 'h' => \$opts{help},
350 'prompt!' => \$opts{prompt},
351 'y' => sub { $opts{prompt} = 0; },
352 'symlinks' => \$opts{symlinks},
353 'no-symlinks' => sub { $opts{symlinks} = 0; },
354 't|tool:s' => \$opts{difftool_cmd},
355 'tool-help' => \$opts{tool_help},
356 'trust-exit-code' => \$opts{trust_exit_code},
357 'no-trust-exit-code' => sub { $opts{trust_exit_code} = 0; },
358 'x|extcmd:s' => \$opts{extcmd});
360 if (defined($opts{help})) {
361 usage(0);
363 if (defined($opts{tool_help})) {
364 print_tool_help();
366 if (defined($opts{difftool_cmd})) {
367 if (length($opts{difftool_cmd}) > 0) {
368 $ENV{GIT_DIFF_TOOL} = $opts{difftool_cmd};
369 } else {
370 print "No <tool> given for --tool=<tool>\n";
371 usage(1);
374 if (defined($opts{extcmd})) {
375 if (length($opts{extcmd}) > 0) {
376 $ENV{GIT_DIFFTOOL_EXTCMD} = $opts{extcmd};
377 } else {
378 print "No <cmd> given for --extcmd=<cmd>\n";
379 usage(1);
382 if ($opts{gui}) {
383 my $guitool = Git::config('diff.guitool');
384 if (defined($guitool) && length($guitool) > 0) {
385 $ENV{GIT_DIFF_TOOL} = $guitool;
389 if (!defined $opts{trust_exit_code}) {
390 $opts{trust_exit_code} = Git::config_bool('difftool.trustExitCode');
392 if ($opts{trust_exit_code}) {
393 $ENV{GIT_DIFFTOOL_TRUST_EXIT_CODE} = 'true';
394 } else {
395 $ENV{GIT_DIFFTOOL_TRUST_EXIT_CODE} = 'false';
398 # In directory diff mode, 'git-difftool--helper' is called once
399 # to compare the a/b directories. In file diff mode, 'git diff'
400 # will invoke a separate instance of 'git-difftool--helper' for
401 # each file that changed.
402 if (defined($opts{dirdiff})) {
403 dir_diff($opts{extcmd}, $opts{symlinks});
404 } else {
405 file_diff($opts{prompt});
409 sub dir_diff
411 my ($extcmd, $symlinks) = @_;
412 my $rc;
413 my $error = 0;
414 my $repo = Git->repository();
415 my $workdir = find_worktree();
416 my ($a, $b, $tmpdir, @worktree) =
417 setup_dir_diff($repo, $workdir, $symlinks);
419 if (defined($extcmd)) {
420 $rc = system($extcmd, $a, $b);
421 } else {
422 $ENV{GIT_DIFFTOOL_DIRDIFF} = 'true';
423 $rc = system('git', 'difftool--helper', $a, $b);
425 # If the diff including working copy files and those
426 # files were modified during the diff, then the changes
427 # should be copied back to the working tree.
428 # Do not copy back files when symlinks are used and the
429 # external tool did not replace the original link with a file.
431 # These hashes are loaded lazily since they aren't needed
432 # in the common case of --symlinks and the difftool updating
433 # files through the symlink.
434 my %wt_modified;
435 my %tmp_modified;
436 my $indices_loaded = 0;
438 for my $file (@worktree) {
439 next if $symlinks && -l "$b/$file";
440 next if ! -f "$b/$file";
442 if (!$indices_loaded) {
443 %wt_modified = changed_files($repo->repo_path(),
444 "$tmpdir/wtindex", "$workdir");
445 %tmp_modified = changed_files($repo->repo_path(),
446 "$tmpdir/wtindex", "$b");
447 $indices_loaded = 1;
450 if (exists $wt_modified{$file} and exists $tmp_modified{$file}) {
451 my $errmsg = "warning: Both files modified: ";
452 $errmsg .= "'$workdir/$file' and '$b/$file'.\n";
453 $errmsg .= "warning: Working tree file has been left.\n";
454 $errmsg .= "warning:\n";
455 warn $errmsg;
456 $error = 1;
457 } elsif (exists $tmp_modified{$file}) {
458 my $mode = stat("$b/$file")->mode;
459 copy("$b/$file", "$workdir/$file") or
460 exit_cleanup($tmpdir, 1);
462 chmod($mode, "$workdir/$file") or
463 exit_cleanup($tmpdir, 1);
466 if ($error) {
467 warn "warning: Temporary files exist in '$tmpdir'.\n";
468 warn "warning: You may want to cleanup or recover these.\n";
469 exit(1);
470 } else {
471 exit_cleanup($tmpdir, $rc);
475 sub file_diff
477 my ($prompt) = @_;
479 if (defined($prompt)) {
480 if ($prompt) {
481 $ENV{GIT_DIFFTOOL_PROMPT} = 'true';
482 } else {
483 $ENV{GIT_DIFFTOOL_NO_PROMPT} = 'true';
487 $ENV{GIT_PAGER} = '';
488 $ENV{GIT_EXTERNAL_DIFF} = 'git-difftool--helper';
490 # ActiveState Perl for Win32 does not implement POSIX semantics of
491 # exec* system call. It just spawns the given executable and finishes
492 # the starting program, exiting with code 0.
493 # system will at least catch the errors returned by git diff,
494 # allowing the caller of git difftool better handling of failures.
495 my $rc = system('git', 'diff', @ARGV);
496 exit($rc | ($rc >> 8));
499 main();